misc/fuel/fuel-eval.el

   1 ;;; fuel-eval.el --- evaluating Factor expressions
   2
   3 ;; Copyright (C) 2008, 2009  Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages
   8 ;; Start date: Tue Dec 02, 2008
   9
  10 ;;; Commentary:
  11
  12 ;; Protocols for sending evaluations to the Factor listener.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-syntax)
  17 (require 'fuel-connection)
  18 (require 'fuel-log)
  19 (require 'fuel-base)
  20
  21 (eval-when-compile (require 'cl))
  22
  23 \f
  24 ;;; Simple sexp-based representation of factor code
  25
  26 (defun factor (sexp)
  27   (cond ((null sexp) "f")
  28         ((eq sexp t) "t")
  29         ((or (stringp sexp) (numberp sexp)) (format "%S" sexp))
  30         ((vectorp sexp) (factor (cons :quotation (append sexp nil))))
  31         ((listp sexp)
  32          (case (car sexp)
  33            (:array (factor--seq 'V{ '} (cdr sexp)))
  34            (:quote (format "\\ %s" (factor `(:factor ,(cadr sexp)))))
  35            (:quotation (factor--seq '\[ '\] (cdr sexp)))
  36            (:using (factor `(USING: ,@(cdr sexp) :end)))
  37            (:factor (format "%s" (mapconcat 'identity (cdr sexp) " ")))
  38            (:fuel (factor--fuel-factor (cons :rs (cdr sexp))))
  39            (:fuel* (factor--fuel-factor (cons :nrs (cdr sexp))))
  40            (t (mapconcat 'factor sexp " "))))
  41         ((keywordp sexp)
  42          (factor (case sexp
  43                    (:rs 'fuel-eval-restartable)
  44                    (:nrs 'fuel-eval-non-restartable)
  45                    (:in (or (fuel-syntax--current-vocab) "fuel"))
  46                    (:usings `(:array ,@(fuel-syntax--usings)))
  47                    (:get 'fuel-eval-set-result)
  48                    (:end '\;)
  49                    (t `(:factor ,(symbol-name sexp))))))
  50         ((symbolp sexp) (symbol-name sexp))))
  51
  52 (defsubst factor--seq (begin end forms)
  53   (format "%s %s %s" begin (if forms (factor forms) "") end))
  54
  55 (defsubst factor--fuel-factor (sexp)
  56   (factor `(,(factor--fuel-restart (nth 0 sexp))
  57             ,(factor--fuel-lines (nth 1 sexp))
  58             ,(factor--fuel-in (nth 2 sexp))
  59             ,(factor--fuel-usings (nth 3 sexp))
  60             fuel-eval-in-context)))
  61
  62 (defsubst factor--fuel-restart (rs)
  63   (unless (member rs '(:rs :nrs))
  64     (error "Invalid restart spec (%s)" rs))
  65   rs)
  66
  67 (defsubst factor--fuel-lines (lst)
  68   (cons :array (mapcar 'factor lst)))
  69
  70 (defsubst factor--fuel-in (in)
  71   (cond ((or (eq in :in) (null in)) :in)
  72         ((eq in 'f) 'f)
  73         ((eq in 't) "fuel")
  74         ((stringp in) in)
  75         (t (error "Invalid 'in' (%s)" in))))
  76
  77 (defsubst factor--fuel-usings (usings)
  78   (cond ((null usings) :usings)
  79         ((eq usings t) nil)
  80         ((listp usings) `(:array ,@usings))
  81         (t (error "Invalid 'usings' (%s)" usings))))
  82
  83 \f
  84 ;;; Code sending:
  85
  86 (defvar fuel-eval--default-proc-function nil)
  87 (defsubst fuel-eval--default-proc ()
  88   (and fuel-eval--default-proc-function
  89        (funcall fuel-eval--default-proc-function)))
  90
  91 (defvar fuel-eval--proc nil)
  92
  93 (defvar fuel-eval--sync-retort nil)
  94
  95 (defun fuel-eval--send/wait (code &optional timeout buffer)
  96   (setq fuel-eval--sync-retort nil)
  97   (fuel-con--send-string/wait (or fuel-eval--proc (fuel-eval--default-proc))
  98                               (if (stringp code) code (factor code))
  99                               '(lambda (s)
 100                                  (setq fuel-eval--sync-retort
 101                                        (fuel-eval--parse-retort s)))
 102                               timeout
 103                               buffer)
 104   fuel-eval--sync-retort)
 105
 106 (defun fuel-eval--send (code cont &optional buffer)
 107   (fuel-con--send-string (or fuel-eval--proc (fuel-eval--default-proc))
 108                          (if (stringp code) code (factor code))
 109                          `(lambda (s) (,cont (fuel-eval--parse-retort s)))
 110                          buffer))
 111
 112 \f
 113 ;;; Retort and retort-error datatypes:
 114
 115 (defsubst fuel-eval--retort-make (err result &optional output)
 116   (list err result output))
 117
 118 (defsubst fuel-eval--retort-error (ret) (nth 0 ret))
 119 (defsubst fuel-eval--retort-result (ret) (nth 1 ret))
 120 (defsubst fuel-eval--retort-output (ret) (nth 2 ret))
 121
 122 (defsubst fuel-eval--retort-p (ret)
 123   (and (listp ret) (= 3 (length ret))))
 124
 125 (defsubst fuel-eval--make-parse-error-retort (str)
 126   (fuel-eval--retort-make (cons 'fuel-parse-retort-error str) nil))
 127
 128 (defun fuel-eval--parse-retort (ret)
 129   (fuel-log--info "RETORT: %S" ret)
 130   (if (fuel-eval--retort-p ret) ret
 131     (fuel-eval--make-parse-error-retort ret)))
 132
 133 (defsubst fuel-eval--error-name (err) (car err))
 134
 135 (defun fuel-eval--error-name-p (err name)
 136   (unless (null err)
 137     (or (and (eq (fuel-eval--error-name err) name) err)
 138         (assoc name err))))
 139
 140 (defsubst fuel-eval--error-restarts (err)
 141   (cdr (assoc :restarts (or (fuel-eval--error-name-p err 'condition)
 142                             (fuel-eval--error-name-p err 'lexer-error)))))
 143
 144 (defsubst fuel-eval--error-file (err)
 145   (nth 1 (fuel-eval--error-name-p err 'source-file-error)))
 146
 147 (defsubst fuel-eval--error-lexer-p (err)
 148   (or (fuel-eval--error-name-p err 'lexer-error)
 149       (fuel-eval--error-name-p (fuel-eval--error-name-p err 'source-file-error)
 150                                'lexer-error)))
 151
 152 (defsubst fuel-eval--error-line/column (err)
 153   (let ((err (fuel-eval--error-lexer-p err)))
 154     (cons (nth 1 err) (nth 2 err))))
 155
 156 (defsubst fuel-eval--error-line-text (err)
 157   (nth 3 (fuel-eval--error-lexer-p err)))
 158
 159 \f
 160 (provide 'fuel-eval)
 161 ;;; fuel-eval.el ends here