core/kernel/kernel.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USE: slots.private
   4 USE: kernel.private
   5 USE: math.private
   6 IN: kernel
   7
   8 BUILTIN: callstack ;
   9 BUILTIN: tuple ;
  10 BUILTIN: wrapper { wrapped read-only } ;
  11
  12 PRIMITIVE: -rot ( x y z -- z x y )
  13 PRIMITIVE: dup ( x -- x x )
  14 PRIMITIVE: dupd ( x y -- x x y )
  15 PRIMITIVE: drop ( x -- )
  16 PRIMITIVE: nip ( x y -- y )
  17 PRIMITIVE: over ( x y -- x y x )
  18 PRIMITIVE: pick ( x y z -- x y z x )
  19 PRIMITIVE: rot ( x y z -- y z x )
  20 PRIMITIVE: swap ( x y -- y x )
  21 PRIMITIVE: swapd ( x y z -- y x z )
  22 PRIMITIVE: 2drop ( x y -- )
  23 PRIMITIVE: 2dup ( x y -- x y x y )
  24 PRIMITIVE: 2nip ( x y z -- z )
  25 PRIMITIVE: 3drop ( x y z -- )
  26 PRIMITIVE: 3dup ( x y z -- x y z x y z )
  27 PRIMITIVE: 4drop ( w x y z -- )
  28 PRIMITIVE: 4dup ( w x y z -- w x y z w x y z )
  29
  30 PRIMITIVE: (clone) ( obj -- newobj )
  31 PRIMITIVE: eq? ( obj1 obj2 -- ? )
  32 PRIMITIVE: <wrapper> ( obj -- wrapper )
  33 PRIMITIVE: die ( -- )
  34 PRIMITIVE: callstack>array ( callstack -- array )
  35
  36 <PRIVATE
  37 PRIMITIVE: (call) ( quot -- )
  38 PRIMITIVE: (execute) ( word -- )
  39 PRIMITIVE: (identity-hashcode) ( obj -- code )
  40 PRIMITIVE: become ( old new -- )
  41 PRIMITIVE: c-to-factor ( -- )
  42 PRIMITIVE: callstack-bounds ( -- start end )
  43 PRIMITIVE: check-datastack ( array in# out# -- ? )
  44 PRIMITIVE: compute-identity-hashcode ( obj -- )
  45 PRIMITIVE: context-object ( n -- obj )
  46 PRIMITIVE: fpu-state ( -- )
  47 PRIMITIVE: innermost-frame-executing ( callstack -- obj )
  48 PRIMITIVE: innermost-frame-scan ( callstack -- n )
  49 PRIMITIVE: lazy-jit-compile ( -- )
  50 PRIMITIVE: leaf-signal-handler ( -- )
  51 PRIMITIVE: set-callstack ( callstack -- * )
  52 PRIMITIVE: set-context-object ( obj n -- )
  53 PRIMITIVE: set-datastack ( array -- )
  54 PRIMITIVE: set-fpu-state ( -- )
  55 PRIMITIVE: set-innermost-frame-quotation ( n callstack -- )
  56 PRIMITIVE: set-retainstack ( array -- )
  57 PRIMITIVE: set-special-object ( obj n -- )
  58 PRIMITIVE: signal-handler ( -- )
  59 PRIMITIVE: special-object ( n -- obj )
  60 PRIMITIVE: strip-stack-traces ( -- )
  61 PRIMITIVE: tag ( object -- n )
  62 PRIMITIVE: unwind-native-frames ( -- )
  63 PRIVATE>
  64
  65 DEFER: dip
  66 DEFER: 2dip
  67 DEFER: 3dip
  68
  69 ! Stack stuff
  70 : 2over ( x y z -- x y z x y ) pick pick ; inline
  71
  72 : clear ( -- ) { } set-datastack ;
  73
  74 ! Combinators
  75 GENERIC: call ( callable -- )
  76
  77 GENERIC: execute ( word -- )
  78
  79 DEFER: if
  80
  81 : ? ( ? true false -- true/false )
  82     ! 'if' and '?' can be defined in terms of each other
  83     ! because the JIT special-cases an 'if' preceded by
  84     ! two literal quotations.
  85     rot [ drop ] [ nip ] if ; inline
  86
  87 : if ( ..a ? true: ( ..a -- ..b ) false: ( ..a -- ..b ) -- ..b ) ? call ;
  88
  89 ! Single branch
  90 : unless ( ..a ? false: ( ..a -- ..a ) -- ..a )
  91     swap [ drop ] [ call ] if ; inline
  92
  93 : when ( ..a ? true: ( ..a -- ..a ) -- ..a )
  94     swap [ call ] [ drop ] if ; inline
  95
  96 ! Anaphoric
  97 : if* ( ..a ? true: ( ..a ? -- ..b ) false: ( ..a -- ..b ) -- ..b )
  98     pick [ drop call ] [ 2nip call ] if ; inline
  99
 100 : when* ( ..a ? true: ( ..a ? -- ..a ) -- ..a )
 101     over [ call ] [ 2drop ] if ; inline
 102
 103 : unless* ( ..a ? false: ( ..a -- ..a x ) -- ..a x )
 104     over [ drop ] [ nip call ] if ; inline
 105
 106 : transmute* ( obj quot: ( obj -- obj/f ) -- new/old changed? )
 107     over [ call ] dip over [ drop t ] [ nip f ] if ; inline
 108
 109 : transmute ( obj quot: ( obj -- new/old ) -- new/old ) transmute* drop ; inline
 110
 111 : ?transmute ( obj/f quot -- obj' ) dupd when ; inline
 112
 113 ! Default
 114
 115 : ?if-old ( ..a obj cond true: ( ..a cond -- ..b ) false: ( ..a default -- ..b ) -- ..b )
 116     pick [ drop [ drop ] 2dip call ] [ 2nip call ] if ; inline
 117
 118 : ?when ( ..a obj cond: ( ..a obj -- obj/f ) true: ( ..a cond -- ..b ) -- ..b )
 119     [ transmute* ] dip when ; inline
 120
 121 : ?unless ( ..a obj cond: ( ..a obj -- obj/f ) false: ( ..a default -- ..b ) -- ..b )
 122     [ transmute* ] dip unless ; inline
 123
 124 : ?if ( ..a obj cond true: ( ..a cond -- ..b ) false: ( ..a default -- ..b ) -- ..b )
 125     [ transmute* ] 2dip if ; inline
 126
 127 ! Dippers.
 128 ! Not declared inline because the compiler special-cases them
 129
 130 : dip ( x quot -- x ) swap [ call ] dip ;
 131
 132 : 2dip ( x y quot -- x y ) swap [ dip ] dip ;
 133
 134 : 3dip ( x y z quot -- x y z ) swap [ 2dip ] dip ;
 135
 136 : 4dip ( w x y z quot -- w x y z ) swap [ 3dip ] dip ; inline
 137
 138 ! Misfits
 139 : tuck ( x y -- y x y ) dup -rot ; inline
 140
 141 : spin ( x y z -- z y x ) -rot swap ; inline
 142
 143 : rotd ( w x y z -- x y w z ) [ rot ] dip ; inline
 144
 145 : -rotd ( w x y z -- y w x z ) [ -rot ] dip ; inline
 146
 147 : roll ( w x y z -- x y z w ) rotd swap ; inline
 148
 149 : -roll ( w x y z -- z w x y ) swap -rotd ; inline
 150
 151 : nipd ( x y z -- y z ) [ nip ] dip ; inline
 152
 153 : overd ( x y z -- x y x z ) [ over ] dip ; inline
 154
 155 : pickd ( w x y z -- w x y w z ) [ pick ] dip ; inline
 156
 157 : 2nipd ( w x y z -- y z ) [ 2drop ] 2dip ; inline
 158
 159 : 3nipd ( v w x y z -- y z ) [ 3drop ] 2dip ; inline
 160
 161 : 3nip ( w x y z -- z ) 2nip nip ; inline
 162
 163 : 4nip ( v w x y z -- z ) 2nip 2nip ; inline
 164
 165 : 5nip ( u v w x y z -- z ) 3nip 2nip ; inline
 166
 167 : 5drop ( v w x y z -- ) 4drop drop ; inline
 168
 169 : reach ( w x y z -- w x y z w ) [ pick ] dip swap ; inline
 170
 171 ! Keepers
 172 : keep ( ..a x quot: ( ..a x -- ..b ) -- ..b x )
 173     over [ call ] dip ; inline
 174
 175 : 2keep ( ..a x y quot: ( ..a x y -- ..b ) -- ..b x y )
 176     [ 2dup ] dip 2dip ; inline
 177
 178 : 3keep ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x y z )
 179     [ 3dup ] dip 3dip ; inline
 180
 181 : 4keep ( ..a w x y z quot: ( ..a w x y z -- ..b ) -- ..b w x y z )
 182     [ 4dup ] dip 4dip ; inline
 183
 184 : keepd ( ..a x y quot: ( ..a x y -- ..b ) -- ..b x )
 185     2keep drop ; inline
 186
 187 : keepdd ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x )
 188     3keep 2drop ; inline
 189
 190 : 2keepd ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x y )
 191     3keep drop ; inline
 192
 193 ! Cleavers
 194 : bi ( x p q -- )
 195     [ keep ] dip call ; inline
 196
 197 : tri ( x p q r -- )
 198     [ [ keep ] dip keep ] dip call ; inline
 199
 200 ! Double cleavers
 201 : 2bi ( x y p q -- )
 202     [ 2keep ] dip call ; inline
 203
 204 : 2tri ( x y p q r -- )
 205     [ [ 2keep ] dip 2keep ] dip call ; inline
 206
 207 ! Triple cleavers
 208 : 3bi ( x y z p q -- )
 209     [ 3keep ] dip call ; inline
 210
 211 : 3tri ( x y z p q r -- )
 212     [ [ 3keep ] dip 3keep ] dip call ; inline
 213
 214 ! Spreaders
 215 : bi* ( x y p q -- )
 216     [ dip ] dip call ; inline
 217
 218 : tri* ( x y z p q r -- )
 219     [ [ 2dip ] dip dip ] dip call ; inline
 220
 221 ! Double spreaders
 222 : 2bi* ( w x y z p q -- )
 223     [ 2dip ] dip call ; inline
 224
 225 : 2tri* ( u v w x y z p q r -- )
 226     [ 4dip ] 2dip 2bi* ; inline
 227
 228 ! Appliers
 229 : bi@ ( x y quot -- )
 230     dup bi* ; inline
 231
 232 : tri@ ( x y z quot -- )
 233     dup dup tri* ; inline
 234
 235 ! Double appliers
 236 : 2bi@ ( w x y z quot -- )
 237     dup 2bi* ; inline
 238
 239 : 2tri@ ( u v w x y z quot -- )
 240     dup dup 2tri* ; inline
 241
 242 ! Quotation building
 243 : 2curry ( obj1 obj2 quot -- curried )
 244     curry curry ; inline
 245
 246 : 3curry ( obj1 obj2 obj3 quot -- curried )
 247     curry curry curry ; inline
 248
 249 : with ( param obj quot -- obj curried )
 250     swapd [ swapd call ] 2curry ; inline
 251
 252 : 2with ( param1 param2 obj quot -- obj curried )
 253     with with ; inline
 254
 255 : withd ( param obj quot -- obj curried )
 256     swapd [ -rotd call ] 2curry ; inline
 257
 258 : prepose ( quot1 quot2 -- composed )
 259     swap compose ; inline
 260
 261 ! Curried cleavers
 262 <PRIVATE
 263
 264 : currier ( quot -- quot' ) [ curry ] curry ; inline
 265
 266 PRIVATE>
 267
 268 : bi-curry ( x p q -- p' q' ) [ currier ] bi@ bi ; inline
 269
 270 : tri-curry ( x p q r -- p' q' r' ) [ currier ] tri@ tri ; inline
 271
 272 : bi-curry* ( x y p q -- p' q' ) [ currier ] bi@ bi* ; inline
 273
 274 : tri-curry* ( x y z p q r -- p' q' r' ) [ currier ] tri@ tri* ; inline
 275
 276 : bi-curry@ ( x y q -- p' q' ) currier bi@ ; inline
 277
 278 : tri-curry@ ( x y z q -- p' q' r' ) currier tri@ ; inline
 279
 280 ! Booleans
 281 UNION: boolean POSTPONE: t POSTPONE: f ;
 282
 283 : >boolean ( obj -- ? ) [ t ] [ f ] if ; inline
 284
 285 : not ( obj -- ? ) [ f ] [ t ] if ; inline
 286
 287 : and ( obj1 obj2 -- ? ) over ? ; inline
 288
 289 : or ( obj1 obj2 -- ? ) dupd ? ; inline
 290
 291 : xor ( obj1 obj2 -- ? ) [ f swap ? ] when* ; inline
 292
 293 : both? ( x y quot -- ? ) bi@ and ; inline
 294
 295 : either? ( x y quot -- ? ) bi@ or ; inline
 296
 297 : most ( x y quot -- z ) 2keep ? ; inline
 298
 299 : negate ( quot -- quot' ) [ not ] compose ; inline
 300
 301 ! Loops
 302 : loop ( ... pred: ( ... -- ... ? ) -- ... )
 303     [ call ] keep [ loop ] curry when ; inline recursive
 304
 305 : do ( pred body -- pred body )
 306     dup 2dip ; inline
 307
 308 : while ( ..a pred: ( ..a -- ..b ? ) body: ( ..b -- ..a ) -- ..b )
 309     swap do compose [ loop ] curry when ; inline
 310
 311 : while* ( ..a pred: ( ..a -- ..b ? ) body: ( ..b ? -- ..a ) -- ..b )
 312     [ [ dup ] compose ] dip while drop ; inline
 313
 314 : until ( ..a pred: ( ..a -- ..b ? ) body: ( ..b -- ..a ) -- ..b )
 315     [ negate ] dip while ; inline
 316
 317 ! Object protocol
 318 GENERIC: hashcode* ( depth obj -- code ) flushable
 319
 320 M: object hashcode* 2drop 0 ; inline
 321
 322 M: f hashcode* 2drop 31337 ; inline
 323
 324 : hashcode ( obj -- code ) 3 swap hashcode* ; inline
 325
 326 GENERIC: equal? ( obj1 obj2 -- ? )
 327
 328 M: object equal? 2drop f ; inline
 329
 330 TUPLE: identity-tuple ;
 331
 332 M: identity-tuple equal? 2drop f ; inline
 333
 334 : identity-hashcode ( obj -- code )
 335     dup tag 0 eq? [
 336         dup tag 1 eq? [ drop 0 ] [
 337             dup (identity-hashcode) dup 0 eq? [
 338                 drop dup compute-identity-hashcode
 339                 (identity-hashcode)
 340             ] [ nip ] if
 341         ] if
 342     ] unless ; inline
 343
 344 M: identity-tuple hashcode* nip identity-hashcode ; inline
 345
 346 : = ( obj1 obj2 -- ? )
 347     2dup eq? [ 2drop t ] [
 348         2dup both-fixnums? [ 2drop f ] [ equal? ] if
 349     ] if ; inline
 350
 351 : same? ( x y quot -- ? ) bi@ = ; inline
 352
 353 GENERIC: clone ( obj -- cloned )
 354
 355 M: object clone ; inline
 356
 357 M: callstack clone (clone) ; inline
 358
 359 ! Tuple construction
 360 GENERIC: new ( class -- tuple )
 361
 362 GENERIC: boa ( slots... class -- tuple )
 363
 364 ! Error handling -- defined early so that other files can
 365 ! throw errors before continuations are loaded
 366 GENERIC: throw ( error -- * )
 367
 368 ERROR: assert got expect ;
 369
 370 : assert= ( a b -- ) 2dup = [ 2drop ] [ assert ] if ;
 371
 372 <PRIVATE
 373
 374 : declare ( spec -- ) drop ;
 375
 376 : do-primitive ( number -- ) "Improper primitive call" throw ;
 377
 378 ! Special object count and identifiers must be kept in sync with:
 379 !   vm/objects.hpp
 380 CONSTANT: special-object-count 85
 381
 382 CONSTANT: OBJ-WALKER-HOOK 3
 383
 384 CONSTANT: OBJ-CALLCC-1 4
 385
 386 CONSTANT: ERROR-HANDLER-QUOT 5
 387
 388 CONSTANT: OBJ-CELL-SIZE 7
 389 CONSTANT: OBJ-CPU 8
 390 CONSTANT: OBJ-OS 9
 391
 392 CONSTANT: OBJ-ARGS 10
 393 CONSTANT: OBJ-STDIN 11
 394 CONSTANT: OBJ-STDOUT 12
 395
 396 CONSTANT: OBJ-IMAGE 13
 397 CONSTANT: OBJ-EXECUTABLE 14
 398
 399 CONSTANT: OBJ-EMBEDDED 15
 400 CONSTANT: OBJ-EVAL-CALLBACK 16
 401 CONSTANT: OBJ-YIELD-CALLBACK 17
 402 CONSTANT: OBJ-SLEEP-CALLBACK 18
 403
 404 CONSTANT: OBJ-STARTUP-QUOT 20
 405 CONSTANT: OBJ-GLOBAL 21
 406 CONSTANT: OBJ-SHUTDOWN-QUOT 22
 407
 408 CONSTANT: JIT-PROLOG 23
 409 CONSTANT: JIT-PRIMITIVE-WORD 24
 410 CONSTANT: JIT-PRIMITIVE 25
 411 CONSTANT: JIT-WORD-JUMP 26
 412 CONSTANT: JIT-WORD-CALL 27
 413 CONSTANT: JIT-IF-WORD 28
 414 CONSTANT: JIT-IF 29
 415 CONSTANT: JIT-SAFEPOINT 30
 416 CONSTANT: JIT-EPILOG 31
 417 CONSTANT: JIT-RETURN 32
 418 CONSTANT: JIT-UNUSED 33
 419 CONSTANT: JIT-PUSH-LITERAL 34
 420 CONSTANT: JIT-DIP-WORD 35
 421 CONSTANT: JIT-DIP 36
 422 CONSTANT: JIT-2DIP-WORD 37
 423 CONSTANT: JIT-2DIP 38
 424 CONSTANT: JIT-3DIP-WORD 39
 425 CONSTANT: JIT-3DIP 40
 426 CONSTANT: JIT-EXECUTE 41
 427 CONSTANT: JIT-DECLARE-WORD 42
 428
 429 CONSTANT: C-TO-FACTOR-WORD 43
 430 CONSTANT: LAZY-JIT-COMPILE-WORD 44
 431 CONSTANT: UNWIND-NATIVE-FRAMES-WORD 45
 432 CONSTANT: GET-FPU-STATE-WORD 46
 433 CONSTANT: SET-FPU-STATE-WORD 47
 434 CONSTANT: SIGNAL-HANDLER-WORD 48
 435 CONSTANT: LEAF-SIGNAL-HANDLER-WORD 49
 436 CONSTANT: WIN-EXCEPTION-HANDLER 50
 437
 438 CONSTANT: OBJ-SAMPLE-CALLSTACKS 51
 439
 440 CONSTANT: REDEFINITION-COUNTER 52
 441
 442 CONSTANT: CALLBACK-STUB 53
 443
 444 CONSTANT: PIC-LOAD 54
 445 CONSTANT: PIC-TAG 55
 446 CONSTANT: PIC-TUPLE 56
 447 CONSTANT: PIC-CHECK-TAG 57
 448 CONSTANT: PIC-CHECK-TUPLE 58
 449 CONSTANT: PIC-HIT 59
 450 CONSTANT: PIC-MISS-WORD 60
 451 CONSTANT: PIC-MISS-TAIL-WORD 61
 452
 453 CONSTANT: MEGA-LOOKUP 62
 454 CONSTANT: MEGA-LOOKUP-WORD 63
 455 CONSTANT: MEGA-MISS-WORD 64
 456
 457 CONSTANT: OBJ-UNDEFINED 65
 458
 459 CONSTANT: OBJ-STDERR 66
 460
 461 CONSTANT: OBJ-STAGE2 67
 462
 463 CONSTANT: OBJ-CURRENT-THREAD 68
 464
 465 CONSTANT: OBJ-THREADS 69
 466 CONSTANT: OBJ-RUN-QUEUE 70
 467 CONSTANT: OBJ-SLEEP-QUEUE 71
 468
 469 CONSTANT: OBJ-VM-COMPILER 72
 470
 471 CONSTANT: OBJ-WAITING-CALLBACKS 73
 472
 473 CONSTANT: OBJ-SIGNAL-PIPE 74
 474
 475 CONSTANT: OBJ-VM-COMPILE-TIME 75
 476
 477 CONSTANT: OBJ-VM-VERSION 76
 478 CONSTANT: OBJ-VM-GIT-LABEL 77
 479
 480 CONSTANT: OBJ-CANONICAL-TRUE 78
 481
 482 CONSTANT: OBJ-BIGNUM-ZERO 79
 483 CONSTANT: OBJ-BIGNUM-POS-ONE 80
 484 CONSTANT: OBJ-BIGNUM-NEG-ONE 81
 485
 486 ! Context object count and identifiers must be kept in sync with:
 487 !   vm/contexts.hpp
 488
 489 CONSTANT: context-object-count 4
 490
 491 CONSTANT: CONTEXT-OBJ-NAMESTACK 0
 492 CONSTANT: CONTEXT-OBJ-CATCHSTACK 1
 493 CONSTANT: CONTEXT-OBJ-CONTEXT 2
 494 CONSTANT: CONTEXT-OBJ-IN-CALLBACK-P 3
 495
 496 ! Runtime errors must be kept in sync with:
 497 !   basis/debugger/debugger.factor
 498 !   vm/errors.hpp
 499
 500 ! VM adds this to kernel errors, so that user-space can identify them.
 501 CONSTANT: KERNEL-ERROR 0xfac7
 502
 503 CONSTANT: kernel-error-count 20
 504
 505 CONSTANT: ERROR-EXPIRED 0
 506 CONSTANT: ERROR-IO      1
 507 CONSTANT: ERROR-NOT-IMPLEMENTED 2
 508 CONSTANT: ERROR-TYPE 3
 509 CONSTANT: ERROR-DIVIDE-BY-ZERO 4
 510 CONSTANT: ERROR-SIGNAL 5
 511 CONSTANT: ERROR-ARRAY-SIZE 6
 512 CONSTANT: ERROR-OUT-OF-FIXNUM-RANGE 7
 513 CONSTANT: ERROR-FFI 8
 514 CONSTANT: ERROR-UNDEFINED-SYMBOL 9
 515 CONSTANT: ERROR-DATASTACK-UNDERFLOW 10
 516 CONSTANT: ERROR-DATASTACK-OVERFLOW 11
 517 CONSTANT: ERROR-RETAINSTACK-UNDERFLOW 12
 518 CONSTANT: ERROR-RETAINSTACK-OVERFLOW 13
 519 CONSTANT: ERROR-CALLSTACK-UNDERFLOW 14
 520 CONSTANT: ERROR-CALLSTACK-OVERFLOW 15
 521 CONSTANT: ERROR-MEMORY 16
 522 CONSTANT: ERROR-FP-TRAP 17
 523 CONSTANT: ERROR-INTERRUPT 18
 524 CONSTANT: ERROR-CALLBACK-SPACE-OVERFLOW 19
 525
 526 PRIMITIVE: callstack-for ( context -- array )
 527 PRIMITIVE: retainstack-for ( context -- array )
 528 PRIMITIVE: datastack-for ( context -- array )
 529
 530 : context ( -- context )
 531     CONTEXT-OBJ-CONTEXT context-object ; inline
 532
 533 PRIVATE>
 534
 535 : get-callstack ( -- callstack )
 536     context callstack-for ; inline
 537
 538 : get-datastack ( -- array )
 539     context datastack-for ; inline
 540
 541 : get-retainstack ( -- array )
 542     context retainstack-for ; inline