core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 PRIVATE>
  95
  96 ! The f object supports the sequence protocol trivially
  97 M: f length drop 0 ; inline
  98 M: f nth-unsafe nip ; inline
  99 M: f like drop [ f ] when-empty ; inline
 100
 101 INSTANCE: f immutable-sequence
 102
 103 ! Integer sequences
 104 TUPLE: iota { n integer read-only } ;
 105
 106 : iota ( n -- iota ) \ iota boa ; inline
 107
 108 M: iota length n>> ; inline
 109 M: iota nth-unsafe drop ; inline
 110
 111 INSTANCE: iota immutable-sequence
 112
 113 <PRIVATE
 114
 115 : first-unsafe ( seq -- first )
 116     0 swap nth-unsafe ; inline
 117
 118 : first2-unsafe ( seq -- first second )
 119     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 120
 121 : first3-unsafe ( seq -- first second third )
 122     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 123
 124 : first4-unsafe ( seq -- first second third fourth )
 125     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 126
 127 : exchange-unsafe ( m n seq -- )
 128     [ [ nth-unsafe ] curry bi@ ]
 129     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 130
 131 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 132
 133 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 134
 135 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 136
 137 : (1sequence) ( obj seq -- seq )
 138     [ 0 swap set-nth-unsafe ] keep ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep
 142     (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep
 146     (2sequence) ; inline
 147
 148 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 149     [ 3 swap set-nth-unsafe ] keep
 150     (3sequence) ; inline
 151
 152 PRIVATE>
 153
 154 : 1sequence ( obj exemplar -- seq )
 155     1 swap [ (1sequence) ] new-like ; inline
 156
 157 : 2sequence ( obj1 obj2 exemplar -- seq )
 158     2 swap [ (2sequence) ] new-like ; inline
 159
 160 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 161     3 swap [ (3sequence) ] new-like ; inline
 162
 163 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 164     4 swap [ (4sequence) ] new-like ; inline
 165
 166 : first2 ( seq -- first second )
 167     1 swap bounds-check nip first2-unsafe ; inline
 168
 169 : first3 ( seq -- first second third )
 170     2 swap bounds-check nip first3-unsafe ; inline
 171
 172 : first4 ( seq -- first second third fourth )
 173     3 swap bounds-check nip first4-unsafe ; inline
 174
 175 : ?nth ( n seq -- elt/f )
 176     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 177
 178 MIXIN: virtual-sequence
 179 GENERIC: virtual-exemplar ( seq -- seq' )
 180 GENERIC: virtual@ ( n seq -- n' seq' )
 181
 182 M: virtual-sequence nth virtual@ nth ; inline
 183 M: virtual-sequence set-nth virtual@ set-nth ; inline
 184 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 185 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 186 M: virtual-sequence like virtual-exemplar like ; inline
 187 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 188
 189 INSTANCE: virtual-sequence sequence
 190
 191 ! A reversal of an underlying sequence.
 192 TUPLE: reversed { seq read-only } ;
 193
 194 C: <reversed> reversed
 195
 196 M: reversed virtual-exemplar seq>> ; inline
 197 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 198 M: reversed length seq>> length ; inline
 199
 200 INSTANCE: reversed virtual-sequence
 201
 202 ! A slice of another sequence.
 203 TUPLE: slice
 204 { from read-only }
 205 { to read-only }
 206 { seq read-only } ;
 207
 208 : collapse-slice ( m n slice -- m' n' seq )
 209     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 210
 211 TUPLE: slice-error from to seq reason ;
 212
 213 : slice-error ( from to seq ? string -- from to seq )
 214     [ \ slice-error boa throw ] curry when ; inline
 215
 216 : check-slice ( from to seq -- from to seq )
 217     3dup
 218     [ 2drop 0 < "start < 0" slice-error ]
 219     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 220     [ drop > "start > end" slice-error ]
 221     3tri ; inline
 222
 223 : <slice> ( from to seq -- slice )
 224     check-slice
 225     dup slice? [ collapse-slice ] when
 226     slice boa ; inline
 227
 228 M: slice virtual-exemplar seq>> ; inline
 229
 230 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 231
 232 M: slice length [ to>> ] [ from>> ] bi - ; inline
 233
 234 : short ( seq n -- seq n' ) over length min ; inline
 235
 236 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 237
 238 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 239
 240 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 241
 242 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 243
 244 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 245
 246 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 247
 248 INSTANCE: slice virtual-sequence
 249
 250 ! One element repeated many times
 251 TUPLE: repetition { len read-only } { elt read-only } ;
 252
 253 C: <repetition> repetition
 254
 255 M: repetition length len>> ; inline
 256 M: repetition nth-unsafe nip elt>> ; inline
 257
 258 INSTANCE: repetition immutable-sequence
 259
 260 <PRIVATE
 261
 262 ERROR: integer-length-expected obj ;
 263
 264 : check-length ( n -- n )
 265     dup integer? [ integer-length-expected ] unless ; inline
 266
 267 TUPLE: copy-state
 268     { src-i read-only }
 269     { src read-only }
 270     { dst-i read-only }
 271     { dst read-only } ;
 272
 273 C: <copy> copy-state
 274
 275 : ((copy)) ( n copy -- )
 276     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 277     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 278
 279 : (copy) ( n copy -- dst )
 280     over 0 <= [ nip dst>> ] [ [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi ] if ;
 281     inline recursive
 282
 283 : subseq>copy ( from to seq -- n copy )
 284     [ over - check-length swap ] dip
 285     3dup nip new-sequence 0 swap <copy> ; inline
 286
 287 : check-copy ( src n dst -- src n dst )
 288     3dup over 0 < [ bounds-error ] when
 289     [ swap length + ] dip lengthen ; inline
 290
 291 PRIVATE>
 292
 293 : subseq ( from to seq -- subseq )
 294     [ check-slice subseq>copy (copy) ] keep like ;
 295
 296 : head ( seq n -- headseq ) (head) subseq ;
 297
 298 : tail ( seq n -- tailseq ) (tail) subseq ;
 299
 300 : rest ( seq -- tailseq ) 1 tail ;
 301
 302 : head* ( seq n -- headseq ) from-end head ;
 303
 304 : tail* ( seq n -- tailseq ) from-end tail ;
 305
 306 : but-last ( seq -- headseq ) 1 head* ;
 307
 308 : copy ( src i dst -- )
 309     #! The check-length call forces partial dispatch
 310     [ [ length check-length 0 ] keep ] 2dip
 311     check-copy <copy> (copy) drop ; inline
 312
 313 M: sequence clone-like
 314     [ dup length ] dip new-sequence [ 0 swap copy ] keep ; inline
 315
 316 M: immutable-sequence clone-like like ; inline
 317
 318 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 319
 320 <PRIVATE
 321
 322 : (append) ( seq1 seq2 accum -- accum )
 323     [ [ over length ] dip copy ]
 324     [ 0 swap copy ]
 325     [ ] tri ; inline
 326
 327 PRIVATE>
 328
 329 : append-as ( seq1 seq2 exemplar -- newseq )
 330     [ over length over length + ] dip
 331     [ (append) ] new-like ; inline
 332
 333 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 334     [ 3dup [ length ] tri@ + + ] dip [
 335         [ [ 2over [ length ] bi@ + ] dip copy ]
 336         [ (append) ] bi
 337     ] new-like ; inline
 338
 339 : append ( seq1 seq2 -- newseq ) over append-as ;
 340
 341 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 342
 343 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 344
 345 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 346
 347 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 348
 349 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 350     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 351
 352 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 353
 354 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 355
 356 <PRIVATE
 357
 358 : ((each)) ( seq -- n quot )
 359     [ length ] keep [ nth-unsafe ] curry ; inline
 360
 361 : (each) ( seq quot -- n quot' )
 362     [ ((each)) ] dip compose ; inline
 363
 364 : (each-index) ( seq quot -- n quot' )
 365     [ ((each)) [ keep ] curry ] dip compose ; inline
 366
 367 : (collect) ( quot into -- quot' )
 368     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 369
 370 : collect ( n quot into -- )
 371     (collect) each-integer ; inline
 372
 373 : map-into ( seq quot into -- )
 374     [ (each) ] dip collect ; inline
 375
 376 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 377     [ nth-unsafe ] bi-curry@ bi ; inline
 378
 379 : (2each) ( seq1 seq2 quot -- n quot' )
 380     [
 381         [ min-length ] 2keep
 382         [ 2nth-unsafe ] 2curry
 383     ] dip compose ; inline
 384
 385 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 386     [ nth-unsafe ] tri-curry@ tri ; inline
 387
 388 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 389     [
 390         [ [ length ] tri@ min min ]
 391         [ [ 3nth-unsafe ] 3curry ] 3bi
 392     ] dip compose ; inline
 393
 394 : finish-find ( i seq -- i elt )
 395     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 396
 397 : (find) ( seq quot quot' -- i elt )
 398     pick [ [ (each) ] dip call ] dip finish-find ; inline
 399
 400 : (find-from) ( n seq quot quot' -- i elt )
 401     [ 2dup bounds-check? ] 2dip
 402     [ (find) ] 2curry
 403     [ 2drop f f ]
 404     if ; inline
 405
 406 : (find-index) ( seq quot quot' -- i elt )
 407     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 408
 409 : (accumulate) ( seq identity quot -- identity seq quot )
 410     [ swap ] dip [ curry keep ] curry ; inline
 411
 412 PRIVATE>
 413
 414 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 415     (each) each-integer ; inline
 416
 417 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 418     swapd each ; inline
 419
 420 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 421     [ over ] dip [ [ collect ] keep ] new-like ; inline
 422
 423 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 424     [ (each) ] dip map-integers ; inline
 425
 426 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 427     over map-as ; inline
 428
 429 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 430     [ [ drop ] prepose ] dip map-integers ; inline
 431
 432 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 433     { } replicate-as ; inline
 434
 435 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 436     over [ map-into ] keep ; inline
 437
 438 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 439     [ (accumulate) ] dip map-as ; inline
 440
 441 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 442     pick accumulate-as ; inline
 443
 444 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 445     (accumulate) map! ; inline
 446
 447 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 448     (2each) each-integer ; inline
 449
 450 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 451     [ -rot ] dip 2each ; inline
 452
 453 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 454     [ (2each) ] dip map-integers ; inline
 455
 456 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 457     pick 2map-as ; inline
 458
 459 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 460     (2each) all-integers? ; inline
 461
 462 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 463     (3each) each-integer ; inline
 464
 465 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 466     [ (3each) ] dip map-integers ; inline
 467
 468 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 469     [ pick ] dip swap 3map-as ; inline
 470
 471 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 472     [ (find-integer) ] (find-from) ; inline
 473
 474 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 475     [ find-integer ] (find) ; inline
 476
 477 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 478     [ nip find-last-integer ] (find-from) ; inline
 479
 480 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 481     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 482
 483 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 484     [ find-integer ] (find-index) ; inline
 485
 486 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 487     (each) all-integers? ; inline
 488
 489 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 490     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 491
 492 : selector-for ( quot exemplar -- selector accum )
 493     [ length ] keep new-resizable [ [ push-if ] 2curry ] keep ; inline
 494
 495 : selector ( quot -- selector accum )
 496     V{ } selector-for ; inline
 497
 498 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 499     dup [ selector-for [ each ] dip ] curry dip like ; inline
 500
 501 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 502     over filter-as ; inline
 503
 504 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 505     [ keep swap ] 2dip ? push ; inline
 506
 507 : 2selector ( quot -- selector accum1 accum2 )
 508     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 509
 510 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 511     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 512
 513 : collector-for ( quot exemplar -- quot' vec )
 514     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 515
 516 : collector ( quot -- quot' vec )
 517     V{ } collector-for ; inline
 518
 519 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 520     dup [ collector-for [ while ] dip ] curry dip like ; inline
 521
 522 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 523     { } produce-as ; inline
 524
 525 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 526     [ dup ] swap [ keep ] curry produce nip ; inline
 527
 528 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 529     (each-index) each-integer ; inline
 530
 531 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 532     pick empty? [ 3drop ] [
 533         [ [ drop first-unsafe ] dip call ]
 534         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 535         3bi
 536     ] if ; inline
 537
 538 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 539     [ dup length iota ] dip 2map ; inline
 540
 541 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 542     swapd each-index ; inline
 543
 544 : index ( obj seq -- n )
 545     [ = ] with find drop ;
 546
 547 : index-from ( obj i seq -- n )
 548     rot [ = ] curry find-from drop ;
 549
 550 : last-index ( obj seq -- n )
 551     [ = ] with find-last drop ;
 552
 553 : last-index-from ( obj i seq -- n )
 554     rot [ = ] curry find-last-from drop ;
 555
 556 <PRIVATE
 557
 558 : (indices) ( elt i obj accum -- )
 559     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 560
 561 PRIVATE>
 562
 563 : indices ( obj seq -- indices )
 564     swap V{ } clone
 565     [ [ (indices) ] 2curry each-index ] keep ;
 566
 567 : nths ( indices seq -- seq' )
 568     [ [ nth ] curry ] keep map-as ;
 569
 570 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 571     find drop >boolean ; inline
 572
 573 : member? ( elt seq -- ? )
 574     [ = ] with any? ;
 575
 576 : member-eq? ( elt seq -- ? )
 577     [ eq? ] with any? ;
 578
 579 : remove ( elt seq -- newseq )
 580     [ = not ] with filter ;
 581
 582 : remove-eq ( elt seq -- newseq )
 583     [ eq? not ] with filter ;
 584
 585 : sift ( seq -- newseq )
 586     [ ] filter ;
 587
 588 : harvest ( seq -- newseq )
 589     [ empty? not ] filter ;
 590
 591 : mismatch ( seq1 seq2 -- i )
 592     [ min-length ] 2keep
 593     [ 2nth-unsafe = not ] 2curry
 594     find-integer ; inline
 595
 596 M: sequence <=>
 597     [ mismatch ] 2keep pick
 598     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 599
 600 : sequence= ( seq1 seq2 -- ? )
 601     2dup [ length ] bi@ =
 602     [ mismatch not ] [ 2drop f ] if ; inline
 603
 604 ERROR: assert-sequence got expected ;
 605
 606 : assert-sequence= ( a b -- )
 607     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 608
 609 <PRIVATE
 610
 611 : sequence-hashcode-step ( oldhash newpart -- newhash )
 612     >fixnum swap [
 613         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 614         fixnum+fast fixnum+fast
 615     ] keep fixnum-bitxor ; inline
 616
 617 PRIVATE>
 618
 619 : sequence-hashcode ( n seq -- x )
 620     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 621
 622 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 623
 624 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 625
 626 : move ( to from seq -- )
 627     2over =
 628     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 629
 630 <PRIVATE
 631
 632 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 633     2dup length < [
 634         [ move ] 3keep
 635         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 636         [ 1 + ] dip
 637         (filter!)
 638     ] [ nip set-length drop ] if ; inline recursive
 639
 640 PRIVATE>
 641
 642 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 643     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 644
 645 : remove! ( elt seq -- seq )
 646     [ = not ] with filter! ;
 647
 648 : remove-eq! ( elt seq -- seq )
 649     [ eq? not ] with filter! ;
 650
 651 : prefix ( seq elt -- newseq )
 652     over [ over length 1 + ] dip [
 653         [ 0 swap set-nth-unsafe ] keep
 654         [ 1 swap copy ] keep
 655     ] new-like ;
 656
 657 : suffix ( seq elt -- newseq )
 658     over [ over length 1 + ] dip [
 659         [ [ over length ] dip set-nth-unsafe ] keep
 660         [ 0 swap copy ] keep
 661     ] new-like ;
 662
 663 : suffix! ( seq elt -- seq ) over push ; inline
 664
 665 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 666
 667 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 668
 669 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 670
 671 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 672
 673 <PRIVATE
 674
 675 : move-backward ( shift from to seq -- )
 676     2over = [
 677         2drop 2drop
 678     ] [
 679         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 680         move-backward
 681     ] if ;
 682
 683 : move-forward ( shift from to seq -- )
 684     2over = [
 685         2drop 2drop
 686     ] [
 687         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 688         move-forward
 689     ] if ;
 690
 691 : (open-slice) ( shift from to seq ? -- )
 692     [
 693         [ [ 1 - ] bi@ ] dip move-forward
 694     ] [
 695         [ over - ] 2dip move-backward
 696     ] if ;
 697
 698 : open-slice ( shift from seq -- )
 699     pick 0 = [
 700         3drop
 701     ] [
 702         pick over length + over
 703         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 704         set-length
 705     ] if ;
 706
 707 PRIVATE>
 708
 709 : delete-slice ( from to seq -- )
 710     check-slice [ over [ - ] dip ] dip open-slice ;
 711
 712 : remove-nth! ( n seq -- seq )
 713     [ [ dup 1 + ] dip delete-slice ] keep ;
 714
 715 : snip ( from to seq -- head tail )
 716     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 717
 718 : snip-slice ( from to seq -- head tail )
 719     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 720
 721 : replace-slice ( new from to seq -- seq' )
 722     snip-slice surround ;
 723
 724 : remove-nth ( n seq -- seq' )
 725     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 726
 727 : pop ( seq -- elt )
 728     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 729
 730 : exchange ( m n seq -- )
 731     [ nip bounds-check 2drop ]
 732     [ bounds-check 3drop ]
 733     [ exchange-unsafe ]
 734     3tri ;
 735
 736 : reverse! ( seq -- seq )
 737     [
 738         [ length 2/ iota ] [ length ] [ ] tri
 739         [ [ over - 1 - ] dip exchange-unsafe ] 2curry each
 740     ] keep ;
 741
 742 : reverse ( seq -- newseq )
 743     [
 744         dup [ length ] keep new-sequence
 745         [ 0 swap copy ] keep reverse!
 746     ] keep like ;
 747
 748 : sum-lengths ( seq -- n )
 749     0 [ length + ] reduce ;
 750
 751 : concat-as ( seq exemplar -- newseq )
 752     swap [ { } ] [
 753         [ sum-lengths over new-resizable ] keep
 754         [ append! ] each
 755     ] if-empty swap like ;
 756
 757 : concat ( seq -- newseq )
 758     [ { } ] [ dup first concat-as ] if-empty ;
 759
 760 <PRIVATE
 761
 762 : joined-length ( seq glue -- n )
 763     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 764
 765 PRIVATE>
 766
 767 : join ( seq glue -- newseq )
 768     dup empty? [ concat-as ] [
 769         [
 770             2dup joined-length over new-resizable [
 771                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 772                 interleave
 773             ] keep
 774         ] keep like
 775     ] if ;
 776
 777 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 778     [
 779         [ over length [-] dup 0 = [ drop ] ] dip
 780         [ <repetition> ] curry
 781     ] dip compose if ; inline
 782
 783 : pad-head ( seq n elt -- padded )
 784     [ swap dup append-as ] padding ;
 785
 786 : pad-tail ( seq n elt -- padded )
 787     [ append ] padding ;
 788
 789 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 790
 791 : head? ( seq begin -- ? )
 792     2dup shorter? [
 793         2drop f
 794     ] [
 795         [ nip ] [ length head-slice ] 2bi sequence=
 796     ] if ;
 797
 798 : tail? ( seq end -- ? )
 799     2dup shorter? [
 800         2drop f
 801     ] [
 802         [ nip ] [ length tail-slice* ] 2bi sequence=
 803     ] if ;
 804
 805 : cut-slice ( seq n -- before-slice after-slice )
 806     [ head-slice ] [ tail-slice ] 2bi ;
 807
 808 : insert-nth ( elt n seq -- seq' )
 809     swap cut-slice [ swap suffix ] dip append ;
 810
 811 : midpoint@ ( seq -- n ) length 2/ ; inline
 812
 813 : halves ( seq -- first-slice second-slice )
 814     dup midpoint@ cut-slice ;
 815
 816 : binary-reduce ( ... seq start quot: ( ... elt1 elt2 -- ... newelt ) -- ... value )
 817     #! We can't use case here since combinators depends on
 818     #! sequences
 819     pick length dup 0 3 between? [
 820         >fixnum {
 821             [ drop nip ]
 822             [ 2drop first ]
 823             [ [ drop first2 ] dip call ]
 824             [ [ drop first3 ] dip bi@ ]
 825         } dispatch
 826     ] [
 827         drop
 828         [ halves ] 2dip
 829         [ [ binary-reduce ] 2curry bi@ ] keep
 830         call
 831     ] if ; inline recursive
 832
 833 : cut ( seq n -- before after )
 834     [ head ] [ tail ] 2bi ;
 835
 836 : cut* ( seq n -- before after )
 837     [ head* ] [ tail* ] 2bi ;
 838
 839 <PRIVATE
 840
 841 : (start) ( subseq seq n -- subseq seq ? )
 842     pick length iota [
 843         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 844     ] all? nip ; inline
 845
 846 : prepare-2map-reduce ( seq1 seq2 map-quot -- initial length seq1 seq2 )
 847     [ drop min-length dup 1 < [ "Empty sequence" throw ] when 1 - ]
 848     [ drop [ [ 1 + ] 2dip 2nth-unsafe ] 2curry ]
 849     [ [ [ first-unsafe ] bi@ ] dip call ]
 850     3tri -rot ; inline
 851
 852 PRIVATE>
 853
 854 : start* ( subseq seq n -- i )
 855     pick length pick length swap - 1 + iota
 856     [ (start) ] find-from
 857     swap [ 3drop ] dip ;
 858
 859 : start ( subseq seq -- i ) 0 start* ; inline
 860
 861 : subseq? ( subseq seq -- ? ) start >boolean ;
 862
 863 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 864     2dup mismatch [ 2dup min-length ] unless*
 865     [ tail-slice ] curry bi@ ;
 866
 867 : unclip ( seq -- rest first )
 868     [ rest ] [ first-unsafe ] bi ;
 869
 870 : unclip-last ( seq -- butlast last )
 871     [ but-last ] [ last ] bi ;
 872
 873 : unclip-slice ( seq -- rest-slice first )
 874     [ rest-slice ] [ first-unsafe ] bi ; inline
 875
 876 : map-reduce ( ..a seq map-quot: ( ..a x -- ..b elt ) reduce-quot: ( ..b prev elt -- ..a next ) -- ..a result )
 877     [ [ unclip-slice ] dip [ call ] keep ] dip
 878     compose reduce ; inline
 879
 880 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 881     [ [ prepare-2map-reduce ] keep ] dip
 882     compose compose each-integer ; inline
 883
 884 <PRIVATE
 885
 886 : (map-find) ( seq quot find-quot -- result elt )
 887     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 888     [ [ drop f ] unless ] dip ; inline
 889
 890 PRIVATE>
 891
 892 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 893     [ find ] (map-find) ; inline
 894
 895 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 896     [ find-last ] (map-find) ; inline
 897
 898 : unclip-last-slice ( seq -- butlast-slice last )
 899     [ but-last-slice ] [ last ] bi ; inline
 900
 901 <PRIVATE
 902
 903 : (trim-head) ( seq quot -- seq n )
 904     over [ [ not ] compose find drop ] dip
 905     [ length or ] keep swap ; inline
 906
 907 : (trim-tail) ( seq quot -- seq n )
 908     over [ [ not ] compose find-last drop ?1+ ] dip
 909     swap ; inline
 910
 911 PRIVATE>
 912
 913 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 914     (trim-head) tail-slice ; inline
 915
 916 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 917     (trim-head) tail ; inline
 918
 919 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 920     (trim-tail) head-slice ; inline
 921
 922 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 923     (trim-tail) head ; inline
 924
 925 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 926     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 927
 928 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 929     [ trim-slice ] [ drop ] 2bi like ; inline
 930
 931 GENERIC: sum ( seq -- n )
 932 M: object sum 0 [ + ] binary-reduce ; inline
 933
 934 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 935
 936 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 937
 938 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 939
 940 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 941     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 942
 943 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n ) [ 1 0 ? ] compose map-sum ; inline
 944
 945 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 946     [ with each ] 2curry each ; inline
 947
 948 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 949     [ with map ] 2curry map ; inline
 950
 951 : cartesian-product ( seq1 seq2 -- newseq )
 952     [ { } 2sequence ] cartesian-map ;
 953
 954 ! We hand-optimize flip to such a degree because type hints
 955 ! cannot express that an array is an array of arrays yet, and
 956 ! this word happens to be performance-critical since the compiler
 957 ! itself uses it. Optimizing it like this reduced compile time.
 958 <PRIVATE
 959
 960 : generic-flip ( matrix -- newmatrix )
 961     [ dup first length [ length min ] reduce iota ] keep
 962     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 963
 964 USE: arrays
 965
 966 : array-length ( array -- len )
 967     { array } declare length>> ; inline
 968
 969 : array-flip ( matrix -- newmatrix )
 970     { array } declare
 971     [ dup first array-length [ array-length min ] reduce iota ] keep
 972     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 973
 974 PRIVATE>
 975
 976 : flip ( matrix -- newmatrix )
 977     dup empty? [
 978         dup array? [
 979             dup [ array? ] all?
 980             [ array-flip ] [ generic-flip ] if
 981         ] [ generic-flip ] if
 982     ] unless ;