misc/fuel/fuel-listener.el

   1 ;;; fuel-listener.el --- starting the fuel listener
   2
   3 ;; Copyright (C) 2008, 2009  Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages
   8
   9 ;;; Commentary:
  10
  11 ;; Utilities to maintain and switch to a factor listener comint
  12 ;; buffer, with an accompanying major fuel-listener-mode.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-stack)
  17 (require 'fuel-completion)
  18 (require 'fuel-xref)
  19 (require 'fuel-eval)
  20 (require 'fuel-connection)
  21 (require 'fuel-syntax)
  22 (require 'fuel-base)
  23
  24 (require 'comint)
  25
  26 \f
  27 ;;; Customization:
  28
  29 (defgroup fuel-listener nil
  30   "Interacting with a Factor listener inside Emacs."
  31   :group 'fuel)
  32
  33 (defcustom fuel-listener-factor-binary
  34   (expand-file-name "factor" fuel-factor-root-dir)
  35   "Full path to the factor executable to use when starting a listener."
  36   :type '(file :must-match t)
  37   :group 'fuel-listener)
  38
  39 (defcustom fuel-listener-factor-image
  40   (expand-file-name "factor.image" fuel-factor-root-dir)
  41   "Full path to the factor image to use when starting a listener."
  42   :type '(file :must-match t)
  43   :group 'fuel-listener)
  44
  45 (defcustom fuel-listener-use-other-window t
  46   "Use a window other than the current buffer's when switching to
  47 the factor-listener buffer."
  48   :type 'boolean
  49   :group 'fuel-listener)
  50
  51 (defcustom fuel-listener-window-allow-split t
  52   "Allow window splitting when switching to the fuel listener
  53 buffer."
  54   :type 'boolean
  55   :group 'fuel-listener)
  56
  57 \f
  58 ;;; Fuel listener buffer/process:
  59
  60 (defvar fuel-listener--buffer nil
  61   "The buffer in which the Factor listener is running.")
  62
  63 (defun fuel-listener--buffer ()
  64   (if (buffer-live-p fuel-listener--buffer)
  65       fuel-listener--buffer
  66     (with-current-buffer (get-buffer-create "*fuel listener*")
  67       (fuel-listener-mode)
  68       (setq fuel-listener--buffer (current-buffer)))))
  69
  70 (defun fuel-listener--start-process ()
  71   (let ((factor (expand-file-name fuel-listener-factor-binary))
  72         (image (expand-file-name fuel-listener-factor-image))
  73         (comint-redirect-perform-sanity-check nil))
  74     (unless (file-executable-p factor)
  75       (error "Could not run factor: %s is not executable" factor))
  76     (unless (file-readable-p image)
  77       (error "Could not run factor: image file %s not readable" image))
  78     (message "Starting FUEL listener (this may take a while) ...")
  79     (pop-to-buffer (fuel-listener--buffer))
  80     (make-comint-in-buffer "fuel listener" (current-buffer) factor nil
  81                            "-run=listener" (format "-i=%s" image))
  82     (fuel-listener--wait-for-prompt 10000)
  83     (fuel-con--setup-connection (current-buffer))))
  84
  85 (defun fuel-listener--process (&optional start)
  86   (or (and (buffer-live-p (fuel-listener--buffer))
  87            (get-buffer-process (fuel-listener--buffer)))
  88       (if (not start)
  89           (error "No running factor listener (try M-x run-factor)")
  90         (fuel-listener--start-process)
  91         (fuel-listener--process))))
  92
  93 (setq fuel-eval--default-proc-function 'fuel-listener--process)
  94
  95 (defun fuel-listener--wait-for-prompt (timeout)
  96   (let ((p (point)) (seen))
  97     (while (and (not seen) (> timeout 0))
  98       (sleep-for 0.1)
  99       (setq timeout (- timeout 100))
 100       (goto-char p)
 101       (setq seen (re-search-forward comint-prompt-regexp nil t)))
 102     (goto-char (point-max))
 103     (unless seen (error "No prompt found!"))))
 104
 105 (defun fuel-listener-nuke ()
 106   (interactive)
 107   (goto-char (point-max))
 108   (comint-kill-region comint-last-input-start (point))
 109   (comint-redirect-cleanup)
 110   (fuel-con--setup-connection fuel-listener--buffer))
 111
 112 \f
 113 ;;; Interface: starting fuel listener
 114
 115 (defalias 'switch-to-factor 'run-factor)
 116 (defalias 'switch-to-fuel-listener 'run-factor)
 117 ;;;###autoload
 118 (defun run-factor (&optional arg)
 119   "Show the fuel-listener buffer, starting the process if needed."
 120   (interactive)
 121   (let ((buf (process-buffer (fuel-listener--process t)))
 122         (pop-up-windows fuel-listener-window-allow-split))
 123     (if fuel-listener-use-other-window
 124         (pop-to-buffer buf)
 125       (switch-to-buffer buf))))
 126
 127 \f
 128 ;;; Completion support
 129
 130 (defsubst fuel-listener--current-vocab () nil)
 131 (defsubst fuel-listener--usings () nil)
 132
 133 (defun fuel-listener--setup-completion ()
 134   (setq fuel-syntax--current-vocab-function 'fuel-listener--current-vocab)
 135   (setq fuel-syntax--usings-function 'fuel-listener--usings)
 136   (set-syntax-table fuel-syntax--syntax-table))
 137
 138 \f
 139 ;;; Stack mode support
 140
 141 (defun fuel-listener--stack-region ()
 142   (fuel--region-to-string (if (zerop (fuel-syntax--brackets-depth))
 143                               (comint-line-beginning-position)
 144                             (1+ (fuel-syntax--brackets-start)))))
 145
 146 (defun fuel-listener--setup-stack-mode ()
 147   (setq fuel-stack--region-function 'fuel-listener--stack-region))
 148
 149 \f
 150 ;;; Fuel listener mode:
 151
 152 (defun fuel-listener--bol ()
 153   (interactive)
 154   (when (= (point) (comint-bol)) (beginning-of-line)))
 155
 156 ;;;###autoload
 157 (define-derived-mode fuel-listener-mode comint-mode "Fuel Listener"
 158   "Major mode for interacting with an inferior Factor listener process.
 159 \\{fuel-listener-mode-map}"
 160   (set (make-local-variable 'comint-prompt-regexp) fuel-con--prompt-regex)
 161   (set (make-local-variable 'comint-use-prompt-regexp) t)
 162   (set (make-local-variable 'comint-prompt-read-only) t)
 163   (set-syntax-table fuel-syntax--syntax-table)
 164   (fuel-listener--setup-completion)
 165   (fuel-listener--setup-stack-mode))
 166
 167 (define-key fuel-listener-mode-map "\C-cz" 'run-factor)
 168 (define-key fuel-listener-mode-map "\C-c\C-z" 'run-factor)
 169 (define-key fuel-listener-mode-map "\C-a" 'fuel-listener--bol)
 170 (define-key fuel-listener-mode-map "\C-ca" 'fuel-autodoc-mode)
 171 (define-key fuel-listener-mode-map "\C-ch" 'fuel-help)
 172 (define-key fuel-listener-mode-map "\C-cs" 'fuel-stack-mode)
 173 (define-key fuel-listener-mode-map "\C-cp" 'fuel-apropos)
 174 (define-key fuel-listener-mode-map "\M-." 'fuel-edit-word-at-point)
 175 (define-key fuel-listener-mode-map "\C-cv" 'fuel-edit-vocabulary)
 176 (define-key fuel-listener-mode-map "\C-c\C-v" 'fuel-edit-vocabulary)
 177 (define-key fuel-listener-mode-map "\C-ck" 'fuel-run-file)
 178 (define-key fuel-listener-mode-map (kbd "TAB") 'fuel-completion--complete-symbol)
 179
 180 \f
 181 (provide 'fuel-listener)
 182 ;;; fuel-listener.el ends here