misc/fuel/fuel-listener.el

   1 ;;; fuel-listener.el --- starting the fuel listener
   2
   3 ;; Copyright (C) 2008, 2009  Jose Antonio Ortega Ruiz
   4 ;; See http://factorcode.org/license.txt for BSD license.
   5
   6 ;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
   7 ;; Keywords: languages
   8
   9 ;;; Commentary:
  10
  11 ;; Utilities to maintain and switch to a factor listener comint
  12 ;; buffer, with an accompanying major fuel-listener-mode.
  13
  14 ;;; Code:
  15
  16 (require 'fuel-stack)
  17 (require 'fuel-completion)
  18 (require 'fuel-xref)
  19 (require 'fuel-eval)
  20 (require 'fuel-connection)
  21 (require 'fuel-syntax)
  22 (require 'fuel-base)
  23
  24 (require 'comint)
  25
  26 \f
  27 ;;; Customization:
  28
  29 (defgroup fuel-listener nil
  30   "Interacting with a Factor listener inside Emacs."
  31   :group 'fuel)
  32
  33 (defcustom fuel-listener-factor-binary "~/factor/factor"
  34   "Full path to the factor executable to use when starting a listener."
  35   :type '(file :must-match t)
  36   :group 'fuel-listener)
  37
  38 (defcustom fuel-listener-factor-image "~/factor/factor.image"
  39   "Full path to the factor image to use when starting a listener."
  40   :type '(file :must-match t)
  41   :group 'fuel-listener)
  42
  43 (defcustom fuel-listener-use-other-window t
  44   "Use a window other than the current buffer's when switching to
  45 the factor-listener buffer."
  46   :type 'boolean
  47   :group 'fuel-listener)
  48
  49 (defcustom fuel-listener-window-allow-split t
  50   "Allow window splitting when switching to the fuel listener
  51 buffer."
  52   :type 'boolean
  53   :group 'fuel-listener)
  54
  55 \f
  56 ;;; Fuel listener buffer/process:
  57
  58 (defvar fuel-listener--buffer nil
  59   "The buffer in which the Factor listener is running.")
  60
  61 (defun fuel-listener--buffer ()
  62   (if (buffer-live-p fuel-listener--buffer)
  63       fuel-listener--buffer
  64     (with-current-buffer (get-buffer-create "*fuel listener*")
  65       (fuel-listener-mode)
  66       (setq fuel-listener--buffer (current-buffer)))))
  67
  68 (defun fuel-listener--start-process ()
  69   (let ((factor (expand-file-name fuel-listener-factor-binary))
  70         (image (expand-file-name fuel-listener-factor-image))
  71         (comint-redirect-perform-sanity-check nil))
  72     (unless (file-executable-p factor)
  73       (error "Could not run factor: %s is not executable" factor))
  74     (unless (file-readable-p image)
  75       (error "Could not run factor: image file %s not readable" image))
  76     (message "Starting FUEL listener (this may take a while) ...")
  77     (pop-to-buffer (fuel-listener--buffer))
  78     (make-comint-in-buffer "fuel listener" (current-buffer) factor nil
  79                            "-run=listener" (format "-i=%s" image))
  80     (fuel-listener--wait-for-prompt 10000)
  81     (fuel-con--setup-connection (current-buffer))))
  82
  83 (defun fuel-listener--process (&optional start)
  84   (or (and (buffer-live-p (fuel-listener--buffer))
  85            (get-buffer-process (fuel-listener--buffer)))
  86       (if (not start)
  87           (error "No running factor listener (try M-x run-factor)")
  88         (fuel-listener--start-process)
  89         (fuel-listener--process))))
  90
  91 (setq fuel-eval--default-proc-function 'fuel-listener--process)
  92
  93 (defun fuel-listener--wait-for-prompt (timeout)
  94   (let ((p (point)) (seen))
  95     (while (and (not seen) (> timeout 0))
  96       (sleep-for 0.1)
  97       (setq timeout (- timeout 100))
  98       (goto-char p)
  99       (setq seen (re-search-forward comint-prompt-regexp nil t)))
 100     (goto-char (point-max))
 101     (unless seen (error "No prompt found!"))))
 102
 103 (defun fuel-listener-nuke ()
 104   (interactive)
 105   (goto-char (point-max))
 106   (comint-kill-region comint-last-input-start (point))
 107   (comint-redirect-cleanup)
 108   (fuel-con--setup-connection fuel-listener--buffer))
 109
 110 \f
 111 ;;; Interface: starting fuel listener
 112
 113 (defalias 'switch-to-factor 'run-factor)
 114 (defalias 'switch-to-fuel-listener 'run-factor)
 115 ;;;###autoload
 116 (defun run-factor (&optional arg)
 117   "Show the fuel-listener buffer, starting the process if needed."
 118   (interactive)
 119   (let ((buf (process-buffer (fuel-listener--process t)))
 120         (pop-up-windows fuel-listener-window-allow-split))
 121     (if fuel-listener-use-other-window
 122         (pop-to-buffer buf)
 123       (switch-to-buffer buf))))
 124
 125 \f
 126 ;;; Completion support
 127
 128 (defsubst fuel-listener--current-vocab () nil)
 129 (defsubst fuel-listener--usings () nil)
 130
 131 (defun fuel-listener--setup-completion ()
 132   (setq fuel-syntax--current-vocab-function 'fuel-listener--current-vocab)
 133   (setq fuel-syntax--usings-function 'fuel-listener--usings)
 134   (set-syntax-table fuel-syntax--syntax-table))
 135
 136 \f
 137 ;;; Stack mode support
 138
 139 (defun fuel-listener--stack-region ()
 140   (fuel--region-to-string (if (zerop (fuel-syntax--brackets-depth))
 141                               (comint-line-beginning-position)
 142                             (1+ (fuel-syntax--brackets-start)))))
 143
 144 (defun fuel-listener--setup-stack-mode ()
 145   (setq fuel-stack--region-function 'fuel-listener--stack-region))
 146
 147 \f
 148 ;;; Fuel listener mode:
 149
 150 (defun fuel-listener--bol ()
 151   (interactive)
 152   (when (= (point) (comint-bol)) (beginning-of-line)))
 153
 154 ;;;###autoload
 155 (define-derived-mode fuel-listener-mode comint-mode "Fuel Listener"
 156   "Major mode for interacting with an inferior Factor listener process.
 157 \\{fuel-listener-mode-map}"
 158   (set (make-local-variable 'comint-prompt-regexp) fuel-con--prompt-regex)
 159   (set (make-local-variable 'comint-use-prompt-regexp) t)
 160   (set (make-local-variable 'comint-prompt-read-only) t)
 161   (set-syntax-table fuel-syntax--syntax-table)
 162   (fuel-listener--setup-completion)
 163   (fuel-listener--setup-stack-mode))
 164
 165 (define-key fuel-listener-mode-map "\C-cz" 'run-factor)
 166 (define-key fuel-listener-mode-map "\C-c\C-z" 'run-factor)
 167 (define-key fuel-listener-mode-map "\C-a" 'fuel-listener--bol)
 168 (define-key fuel-listener-mode-map "\C-ca" 'fuel-autodoc-mode)
 169 (define-key fuel-listener-mode-map "\C-ch" 'fuel-help)
 170 (define-key fuel-listener-mode-map "\C-cs" 'fuel-stack-mode)
 171 (define-key fuel-listener-mode-map "\C-cp" 'fuel-apropos)
 172 (define-key fuel-listener-mode-map "\M-." 'fuel-edit-word-at-point)
 173 (define-key fuel-listener-mode-map "\C-cv" 'fuel-edit-vocabulary)
 174 (define-key fuel-listener-mode-map "\C-c\C-v" 'fuel-edit-vocabulary)
 175 (define-key fuel-listener-mode-map "\C-ck" 'fuel-run-file)
 176 (define-key fuel-listener-mode-map (kbd "TAB") 'fuel-completion--complete-symbol)
 177
 178 \f
 179 (provide 'fuel-listener)
 180 ;;; fuel-listener.el ends here