core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private locals slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 ! The f object supports the sequence protocol trivially
  95 M: f length drop 0 ;
  96 M: f nth-unsafe nip ;
  97 M: f like drop [ f ] when-empty ;
  98
  99 INSTANCE: f immutable-sequence
 100
 101 ! Integers support the sequence protocol
 102 M: integer length ;
 103 M: integer nth-unsafe drop ;
 104
 105 INSTANCE: integer immutable-sequence
 106
 107 PRIVATE>
 108
 109 ! In the future, this will replace integer sequences
 110 TUPLE: iota { n integer read-only } ;
 111
 112 : iota ( n -- iota ) \ iota boa ; inline
 113
 114 <PRIVATE
 115
 116 M: iota length n>> ;
 117 M: iota nth-unsafe drop ;
 118
 119 INSTANCE: iota immutable-sequence
 120
 121 : first-unsafe ( seq -- first )
 122     0 swap nth-unsafe ; inline
 123
 124 : first2-unsafe ( seq -- first second )
 125     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 126
 127 : first3-unsafe ( seq -- first second third )
 128     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 129
 130 : first4-unsafe ( seq -- first second third fourth )
 131     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 132
 133 : exchange-unsafe ( m n seq -- )
 134     [ [ nth-unsafe ] curry bi@ ]
 135     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 136
 137 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 138
 139 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 140
 141 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 142
 143 : (1sequence) ( obj seq -- seq )
 144     [ 0 swap set-nth-unsafe ] keep ; inline
 145
 146 : (2sequence) ( obj1 obj2 seq -- seq )
 147     [ 1 swap set-nth-unsafe ] keep
 148     (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep
 152     (2sequence) ; inline
 153
 154 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 155     [ 3 swap set-nth-unsafe ] keep
 156     (3sequence) ; inline
 157
 158 PRIVATE>
 159
 160 : 1sequence ( obj exemplar -- seq )
 161     1 swap [ (1sequence) ] new-like ; inline
 162
 163 : 2sequence ( obj1 obj2 exemplar -- seq )
 164     2 swap [ (2sequence) ] new-like ; inline
 165
 166 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 167     3 swap [ (3sequence) ] new-like ; inline
 168
 169 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 170     4 swap [ (4sequence) ] new-like ; inline
 171
 172 : first2 ( seq -- first second )
 173     1 swap bounds-check nip first2-unsafe ; flushable
 174
 175 : first3 ( seq -- first second third )
 176     2 swap bounds-check nip first3-unsafe ; flushable
 177
 178 : first4 ( seq -- first second third fourth )
 179     3 swap bounds-check nip first4-unsafe ; flushable
 180
 181 : ?nth ( n seq -- elt/f )
 182     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 183
 184 MIXIN: virtual-sequence
 185 GENERIC: virtual-seq ( seq -- seq' )
 186 GENERIC: virtual@ ( n seq -- n' seq' )
 187
 188 M: virtual-sequence nth virtual@ nth ;
 189 M: virtual-sequence set-nth virtual@ set-nth ;
 190 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 191 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 192 M: virtual-sequence like virtual-seq like ;
 193 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 194
 195 INSTANCE: virtual-sequence sequence
 196
 197 ! A reversal of an underlying sequence.
 198 TUPLE: reversed { seq read-only } ;
 199
 200 C: <reversed> reversed
 201
 202 M: reversed virtual-seq seq>> ;
 203
 204 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ;
 205
 206 M: reversed length seq>> length ;
 207
 208 INSTANCE: reversed virtual-sequence
 209
 210 ! A slice of another sequence.
 211 TUPLE: slice
 212 { from read-only }
 213 { to read-only }
 214 { seq read-only } ;
 215
 216 : collapse-slice ( m n slice -- m' n' seq )
 217     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 218
 219 TUPLE: slice-error from to seq reason ;
 220
 221 : slice-error ( from to seq ? string -- from to seq )
 222     [ \ slice-error boa throw ] curry when ; inline
 223
 224 : check-slice ( from to seq -- from to seq )
 225     3dup
 226     [ 2drop 0 < "start < 0" slice-error ]
 227     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 228     [ drop > "start > end" slice-error ]
 229     3tri ; inline
 230
 231 : <slice> ( from to seq -- slice )
 232     dup slice? [ collapse-slice ] when
 233     check-slice
 234     slice boa ; inline
 235
 236 M: slice virtual-seq seq>> ;
 237
 238 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 239
 240 M: slice length [ to>> ] [ from>> ] bi - ;
 241
 242 : short ( seq n -- seq n' ) over length min ; inline
 243
 244 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 245
 246 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 247
 248 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 249
 250 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 251
 252 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 253
 254 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 255
 256 INSTANCE: slice virtual-sequence
 257
 258 ! One element repeated many times
 259 TUPLE: repetition { len read-only } { elt read-only } ;
 260
 261 C: <repetition> repetition
 262
 263 M: repetition length len>> ;
 264 M: repetition nth-unsafe nip elt>> ;
 265
 266 INSTANCE: repetition immutable-sequence
 267
 268 <PRIVATE
 269
 270 : check-length ( n -- n )
 271     #! Ricing.
 272     dup integer? [ "length not an integer" throw ] unless ; inline
 273
 274 : ((copy)) ( dst i src j n -- dst i src j n )
 275     dup -roll [
 276         + swap nth-unsafe -roll [
 277             + swap set-nth-unsafe
 278         ] 3keep drop
 279     ] 3keep ; inline
 280
 281 : (copy) ( dst i src j n -- dst )
 282     dup 0 <= [ 2drop 2drop ] [ 1 - ((copy)) (copy) ] if ;
 283     inline recursive
 284
 285 : prepare-subseq ( from to seq -- dst i src j n )
 286     #! The check-length call forces partial dispatch
 287     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 288     -rot drop roll length check-length ; inline
 289
 290 : check-copy ( src n dst -- )
 291     over 0 < [ bounds-error ] when
 292     [ swap length + ] dip lengthen ; inline
 293
 294 PRIVATE>
 295
 296 : subseq ( from to seq -- subseq )
 297     [ check-slice prepare-subseq (copy) ] keep like ;
 298
 299 : head ( seq n -- headseq ) (head) subseq ;
 300
 301 : tail ( seq n -- tailseq ) (tail) subseq ;
 302
 303 : rest ( seq -- tailseq ) 1 tail ;
 304
 305 : head* ( seq n -- headseq ) from-end head ;
 306
 307 : tail* ( seq n -- tailseq ) from-end tail ;
 308
 309 : but-last ( seq -- headseq ) 1 head* ;
 310
 311 : copy ( src i dst -- )
 312     #! The check-length call forces partial dispatch
 313     pick length check-length [ 3dup check-copy spin 0 ] dip
 314     (copy) drop ; inline
 315
 316 M: sequence clone-like
 317     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 318
 319 M: immutable-sequence clone-like like ;
 320
 321 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 322
 323 <PRIVATE
 324
 325 : (append) ( seq1 seq2 accum -- accum )
 326     [ [ over length ] dip copy ]
 327     [ 0 swap copy ]
 328     [ ] tri ; inline
 329
 330 PRIVATE>
 331
 332 : append-as ( seq1 seq2 exemplar -- newseq )
 333     [ over length over length + ] dip
 334     [ (append) ] new-like ; inline
 335
 336 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 337     [ 3dup [ length ] tri@ + + ] dip [
 338         [ [ 2over [ length ] bi@ + ] dip copy ]
 339         [ (append) ] bi
 340     ] new-like ; inline
 341
 342 : append ( seq1 seq2 -- newseq ) over append-as ;
 343
 344 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 345
 346 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 347
 348 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 349
 350 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 351
 352 : change-nth ( i seq quot -- )
 353     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 354
 355 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 356
 357 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 358
 359 <PRIVATE
 360
 361 : (each) ( seq quot -- n quot' )
 362     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 363
 364 : (collect) ( quot into -- quot' )
 365     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 366
 367 : collect ( n quot into -- )
 368     (collect) each-integer ; inline
 369
 370 : map-into ( seq quot into -- )
 371     [ (each) ] dip collect ; inline
 372
 373 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 374     [ nth-unsafe ] bi-curry@ bi ; inline
 375
 376 : (2each) ( seq1 seq2 quot -- n quot' )
 377     [
 378         [ min-length ] 2keep
 379         [ 2nth-unsafe ] 2curry
 380     ] dip compose ; inline
 381
 382 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 383     [ nth-unsafe ] tri-curry@ tri ; inline
 384
 385 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 386     [
 387         [ [ length ] tri@ min min ]
 388         [ [ 3nth-unsafe ] 3curry ] 3bi
 389     ] dip compose ; inline
 390
 391 : finish-find ( i seq -- i elt )
 392     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 393
 394 : (find) ( seq quot quot' -- i elt )
 395     pick [ [ (each) ] dip call ] dip finish-find ; inline
 396
 397 : (find-from) ( n seq quot quot' -- i elt )
 398     [ 2dup bounds-check? ] 2dip
 399     [ (find) ] 2curry
 400     [ 2drop f f ]
 401     if ; inline
 402
 403 PRIVATE>
 404
 405 : each ( seq quot -- )
 406     (each) each-integer ; inline
 407
 408 : reduce ( seq identity quot -- result )
 409     swapd each ; inline
 410
 411 : map-as ( seq quot exemplar -- newseq )
 412     [ over length ] dip [ [ map-into ] keep ] new-like ; inline
 413
 414 : map ( seq quot -- newseq )
 415     over map-as ; inline
 416
 417 : replicate ( seq quot -- newseq )
 418     [ drop ] prepose map ; inline
 419
 420 : replicate-as ( seq quot exemplar -- newseq )
 421     [ [ drop ] prepose ] dip map-as ; inline
 422
 423 : change-each ( seq quot -- )
 424     over map-into ; inline
 425
 426 : accumulate ( seq identity quot -- final newseq )
 427     swapd [ [ call ] [ 2drop ] 3bi ] curry { } map-as ; inline
 428
 429 : 2each ( seq1 seq2 quot -- )
 430     (2each) each-integer ; inline
 431
 432 : 2reverse-each ( seq1 seq2 quot -- )
 433     [ [ <reversed> ] bi@ ] dip 2each ; inline
 434
 435 : 2reduce ( seq1 seq2 identity quot -- result )
 436     [ -rot ] dip 2each ; inline
 437
 438 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 439     [ (2each) ] dip map-as ; inline
 440
 441 : 2map ( seq1 seq2 quot -- newseq )
 442     pick 2map-as ; inline
 443
 444 : 2all? ( seq1 seq2 quot -- ? )
 445     (2each) all-integers? ; inline
 446
 447 : 3each ( seq1 seq2 seq3 quot -- )
 448     (3each) each ; inline
 449
 450 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 451     [ (3each) ] dip map-as ; inline
 452
 453 : 3map ( seq1 seq2 seq3 quot -- newseq )
 454     [ pick ] dip swap 3map-as ; inline
 455
 456 : find-from ( n seq quot -- i elt )
 457     [ (find-integer) ] (find-from) ; inline
 458
 459 : find ( seq quot -- i elt )
 460     [ find-integer ] (find) ; inline
 461
 462 : find-last-from ( n seq quot -- i elt )
 463     [ nip find-last-integer ] (find-from) ; inline
 464
 465 : find-last ( seq quot -- i elt )
 466     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 467
 468 : all? ( seq quot -- ? )
 469     (each) all-integers? ; inline
 470
 471 : push-if ( elt quot accum -- )
 472     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 473
 474 : pusher ( quot -- quot accum )
 475     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 476
 477 : filter ( seq quot -- subseq )
 478     over [ pusher [ each ] dip ] dip like ; inline
 479
 480 : push-either ( elt quot accum1 accum2 -- )
 481     [ keep swap ] 2dip ? push ; inline
 482
 483 : 2pusher ( quot -- quot accum1 accum2 )
 484     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 485
 486 : partition ( seq quot -- trueseq falseseq )
 487     over [ 2pusher [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 488
 489 : accumulator ( quot -- quot' vec )
 490     V{ } clone [ [ push ] curry compose ] keep ; inline
 491
 492 : produce-as ( pred quot exemplar -- seq )
 493     [ accumulator [ while ] dip ] dip like ; inline
 494
 495 : produce ( pred quot -- seq )
 496     { } produce-as ; inline
 497
 498 : follow ( obj quot -- seq )
 499     [ dup ] swap [ keep ] curry produce nip ; inline
 500
 501 : prepare-index ( seq quot -- seq n quot )
 502     [ dup length ] dip ; inline
 503
 504 : each-index ( seq quot -- )
 505     prepare-index 2each ; inline
 506
 507 : interleave ( seq between quot -- )
 508     swap [ drop ] [ [ 2dip call ] 2curry ] 2bi
 509     [ [ 0 = ] 2dip if ] 2curry
 510     each-index ; inline
 511
 512 : map-index ( seq quot -- newseq )
 513     prepare-index 2map ; inline
 514
 515 : reduce-index ( seq identity quot -- )
 516     swapd each-index ; inline
 517
 518 : index ( obj seq -- n )
 519     [ = ] with find drop ;
 520
 521 : index-from ( obj i seq -- n )
 522     rot [ = ] curry find-from drop ;
 523
 524 : last-index ( obj seq -- n )
 525     [ = ] with find-last drop ;
 526
 527 : last-index-from ( obj i seq -- n )
 528     rot [ = ] curry find-last-from drop ;
 529
 530 : (indices) ( elt i obj accum -- )
 531     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 532
 533 : indices ( obj seq -- indices )
 534     swap V{ } clone
 535     [ [ (indices) ] 2curry each-index ] keep ;
 536
 537 : nths ( indices seq -- seq' )
 538     [ nth ] curry map ;
 539
 540 : any? ( seq quot -- ? )
 541     find drop >boolean ; inline
 542
 543 : member? ( elt seq -- ? )
 544     [ = ] with any? ;
 545
 546 : memq? ( elt seq -- ? )
 547     [ eq? ] with any? ;
 548
 549 : remove ( elt seq -- newseq )
 550     [ = not ] with filter ;
 551
 552 : remq ( elt seq -- newseq )
 553     [ eq? not ] with filter ;
 554
 555 : sift ( seq -- newseq )
 556     [ ] filter ;
 557
 558 : harvest ( seq -- newseq )
 559     [ empty? not ] filter ;
 560
 561 : mismatch ( seq1 seq2 -- i )
 562     [ min-length iota ] 2keep
 563     [ 2nth-unsafe = not ] 2curry
 564     find drop ; inline
 565
 566 M: sequence <=>
 567     2dup mismatch
 568     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 569
 570 : sequence= ( seq1 seq2 -- ? )
 571     2dup [ length ] bi@ =
 572     [ mismatch not ] [ 2drop f ] if ; inline
 573
 574 ERROR: assert-sequence got expected ;
 575
 576 : assert-sequence= ( a b -- )
 577     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 578
 579 : sequence-hashcode-step ( oldhash newpart -- newhash )
 580     >fixnum swap [
 581         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 582         fixnum+fast fixnum+fast
 583     ] keep fixnum-bitxor ; inline
 584
 585 : sequence-hashcode ( n seq -- x )
 586     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 587
 588 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 589
 590 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 591
 592 : move ( to from seq -- )
 593     2over =
 594     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 595
 596 <PRIVATE
 597
 598 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 599     2dup length < [
 600         [ move ] 3keep
 601         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 602         [ 1 + ] dip
 603         (filter-here)
 604     ] [ nip set-length drop ] if ; inline recursive
 605
 606 PRIVATE>
 607
 608 : filter-here ( seq quot -- )
 609     swap [ 0 0 ] dip (filter-here) ; inline
 610
 611 : delete ( elt seq -- )
 612     [ = not ] with filter-here ;
 613
 614 : delq ( elt seq -- )
 615     [ eq? not ] with filter-here ;
 616
 617 : prefix ( seq elt -- newseq )
 618     over [ over length 1 + ] dip [
 619         [ 0 swap set-nth-unsafe ] keep
 620         [ 1 swap copy ] keep
 621     ] new-like ;
 622
 623 : suffix ( seq elt -- newseq )
 624     over [ over length 1 + ] dip [
 625         [ [ over length ] dip set-nth-unsafe ] keep
 626         [ 0 swap copy ] keep
 627     ] new-like ;
 628
 629 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 630
 631 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 632
 633 <PRIVATE
 634
 635 : move-backward ( shift from to seq -- )
 636     2over = [
 637         2drop 2drop
 638     ] [
 639         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 640         move-backward
 641     ] if ;
 642
 643 : move-forward ( shift from to seq -- )
 644     2over = [
 645         2drop 2drop
 646     ] [
 647         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 648         move-forward
 649     ] if ;
 650
 651 : (open-slice) ( shift from to seq ? -- )
 652     [
 653         [ [ 1 - ] bi@ ] dip move-forward
 654     ] [
 655         [ over - ] 2dip move-backward
 656     ] if ;
 657
 658 : open-slice ( shift from seq -- )
 659     pick 0 = [
 660         3drop
 661     ] [
 662         pick over length + over
 663         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 664         set-length
 665     ] if ;
 666
 667 PRIVATE>
 668
 669 : delete-slice ( from to seq -- )
 670     check-slice [ over [ - ] dip ] dip open-slice ;
 671
 672 : delete-nth ( n seq -- )
 673     [ dup 1 + ] dip delete-slice ;
 674
 675 : snip ( from to seq -- head tail )
 676     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 677
 678 : snip-slice ( from to seq -- head tail )
 679     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 680
 681 : replace-slice ( new from to seq -- seq' )
 682     snip-slice surround ;
 683
 684 : remove-nth ( n seq -- seq' )
 685     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 686
 687 : pop ( seq -- elt )
 688     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 689
 690 : exchange ( m n seq -- )
 691     [ nip bounds-check 2drop ]
 692     [ bounds-check 3drop ]
 693     [ exchange-unsafe ]
 694     3tri ;
 695
 696 : reverse-here ( seq -- )
 697     [ length 2/ ] [ length ] [ ] tri
 698     [ [ over - 1 - ] dip exchange-unsafe ] 2curry each ;
 699
 700 : reverse ( seq -- newseq )
 701     [
 702         dup [ length ] keep new-sequence
 703         [ 0 swap copy ] keep
 704         [ reverse-here ] keep
 705     ] keep like ;
 706
 707 : sum-lengths ( seq -- n )
 708     0 [ length + ] reduce ;
 709
 710 : concat-as ( seq exemplar -- newseq )
 711     swap [ { } ] [
 712         [ sum-lengths over new-resizable ] keep
 713         [ over push-all ] each
 714     ] if-empty swap like ;
 715
 716 : concat ( seq -- newseq )
 717     [ { } ] [ dup first concat-as ] if-empty ;
 718
 719 <PRIVATE
 720
 721 : joined-length ( seq glue -- n )
 722     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 723
 724 PRIVATE>
 725
 726 : join ( seq glue -- newseq )
 727     dup empty? [ concat-as ] [
 728         [
 729             2dup joined-length over new-resizable [
 730                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 731                 interleave
 732             ] keep
 733         ] keep like
 734     ] if ;
 735
 736 : padding ( seq n elt quot -- newseq )
 737     [
 738         [ over length [-] dup 0 = [ drop ] ] dip
 739         [ <repetition> ] curry
 740     ] dip compose if ; inline
 741
 742 : pad-head ( seq n elt -- padded )
 743     [ swap dup append-as ] padding ;
 744
 745 : pad-tail ( seq n elt -- padded )
 746     [ append ] padding ;
 747
 748 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 749
 750 : head? ( seq begin -- ? )
 751     2dup shorter? [
 752         2drop f
 753     ] [
 754         [ nip ] [ length head-slice ] 2bi sequence=
 755     ] if ;
 756
 757 : tail? ( seq end -- ? )
 758     2dup shorter? [
 759         2drop f
 760     ] [
 761         [ nip ] [ length tail-slice* ] 2bi sequence=
 762     ] if ;
 763
 764 : cut-slice ( seq n -- before-slice after-slice )
 765     [ head-slice ] [ tail-slice ] 2bi ;
 766
 767 : insert-nth ( elt n seq -- seq' )
 768     swap cut-slice [ swap suffix ] dip append ;
 769
 770 : midpoint@ ( seq -- n ) length 2/ ; inline
 771
 772 : halves ( seq -- first-slice second-slice )
 773     dup midpoint@ cut-slice ;
 774
 775 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 776     #! We can't use case here since combinators depends on
 777     #! sequences
 778     pick length dup 0 3 between? [
 779         >fixnum {
 780             [ drop nip ]
 781             [ 2drop first ]
 782             [ [ drop first2 ] dip call ]
 783             [ [ drop first3 ] dip bi@ ]
 784         } dispatch
 785     ] [
 786         drop
 787         [ halves ] 2dip
 788         [ [ binary-reduce ] 2curry bi@ ] keep
 789         call
 790     ] if ; inline recursive
 791
 792 : cut ( seq n -- before after )
 793     [ head ] [ tail ] 2bi ;
 794
 795 : cut* ( seq n -- before after )
 796     [ head* ] [ tail* ] 2bi ;
 797
 798 <PRIVATE
 799
 800 : (start) ( subseq seq n -- subseq seq ? )
 801     pick length [
 802         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 803     ] all? nip ; inline
 804
 805 PRIVATE>
 806
 807 : start* ( subseq seq n -- i )
 808     pick length pick length swap - 1 +
 809     [ (start) ] find-from
 810     swap [ 3drop ] dip ;
 811
 812 : start ( subseq seq -- i ) 0 start* ; inline
 813
 814 : subseq? ( subseq seq -- ? ) start >boolean ;
 815
 816 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 817     2dup mismatch [ 2dup min-length ] unless*
 818     [ tail-slice ] curry bi@ ;
 819
 820 : unclip ( seq -- rest first )
 821     [ rest ] [ first-unsafe ] bi ;
 822
 823 : unclip-last ( seq -- butlast last )
 824     [ but-last ] [ last ] bi ;
 825
 826 : unclip-slice ( seq -- rest-slice first )
 827     [ rest-slice ] [ first-unsafe ] bi ; inline
 828
 829 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 830     [ unclip-slice ] bi@ swapd ; inline
 831
 832 : map-reduce ( seq map-quot reduce-quot -- result )
 833     [ [ unclip-slice ] dip [ call ] keep ] dip
 834     compose reduce ; inline
 835
 836 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 837     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 838     compose 2reduce ; inline
 839
 840 <PRIVATE
 841
 842 : (map-find) ( seq quot find-quot -- result elt )
 843     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 844     [ [ drop f ] unless ] dip ; inline
 845
 846 PRIVATE>
 847
 848 : map-find ( seq quot -- result elt )
 849     [ find ] (map-find) ; inline
 850
 851 : map-find-last ( seq quot -- result elt )
 852     [ find-last ] (map-find) ; inline
 853
 854 : unclip-last-slice ( seq -- butlast-slice last )
 855     [ but-last-slice ] [ last ] bi ; inline
 856
 857 : <flat-slice> ( seq -- slice )
 858     dup slice? [ { } like ] when
 859     [ drop 0 ] [ length ] [ ] tri <slice> ;
 860     inline
 861
 862 <PRIVATE
 863
 864 : (trim-head) ( seq quot -- seq n )
 865     over [ [ not ] compose find drop ] dip
 866     [ length or ] keep swap ; inline
 867
 868 : (trim-tail) ( seq quot -- seq n )
 869     over [ [ not ] compose find-last drop ?1+ ] dip
 870     swap ; inline
 871
 872 PRIVATE>
 873
 874 : trim-head-slice ( seq quot -- slice )
 875     (trim-head) tail-slice ; inline
 876
 877 : trim-head ( seq quot -- newseq )
 878     (trim-head) tail ; inline
 879
 880 : trim-tail-slice ( seq quot -- slice )
 881     (trim-tail) head-slice ; inline
 882
 883 : trim-tail ( seq quot -- newseq )
 884     (trim-tail) head ; inline
 885
 886 : trim-slice ( seq quot -- slice )
 887     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 888
 889 : trim ( seq quot -- newseq )
 890     [ trim-slice ] [ drop ] 2bi like ; inline
 891
 892 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 893
 894 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 895
 896 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 897
 898 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 899
 900 : sigma ( seq quot -- n )
 901     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 902
 903 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 904
 905 ! We hand-optimize flip to such a degree because type hints
 906 ! cannot express that an array is an array of arrays yet, and
 907 ! this word happens to be performance-critical since the compiler
 908 ! itself uses it. Optimizing it like this reduced compile time.
 909 <PRIVATE
 910
 911 : generic-flip ( matrix -- newmatrix )
 912     [ dup first length [ length min ] reduce ] keep
 913     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 914
 915 USE: arrays
 916
 917 : array-length ( array -- len )
 918     { array } declare length>> ; inline
 919
 920 : array-flip ( matrix -- newmatrix )
 921     { array } declare
 922     [ dup first array-length [ array-length min ] reduce ] keep
 923     [ [ array-nth ] with { } map-as ] curry { } map-as ;
 924
 925 PRIVATE>
 926
 927 : flip ( matrix -- newmatrix )
 928     dup empty? [
 929         dup array? [
 930             dup [ array? ] all?
 931             [ array-flip ] [ generic-flip ] if
 932         ] [ generic-flip ] if
 933     ] unless ;
 934
 935 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
 936
 937 :: reduce-r
 938     ( list identity quot: ( obj1 obj2 -- obj ) -- result )
 939     list empty?
 940     [ identity ]
 941     [ list rest identity quot reduce-r list first quot call ] if ;
 942     inline recursive
 943
 944 :: combos ( list1 list2 -- result ) list2 [ [ 2array ] curry list1 swap map ] map concat ;