misc/fuel/fuel-edit.el

   1 ;;; fuel-edit.el -- utilities for file editing
   2
   3 ;; Copyright (C) 2009 Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages, fuel, factor
   8 ;; Start date: Mon Jan 05, 2009 21:16
   9
  10 ;;; Comentary:
  11
  12 ;; Locating and opening factor source and documentation files.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-completion)
  17 (require 'fuel-eval)
  18 (require 'fuel-base)
  19
  20 (require 'etags)
  21
  22 \f
  23 ;;; Customization
  24
  25 (defmacro fuel-edit--define-custom-visit (var group doc)
  26   `(defcustom ,var nil
  27      ,doc
  28      :group ',group
  29      :type '(choice (const :tag "Other window" window)
  30                     (const :tag "Other frame" frame)
  31                     (const :tag "Current window" nil))))
  32
  33 (fuel-edit--define-custom-visit
  34  fuel-edit-word-method fuel
  35  "How the new buffer is opened when invoking \\[fuel-edit-word-at-point]")
  36
  37 \f
  38 ;;; Auxiliar functions:
  39
  40 (defun fuel-edit--visit-file (file method)
  41   (cond ((eq method 'window) (find-file-other-window file))
  42         ((eq method 'frame) (find-file-other-frame file))
  43         (t (find-file file))))
  44
  45 (defun fuel-edit--looking-at-vocab ()
  46   (save-excursion
  47     (fuel-syntax--beginning-of-defun)
  48     (looking-at "USING:\\|USE:\\|IN:")))
  49
  50 (defun fuel-edit--try-edit (ret)
  51   (let* ((err (fuel-eval--retort-error ret))
  52          (loc (fuel-eval--retort-result ret)))
  53     (when (or err (not loc) (not (listp loc)) (not (stringp (car loc))))
  54       (error "Couldn't find edit location"))
  55     (unless (file-readable-p (car loc))
  56       (error "Couldn't open '%s' for read" (car loc)))
  57     (fuel-edit--visit-file (car loc) fuel-edit-word-method)
  58     (goto-line (if (numberp (cadr loc)) (cadr loc) 1))))
  59
  60 (defun fuel-edit--edit-article (name)
  61   (let ((cmd `(:fuel* (,name fuel-get-article-location) "fuel" t)))
  62     (fuel-edit--try-edit (fuel-eval--send/wait cmd))))
  63
  64 \f
  65 ;;; Editing commands:
  66
  67 (defvar fuel-edit--word-history nil)
  68 (defvar fuel-edit--previous-location nil)
  69
  70 (defun fuel-edit-vocabulary (&optional refresh vocab)
  71   "Visits vocabulary file in Emacs.
  72 When called interactively, asks for vocabulary with completion.
  73 With prefix argument, refreshes cached vocabulary list."
  74   (interactive "P")
  75   (let* ((vocab (or vocab (fuel-completion--read-vocab refresh)))
  76          (cmd `(:fuel* (,vocab fuel-get-vocab-location) "fuel" t)))
  77     (fuel-edit--try-edit (fuel-eval--send/wait cmd))))
  78
  79 (defun fuel-edit-word (&optional arg)
  80   "Asks for a word to edit, with completion.
  81 With prefix, only words visible in the current vocabulary are
  82 offered."
  83   (interactive "P")
  84   (let* ((word (fuel-completion--read-word "Edit word: "
  85                                            nil
  86                                            fuel-edit--word-history
  87                                            arg))
  88          (cmd `(:fuel* ((:quote ,word) fuel-get-word-location))))
  89     (fuel-edit--try-edit (fuel-eval--send/wait cmd))))
  90
  91 (defun fuel-edit-word-at-point (&optional arg)
  92   "Opens a new window visiting the definition of the word at point.
  93 With prefix, asks for the word to edit."
  94   (interactive "P")
  95   (let* ((word (or (and (not arg) (fuel-syntax-symbol-at-point))
  96                    (fuel-completion--read-word "Edit word: ")))
  97          (cmd `(:fuel* ((:quote ,word) fuel-get-word-location)))
  98          (marker (and (not arg) (point-marker))))
  99     (if (and (not arg) (fuel-edit--looking-at-vocab))
 100         (fuel-edit-vocabulary nil word)
 101       (fuel-edit--try-edit (fuel-eval--send/wait cmd)))
 102     (when marker (ring-insert find-tag-marker-ring marker))))
 103
 104 (defun fuel-edit-word-doc-at-point (&optional arg word)
 105   "Opens a new window visiting the documentation file for the word at point.
 106 With prefix, asks for the word to edit."
 107   (interactive "P")
 108   (let* ((word (or word
 109                    (and (not arg) (fuel-syntax-symbol-at-point))
 110                    (fuel-completion--read-word "Edit word: ")))
 111          (cmd `(:fuel* ((:quote ,word) fuel-get-doc-location)))
 112          (marker (and (not arg) (point-marker))))
 113     (condition-case nil
 114         (fuel-edit--try-edit (fuel-eval--send/wait cmd))
 115       (error
 116        (message "Documentation for '%s' not found" word)
 117        (when (and (eq major-mode 'factor-mode)
 118                   (y-or-n-p (concat "No documentation found. "
 119                                     "Do you want to open the vocab's "
 120                                     "doc file? ")))
 121          (when marker (ring-insert find-tag-marker-ring marker))
 122          (find-file-other-window
 123           (format "%s-docs.factor"
 124                   (file-name-sans-extension (buffer-file-name)))))))))
 125
 126 (defun fuel-edit-pop-edit-word-stack ()
 127   "Pop back to where \\[fuel-edit-word-at-point] or \\[fuel-edit-word-doc-at-point]
 128 was last invoked."
 129   (interactive)
 130   (condition-case nil
 131       (pop-tag-mark)
 132     (error "No previous location for find word or vocab invokation")))
 133
 134 (defvar fuel-edit--buffer-history nil)
 135
 136 (defun fuel-switch-to-buffer (&optional method)
 137   "Switch to any of the existing Factor buffers, with completion."
 138   (interactive)
 139   (let ((buffer (completing-read "Factor buffer: "
 140                                  (remove (buffer-name)
 141                                          (mapcar 'buffer-name (buffer-list)))
 142                                  '(lambda (s) (string-match "\\.factor$" s))
 143                                  t
 144                                  nil
 145                                  fuel-edit--buffer-history)))
 146     (cond ((eq method 'window) (switch-to-buffer-other-window buffer))
 147           ((eq method 'frame) (switch-to-buffer-other-frame buffer))
 148           (t (switch-to-buffer buffer)))))
 149
 150 (defun fuel-switch-to-buffer-other-window ()
 151   "Switch to any of the existing Factor buffers, in other window."
 152   (interactive)
 153   (fuel-switch-to-buffer 'window))
 154
 155 (defun fuel-switch-to-buffer-other-frame ()
 156   "Switch to any of the existing Factor buffers, in other frame."
 157   (interactive)
 158   (fuel-switch-to-buffer 'frame))
 159
 160 \f
 161 (provide 'fuel-edit)
 162 ;;; fuel-edit.el ends here