basis/cpu/x86/x86.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs alien alien.c-types arrays strings
   4 cpu.x86.assembler cpu.x86.assembler.private cpu.x86.assembler.operands
   5 cpu.architecture kernel kernel.private math memory namespaces make
   6 sequences words system layouts combinators math.order fry locals
   7 compiler.constants
   8 compiler.cfg.registers
   9 compiler.cfg.instructions
  10 compiler.cfg.intrinsics
  11 compiler.cfg.comparisons
  12 compiler.cfg.stack-frame
  13 compiler.codegen
  14 compiler.codegen.fixup ;
  15 IN: cpu.x86
  16
  17 << enable-fixnum-log2 >>
  18
  19 ! Add some methods to the assembler to be more useful to the backend
  20 M: label JMP 0 JMP rc-relative label-fixup ;
  21 M: label JUMPcc [ 0 ] dip JUMPcc rc-relative label-fixup ;
  22
  23 M: x86 two-operand? t ;
  24
  25 HOOK: stack-reg cpu ( -- reg )
  26
  27 HOOK: reserved-area-size cpu ( -- n )
  28
  29 : stack@ ( n -- op ) stack-reg swap [+] ;
  30
  31 : param@ ( n -- op ) reserved-area-size + stack@ ;
  32
  33 : spill@ ( n -- op ) spill-offset param@ ;
  34
  35 : gc-root@ ( n -- op ) gc-root-offset param@ ;
  36
  37 : decr-stack-reg ( n -- )
  38     dup 0 = [ drop ] [ stack-reg swap SUB ] if ;
  39
  40 : incr-stack-reg ( n -- )
  41     dup 0 = [ drop ] [ stack-reg swap ADD ] if ;
  42
  43 : align-stack ( n -- n' )
  44     os macosx? cpu x86.64? or [ 16 align ] when ;
  45
  46 M: x86 stack-frame-size ( stack-frame -- i )
  47     (stack-frame-size) 3 cells reserved-area-size + + align-stack ;
  48
  49 ! Must be a volatile register not used for parameter passing, for safe
  50 ! use in calls in and out of C
  51 HOOK: temp-reg cpu ( -- reg )
  52
  53 ! Fastcall calling convention
  54 HOOK: param-reg-1 cpu ( -- reg )
  55 HOOK: param-reg-2 cpu ( -- reg )
  56
  57 HOOK: pic-tail-reg cpu ( -- reg )
  58
  59 M: x86 %load-immediate dup 0 = [ drop dup XOR ] [ MOV ] if ;
  60
  61 M: x86 %load-reference swap 0 MOV rc-absolute-cell rel-immediate ;
  62
  63 HOOK: ds-reg cpu ( -- reg )
  64 HOOK: rs-reg cpu ( -- reg )
  65
  66 : reg-stack ( n reg -- op ) swap cells neg [+] ;
  67
  68 GENERIC: loc>operand ( loc -- operand )
  69
  70 M: ds-loc loc>operand n>> ds-reg reg-stack ;
  71 M: rs-loc loc>operand n>> rs-reg reg-stack ;
  72
  73 M: x86 %peek loc>operand MOV ;
  74 M: x86 %replace loc>operand swap MOV ;
  75 : (%inc) ( n reg -- ) swap cells dup 0 > [ ADD ] [ neg SUB ] if ; inline
  76 M: x86 %inc-d ( n -- ) ds-reg (%inc) ;
  77 M: x86 %inc-r ( n -- ) rs-reg (%inc) ;
  78
  79 M: x86 %call ( word -- ) 0 CALL rc-relative rel-word-pic ;
  80
  81 : xt-tail-pic-offset ( -- n )
  82     #! See the comment in vm/cpu-x86.hpp
  83     cell 4 + 1 + ; inline
  84
  85 M: x86 %jump ( word -- )
  86     pic-tail-reg 0 MOV xt-tail-pic-offset rc-absolute-cell rel-here
  87     0 JMP rc-relative rel-word-pic-tail ;
  88
  89 M: x86 %jump-label ( label -- ) 0 JMP rc-relative label-fixup ;
  90
  91 M: x86 %return ( -- ) 0 RET ;
  92
  93 : code-alignment ( align -- n )
  94     [ building get length dup ] dip align swap - ;
  95
  96 : align-code ( n -- )
  97     0 <repetition> % ;
  98
  99 :: (%slot) ( obj slot tag temp -- op )
 100     temp slot obj [+] LEA
 101     temp tag neg [+] ; inline
 102
 103 :: (%slot-imm) ( obj slot tag -- op )
 104     obj slot cells tag - [+] ; inline
 105
 106 M: x86 %slot ( dst obj slot tag temp -- ) (%slot) MOV ;
 107 M: x86 %slot-imm ( dst obj slot tag -- ) (%slot-imm) MOV ;
 108 M: x86 %set-slot ( src obj slot tag temp -- ) (%slot) swap MOV ;
 109 M: x86 %set-slot-imm ( src obj slot tag -- ) (%slot-imm) swap MOV ;
 110
 111 M: x86 %add     2over eq? [ nip ADD ] [ [+] LEA ] if ;
 112 M: x86 %add-imm 2over eq? [ nip ADD ] [ [+] LEA ] if ;
 113 M: x86 %sub     nip SUB ;
 114 M: x86 %sub-imm 2over eq? [ nip SUB ] [ neg [+] LEA ] if ;
 115 M: x86 %mul     nip swap IMUL2 ;
 116 M: x86 %mul-imm IMUL3 ;
 117 M: x86 %and     nip AND ;
 118 M: x86 %and-imm nip AND ;
 119 M: x86 %or      nip OR ;
 120 M: x86 %or-imm  nip OR ;
 121 M: x86 %xor     nip XOR ;
 122 M: x86 %xor-imm nip XOR ;
 123 M: x86 %shl-imm nip SHL ;
 124 M: x86 %shr-imm nip SHR ;
 125 M: x86 %sar-imm nip SAR ;
 126 M: x86 %not     drop NOT ;
 127 M: x86 %log2    BSR ;
 128
 129 :: overflow-template ( label dst src1 src2 insn -- )
 130     src1 src2 insn call
 131     label JO ; inline
 132
 133 M: x86 %fixnum-add ( label dst src1 src2 -- )
 134     [ ADD ] overflow-template ;
 135
 136 M: x86 %fixnum-sub ( label dst src1 src2 -- )
 137     [ SUB ] overflow-template ;
 138
 139 M: x86 %fixnum-mul ( label dst src1 src2 -- )
 140     [ swap IMUL2 ] overflow-template ;
 141
 142 : bignum@ ( reg n -- op )
 143     cells bignum tag-number - [+] ; inline
 144
 145 M:: x86 %integer>bignum ( dst src temp -- )
 146     #! on entry, inreg is a signed 32-bit quantity
 147     #! exits with tagged ptr to bignum in outreg
 148     #! 1 cell header, 1 cell length, 1 cell sign, + digits
 149     #! length is the # of digits + sign
 150     [
 151         "end" define-label
 152         ! Load cached zero value
 153         dst 0 >bignum %load-reference
 154         src 0 CMP
 155         ! Is it zero? Then just go to the end and return this zero
 156         "end" get JE
 157         ! Allocate a bignum
 158         dst 4 cells bignum temp %allot
 159         ! Write length
 160         dst 1 bignum@ 2 tag-fixnum MOV
 161         ! Store value
 162         dst 3 bignum@ src MOV
 163         ! Compute sign
 164         temp src MOV
 165         temp cell-bits 1 - SAR
 166         temp 1 AND
 167         ! Store sign
 168         dst 2 bignum@ temp MOV
 169         ! Make negative value positive
 170         temp temp ADD
 171         temp NEG
 172         temp 1 ADD
 173         src temp IMUL2
 174         ! Store the bignum
 175         dst 3 bignum@ temp MOV
 176         "end" resolve-label
 177     ] with-scope ;
 178
 179 M:: x86 %bignum>integer ( dst src temp -- )
 180     [
 181         "end" define-label
 182         ! load length
 183         temp src 1 bignum@ MOV
 184         ! if the length is 1, its just the sign and nothing else,
 185         ! so output 0
 186         dst 0 MOV
 187         temp 1 tag-fixnum CMP
 188         "end" get JE
 189         ! load the value
 190         dst src 3 bignum@ MOV
 191         ! load the sign
 192         temp src 2 bignum@ MOV
 193         ! convert it into -1 or 1
 194         temp temp ADD
 195         temp NEG
 196         temp 1 ADD
 197         ! make dst signed
 198         temp dst IMUL2
 199         "end" resolve-label
 200     ] with-scope ;
 201
 202 M: x86 %add-float nip ADDSD ;
 203 M: x86 %sub-float nip SUBSD ;
 204 M: x86 %mul-float nip MULSD ;
 205 M: x86 %div-float nip DIVSD ;
 206
 207 M: x86 %integer>float CVTSI2SD ;
 208 M: x86 %float>integer CVTTSD2SI ;
 209
 210 GENERIC: copy-register* ( dst src rep -- )
 211
 212 M: int-rep copy-register* drop MOV ;
 213 M: tagged-rep copy-register* drop MOV ;
 214 M: single-float-rep copy-register* drop MOVSS ;
 215 M: double-float-rep copy-register* drop MOVSD ;
 216
 217 : copy-register ( dst src rep -- )
 218     2over eq? [ 3drop ] [ copy-register* ] if ;
 219
 220 M: x86 %copy ( dst src rep -- ) copy-register ;
 221
 222 M: x86 %unbox-float ( dst src -- )
 223     float-offset [+] MOVSD ;
 224
 225 M:: x86 %unbox-any-c-ptr ( dst src temp -- )
 226     [
 227         { "is-byte-array" "end" "start" } [ define-label ] each
 228         dst 0 MOV
 229         temp src MOV
 230         ! We come back here with displaced aliens
 231         "start" resolve-label
 232         ! Is the object f?
 233         temp \ f tag-number CMP
 234         "end" get JE
 235         ! Is the object an alien?
 236         temp header-offset [+] alien type-number tag-fixnum CMP
 237         "is-byte-array" get JNE
 238         ! If so, load the offset and add it to the address
 239         dst temp alien-offset [+] ADD
 240         ! Now recurse on the underlying alien
 241         temp temp underlying-alien-offset [+] MOV
 242         "start" get JMP
 243         "is-byte-array" resolve-label
 244         ! Add byte array address to address being computed
 245         dst temp ADD
 246         ! Add an offset to start of byte array's data
 247         dst byte-array-offset ADD
 248         "end" resolve-label
 249     ] with-scope ;
 250
 251 M:: x86 %box-float ( dst src temp -- )
 252     dst 16 float temp %allot
 253     dst float-offset [+] src MOVSD ;
 254
 255 : alien@ ( reg n -- op ) cells alien tag-number - [+] ;
 256
 257 M:: x86 %box-alien ( dst src temp -- )
 258     [
 259         "end" define-label
 260         dst \ f tag-number MOV
 261         src 0 CMP
 262         "end" get JE
 263         dst 4 cells alien temp %allot
 264         dst 1 alien@ \ f tag-number MOV
 265         dst 2 alien@ \ f tag-number MOV
 266         ! Store src in alien-offset slot
 267         dst 3 alien@ src MOV
 268         "end" resolve-label
 269     ] with-scope ;
 270
 271 ! The 'small-reg' mess is pretty crappy, but its only used on x86-32.
 272 ! On x86-64, all registers have 8-bit versions. However, a similar
 273 ! problem arises for shifts, where the shift count must be in CL, and
 274 ! so one day I will fix this properly by adding precoloring to the
 275 ! register allocator.
 276
 277 HOOK: has-small-reg? cpu ( reg size -- ? )
 278
 279 CONSTANT: have-byte-regs { EAX ECX EDX EBX }
 280
 281 M: x86.32 has-small-reg?
 282     {
 283         { 8 [ have-byte-regs memq? ] }
 284         { 16 [ drop t ] }
 285         { 32 [ drop t ] }
 286     } case ;
 287
 288 M: x86.64 has-small-reg? 2drop t ;
 289
 290 : small-reg-that-isn't ( exclude -- reg' )
 291     [ have-byte-regs ] dip
 292     [ native-version-of ] map
 293     '[ _ memq? not ] find nip ;
 294
 295 : with-save/restore ( reg quot -- )
 296     [ drop PUSH ] [ call ] [ drop POP ] 2tri ; inline
 297
 298 :: with-small-register ( dst exclude size quot: ( new-dst -- ) -- )
 299     ! If the destination register overlaps a small register with
 300     ! 'size' bits, we call the quot with that. Otherwise, we find a
 301     ! small register that is not in exclude, and call quot, saving and
 302     ! restoring the small register.
 303     dst size has-small-reg? [ dst quot call ] [
 304         exclude small-reg-that-isn't
 305         [ quot call ] with-save/restore
 306     ] if ; inline
 307
 308 : ?MOV ( dst src -- )
 309     2dup = [ 2drop ] [ MOV ] if ; inline
 310
 311 M:: x86 %string-nth ( dst src index temp -- )
 312     ! We request a small-reg of size 8 since those of size 16 are
 313     ! a superset.
 314     "end" define-label
 315     dst { src index temp } 8 [| new-dst |
 316         ! Load the least significant 7 bits into new-dst.
 317         ! 8th bit indicates whether we have to load from
 318         ! the aux vector or not.
 319         temp src index [+] LEA
 320         new-dst 8-bit-version-of temp string-offset [+] MOV
 321         new-dst new-dst 8-bit-version-of MOVZX
 322         ! Do we have to look at the aux vector?
 323         new-dst HEX: 80 CMP
 324         "end" get JL
 325         ! Yes, this is a non-ASCII character. Load aux vector
 326         temp src string-aux-offset [+] MOV
 327         new-dst temp XCHG
 328         ! Compute index
 329         new-dst index ADD
 330         new-dst index ADD
 331         ! Load high 16 bits
 332         new-dst 16-bit-version-of new-dst byte-array-offset [+] MOV
 333         new-dst new-dst 16-bit-version-of MOVZX
 334         new-dst 7 SHL
 335         ! Compute code point
 336         new-dst temp XOR
 337         "end" resolve-label
 338         dst new-dst ?MOV
 339     ] with-small-register ;
 340
 341 M:: x86 %set-string-nth-fast ( ch str index temp -- )
 342     ch { index str temp } 8 [| new-ch |
 343         new-ch ch ?MOV
 344         temp str index [+] LEA
 345         temp string-offset [+] new-ch 8-bit-version-of MOV
 346     ] with-small-register ;
 347
 348 :: %alien-integer-getter ( dst src size quot -- )
 349     dst { src } size [| new-dst |
 350         new-dst dup size n-bit-version-of dup src [] MOV
 351         quot call
 352         dst new-dst ?MOV
 353     ] with-small-register ; inline
 354
 355 : %alien-unsigned-getter ( dst src size -- )
 356     [ MOVZX ] %alien-integer-getter ; inline
 357
 358 M: x86 %alien-unsigned-1 8 %alien-unsigned-getter ;
 359 M: x86 %alien-unsigned-2 16 %alien-unsigned-getter ;
 360 M: x86 %alien-unsigned-4 32 [ 2drop ] %alien-integer-getter ;
 361
 362 : %alien-signed-getter ( dst src size -- )
 363     [ MOVSX ] %alien-integer-getter ; inline
 364
 365 M: x86 %alien-signed-1 8 %alien-signed-getter ;
 366 M: x86 %alien-signed-2 16 %alien-signed-getter ;
 367 M: x86 %alien-signed-4 32 %alien-signed-getter ;
 368
 369 M: x86 %alien-cell [] MOV ;
 370 M: x86 %alien-float dupd [] MOVSS dup CVTSS2SD ;
 371 M: x86 %alien-double [] MOVSD ;
 372
 373 :: %alien-integer-setter ( ptr value size -- )
 374     value { ptr } size [| new-value |
 375         new-value value ?MOV
 376         ptr [] new-value size n-bit-version-of MOV
 377     ] with-small-register ; inline
 378
 379 M: x86 %set-alien-integer-1 8 %alien-integer-setter ;
 380 M: x86 %set-alien-integer-2 16 %alien-integer-setter ;
 381 M: x86 %set-alien-integer-4 32 %alien-integer-setter ;
 382 M: x86 %set-alien-cell [ [] ] dip MOV ;
 383 M: x86 %set-alien-float dup dup CVTSD2SS [ [] ] dip MOVSS ;
 384 M: x86 %set-alien-double [ [] ] dip MOVSD ;
 385
 386 : shift-count? ( reg -- ? ) { ECX RCX } memq? ;
 387
 388 :: emit-shift ( dst src1 src2 quot -- )
 389     src2 shift-count? [
 390         dst CL quot call
 391     ] [
 392         dst shift-count? [
 393             dst src2 XCHG
 394             src2 CL quot call
 395             dst src2 XCHG
 396         ] [
 397             ECX native-version-of [
 398                 CL src2 MOV
 399                 drop dst CL quot call
 400             ] with-save/restore
 401         ] if
 402     ] if ; inline
 403
 404 M: x86 %shl [ SHL ] emit-shift ;
 405 M: x86 %shr [ SHR ] emit-shift ;
 406 M: x86 %sar [ SAR ] emit-shift ;
 407
 408 : load-zone-ptr ( reg -- )
 409     #! Load pointer to start of zone array
 410     0 MOV "nursery" f rc-absolute-cell rel-dlsym ;
 411
 412 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 413     [ drop load-zone-ptr ] [ swap cell [+] MOV ] 2bi ;
 414
 415 : inc-allot-ptr ( nursery-ptr n -- )
 416     [ cell [+] ] dip 8 align ADD ;
 417
 418 : store-header ( temp class -- )
 419     [ [] ] [ type-number tag-fixnum ] bi* MOV ;
 420
 421 : store-tagged ( dst tag -- )
 422     tag-number OR ;
 423
 424 M:: x86 %allot ( dst size class nursery-ptr -- )
 425     nursery-ptr dst load-allot-ptr
 426     dst class store-header
 427     dst class store-tagged
 428     nursery-ptr size inc-allot-ptr ;
 429
 430 M:: x86 %write-barrier ( src card# table -- )
 431     #! Mark the card pointed to by vreg.
 432     ! Mark the card
 433     card# src MOV
 434     card# card-bits SHR
 435     table "cards_offset" f %alien-global
 436     table table [] MOV
 437     table card# [+] card-mark <byte> MOV
 438
 439     ! Mark the card deck
 440     card# deck-bits card-bits - SHR
 441     table "decks_offset" f %alien-global
 442     table table [] MOV
 443     table card# [+] card-mark <byte> MOV ;
 444
 445 M:: x86 %check-nursery ( label temp1 temp2 -- )
 446     temp1 load-zone-ptr
 447     temp2 temp1 cell [+] MOV
 448     temp2 1024 ADD
 449     temp1 temp1 3 cells [+] MOV
 450     temp2 temp1 CMP
 451     label JLE ;
 452
 453 M: x86 %save-gc-root ( gc-root register -- ) [ gc-root@ ] dip MOV ;
 454
 455 M: x86 %load-gc-root ( gc-root register -- ) swap gc-root@ MOV ;
 456
 457 M:: x86 %call-gc ( gc-root-count -- )
 458     ! Pass pointer to start of GC roots as first parameter
 459     param-reg-1 gc-root-base param@ LEA
 460     ! Pass number of roots as second parameter
 461     param-reg-2 gc-root-count MOV
 462     ! Call GC
 463     %prepare-alien-invoke
 464     "inline_gc" f %alien-invoke ;
 465
 466 M: x86 %alien-global
 467     [ 0 MOV ] 2dip rc-absolute-cell rel-dlsym ;
 468
 469 M: x86 %epilogue ( n -- ) cell - incr-stack-reg ;
 470
 471 :: %boolean ( dst temp word -- )
 472     dst \ f tag-number MOV
 473     temp 0 MOV \ t rc-absolute-cell rel-immediate
 474     dst temp word execute ; inline
 475
 476 M: x86 %compare ( dst temp cc src1 src2 -- )
 477     CMP {
 478         { cc< [ \ CMOVL %boolean ] }
 479         { cc<= [ \ CMOVLE %boolean ] }
 480         { cc> [ \ CMOVG %boolean ] }
 481         { cc>= [ \ CMOVGE %boolean ] }
 482         { cc= [ \ CMOVE %boolean ] }
 483         { cc/= [ \ CMOVNE %boolean ] }
 484     } case ;
 485
 486 M: x86 %compare-imm ( dst temp cc src1 src2 -- )
 487     %compare ;
 488
 489 M: x86 %compare-float ( dst temp cc src1 src2 -- )
 490     UCOMISD {
 491         { cc< [ \ CMOVB %boolean ] }
 492         { cc<= [ \ CMOVBE %boolean ] }
 493         { cc> [ \ CMOVA %boolean ] }
 494         { cc>= [ \ CMOVAE %boolean ] }
 495         { cc= [ \ CMOVE %boolean ] }
 496         { cc/= [ \ CMOVNE %boolean ] }
 497     } case ;
 498
 499 M: x86 %compare-branch ( label cc src1 src2 -- )
 500     CMP {
 501         { cc< [ JL ] }
 502         { cc<= [ JLE ] }
 503         { cc> [ JG ] }
 504         { cc>= [ JGE ] }
 505         { cc= [ JE ] }
 506         { cc/= [ JNE ] }
 507     } case ;
 508
 509 M: x86 %compare-imm-branch ( label src1 src2 cc -- )
 510     %compare-branch ;
 511
 512 M: x86 %compare-float-branch ( label cc src1 src2 -- )
 513     UCOMISD {
 514         { cc< [ JB ] }
 515         { cc<= [ JBE ] }
 516         { cc> [ JA ] }
 517         { cc>= [ JAE ] }
 518         { cc= [ JE ] }
 519         { cc/= [ JNE ] }
 520     } case ;
 521
 522 M: x86 %spill ( src n rep -- ) [ spill@ swap ] dip copy-register ;
 523 M: x86 %reload ( dst n rep -- ) [ spill@ ] dip copy-register ;
 524
 525 M: x86 %loop-entry 16 code-alignment [ NOP ] times ;
 526
 527 M: x86 %prepare-alien-invoke
 528     #! Save Factor stack pointers in case the C code calls a
 529     #! callback which does a GC, which must reliably trace
 530     #! all roots.
 531     temp-reg "stack_chain" f %alien-global
 532     temp-reg temp-reg [] MOV
 533     temp-reg [] stack-reg MOV
 534     temp-reg [] cell SUB
 535     temp-reg 2 cells [+] ds-reg MOV
 536     temp-reg 3 cells [+] rs-reg MOV ;
 537
 538 M: x86 value-struct? drop t ;
 539
 540 M: x86 small-enough? ( n -- ? )
 541     HEX: -80000000 HEX: 7fffffff between? ;
 542
 543 : next-stack@ ( n -- operand )
 544     #! nth parameter from the next stack frame. Used to box
 545     #! input values to callbacks; the callback has its own
 546     #! stack frame set up, and we want to read the frame
 547     #! set up by the caller.
 548     stack-frame get total-size>> + stack@ ;