misc/fuel/fuel-debug-uses.el

   1 ;;; fuel-debug-uses.el -- retrieving USING: stanzas
   2
   3 ;; Copyright (C) 2008 Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages, fuel, factor
   8 ;; Start date: Tue Dec 23, 2008 04:23
   9
  10 ;;; Comentary:
  11
  12 ;; Support for getting and updating factor source vocabulary lists.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-debug)
  17 (require 'fuel-eval)
  18 (require 'fuel-popup)
  19 (require 'fuel-font-lock)
  20 (require 'fuel-base)
  21
  22
  23 \f
  24 ;;; Customization:
  25
  26 (fuel-font-lock--defface fuel-font-lock-debug-uses-header
  27   'bold fuel-debug "headers in Uses buffers")
  28
  29 (fuel-font-lock--defface fuel-font-lock-debug-uses-prompt
  30   'italic fuel-debug "prompts in Uses buffers")
  31
  32 \f
  33 ;;; Utility functions:
  34
  35 (defun fuel-debug--file-lines (file)
  36   (when (file-readable-p file)
  37     (with-current-buffer (find-file-noselect file)
  38       (save-excursion
  39         (goto-char (point-min))
  40         (let ((lines) (in-usings))
  41           (while (not (eobp))
  42             (when (looking-at "^USING: ") (setq in-usings t))
  43             (let ((line (substring-no-properties (thing-at-point 'line) 0 -1)))
  44               (when in-usings (setq line (concat "! " line)))
  45               (push line lines))
  46             (when (and in-usings (looking-at ".*\\_<;\\_>")) (setq in-usings nil))
  47             (forward-line))
  48           (reverse lines))))))
  49
  50 (defun fuel-debug--uses-filter (restarts)
  51   (let ((result) (i 1) (rn 0))
  52     (dolist (r restarts (reverse result))
  53       (setq rn (1+ rn))
  54       (when (string-match "Use the .+ vocabulary\\|Defer" r)
  55         (push (list i rn r) result)
  56         (setq i (1+ i))))))
  57
  58 \f
  59 ;;; Retrieving USINGs:
  60
  61 (fuel-popup--define fuel-debug--uses-buffer
  62   "*fuel uses*" 'fuel-debug-uses-mode)
  63
  64 (make-variable-buffer-local
  65  (defvar fuel-debug--uses-file nil))
  66
  67 (make-variable-buffer-local
  68  (defvar fuel-debug--uses-restarts nil))
  69
  70 (defsubst fuel-debug--uses-insert-title ()
  71   (insert "Infering USING: stanza for " fuel-debug--uses-file ".\n\n"))
  72
  73 (defun fuel-debug--uses-prepare (file)
  74   (fuel--with-popup (fuel-debug--uses-buffer)
  75     (setq fuel-debug--uses-file file
  76           fuel-debug--uses nil
  77           fuel-debug--uses-restarts nil)
  78     (erase-buffer)
  79     (fuel-debug--uses-insert-title)))
  80
  81 (defun fuel-debug--uses-clean ()
  82   (setq fuel-debug--uses-file nil
  83         fuel-debug--uses nil
  84         fuel-debug--uses-restarts nil))
  85
  86 (defun fuel-debug--uses-for-file (file)
  87   (let* ((lines (fuel-debug--file-lines file))
  88          (cmd `(:fuel ((V{ ,@lines } fuel-get-uses)) t t)))
  89     (fuel-debug--uses-prepare file)
  90     (fuel--with-popup (fuel-debug--uses-buffer)
  91       (insert "Asking Factor. Please, wait ...\n")
  92       (fuel-eval--send cmd 'fuel-debug--uses-cont))
  93     (fuel-popup--display (fuel-debug--uses-buffer))))
  94
  95 (defun fuel-debug--uses-cont (retort)
  96   (let ((uses (fuel-debug--uses retort))
  97         (err (fuel-eval--retort-error retort)))
  98     (if uses (fuel-debug--uses-display uses)
  99       (fuel-debug--uses-display-err retort))))
 100
 101 (defun fuel-debug--uses-display (uses)
 102   (let* ((inhibit-read-only t)
 103          (old (with-current-buffer (find-file-noselect fuel-debug--uses-file)
 104                 (sort (fuel-syntax--find-usings t) 'string<)))
 105          (new (sort uses 'string<)))
 106     (erase-buffer)
 107     (fuel-debug--uses-insert-title)
 108     (if (equalp old new)
 109         (progn
 110           (insert "Current USING: is already fine!. Type 'q' to bury buffer.\n")
 111           (fuel-debug--uses-clean))
 112       (fuel-debug--highlight-names old new 'fuel-font-lock-debug-unneeded-vocab)
 113       (fuel-debug--highlight-names new old 'fuel-font-lock-debug-missing-vocab)
 114       (fuel-debug--insert-vlist "Current vocabulary list:" old)
 115       (newline)
 116       (fuel-debug--insert-vlist "Correct vocabulary list:" new)
 117       (setq fuel-debug--uses new)
 118       (insert "\nType 'y' to update your USING: to the new one.\n"))))
 119
 120 (defun fuel-debug--uses-display-err (retort)
 121   (let* ((inhibit-read-only t)
 122          (err (fuel-eval--retort-error retort))
 123          (restarts (fuel-debug--uses-filter (fuel-eval--error-restarts err)))
 124          (unique (= 1 (length restarts))))
 125     (erase-buffer)
 126     (fuel-debug--uses-insert-title)
 127     (insert (fuel-eval--retort-output retort))
 128     (newline)
 129     (if (not restarts)
 130         (insert "\nSorry, couldn't infer the vocabulary list.\n")
 131       (setq fuel-debug--uses-restarts restarts)
 132       (if unique (fuel-debug--uses-restart 1)
 133         (insert "\nPlease, type the number of the desired vocabulary:\n\n")
 134         (dolist (r restarts)
 135           (insert (format " :%s %s\n" (first r) (third r))))))))
 136
 137 (defun fuel-debug--uses-update-usings ()
 138   (interactive)
 139   (let ((inhibit-read-only t)
 140         (file fuel-debug--uses-file)
 141         (uses fuel-debug--uses))
 142     (when (and uses file)
 143       (insert "\nDone!")
 144       (fuel-debug--uses-clean)
 145       (fuel-popup--quit)
 146       (fuel-debug--replace-usings file uses)
 147       (message "USING: updated!"))))
 148
 149 (defun fuel-debug--uses-restart (n)
 150   (when (and (> n 0) (<= n (length fuel-debug--uses-restarts)))
 151     (let* ((inhibit-read-only t)
 152            (restart (format ":%s" (cadr (nth (1- n) fuel-debug--uses-restarts))))
 153            (cmd `(:fuel ([ (:factor ,restart) ] fuel-with-autouse) t t)))
 154       (setq fuel-debug--uses-restarts nil)
 155       (insert "\nAsking Factor. Please, wait ...\n")
 156       (fuel-eval--send cmd 'fuel-debug--uses-cont))))
 157
 158 \f
 159 ;;; Fuel uses mode:
 160
 161 (defvar fuel-debug-uses-mode-map
 162   (let ((map (make-keymap)))
 163     (suppress-keymap map)
 164     (dotimes (n 9)
 165       (define-key map (vector (+ ?1 n))
 166         `(lambda () (interactive) (fuel-debug--uses-restart ,(1+ n)))))
 167     (define-key map "y" 'fuel-debug--uses-update-usings)
 168     (define-key map "\C-c\C-c" 'fuel-debug--uses-update-usings)
 169     map))
 170
 171 (defconst fuel-debug--uses-header-regex
 172   (format "^%s.*$" (regexp-opt '("Infering USING: stanza for "
 173                                  "Current USING: is already fine!"
 174                                  "Current vocabulary list:"
 175                                  "Correct vocabulary list:"
 176                                  "Sorry, couldn't infer the vocabulary list."
 177                                  "Done!"))))
 178
 179 (defconst fuel-debug--uses-prompt-regex
 180   (format "^%s" (regexp-opt '("Asking Factor. Please, wait ..."
 181                               "Please, type the number of the desired vocabulary:"
 182                               "Type 'y' to update your USING: to the new one."))))
 183
 184 (defconst fuel-debug--uses-font-lock-keywords
 185   `((,fuel-debug--uses-header-regex . 'fuel-font-lock-debug-uses-header)
 186     (,fuel-debug--uses-prompt-regex . 'fuel-font-lock-debug-uses-prompt)
 187     (,fuel-debug--restart-regex (1 'fuel-font-lock-debug-restart-number)
 188                                 (2 'fuel-font-lock-debug-restart-name))))
 189
 190 (defun fuel-debug-uses-mode ()
 191   "A major mode for displaying Factor's USING: inference results."
 192   (interactive)
 193   (kill-all-local-variables)
 194   (buffer-disable-undo)
 195   (setq major-mode 'fuel-debug-uses-mode)
 196   (setq mode-name "Fuel Uses:")
 197   (set (make-local-variable 'font-lock-defaults)
 198        '(fuel-debug--uses-font-lock-keywords t nil nil nil))
 199   (use-local-map fuel-debug-uses-mode-map))
 200
 201 \f
 202 (provide 'fuel-debug-uses)
 203 ;;; fuel-debug-uses.el ends here