extra/webapps/wiki/wiki.factor

   1 ! Copyright (C) 2008 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel hashtables calendar random assocs
   4 namespaces splitting sequences sorting math.order present
   5 io.files io.encodings.ascii
   6 syndication
   7 html.components html.forms
   8 http.server
   9 http.server.dispatchers
  10 furnace
  11 furnace.actions
  12 furnace.redirection
  13 furnace.auth
  14 furnace.auth.login
  15 furnace.boilerplate
  16 furnace.syndication
  17 validators
  18 db.types db.tuples lcs farkup urls ;
  19 IN: webapps.wiki
  20
  21 : wiki-url ( rest path -- url )
  22     [ "$wiki/" % % "/" % % ] "" make
  23     <url> swap >>path ;
  24
  25 : view-url ( title -- url ) "view" wiki-url ;
  26
  27 : edit-url ( title -- url ) "edit" wiki-url ;
  28
  29 : revisions-url ( title -- url ) "revisions" wiki-url ;
  30
  31 : revision-url ( id -- url ) "revision" wiki-url ;
  32
  33 : user-edits-url ( author -- url ) "user-edits" wiki-url ;
  34
  35 TUPLE: wiki < dispatcher ;
  36
  37 SYMBOL: can-delete-wiki-articles?
  38
  39 can-delete-wiki-articles? define-capability
  40
  41 TUPLE: article title revision ;
  42
  43 article "ARTICLES" {
  44     { "title" "TITLE" { VARCHAR 256 } +not-null+ +user-assigned-id+ }
  45     { "revision" "REVISION" INTEGER +not-null+ } ! revision id
  46 } define-persistent
  47
  48 : <article> ( title -- article ) article new swap >>title ;
  49
  50 TUPLE: revision id title author date content description ;
  51
  52 revision "REVISIONS" {
  53     { "id" "ID" INTEGER +db-assigned-id+ }
  54     { "title" "TITLE" { VARCHAR 256 } +not-null+ } ! article id
  55     { "author" "AUTHOR" { VARCHAR 256 } +not-null+ } ! uid
  56     { "date" "DATE" TIMESTAMP +not-null+ }
  57     { "content" "CONTENT" TEXT +not-null+ }
  58     { "description" "DESCRIPTION" TEXT }
  59 } define-persistent
  60
  61 M: revision feed-entry-title
  62     [ title>> ] [ drop " by " ] [ author>> ] tri 3append ;
  63
  64 M: revision feed-entry-date date>> ;
  65
  66 M: revision feed-entry-url id>> revision-url ;
  67
  68 : reverse-chronological-order ( seq -- sorted )
  69     [ [ date>> ] compare invert-comparison ] sort ;
  70
  71 : <revision> ( id -- revision )
  72     revision new swap >>id ;
  73
  74 : validate-title ( -- )
  75     { { "title" [ v-one-line ] } } validate-params ;
  76
  77 : validate-author ( -- )
  78     { { "author" [ v-username ] } } validate-params ;
  79
  80 : <article-boilerplate> ( responder -- responder' )
  81     <boilerplate>
  82         { wiki "page-common" } >>template ;
  83
  84 : <main-article-action> ( -- action )
  85     <action>
  86         [ "Front Page" view-url <redirect> ] >>display ;
  87
  88 : latest-revision ( title -- revision/f )
  89     <article> select-tuple
  90     dup [ revision>> <revision> select-tuple ] when ;
  91
  92 : <view-article-action> ( -- action )
  93     <action>
  94
  95         "title" >>rest
  96
  97         [
  98             validate-title
  99         ] >>init
 100
 101         [
 102             "title" value dup latest-revision [
 103                 from-object
 104                 { wiki "view" } <chloe-content>
 105             ] [
 106                 edit-url <redirect>
 107             ] ?if
 108         ] >>display
 109
 110     <article-boilerplate> ;
 111
 112 : <view-revision-action> ( -- action )
 113     <page-action>
 114
 115         "id" >>rest
 116
 117         [
 118             validate-integer-id
 119             "id" value <revision>
 120             select-tuple from-object
 121             URL" $wiki/view/" adjust-url present relative-link-prefix set
 122         ] >>init
 123
 124         { wiki "view" } >>template
 125
 126     <article-boilerplate> ;
 127
 128 : <random-article-action> ( -- action )
 129     <action>
 130         [
 131             article new select-tuples random
 132             [ title>> ] [ "Front Page" ] if*
 133             view-url <redirect>
 134         ] >>display ;
 135
 136 : amend-article ( revision article -- )
 137     swap id>> >>revision update-tuple ;
 138
 139 : add-article ( revision -- )
 140     [ title>> ] [ id>> ] bi article boa insert-tuple ;
 141
 142 : add-revision ( revision -- )
 143     [ insert-tuple ]
 144     [
 145         dup title>> <article> select-tuple
 146         [ amend-article ] [ add-article ] if*
 147     ] bi ;
 148
 149 : <edit-article-action> ( -- action )
 150     <page-action>
 151
 152         "title" >>rest
 153
 154         [
 155             validate-title
 156
 157             "title" value <article> select-tuple
 158             [ revision>> <revision> select-tuple ]
 159             [ f <revision> "title" value >>title ]
 160             if*
 161
 162             [ title>> "title" set-value ]
 163             [ content>> "content" set-value ]
 164             bi
 165         ] >>init
 166
 167         { wiki "edit" } >>template
 168
 169     <article-boilerplate> ;
 170
 171 : <submit-article-action> ( -- action )
 172     <action>
 173         [
 174             validate-title
 175
 176             {
 177                 { "content" [ v-required ] }
 178                 { "description" [ [ v-one-line ] v-optional ] }
 179             } validate-params
 180
 181             f <revision>
 182                 "title" value >>title
 183                 now >>date
 184                 username >>author
 185                 "content" value >>content
 186                 "description" value >>description
 187             [ add-revision ] [ title>> view-url <redirect> ] bi
 188         ] >>submit
 189
 190     <protected>
 191         "edit wiki articles" >>description ;
 192
 193 : <revisions-boilerplate> ( responder -- responder )
 194     <boilerplate>
 195         { wiki "revisions-common" } >>template ;
 196
 197 : list-revisions ( -- seq )
 198     f <revision> "title" value >>title select-tuples
 199     reverse-chronological-order ;
 200
 201 : <list-revisions-action> ( -- action )
 202     <page-action>
 203
 204         "title" >>rest
 205
 206         [
 207             validate-title
 208             list-revisions "revisions" set-value
 209         ] >>init
 210
 211         { wiki "revisions" } >>template
 212
 213     <revisions-boilerplate>
 214     <article-boilerplate> ;
 215
 216 : <list-revisions-feed-action> ( -- action )
 217     <feed-action>
 218
 219         "title" >>rest
 220
 221         [ validate-title ] >>init
 222
 223         [ "Revisions of " "title" value append ] >>title
 224
 225         [ "title" value revisions-url ] >>url
 226
 227         [ list-revisions ] >>entries ;
 228
 229 : rollback-description ( description -- description' )
 230     [ "Rollback of '" swap "'" 3append ] [ "Rollback" ] if* ;
 231
 232 : <rollback-action> ( -- action )
 233     <action>
 234
 235         [ validate-integer-id ] >>validate
 236
 237         [
 238             "id" value <revision> select-tuple
 239                 f >>id
 240                 now >>date
 241                 username >>author
 242                 [ rollback-description ] change-description
 243             [ add-revision ]
 244             [ title>> revisions-url <redirect> ] bi
 245         ] >>submit
 246
 247     <protected>
 248         "rollback wiki articles" >>description ;
 249
 250 : list-changes ( -- seq )
 251     f <revision> select-tuples
 252     reverse-chronological-order ;
 253
 254 : <list-changes-action> ( -- action )
 255     <page-action>
 256         [ list-changes "revisions" set-value ] >>init
 257         { wiki "changes" } >>template
 258
 259     <revisions-boilerplate> ;
 260
 261 : <list-changes-feed-action> ( -- action )
 262     <feed-action>
 263         [ URL" $wiki/changes" ] >>url
 264         [ "All changes" ] >>title
 265         [ list-changes ] >>entries ;
 266
 267 : <delete-action> ( -- action )
 268     <action>
 269
 270         [ validate-title ] >>validate
 271
 272         [
 273             "title" value <article> delete-tuples
 274             f <revision> "title" value >>title delete-tuples
 275             URL" $wiki" <redirect>
 276         ] >>submit
 277
 278      <protected>
 279         "delete wiki articles" >>description
 280         { can-delete-wiki-articles? } >>capabilities ;
 281
 282 : <diff-action> ( -- action )
 283     <page-action>
 284
 285         [
 286             {
 287                 { "old-id" [ v-integer ] }
 288                 { "new-id" [ v-integer ] }
 289             } validate-params
 290
 291             "old-id" "new-id"
 292             [ value <revision> select-tuple ] bi@
 293             [
 294                 over title>> "title" set-value
 295                 [ "old" [ from-object ] nest-form ]
 296                 [ "new" [ from-object ] nest-form ]
 297                 bi*
 298             ]
 299             [ [ content>> string-lines ] bi@ diff "diff" set-value ]
 300             2bi
 301         ] >>init
 302
 303         { wiki "diff" } >>template
 304
 305     <article-boilerplate> ;
 306
 307 : <list-articles-action> ( -- action )
 308     <page-action>
 309
 310         [
 311             f <article> select-tuples
 312             [ [ title>> ] compare ] sort
 313             "articles" set-value
 314         ] >>init
 315
 316         { wiki "articles" } >>template ;
 317
 318 : list-user-edits ( -- seq )
 319     f <revision> "author" value >>author select-tuples
 320     reverse-chronological-order ;
 321
 322 : <user-edits-action> ( -- action )
 323     <page-action>
 324
 325         "author" >>rest
 326
 327         [
 328             validate-author
 329             list-user-edits "revisions" set-value
 330         ] >>init
 331
 332         { wiki "user-edits" } >>template
 333
 334     <revisions-boilerplate> ;
 335
 336 : <user-edits-feed-action> ( -- action )
 337     <feed-action>
 338         "author" >>rest
 339         [ validate-author ] >>init
 340         [ "Edits by " "author" value append ] >>title
 341         [ "author" value user-edits-url ] >>url
 342         [ list-user-edits ] >>entries ;
 343
 344 : init-sidebar ( -- )
 345     "Sidebar" latest-revision [ "sidebar" [ from-object ] nest-form ] when*
 346     "Footer" latest-revision [ "footer" [ from-object ] nest-form ] when* ;
 347
 348 : <wiki> ( -- dispatcher )
 349     wiki new-dispatcher
 350         <main-article-action> "" add-responder
 351         <view-article-action> "view" add-responder
 352         <view-revision-action> "revision" add-responder
 353         <random-article-action> "random" add-responder
 354         <list-revisions-action> "revisions" add-responder
 355         <list-revisions-feed-action> "revisions.atom" add-responder
 356         <diff-action> "diff" add-responder
 357         <edit-article-action> "edit" add-responder
 358         <submit-article-action> "submit" add-responder
 359         <rollback-action> "rollback" add-responder
 360         <user-edits-action> "user-edits" add-responder
 361         <list-articles-action> "articles" add-responder
 362         <list-changes-action> "changes" add-responder
 363         <user-edits-feed-action> "user-edits.atom" add-responder
 364         <list-changes-feed-action> "changes.atom" add-responder
 365         <delete-action> "delete" add-responder
 366     <boilerplate>
 367         [ init-sidebar ] >>init
 368         { wiki "wiki-common" } >>template ;
 369
 370 : init-wiki ( -- )
 371     "resource:extra/webapps/wiki/initial-content" directory* keys
 372     [
 373         [ ascii file-contents ] [ file-name "." split1 drop ] bi
 374         f <revision>
 375             swap >>title
 376             swap >>content
 377             "slava" >>author
 378             now >>date
 379         add-revision
 380     ] each ;