basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs binary-search combinators
   4 compiler.cfg.def-use compiler.cfg.instructions
   5 compiler.cfg.linearization compiler.cfg.liveness
   6 compiler.cfg.registers compiler.cfg.ssa.destruction.leaders
   7 cpu.architecture fry kernel locals math math.order namespaces
   8 sequences ;
   9 IN: compiler.cfg.linear-scan.live-intervals
  10
  11 TUPLE: live-range from to ;
  12
  13 C: <live-range> live-range
  14
  15 TUPLE: vreg-use n def-rep use-rep spill-slot? ;
  16
  17 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  18
  19 TUPLE: live-interval-state
  20 vreg
  21 reg spill-to spill-rep reload-from reload-rep
  22 start end ranges uses
  23 reg-class ;
  24
  25 : first-use ( live-interval -- use ) uses>> first ; inline
  26
  27 : last-use ( live-interval -- use ) uses>> last ; inline
  28
  29 : new-use ( insn# uses -- use )
  30     [ <vreg-use> dup ] dip push ;
  31
  32 : last-use? ( insn# uses -- use/f )
  33     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  34
  35 :: (add-use) ( insn# live-interval spill-slot? -- use )
  36     live-interval uses>> :> uses
  37     insn# uses last-use? [ insn# uses new-use ] unless*
  38     spill-slot? [ t >>spill-slot? ] when ;
  39
  40 GENERIC: covers? ( insn# obj -- ? )
  41
  42 M: f covers? 2drop f ;
  43
  44 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  45
  46 M: live-interval-state covers? ( insn# live-interval -- ? )
  47     ranges>>
  48     dup length 4 <= [
  49         [ covers? ] with any?
  50     ] [
  51         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  52         covers?
  53     ] if ;
  54
  55 : (find-use) ( insn# live-interval -- vreg-use )
  56     uses>> [ n>> <=> ] with search nip ;
  57
  58 :: find-use ( insn# live-interval -- vreg-use )
  59     insn# live-interval (find-use)
  60     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  61
  62 : add-new-range ( from to live-interval -- )
  63     [ <live-range> ] dip ranges>> push ;
  64
  65 : shorten-range ( n live-interval -- )
  66     dup ranges>> empty?
  67     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  68
  69 : extend-range ( from to live-range -- )
  70     ranges>> last
  71     [ max ] change-to
  72     [ min ] change-from
  73     drop ;
  74
  75 : extend-range? ( to live-interval -- ? )
  76     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  77
  78 : add-range ( from to live-interval -- )
  79     2dup extend-range?
  80     [ extend-range ] [ add-new-range ] if ;
  81
  82 : <live-interval> ( vreg reg-class -- live-interval )
  83     \ live-interval-state new
  84         V{ } clone >>uses
  85         V{ } clone >>ranges
  86         swap >>reg-class
  87         swap >>vreg ;
  88
  89 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  90
  91 : block-to ( bb -- n ) instructions>> last insn#>> ;
  92
  93 SYMBOLS: from to ;
  94
  95 SYMBOL: live-intervals
  96
  97 : live-interval ( vreg -- live-interval )
  98     leader live-intervals get
  99     [ dup rep-of reg-class-of <live-interval> ] cache ;
 100
 101 GENERIC: compute-live-intervals* ( insn -- )
 102
 103 M: insn compute-live-intervals* drop ;
 104
 105 :: record-def ( vreg n spill-slot? -- )
 106     vreg live-interval :> live-interval
 107
 108     n live-interval shorten-range
 109     n live-interval spill-slot? (add-use) vreg rep-of >>def-rep drop ;
 110
 111 :: record-use ( vreg n spill-slot? -- )
 112     vreg live-interval :> live-interval
 113
 114     from get n live-interval add-range
 115     n live-interval spill-slot? (add-use) vreg rep-of >>use-rep drop ;
 116
 117 :: record-temp ( vreg n -- )
 118     vreg live-interval :> live-interval
 119
 120     n n live-interval add-range
 121     n live-interval f (add-use) vreg rep-of >>def-rep drop ;
 122
 123 M: vreg-insn compute-live-intervals* ( insn -- )
 124     dup insn#>>
 125     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 126     [ [ uses-vregs ] dip '[ _ f record-use ] each ]
 127     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 128     2tri ;
 129
 130 ! Extend lifetime intervals of base pointers, so that their
 131 ! values are available even if the base pointer is never used
 132 ! again.
 133
 134 GENERIC: uses-vregs* ( insn -- seq )
 135
 136 M: gc-map-insn uses-vregs*
 137     [ uses-vregs ] [ gc-map>> derived-roots>> values ] bi append ;
 138
 139 M: vreg-insn uses-vregs* uses-vregs ;
 140
 141 M: insn uses-vregs* drop f ;
 142
 143 M: clobber-insn compute-live-intervals* ( insn -- )
 144     dup insn#>>
 145     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 146     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 147     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 148     2tri ;
 149
 150 M: hairy-clobber-insn compute-live-intervals* ( insn -- )
 151     dup insn#>>
 152     [ [ defs-vregs ] dip '[ _ t record-def ] each ]
 153     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 154     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 155     2tri ;
 156
 157 : handle-live-out ( bb -- )
 158     live-out dup assoc-empty? [ drop ] [
 159         [ from get to get ] dip keys
 160         [ live-interval add-range ] 2with each
 161     ] if ;
 162
 163 TUPLE: sync-point n keep-dst? ;
 164
 165 C: <sync-point> sync-point
 166
 167 ! Sequence of sync points
 168 SYMBOL: sync-points
 169
 170 GENERIC: compute-sync-points* ( insn -- )
 171
 172 M: hairy-clobber-insn compute-sync-points*
 173     insn#>> f <sync-point> sync-points get push ;
 174
 175 M: clobber-insn compute-sync-points*
 176     insn#>> t <sync-point> sync-points get push ;
 177
 178 M: insn compute-sync-points* drop ;
 179
 180 : compute-live-intervals-step ( bb -- )
 181     dup kill-block?>> [ drop ] [
 182         {
 183             [ block-from from set ]
 184             [ block-to to set ]
 185             [ handle-live-out ]
 186             [
 187                 instructions>> <reversed> [
 188                     [ compute-live-intervals* ]
 189                     [ compute-sync-points* ]
 190                     bi
 191                 ] each
 192             ]
 193         } cleave
 194     ] if ;
 195
 196 : init-live-intervals ( -- )
 197     H{ } clone live-intervals set
 198     V{ } clone sync-points set ;
 199
 200 : compute-start/end ( live-interval -- )
 201     dup ranges>> [ first from>> ] [ last to>> ] bi
 202     [ >>start ] [ >>end ] bi* drop ;
 203
 204 ERROR: bad-live-interval live-interval ;
 205
 206 : check-start ( live-interval -- )
 207     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 208
 209 : finish-live-intervals ( live-intervals -- seq )
 210     ! Since live intervals are computed in a backward order, we have
 211     ! to reverse some sequences, and compute the start and end.
 212     values dup [
 213         {
 214             [ [ { } like reverse! ] change-ranges drop ]
 215             [ [ { } like reverse! ] change-uses drop ]
 216             [ compute-start/end ]
 217             [ check-start ]
 218         } cleave
 219     ] each ;
 220
 221 : compute-live-intervals ( cfg -- live-intervals sync-points )
 222     init-live-intervals
 223     linearization-order <reversed> [ compute-live-intervals-step ] each
 224     live-intervals get finish-live-intervals
 225     sync-points get ;
 226
 227 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 228     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 229
 230 : intersect-live-range ( range1 range2 -- n/f )
 231     2dup [ from>> ] bi@ > [ swap ] when
 232     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 233
 234 : intersect-live-ranges ( ranges1 ranges2 -- n )
 235     {
 236         { [ over empty? ] [ 2drop f ] }
 237         { [ dup empty? ] [ 2drop f ] }
 238         [
 239             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 240                 drop
 241                 2dup [ first from>> ] bi@ <
 242                 [ [ rest-slice ] dip ] [ rest-slice ] if
 243                 intersect-live-ranges
 244             ] if
 245         ]
 246     } cond ;
 247
 248 : intervals-intersect? ( interval1 interval2 -- ? )
 249     relevant-ranges intersect-live-ranges >boolean ; inline