misc/fuel/fuel-listener.el

   1 ;;; fuel-listener.el --- starting the fuel listener
   2
   3 ;; Copyright (C) 2008  Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages
   8
   9 ;;; Commentary:
  10
  11 ;; Utilities to maintain and switch to a factor listener comint
  12 ;; buffer, with an accompanying major fuel-listener-mode.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-eval)
  17 (require 'fuel-completion)
  18 (require 'fuel-connection)
  19 (require 'fuel-syntax)
  20 (require 'fuel-base)
  21
  22 (require 'comint)
  23
  24 \f
  25 ;;; Customization:
  26
  27 (defgroup fuel-listener nil
  28   "Interacting with a Factor listener inside Emacs"
  29   :group 'fuel)
  30
  31 (defcustom fuel-listener-factor-binary "~/factor/factor"
  32   "Full path to the factor executable to use when starting a listener."
  33   :type '(file :must-match t)
  34   :group 'fuel-listener)
  35
  36 (defcustom fuel-listener-factor-image "~/factor/factor.image"
  37   "Full path to the factor image to use when starting a listener."
  38   :type '(file :must-match t)
  39   :group 'fuel-listener)
  40
  41 (defcustom fuel-listener-use-other-window t
  42   "Use a window other than the current buffer's when switching to
  43 the factor-listener buffer."
  44   :type 'boolean
  45   :group 'fuel-listener)
  46
  47 (defcustom fuel-listener-window-allow-split t
  48   "Allow window splitting when switching to the fuel listener
  49 buffer."
  50   :type 'boolean
  51   :group 'fuel-listener)
  52
  53 \f
  54 ;;; Fuel listener buffer/process:
  55
  56 (defvar fuel-listener--buffer nil
  57   "The buffer in which the Factor listener is running.")
  58
  59 (defun fuel-listener--buffer ()
  60   (if (buffer-live-p fuel-listener--buffer)
  61       fuel-listener--buffer
  62     (with-current-buffer (get-buffer-create "*fuel listener*")
  63       (fuel-listener-mode)
  64       (setq fuel-listener--buffer (current-buffer)))))
  65
  66 (defun fuel-listener--start-process ()
  67   (let ((factor (expand-file-name fuel-listener-factor-binary))
  68         (image (expand-file-name fuel-listener-factor-image))
  69         (comint-redirect-perform-sanity-check nil))
  70     (unless (file-executable-p factor)
  71       (error "Could not run factor: %s is not executable" factor))
  72     (unless (file-readable-p image)
  73       (error "Could not run factor: image file %s not readable" image))
  74     (message "Starting FUEL listener ...")
  75     (pop-to-buffer (fuel-listener--buffer))
  76     (make-comint-in-buffer "fuel listener" (current-buffer) factor nil
  77                            "-run=listener" (format "-i=%s" image))
  78     (fuel-listener--wait-for-prompt 10000)
  79     (fuel-con--setup-connection (current-buffer))
  80     (fuel-con--send-string/wait (current-buffer)
  81                                 fuel-con--init-stanza
  82                                 '(lambda (s) (message "FUEL listener up and running!"))
  83                                 20000)))
  84
  85 (defun fuel-listener--process (&optional start)
  86   (or (and (buffer-live-p (fuel-listener--buffer))
  87            (get-buffer-process (fuel-listener--buffer)))
  88       (if (not start)
  89           (error "No running factor listener (try M-x run-factor)")
  90         (fuel-listener--start-process)
  91         (fuel-listener--process))))
  92
  93 (setq fuel-eval--default-proc-function 'fuel-listener--process)
  94
  95 (defun fuel-listener--wait-for-prompt (timeout)
  96   (let ((p (point)) (seen))
  97     (while (and (not seen) (> timeout 0))
  98       (sleep-for 0.1)
  99       (setq timeout (- timeout 100))
 100       (goto-char p)
 101       (setq seen (re-search-forward comint-prompt-regexp nil t)))
 102     (goto-char (point-max))
 103     (unless seen (error "No prompt found!"))))
 104
 105 \f
 106 ;;; Completion support
 107
 108 (defsubst fuel-listener--current-vocab () nil)
 109 (defsubst fuel-listener--usings () nil)
 110
 111 (defun fuel-listener--setup-completion ()
 112   (setq fuel-syntax--current-vocab-function 'fuel-listener--current-vocab)
 113   (setq fuel-syntax--usings-function 'fuel-listener--usings)
 114   (set-syntax-table fuel-syntax--syntax-table))
 115
 116 \f
 117 ;;; Interface: starting fuel listener
 118
 119 (defalias 'switch-to-factor 'run-factor)
 120 (defalias 'switch-to-fuel-listener 'run-factor)
 121 ;;;###autoload
 122 (defun run-factor (&optional arg)
 123   "Show the fuel-listener buffer, starting the process if needed."
 124   (interactive)
 125   (let ((buf (process-buffer (fuel-listener--process t)))
 126         (pop-up-windows fuel-listener-window-allow-split))
 127     (if fuel-listener-use-other-window
 128         (pop-to-buffer buf)
 129       (switch-to-buffer buf))))
 130
 131 \f
 132 ;;; Fuel listener mode:
 133
 134 ;;;###autoload
 135 (define-derived-mode fuel-listener-mode comint-mode "Fuel Listener"
 136   "Major mode for interacting with an inferior Factor listener process.
 137 \\{fuel-listener-mode-map}"
 138   (set (make-local-variable 'comint-prompt-regexp) fuel-con--prompt-regex)
 139   (set (make-local-variable 'comint-use-prompt-regexp) t)
 140   (set (make-local-variable 'comint-prompt-read-only) t)
 141   (fuel-listener--setup-completion))
 142
 143 (define-key fuel-listener-mode-map "\C-cz" 'run-factor)
 144 (define-key fuel-listener-mode-map "\C-c\C-z" 'run-factor)
 145 (define-key fuel-listener-mode-map "\C-ca" 'fuel-autodoc-mode)
 146 (define-key fuel-listener-mode-map "\C-ch" 'fuel-help)
 147 (define-key fuel-listener-mode-map "\M-." 'fuel-edit-word-at-point)
 148 (define-key fuel-listener-mode-map "\C-cv" 'fuel-edit-vocabulary)
 149 (define-key fuel-listener-mode-map "\C-c\C-v" 'fuel-edit-vocabulary)
 150 (define-key fuel-listener-mode-map "\C-ck" 'fuel-run-file)
 151 (define-key fuel-listener-mode-map (kbd "TAB") 'fuel-completion--complete-symbol)
 152
 153 \f
 154 (provide 'fuel-listener)
 155 ;;; fuel-listener.el ends here