extra/xmode/loader/loader.factor

   1 USING: xmode.loader.syntax xmode.tokens xmode.rules
   2 xmode.keyword-map xml.data xml.utilities xml assocs kernel
   3 combinators sequences math.parser namespaces parser
   4 xmode.utilities regexp io.files ;
   5 IN: xmode.loader
   6
   7 ! Based on org.gjt.sp.jedit.XModeHandler
   8
   9 ! RULES and its children
  10 <TAGS: parse-rule-tag
  11
  12 TAG: PROPS ( rule-set tag -- )
  13     parse-props-tag swap set-rule-set-props ;
  14
  15 TAG: IMPORT ( rule-set tag -- )
  16     "DELEGATE" swap at swap import-rule-set ;
  17
  18 TAG: TERMINATE ( rule-set tag -- )
  19     "AT_CHAR" swap at string>number swap set-rule-set-terminate-char ;
  20
  21 RULE: SEQ seq-rule
  22     shared-tag-attrs delegate-attr literal-start ;
  23
  24 RULE: SEQ_REGEXP seq-rule
  25     shared-tag-attrs delegate-attr regexp-attr regexp-start ;
  26
  27 RULE: SPAN span-rule
  28     shared-tag-attrs delegate-attr match-type-attr span-attrs parse-begin/end-tags init-span-tag ;
  29
  30 RULE: SPAN_REGEXP span-rule
  31     shared-tag-attrs delegate-attr match-type-attr span-attrs regexp-attr parse-begin/end-tags init-span-tag ;
  32
  33 RULE: EOL_SPAN eol-span-rule
  34     shared-tag-attrs delegate-attr match-type-attr literal-start init-eol-span-tag ;
  35
  36 RULE: EOL_SPAN_REGEXP eol-span-rule
  37     shared-tag-attrs delegate-attr match-type-attr regexp-attr regexp-start init-eol-span-tag ;
  38
  39 RULE: MARK_FOLLOWING mark-following-rule
  40     shared-tag-attrs match-type-attr literal-start ;
  41
  42 RULE: MARK_PREVIOUS mark-previous-rule
  43     shared-tag-attrs match-type-attr literal-start ;
  44
  45 TAG: KEYWORDS ( rule-set tag -- key value )
  46     ignore-case? get <keyword-map>
  47     swap child-tags [ over parse-keyword-tag ] each
  48     swap set-rule-set-keywords ;
  49
  50 TAGS>
  51
  52 : ?<regexp> ( string/f -- regexp/f )
  53     dup [ ignore-case? get <regexp> ] when ;
  54
  55 : (parse-rules-tag) ( tag -- rule-set )
  56     <rule-set>
  57     {
  58         { "SET" string>rule-set-name set-rule-set-name }
  59         { "IGNORE_CASE" string>boolean set-rule-set-ignore-case? }
  60         { "HIGHLIGHT_DIGITS" string>boolean set-rule-set-highlight-digits? }
  61         { "DIGIT_RE" ?<regexp> set-rule-set-digit-re }
  62         { "ESCAPE" f add-escape-rule }
  63         { "DEFAULT" string>token set-rule-set-default }
  64         { "NO_WORD_SEP" f set-rule-set-no-word-sep }
  65     } init-from-tag ;
  66
  67 : parse-rules-tag ( tag -- rule-set )
  68     dup (parse-rules-tag) [
  69         dup rule-set-ignore-case? ignore-case? [
  70             swap child-tags [ parse-rule-tag ] with each
  71         ] with-variable
  72     ] keep ;
  73
  74 : merge-rule-set-props ( props rule-set -- )
  75     [ rule-set-props assoc-union ] keep set-rule-set-props ;
  76
  77 ! Top-level entry points
  78 : parse-mode-tag ( tag -- rule-sets )
  79     dup "RULES" tags-named [
  80         parse-rules-tag dup rule-set-name swap
  81     ] H{ } map>assoc
  82     swap "PROPS" tag-named [
  83         parse-props-tag over values
  84         [ merge-rule-set-props ] with each
  85     ] when* ;
  86
  87 : parse-mode ( stream -- rule-sets )
  88     read-xml parse-mode-tag ;