unmaintained/llvm/wrappers/wrappers.factor

   1 ! Copyright (C) 2009 Matthew Willis.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.data alien.strings
   4 io.encodings.utf8 destructors kernel
   5 llvm.core llvm.engine ;
   6
   7 IN: llvm.wrappers
   8
   9 : llvm-throw ( c-string -- )
  10     [ utf8 alien>string ] [ LLVMDisposeMessage ] bi throw ;
  11
  12 : <dispose> ( alien class -- disposable ) new swap >>value ;
  13
  14 TUPLE: module value disposed ;
  15 M: module dispose* value>> LLVMDisposeModule ;
  16
  17 : <module> ( name -- module )
  18     LLVMModuleCreateWithName module <dispose> ;
  19
  20 TUPLE: provider value module disposed ;
  21 M: provider dispose* value>> LLVMDisposeModuleProvider ;
  22
  23 : (provider) ( module -- provider )
  24     [ value>> LLVMCreateModuleProviderForExistingModule provider <dispose> ]
  25     [ t >>disposed value>> ] bi
  26     >>module ;
  27
  28 : <provider> ( module -- provider )
  29     [ (provider) ] with-disposal ;
  30
  31 TUPLE: engine value disposed ;
  32 M: engine dispose* value>> LLVMDisposeExecutionEngine ;
  33
  34 : (engine) ( provider -- engine )
  35     [
  36         value>> f void* <ref> f void* <ref>
  37         [ swapd 0 swap LLVMCreateJITCompiler drop ] 2keep
  38         void* deref [ llvm-throw ] when* void* deref
  39     ]
  40     [ t >>disposed drop ] bi
  41     engine <dispose> ;
  42
  43 : <engine> ( provider -- engine )
  44     [ (engine) ] with-disposal ;
  45
  46 : (add-block) ( name -- basic-block )
  47     "function" swap LLVMAppendBasicBlock ;
  48
  49 TUPLE: builder value disposed ;
  50 M: builder dispose* value>> LLVMDisposeBuilder ;
  51
  52 : <builder> ( name -- builder )
  53     (add-block) LLVMCreateBuilder [ swap LLVMPositionBuilderAtEnd ] keep
  54     builder <dispose> ;
  55
  56 TUPLE: buffer value disposed ;
  57 M: buffer dispose* value>> LLVMDisposeMemoryBuffer ;
  58
  59 : <buffer> ( path -- module )
  60     f void* <ref> f void* <ref>
  61     [ LLVMCreateMemoryBufferWithContentsOfFile drop ] 2keep
  62     void* deref [ llvm-throw ] when* void* deref buffer <dispose> ;