core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 PRIVATE>
  95
  96 ! The f object supports the sequence protocol trivially
  97 M: f length drop 0 ; inline
  98 M: f nth-unsafe nip ; inline
  99 M: f like drop [ f ] when-empty ; inline
 100
 101 INSTANCE: f immutable-sequence
 102
 103 ! Integer sequences
 104 TUPLE: iota { n integer read-only } ;
 105
 106 : iota ( n -- iota ) \ iota boa ; inline
 107
 108 M: iota length n>> ; inline
 109 M: iota nth-unsafe drop ; inline
 110
 111 INSTANCE: iota immutable-sequence
 112
 113 <PRIVATE
 114
 115 : first-unsafe ( seq -- first )
 116     0 swap nth-unsafe ; inline
 117
 118 : first2-unsafe ( seq -- first second )
 119     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 120
 121 : first3-unsafe ( seq -- first second third )
 122     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 123
 124 : first4-unsafe ( seq -- first second third fourth )
 125     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 126
 127 : exchange-unsafe ( m n seq -- )
 128     [ [ nth-unsafe ] curry bi@ ]
 129     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 130
 131 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 132
 133 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 134
 135 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 136
 137 : (1sequence) ( obj seq -- seq )
 138     [ 0 swap set-nth-unsafe ] keep ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep
 142     (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep
 146     (2sequence) ; inline
 147
 148 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 149     [ 3 swap set-nth-unsafe ] keep
 150     (3sequence) ; inline
 151
 152 PRIVATE>
 153
 154 : 1sequence ( obj exemplar -- seq )
 155     1 swap [ (1sequence) ] new-like ; inline
 156
 157 : 2sequence ( obj1 obj2 exemplar -- seq )
 158     2 swap [ (2sequence) ] new-like ; inline
 159
 160 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 161     3 swap [ (3sequence) ] new-like ; inline
 162
 163 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 164     4 swap [ (4sequence) ] new-like ; inline
 165
 166 : first2 ( seq -- first second )
 167     1 swap bounds-check nip first2-unsafe ; inline
 168
 169 : first3 ( seq -- first second third )
 170     2 swap bounds-check nip first3-unsafe ; inline
 171
 172 : first4 ( seq -- first second third fourth )
 173     3 swap bounds-check nip first4-unsafe ; inline
 174
 175 : ?nth ( n seq -- elt/f )
 176     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 177
 178 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 179 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 180 : ?last ( seq -- elt/f ) [ length 1 - ] [ ?nth ] bi ; inline
 181
 182 MIXIN: virtual-sequence
 183 GENERIC: virtual-exemplar ( seq -- seq' )
 184 GENERIC: virtual@ ( n seq -- n' seq' )
 185
 186 M: virtual-sequence nth virtual@ nth ; inline
 187 M: virtual-sequence set-nth virtual@ set-nth ; inline
 188 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 189 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 190 M: virtual-sequence like virtual-exemplar like ; inline
 191 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 192
 193 INSTANCE: virtual-sequence sequence
 194
 195 ! A reversal of an underlying sequence.
 196 TUPLE: reversed { seq read-only } ;
 197
 198 C: <reversed> reversed
 199
 200 M: reversed virtual-exemplar seq>> ; inline
 201 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 202 M: reversed length seq>> length ; inline
 203
 204 INSTANCE: reversed virtual-sequence
 205
 206 ! A slice of another sequence.
 207 TUPLE: slice
 208 { from read-only }
 209 { to read-only }
 210 { seq read-only } ;
 211
 212 : collapse-slice ( m n slice -- m' n' seq )
 213     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 214
 215 TUPLE: slice-error from to seq reason ;
 216
 217 : slice-error ( from to seq ? string -- from to seq )
 218     [ \ slice-error boa throw ] curry when ; inline
 219
 220 : check-slice ( from to seq -- from to seq )
 221     3dup
 222     [ 2drop 0 < "start < 0" slice-error ]
 223     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 224     [ drop > "start > end" slice-error ]
 225     3tri ; inline
 226
 227 <PRIVATE
 228
 229 : <slice-unsafe> ( from to seq -- slice )
 230     slice boa ; inline
 231
 232 PRIVATE>
 233
 234 : <slice> ( from to seq -- slice )
 235     check-slice
 236     dup slice? [ collapse-slice ] when
 237     <slice-unsafe> ; inline
 238
 239 M: slice virtual-exemplar seq>> ; inline
 240
 241 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 242
 243 M: slice length [ to>> ] [ from>> ] bi - ; inline
 244
 245 : short ( seq n -- seq n' ) over length min ; inline
 246
 247 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 248
 249 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 250
 251 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 252
 253 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 254
 255 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 256
 257 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 258
 259 INSTANCE: slice virtual-sequence
 260
 261 ! One element repeated many times
 262 TUPLE: repetition { len read-only } { elt read-only } ;
 263
 264 C: <repetition> repetition
 265
 266 M: repetition length len>> ; inline
 267 M: repetition nth-unsafe nip elt>> ; inline
 268
 269 INSTANCE: repetition immutable-sequence
 270
 271 <PRIVATE
 272
 273 ERROR: integer-length-expected obj ;
 274
 275 : check-length ( n -- n )
 276     dup integer? [ integer-length-expected ] unless ; inline
 277
 278 TUPLE: copy-state
 279     { src-i read-only }
 280     { src read-only }
 281     { dst-i read-only }
 282     { dst read-only } ;
 283
 284 C: <copy> copy-state
 285
 286 : ((copy)) ( n copy -- )
 287     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 288     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 289
 290 : (copy) ( n copy -- dst )
 291     over 0 <= [ nip dst>> ] [ [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi ] if ;
 292     inline recursive
 293
 294 : subseq>copy ( from to seq -- n copy )
 295     [ over - check-length swap ] dip
 296     3dup nip new-sequence 0 swap <copy> ; inline
 297
 298 : bounds-check-head ( n seq -- n seq )
 299     over 0 < [ bounds-error ] when ; inline
 300
 301 : check-copy ( src n dst -- src n dst )
 302     3dup bounds-check-head
 303     [ swap length + ] dip lengthen ; inline
 304
 305 PRIVATE>
 306
 307 : subseq ( from to seq -- subseq )
 308     [ check-slice subseq>copy (copy) ] keep like ;
 309
 310 : head ( seq n -- headseq ) (head) subseq ;
 311
 312 : tail ( seq n -- tailseq ) (tail) subseq ;
 313
 314 : rest ( seq -- tailseq ) 1 tail ;
 315
 316 : head* ( seq n -- headseq ) from-end head ;
 317
 318 : tail* ( seq n -- tailseq ) from-end tail ;
 319
 320 : but-last ( seq -- headseq ) 1 head* ;
 321
 322 : copy ( src i dst -- )
 323     #! The check-length call forces partial dispatch
 324     [ [ length check-length 0 ] keep ] 2dip
 325     check-copy <copy> (copy) drop ; inline
 326
 327 M: sequence clone-like
 328     [ dup length ] dip new-sequence [ 0 swap copy ] keep ; inline
 329
 330 M: immutable-sequence clone-like like ; inline
 331
 332 : push-all ( src dest -- ) [ length ] [ copy ] bi ; inline
 333
 334 <PRIVATE
 335
 336 : (append) ( seq1 seq2 accum -- accum )
 337     [ [ over length ] dip copy ]
 338     [ 0 swap copy ]
 339     [ ] tri ; inline
 340
 341 PRIVATE>
 342
 343 : append-as ( seq1 seq2 exemplar -- newseq )
 344     [ over length over length + ] dip
 345     [ (append) ] new-like ; inline
 346
 347 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 348     [ 3dup [ length ] tri@ + + ] dip [
 349         [ [ 2over [ length ] bi@ + ] dip copy ]
 350         [ (append) ] bi
 351     ] new-like ; inline
 352
 353 : append ( seq1 seq2 -- newseq ) over append-as ;
 354
 355 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 356
 357 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 358
 359 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 360
 361 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 362
 363 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 364     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 365
 366 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 367
 368 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 369
 370 <PRIVATE
 371
 372 : ((each)) ( seq -- n quot )
 373     [ length ] keep [ nth-unsafe ] curry ; inline
 374
 375 : (each) ( seq quot -- n quot' )
 376     [ ((each)) ] dip compose ; inline
 377
 378 : (each-index) ( seq quot -- n quot' )
 379     [ ((each)) [ keep ] curry ] dip compose ; inline
 380
 381 : (collect) ( quot into -- quot' )
 382     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 383
 384 : collect ( n quot into -- )
 385     (collect) each-integer ; inline
 386
 387 : map-into ( seq quot into -- )
 388     [ (each) ] dip collect ; inline
 389
 390 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 391     [ nth-unsafe ] bi-curry@ bi ; inline
 392
 393 : (2each) ( seq1 seq2 quot -- n quot' )
 394     [
 395         [ min-length ] 2keep
 396         [ 2nth-unsafe ] 2curry
 397     ] dip compose ; inline
 398
 399 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 400     [ nth-unsafe ] tri-curry@ tri ; inline
 401
 402 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 403     [
 404         [ [ length ] tri@ min min ]
 405         [ [ 3nth-unsafe ] 3curry ] 3bi
 406     ] dip compose ; inline
 407
 408 : finish-find ( i seq -- i elt )
 409     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 410
 411 : (find) ( seq quot quot' -- i elt )
 412     pick [ [ (each) ] dip call ] dip finish-find ; inline
 413
 414 : (find-from) ( n seq quot quot' -- i elt )
 415     [ 2dup bounds-check? ] 2dip
 416     [ (find) ] 2curry
 417     [ 2drop f f ]
 418     if ; inline
 419
 420 : (find-index) ( seq quot quot' -- i elt )
 421     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 422
 423 : (find-index-from) ( n seq quot quot' -- i elt )
 424     [ 2dup bounds-check? ] 2dip
 425     [ (find-index) ] 2curry
 426     [ 2drop f f ]
 427     if ; inline
 428
 429 : (accumulate) ( seq identity quot -- identity seq quot )
 430     swapd [ curry keep ] curry ; inline
 431
 432 PRIVATE>
 433
 434 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 435     (each) each-integer ; inline
 436
 437 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 438     swapd each ; inline
 439
 440 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 441     [ over ] dip [ [ collect ] keep ] new-like ; inline
 442
 443 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 444     [ (each) ] dip map-integers ; inline
 445
 446 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 447     over map-as ; inline
 448
 449 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 450     [ [ drop ] prepose ] dip map-integers ; inline
 451
 452 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 453     { } replicate-as ; inline
 454
 455 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 456     over [ map-into ] keep ; inline
 457
 458 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 459     [ (accumulate) ] dip map-as ; inline
 460
 461 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 462     pick accumulate-as ; inline
 463
 464 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 465     (accumulate) map! ; inline
 466
 467 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 468     (2each) each-integer ; inline
 469
 470 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 471     [ -rot ] dip 2each ; inline
 472
 473 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 474     [ (2each) ] dip map-integers ; inline
 475
 476 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 477     pick 2map-as ; inline
 478
 479 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 480     (2each) all-integers? ; inline
 481
 482 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 483     (3each) each-integer ; inline
 484
 485 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 486     [ (3each) ] dip map-integers ; inline
 487
 488 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 489     [ pick ] dip swap 3map-as ; inline
 490
 491 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 492     [ (find-integer) ] (find-from) ; inline
 493
 494 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 495     [ find-integer ] (find) ; inline
 496
 497 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 498     [ nip find-last-integer ] (find-from) ; inline
 499
 500 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 501     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 502
 503 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 504     [ (find-integer) ] (find-index-from) ; inline
 505
 506 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 507     [ find-integer ] (find-index) ; inline
 508
 509 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 510     (each) all-integers? ; inline
 511
 512 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 513     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 514
 515 : selector-for ( quot exemplar -- selector accum )
 516     [ length ] keep new-resizable [ [ push-if ] 2curry ] keep ; inline
 517
 518 : selector ( quot -- selector accum )
 519     V{ } selector-for ; inline
 520
 521 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 522     dup [ selector-for [ each ] dip ] curry dip like ; inline
 523
 524 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 525     over filter-as ; inline
 526
 527 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 528     [ keep swap ] 2dip ? push ; inline
 529
 530 : 2selector ( quot -- selector accum1 accum2 )
 531     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 532
 533 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 534     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 535
 536 : collector-for ( quot exemplar -- quot' vec )
 537     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 538
 539 : collector ( quot -- quot' vec )
 540     V{ } collector-for ; inline
 541
 542 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 543     dup [ collector-for [ while ] dip ] curry dip like ; inline
 544
 545 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 546     { } produce-as ; inline
 547
 548 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 549     [ dup ] swap [ keep ] curry produce nip ; inline
 550
 551 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 552     (each-index) each-integer ; inline
 553
 554 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 555     pick empty? [ 3drop ] [
 556         [ [ drop first-unsafe ] dip call ]
 557         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 558         3bi
 559     ] if ; inline
 560
 561 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 562     [ dup length iota ] dip 2map ; inline
 563
 564 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 565     swapd each-index ; inline
 566
 567 : index ( obj seq -- n )
 568     [ = ] with find drop ;
 569
 570 : index-from ( obj i seq -- n )
 571     rot [ = ] curry find-from drop ;
 572
 573 : last-index ( obj seq -- n )
 574     [ = ] with find-last drop ;
 575
 576 : last-index-from ( obj i seq -- n )
 577     rot [ = ] curry find-last-from drop ;
 578
 579 <PRIVATE
 580
 581 : (indices) ( elt i obj accum -- )
 582     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 583
 584 PRIVATE>
 585
 586 : indices ( obj seq -- indices )
 587     swap V{ } clone
 588     [ [ (indices) ] 2curry each-index ] keep ;
 589
 590 : nths ( indices seq -- seq' )
 591     [ [ nth ] curry ] keep map-as ;
 592
 593 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 594     find drop >boolean ; inline
 595
 596 : member? ( elt seq -- ? )
 597     [ = ] with any? ;
 598
 599 : member-eq? ( elt seq -- ? )
 600     [ eq? ] with any? ;
 601
 602 : remove ( elt seq -- newseq )
 603     [ = not ] with filter ;
 604
 605 : remove-eq ( elt seq -- newseq )
 606     [ eq? not ] with filter ;
 607
 608 : sift ( seq -- newseq )
 609     [ ] filter ;
 610
 611 : harvest ( seq -- newseq )
 612     [ empty? not ] filter ;
 613
 614 : mismatch ( seq1 seq2 -- i )
 615     [ min-length ] 2keep
 616     [ 2nth-unsafe = not ] 2curry
 617     find-integer ; inline
 618
 619 M: sequence <=>
 620     [ mismatch ] 2keep pick
 621     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 622
 623 : sequence= ( seq1 seq2 -- ? )
 624     2dup [ length ] bi@ =
 625     [ mismatch not ] [ 2drop f ] if ; inline
 626
 627 ERROR: assert-sequence got expected ;
 628
 629 : assert-sequence= ( a b -- )
 630     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 631
 632 <PRIVATE
 633
 634 : sequence-hashcode-step ( oldhash newpart -- newhash )
 635     >fixnum swap [
 636         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 637         fixnum+fast fixnum+fast
 638     ] keep fixnum-bitxor ; inline
 639
 640 PRIVATE>
 641
 642 : sequence-hashcode ( n seq -- x )
 643     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 644
 645 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 646
 647 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 648
 649 : move ( to from seq -- )
 650     2over =
 651     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 652
 653 <PRIVATE
 654
 655 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 656     2dup length < [
 657         [ move ] 3keep
 658         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 659         [ 1 + ] dip
 660         (filter!)
 661     ] [ nip set-length drop ] if ; inline recursive
 662
 663 PRIVATE>
 664
 665 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 666     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 667
 668 : remove! ( elt seq -- seq )
 669     [ = not ] with filter! ;
 670
 671 : remove-eq! ( elt seq -- seq )
 672     [ eq? not ] with filter! ;
 673
 674 : prefix ( seq elt -- newseq )
 675     over [ over length 1 + ] dip [
 676         (1sequence) [ 1 swap copy ] keep
 677     ] new-like ;
 678
 679 : suffix ( seq elt -- newseq )
 680     over [ over length 1 + ] dip [
 681         [ [ over length ] dip set-nth-unsafe ] keep
 682         [ 0 swap copy ] keep
 683     ] new-like ;
 684
 685 : suffix! ( seq elt -- seq ) over push ; inline
 686
 687 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 688
 689 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 690
 691 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 692
 693 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 694
 695 <PRIVATE
 696
 697 : move-backward ( shift from to seq -- )
 698     2over = [
 699         2drop 2drop
 700     ] [
 701         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 702         move-backward
 703     ] if ;
 704
 705 : move-forward ( shift from to seq -- )
 706     2over = [
 707         2drop 2drop
 708     ] [
 709         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 710         move-forward
 711     ] if ;
 712
 713 : (open-slice) ( shift from to seq ? -- )
 714     [
 715         [ [ 1 - ] bi@ ] dip move-forward
 716     ] [
 717         [ over - ] 2dip move-backward
 718     ] if ;
 719
 720 : open-slice ( shift from seq -- )
 721     pick 0 = [
 722         3drop
 723     ] [
 724         pick over length + over
 725         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 726         set-length
 727     ] if ;
 728
 729 PRIVATE>
 730
 731 : delete-slice ( from to seq -- )
 732     check-slice [ over [ - ] dip ] dip open-slice ;
 733
 734 : remove-nth! ( n seq -- seq )
 735     [ [ dup 1 + ] dip delete-slice ] keep ;
 736
 737 : snip ( from to seq -- head tail )
 738     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 739
 740 : snip-slice ( from to seq -- head tail )
 741     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 742
 743 : replace-slice ( new from to seq -- seq' )
 744     snip-slice surround ;
 745
 746 : remove-nth ( n seq -- seq' )
 747     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 748
 749 : pop ( seq -- elt )
 750     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 751
 752 : exchange ( m n seq -- )
 753     [ nip bounds-check 2drop ]
 754     [ bounds-check 3drop ]
 755     [ exchange-unsafe ]
 756     3tri ;
 757
 758 : midpoint@ ( seq -- n ) length 2/ ; inline
 759
 760 : reverse! ( seq -- seq )
 761     [
 762         [ midpoint@ iota ] [ length ] [ ] tri
 763         [ [ over - 1 - ] dip exchange-unsafe ] 2curry each
 764     ] keep ;
 765
 766 : reverse ( seq -- newseq )
 767     [
 768         dup [ length ] keep new-sequence
 769         [ 0 swap copy ] keep reverse!
 770     ] keep like ;
 771
 772 : sum-lengths ( seq -- n )
 773     0 [ length + ] reduce ;
 774
 775 : concat-as ( seq exemplar -- newseq )
 776     swap [ { } ] [
 777         [ sum-lengths over new-resizable ] keep
 778         [ append! ] each
 779     ] if-empty swap like ;
 780
 781 : concat ( seq -- newseq )
 782     [ { } ] [ dup first concat-as ] if-empty ;
 783
 784 <PRIVATE
 785
 786 : joined-length ( seq glue -- n )
 787     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 788
 789 PRIVATE>
 790
 791 : join ( seq glue -- newseq )
 792     dup empty? [ concat-as ] [
 793         [
 794             2dup joined-length over new-resizable [
 795                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 796                 interleave
 797             ] keep
 798         ] keep like
 799     ] if ;
 800
 801 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 802     [
 803         [ over length [-] dup 0 = [ drop ] ] dip
 804         [ <repetition> ] curry
 805     ] dip compose if ; inline
 806
 807 : pad-head ( seq n elt -- padded )
 808     [ swap dup append-as ] padding ;
 809
 810 : pad-tail ( seq n elt -- padded )
 811     [ append ] padding ;
 812
 813 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 814
 815 : head? ( seq begin -- ? )
 816     2dup shorter? [
 817         2drop f
 818     ] [
 819         [ nip ] [ length head-slice ] 2bi sequence=
 820     ] if ;
 821
 822 : tail? ( seq end -- ? )
 823     2dup shorter? [
 824         2drop f
 825     ] [
 826         [ nip ] [ length tail-slice* ] 2bi sequence=
 827     ] if ;
 828
 829 : cut-slice ( seq n -- before-slice after-slice )
 830     [ head-slice ] [ tail-slice ] 2bi ;
 831
 832 : insert-nth ( elt n seq -- seq' )
 833     swap cut-slice [ swap suffix ] dip append ;
 834
 835 : halves ( seq -- first-slice second-slice )
 836     dup midpoint@ cut-slice ;
 837
 838 : binary-reduce ( ... seq start quot: ( ... elt1 elt2 -- ... newelt ) -- ... value )
 839     #! We can't use case here since combinators depends on
 840     #! sequences
 841     pick length dup 0 3 between? [
 842         >fixnum {
 843             [ drop nip ]
 844             [ 2drop first ]
 845             [ [ drop first2 ] dip call ]
 846             [ [ drop first3 ] dip bi@ ]
 847         } dispatch
 848     ] [
 849         drop
 850         [ halves ] 2dip
 851         [ [ binary-reduce ] 2curry bi@ ] keep
 852         call
 853     ] if ; inline recursive
 854
 855 : cut ( seq n -- before after )
 856     [ head ] [ tail ] 2bi ;
 857
 858 : cut* ( seq n -- before after )
 859     [ head* ] [ tail* ] 2bi ;
 860
 861 <PRIVATE
 862
 863 : (start) ( subseq seq n -- subseq seq ? )
 864     pick length iota [
 865         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 866     ] all? nip ; inline
 867
 868 PRIVATE>
 869
 870 : start* ( subseq seq n -- i )
 871     pick length pick length swap - 1 + iota
 872     [ (start) ] find-from
 873     swap [ 3drop ] dip ;
 874
 875 : start ( subseq seq -- i ) 0 start* ; inline
 876
 877 : subseq? ( subseq seq -- ? ) start >boolean ;
 878
 879 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 880     2dup mismatch [ 2dup min-length ] unless*
 881     [ tail-slice ] curry bi@ ;
 882
 883 : unclip ( seq -- rest first )
 884     [ rest ] [ first-unsafe ] bi ;
 885
 886 : unclip-last ( seq -- butlast last )
 887     [ but-last ] [ last ] bi ;
 888
 889 : unclip-slice ( seq -- rest-slice first )
 890     [ rest-slice ] [ first-unsafe ] bi ; inline
 891
 892 : map-reduce ( ..a seq map-quot: ( ..a x -- ..b elt ) reduce-quot: ( ..b prev elt -- ..a next ) -- ..a result )
 893     [ [ dup first ] dip [ call ] keep ] dip compose
 894     swapd [ 1 ] 2dip (each) (each-integer) ; inline
 895
 896 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 897     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 898     [ -rot ] dip [ 1 ] 3dip (2each) (each-integer) ; inline
 899
 900 <PRIVATE
 901
 902 : (map-find) ( seq quot find-quot -- result elt )
 903     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 904     [ [ drop f ] unless ] dip ; inline
 905
 906 PRIVATE>
 907
 908 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 909     [ find ] (map-find) ; inline
 910
 911 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 912     [ find-last ] (map-find) ; inline
 913
 914 : unclip-last-slice ( seq -- butlast-slice last )
 915     [ but-last-slice ] [ last ] bi ; inline
 916
 917 <PRIVATE
 918
 919 : (trim-head) ( seq quot -- seq n )
 920     over [ [ not ] compose find drop ] dip
 921     [ length or ] keep swap ; inline
 922
 923 : (trim-tail) ( seq quot -- seq n )
 924     over [ [ not ] compose find-last drop ?1+ ] dip
 925     swap ; inline
 926
 927 PRIVATE>
 928
 929 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 930     (trim-head) tail-slice ; inline
 931
 932 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 933     (trim-head) tail ; inline
 934
 935 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 936     (trim-tail) head-slice ; inline
 937
 938 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 939     (trim-tail) head ; inline
 940
 941 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 942     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 943
 944 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 945     [ trim-slice ] [ drop ] 2bi like ; inline
 946
 947 GENERIC: sum ( seq -- n )
 948 M: object sum 0 [ + ] binary-reduce ; inline
 949
 950 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 951
 952 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 953
 954 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 955
 956 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 957     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 958
 959 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n ) [ 1 0 ? ] compose map-sum ; inline
 960
 961 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 962     [ with each ] 2curry each ; inline
 963
 964 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 965     [ with map ] 2curry map ; inline
 966
 967 : cartesian-product ( seq1 seq2 -- newseq )
 968     [ { } 2sequence ] cartesian-map ;
 969
 970 ! We hand-optimize flip to such a degree because type hints
 971 ! cannot express that an array is an array of arrays yet, and
 972 ! this word happens to be performance-critical since the compiler
 973 ! itself uses it. Optimizing it like this reduced compile time.
 974 <PRIVATE
 975
 976 : generic-flip ( matrix -- newmatrix )
 977     [ dup first length [ length min ] reduce iota ] keep
 978     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 979
 980 USE: arrays
 981
 982 : array-length ( array -- len )
 983     { array } declare length>> ; inline
 984
 985 : array-flip ( matrix -- newmatrix )
 986     { array } declare
 987     [ dup first array-length [ array-length min ] reduce iota ] keep
 988     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 989
 990 PRIVATE>
 991
 992 : flip ( matrix -- newmatrix )
 993     dup empty? [
 994         dup array? [
 995             dup [ array? ] all?
 996             [ array-flip ] [ generic-flip ] if
 997         ] [ generic-flip ] if
 998     ] unless ;