misc/fuel/fuel-eval.el

   1 ;;; fuel-eval.el --- evaluating Factor expressions
   2
   3 ;; Copyright (C) 2008  Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages
   8 ;; Start date: Tue Dec 02, 2008
   9
  10 ;;; Commentary:
  11
  12 ;; Protocols for sending evaluations to the Factor listener.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-base)
  17 (require 'fuel-syntax)
  18 (require 'fuel-connection)
  19
  20 (eval-when-compile (require 'cl))
  21
  22 \f
  23 ;;; Simple sexp-based representation of factor code
  24
  25 (defun factor (sexp)
  26   (cond ((null sexp) "f")
  27         ((eq sexp t) "t")
  28         ((or (stringp sexp) (numberp sexp)) (format "%S" sexp))
  29         ((vectorp sexp) (cons :quotation (append sexp nil)))
  30         ((listp sexp)
  31          (case (car sexp)
  32            (:array (factor--seq 'V{ '} (cdr sexp)))
  33            (:quote (format "\\ %s" (factor `(:factor ,(cadr sexp)))))
  34            (:quotation (factor--seq '\[ '\] (cdr sexp)))
  35            (:factor (format "%s" (mapconcat 'identity (cdr sexp) " ")))
  36            (:fuel (factor--fuel-factor (cons :rs (cdr sexp))))
  37            (:fuel* (factor--fuel-factor (cons :nrs (cdr sexp))))
  38            (t (mapconcat 'factor sexp " "))))
  39         ((keywordp sexp)
  40          (factor (case sexp
  41                    (:rs 'fuel-eval-restartable)
  42                    (:nrs 'fuel-eval-non-restartable)
  43                    (:in (fuel-syntax--current-vocab))
  44                    (:usings `(:array ,@(fuel-syntax--usings)))
  45                    (:get 'fuel-eval-set-result)
  46                    (t `(:factor ,(symbol-name sexp))))))
  47         ((symbolp sexp) (symbol-name sexp))))
  48
  49 (defsubst factor--seq (begin end forms)
  50   (format "%s %s %s" begin (if forms (factor forms) "") end))
  51
  52 (defsubst factor--fuel-factor (sexp)
  53   (factor `(,(factor--fuel-restart (nth 0 sexp))
  54             ,(factor--fuel-lines (nth 1 sexp))
  55             ,(factor--fuel-in (nth 2 sexp))
  56             ,(factor--fuel-usings (nth 3 sexp))
  57             fuel-eval-in-context)))
  58
  59 (defsubst factor--fuel-restart (rs)
  60   (unless (member rs '(:rs :nrs))
  61     (error "Invalid restart spec (%s)" rs))
  62   rs)
  63
  64 (defsubst factor--fuel-lines (lst)
  65   (cons :array (mapcar 'factor lst)))
  66
  67 (defsubst factor--fuel-in (in)
  68   (cond ((null in) :in)
  69         ((eq in t) "fuel-scratchpad")
  70         ((stringp in) in)
  71         (t (error "Invalid 'in' (%s)" in))))
  72
  73 (defsubst factor--fuel-usings (usings)
  74   (cond ((null usings) :usings)
  75         ((eq usings t) nil)
  76         ((listp usings) `(:array ,@usings))
  77         (t (error "Invalid 'usings' (%s)" usings))))
  78
  79 \f
  80 ;;; Code sending:
  81
  82 (defvar fuel-eval--default-proc-function nil)
  83 (defsubst fuel-eval--default-proc ()
  84   (and fuel-eval--default-proc-function
  85        (funcall fuel-eval--default-proc-function)))
  86
  87 (defvar fuel-eval--proc nil)
  88
  89 (defvar fuel-eval--sync-retort nil)
  90
  91 (defun fuel-eval--send/wait (code &optional timeout buffer)
  92   (setq fuel-eval--sync-retort nil)
  93   (fuel-con--send-string/wait (or fuel-eval--proc (fuel-eval--default-proc))
  94                               (if (stringp code) code (factor code))
  95                               '(lambda (s)
  96                                  (setq fuel-eval--sync-retort
  97                                        (fuel-eval--parse-retort s)))
  98                               timeout
  99                               buffer)
 100   fuel-eval--sync-retort)
 101
 102 (defun fuel-eval--send (code cont &optional buffer)
 103   (fuel-con--send-string (or fuel-eval--proc (fuel-eval--default-proc))
 104                          (if (stringp code) code (factor code))
 105                          `(lambda (s) (,cont (fuel-eval--parse-retort s)))
 106                          buffer))
 107
 108 \f
 109 ;;; Retort and retort-error datatypes:
 110
 111 (defsubst fuel-eval--retort-make (err result &optional output)
 112   (list err result output))
 113
 114 (defsubst fuel-eval--retort-error (ret) (nth 0 ret))
 115 (defsubst fuel-eval--retort-result (ret) (nth 1 ret))
 116 (defsubst fuel-eval--retort-output (ret) (nth 2 ret))
 117
 118 (defsubst fuel-eval--retort-p (ret)
 119   (and (listp ret) (= 3 (length ret))))
 120
 121 (defsubst fuel-eval--make-parse-error-retort (str)
 122   (fuel-eval--retort-make (cons 'fuel-parse-retort-error str) nil))
 123
 124 (defun fuel-eval--parse-retort (ret)
 125   (if (fuel-eval--retort-p ret) ret
 126     (fuel-eval--make-parse-error-retort ret)))
 127
 128 (defsubst fuel-eval--error-name (err) (car err))
 129
 130 (defsubst fuel-eval--error-restarts (err)
 131   (cdr (assoc :restarts (fuel-eval--error-name-p err 'condition))))
 132
 133 (defun fuel-eval--error-name-p (err name)
 134   (unless (null err)
 135     (or (and (eq (fuel-eval--error-name err) name) err)
 136         (assoc name err))))
 137
 138 (defsubst fuel-eval--error-file (err)
 139   (nth 1 (fuel-eval--error-name-p err 'source-file-error)))
 140
 141 (defsubst fuel-eval--error-lexer-p (err)
 142   (or (fuel-eval--error-name-p err 'lexer-error)
 143       (fuel-eval--error-name-p (fuel-eval--error-name-p err 'source-file-error)
 144                                'lexer-error)))
 145
 146 (defsubst fuel-eval--error-line/column (err)
 147   (let ((err (fuel-eval--error-lexer-p err)))
 148     (cons (nth 1 err) (nth 2 err))))
 149
 150 (defsubst fuel-eval--error-line-text (err)
 151   (nth 3 (fuel-eval--error-lexer-p err)))
 152
 153 \f
 154 (provide 'fuel-eval)
 155 ;;; fuel-eval.el ends here