library/collections/arrays.factor

   1 ! Copyright (C) 2005 Slava Pestov.
   2 ! See http://factor.sf.net/license.txt for BSD license.
   3
   4 IN: kernel-internals
   5 USING: kernel math math-internals sequences sequences-internals ;
   6
   7 : array= ( seq seq -- ? )
   8     #! This is really only used to compare tuples.
   9     over array-capacity over array-capacity number= [
  10         dup array-capacity [
  11             >r 2dup r> tuck swap array-nth >r swap array-nth r> =
  12         ] all? 2nip
  13     ] [
  14         2drop f
  15     ] if ; flushable
  16
  17 IN: arrays
  18
  19 M: array clone (clone) ;
  20 M: array length array-capacity ;
  21 M: array nth bounds-check >r >fixnum r> array-nth ;
  22 M: array set-nth bounds-check >r >fixnum r> set-array-nth ;
  23 M: array nth-unsafe >r >fixnum r> array-nth ;
  24 M: array set-nth-unsafe >r >fixnum r> set-array-nth ;
  25 M: array resize resize-array ;
  26
  27 : >array ( seq -- array )
  28     [ length <array> 0 over ] keep copy-into ; inline
  29
  30 M: array like drop dup array? [ >array ] unless ;
  31
  32 M: byte-array clone (clone) ;
  33 M: byte-array length array-capacity ;
  34 M: byte-array resize resize-array ;
  35
  36 : 1array ( x -- { x } )
  37     1 <array> [ 0 swap set-array-nth ] keep ; flushable
  38
  39 : 2array ( x y -- { x y } )
  40     2 <array>
  41     [ 1 swap set-array-nth ] keep
  42     [ 0 swap set-array-nth ] keep ; flushable
  43
  44 : 3array ( x y z -- { x y z } )
  45     3 <array>
  46     [ 2 swap set-array-nth ] keep
  47     [ 1 swap set-array-nth ] keep
  48     [ 0 swap set-array-nth ] keep ; flushable
  49
  50 : zero-array ( n -- array ) 0 <repeated> >array ;