extra/visionect/visionect.factor

   1 ! Copyright (C) 2020 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: accessors assocs base64 calendar calendar.format
   4 checksums.hmac checksums.sha combinators formatting http
   5 http.client json.reader json.writer kernel math.parser
   6 namespaces sequences ;
   7 IN: visionect
   8
   9 SYMBOL: visionect-base-url
  10 visionect-base-url [ "http://localhost:8081" ] initialize
  11
  12 SYMBOL: visionect-api-key
  13
  14 SYMBOL: visionect-api-secret
  15
  16 <PRIVATE
  17
  18 : visionect-authorization ( verb date path -- auth )
  19     "%s\n\n\n%s\n%s" sprintf visionect-api-secret get sha-256
  20     hmac-bytes >base64 visionect-api-key get ":" rot 3append ;
  21
  22 : set-visionect-headers ( request -- request )
  23     now timestamp>http-string "Date" set-header
  24     dup [ method>> ] [ "Date" header ] [ url>> path>> ] tri
  25     visionect-authorization "Authorization" set-header ;
  26
  27 : visionect-request ( request -- data )
  28     set-visionect-headers http-request nip ;
  29
  30 : visionect-url ( path -- url )
  31     visionect-base-url get prepend ;
  32
  33 : visionect-get ( path -- data )
  34     visionect-url <get-request> visionect-request ;
  35
  36 : visionect-put ( post-data path -- data )
  37     visionect-url <put-request> visionect-request ;
  38
  39 : visionect-delete ( path -- data )
  40     visionect-url <delete-request> visionect-request ;
  41
  42 : visionect-post ( post-data path -- data )
  43     visionect-url <post-request> visionect-request ;
  44
  45 PRIVATE>
  46
  47 ! ## DEVICES
  48
  49 : get-device ( uuid -- device )
  50     "/api/device/" prepend visionect-get "" like json> ;
  51
  52 : update-device ( device -- )
  53     dup "Uuid" of "/api/device/" prepend visionect-put drop ;
  54
  55 : remove-device ( uuid -- )
  56     "/api/device/" prepend visionect-delete drop ;
  57
  58 : all-devices ( -- devices )
  59     "/api/device/" visionect-get "" like json> ;
  60
  61 : update-devices ( devices -- )
  62     json> "/api/device/" visionect-put drop ;
  63
  64 : tclv-list ( uuid -- tclv )
  65     "/api/devicetclv/" prepend visionect-get "" like json> ;
  66
  67 : get-tclv ( uuid type -- config )
  68     [ "/api/cmd/Param/" prepend ] dip
  69     "{\"Data\": [{\"Type\": %d, \"Control\": 0, \"Value\": \"\"}]}"
  70     sprintf swap visionect-post "" like json> ;
  71
  72 : set-tclv ( uuid type value -- config )
  73     [ "/api/cmd/Param/" prepend ] 2dip
  74     "{\"Data\": [{\"Type\": %d, \"Control\": 1, \"Value\": \"%s\"}]}"
  75     sprintf swap visionect-post "" like json> ;
  76
  77 : reboot-device ( uuid -- )
  78     f swap "/api/device/" "/reboot" surround visionect-post drop ;
  79
  80 : reboot-devices ( uuids -- )
  81     >json "/api/device/reboot" visionect-post drop ;
  82
  83 ! ## SESSIONS
  84
  85 : get-session ( uuid -- session )
  86     "/api/session/" prepend visionect-get "" like json> ;
  87
  88 : update-session ( session -- )
  89     dup "Uuid" of "/api/session/" prepend visionect-put drop ;
  90
  91 : remove-session ( uuid -- )
  92     "/api/session/" prepend visionect-delete drop ;
  93
  94 : all-sessions ( -- sessions )
  95     "/api/session/" visionect-get "" like json> ;
  96
  97 : create-session ( session -- )
  98     "/api/session/" visionect-post drop ;
  99
 100 : update-sessions ( sessions -- )
 101     >json "/api/session/" visionect-put drop ;
 102
 103 : restart-session ( uuid -- )
 104     "/api/session/" "/restart" surround visionect-get drop ;
 105
 106 : restart-sessions ( uuids -- )
 107     >json "/api/session/restart" visionect-post drop ;
 108
 109 ! ## USERS
 110
 111 : get-user ( username -- user )
 112     "/api/user/" prepend visionect-get "" like json> ;
 113
 114 : update-user ( user -- )
 115     dup "Username" of "/api/user/" prepend visionect-put drop ;
 116
 117 : remove-user ( username -- )
 118     "/api/user/" prepend visionect-delete drop ;
 119
 120 : all-users ( -- users )
 121     "/api/user/" visionect-get "" like json> ;
 122
 123 : create-user ( user -- )
 124     >json "/api/user/" visionect-post drop ;
 125
 126 : update-users ( users -- )
 127     >json "/api/user/" visionect-put drop ;
 128
 129 ! ## CONFIG
 130
 131 : get-config ( -- config )
 132     "/api/config/" visionect-get "" like json> ;
 133
 134 : update-config ( config -- )
 135     >json "/api/config/" visionect-put drop ;
 136
 137 ! ## LIVE VIEW
 138
 139 : live-view ( uuid cached? -- png )
 140     [ "/api/live/device/" ] 2dip
 141     "/cached.png" "/image.png" ? 3append
 142     visionect-get ;
 143
 144 ! ## DEVICE STATUS
 145
 146 : device-status ( uuid -- status )
 147     "/api/devicestatus/" prepend visionect-get "" like json> ;
 148
 149 : device-status-range ( uuid from to group? -- status )
 150     [ [ timestamp>unix-time ] bi@ ] [ "true" "false" ? ] bi*
 151     "%s?%s,%s,%s" sprintf device-status ;
 152
 153 ! ## BACKENDS
 154
 155 : http-backend ( png uuid -- )
 156     "/backend/" prepend visionect-put drop ;