extra/z-algorithm/z-algorithm.factor

   1 ! Copyright (C) 2010 Dmitry Shubin.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel locals math math.ranges sequences
   4 sequences.private ;
   5 IN: z-algorithm
   6
   7 : lcp ( seq1 seq2 -- n )
   8     [ min-length dup ] 2keep mismatch-unsafe [ nip ] when* ;
   9
  10 <PRIVATE
  11
  12 :: out-of-zbox ( seq Z l r k -- seq Z l r )
  13     seq k tail-slice seq lcp :> Zk
  14     Zk k Z set-nth seq Z
  15     Zk 0 > [ k Zk k + 1 - ] [ l r ] if ; inline
  16
  17 :: inside-zbox ( seq Z l r k -- seq Z l r )
  18     k l - Z nth :> Zk'
  19     r k - 1 +   :> b
  20     seq Z Zk' b <
  21     [ Zk' k Z set-nth l r ] ! still inside
  22     [
  23         seq r 1 + seq b [ tail-slice ] 2bi@ lcp :> q
  24         q b + k Z set-nth k q r +
  25     ] if ; inline
  26
  27 : z-value ( seq Z l r k -- seq Z l r )
  28     2dup < [ out-of-zbox ] [ inside-zbox ] if ; inline
  29
  30 :: (z-values) ( seq -- Z )
  31     seq length dup 0 <array> :> ( len Z )
  32     len 0 Z set-nth
  33     seq Z 0 0 len [1..b) [ z-value ] each 4drop
  34     Z ; inline
  35
  36 PRIVATE>
  37
  38 : z-values ( seq -- Z )
  39     [ { } ] [ (z-values) ] if-empty ;