core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 <PRIVATE
  33
  34 : (if-empty) ( seq quot1 quot2 quot3 -- )
  35     [ [ drop ] prepose ] [ ] tri* if ; inline
  36
  37 PRIVATE>
  38
  39 : if-empty ( seq quot1 quot2 -- )
  40     [ dup empty? ] (if-empty) ; inline
  41
  42 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  43
  44 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  45
  46 : if-zero ( n quot1 quot2 -- )
  47     [ dup zero? ] (if-empty) ; inline
  48
  49 : when-zero ( seq quot -- ) [ ] if-zero ; inline
  50
  51 : unless-zero ( seq quot -- ) [ ] swap if-zero ; inline
  52
  53 : delete-all ( seq -- ) 0 swap set-length ;
  54
  55 : first ( seq -- first ) 0 swap nth ; inline
  56 : second ( seq -- second ) 1 swap nth ; inline
  57 : third ( seq -- third ) 2 swap nth ; inline
  58 : fourth ( seq -- fourth ) 3 swap nth ; inline
  59
  60 : set-first ( first seq -- ) 0 swap set-nth ; inline
  61 : set-second ( second seq -- ) 1 swap set-nth ; inline
  62 : set-third ( third seq -- ) 2 swap set-nth ; inline
  63 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  64
  65 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  66
  67 : bounds-check? ( n seq -- ? )
  68     dupd length < [ 0 >= ] [ drop f ] if ; inline
  69
  70 ERROR: bounds-error index seq ;
  71
  72 : bounds-check ( n seq -- n seq )
  73     2dup bounds-check? [ bounds-error ] unless ; inline
  74
  75 MIXIN: immutable-sequence
  76
  77 ERROR: immutable seq ;
  78
  79 M: immutable-sequence set-nth immutable ;
  80
  81 INSTANCE: immutable-sequence sequence
  82
  83 <PRIVATE
  84
  85 : array-nth ( n array -- elt )
  86     swap 2 fixnum+fast slot ; inline
  87
  88 : set-array-nth ( elt n array -- )
  89     swap 2 fixnum+fast set-slot ; inline
  90
  91 : dispatch ( n array -- ) array-nth call ;
  92
  93 GENERIC: resize ( n seq -- newseq ) flushable
  94
  95 ! Unsafe sequence protocol for inner loops
  96 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  97 GENERIC: set-nth-unsafe ( elt n seq -- )
  98
  99 M: sequence nth bounds-check nth-unsafe ;
 100 M: sequence set-nth bounds-check set-nth-unsafe ;
 101
 102 M: sequence nth-unsafe nth ;
 103 M: sequence set-nth-unsafe set-nth ;
 104
 105 : change-nth-unsafe ( i seq quot -- )
 106     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
 107
 108 ! The f object supports the sequence protocol trivially
 109 M: f length drop 0 ;
 110 M: f nth-unsafe nip ;
 111 M: f like drop [ f ] when-empty ;
 112
 113 INSTANCE: f immutable-sequence
 114
 115 ! Integers support the sequence protocol
 116 M: integer length ;
 117 M: integer nth-unsafe drop ;
 118
 119 INSTANCE: integer immutable-sequence
 120
 121 PRIVATE>
 122
 123 ! In the future, this will replace integer sequences
 124 TUPLE: iota { n integer read-only } ;
 125
 126 : iota ( n -- iota ) \ iota boa ; inline
 127
 128 <PRIVATE
 129
 130 M: iota length n>> ;
 131 M: iota nth-unsafe drop ;
 132
 133 INSTANCE: iota immutable-sequence
 134
 135 : first-unsafe ( seq -- first )
 136     0 swap nth-unsafe ; inline
 137
 138 : first2-unsafe ( seq -- first second )
 139     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 140
 141 : first3-unsafe ( seq -- first second third )
 142     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 143
 144 : first4-unsafe ( seq -- first second third fourth )
 145     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 146
 147 : exchange-unsafe ( m n seq -- )
 148     [ [ nth-unsafe ] curry bi@ ]
 149     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 150
 151 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 152
 153 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 154
 155 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 156
 157 : (1sequence) ( obj seq -- seq )
 158     [ 0 swap set-nth-unsafe ] keep ; inline
 159
 160 : (2sequence) ( obj1 obj2 seq -- seq )
 161     [ 1 swap set-nth-unsafe ] keep
 162     (1sequence) ; inline
 163
 164 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 165     [ 2 swap set-nth-unsafe ] keep
 166     (2sequence) ; inline
 167
 168 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 169     [ 3 swap set-nth-unsafe ] keep
 170     (3sequence) ; inline
 171
 172 PRIVATE>
 173
 174 : 1sequence ( obj exemplar -- seq )
 175     1 swap [ (1sequence) ] new-like ; inline
 176
 177 : 2sequence ( obj1 obj2 exemplar -- seq )
 178     2 swap [ (2sequence) ] new-like ; inline
 179
 180 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 181     3 swap [ (3sequence) ] new-like ; inline
 182
 183 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 184     4 swap [ (4sequence) ] new-like ; inline
 185
 186 : first2 ( seq -- first second )
 187     1 swap bounds-check nip first2-unsafe ; flushable
 188
 189 : first3 ( seq -- first second third )
 190     2 swap bounds-check nip first3-unsafe ; flushable
 191
 192 : first4 ( seq -- first second third fourth )
 193     3 swap bounds-check nip first4-unsafe ; flushable
 194
 195 : ?nth ( n seq -- elt/f )
 196     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 197
 198 MIXIN: virtual-sequence
 199 GENERIC: virtual-seq ( seq -- seq' )
 200 GENERIC: virtual@ ( n seq -- n' seq' )
 201
 202 M: virtual-sequence nth virtual@ nth ;
 203 M: virtual-sequence set-nth virtual@ set-nth ;
 204 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 205 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 206 M: virtual-sequence like virtual-seq like ;
 207 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 208
 209 INSTANCE: virtual-sequence sequence
 210
 211 ! A reversal of an underlying sequence.
 212 TUPLE: reversed { seq read-only } ;
 213
 214 C: <reversed> reversed
 215
 216 M: reversed virtual-seq seq>> ;
 217
 218 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ;
 219
 220 M: reversed length seq>> length ;
 221
 222 INSTANCE: reversed virtual-sequence
 223
 224 ! A slice of another sequence.
 225 TUPLE: slice
 226 { from read-only }
 227 { to read-only }
 228 { seq read-only } ;
 229
 230 : collapse-slice ( m n slice -- m' n' seq )
 231     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 232
 233 TUPLE: slice-error from to seq reason ;
 234
 235 : slice-error ( from to seq ? string -- from to seq )
 236     [ \ slice-error boa throw ] curry when ; inline
 237
 238 : check-slice ( from to seq -- from to seq )
 239     3dup
 240     [ 2drop 0 < "start < 0" slice-error ]
 241     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 242     [ drop > "start > end" slice-error ]
 243     3tri ; inline
 244
 245 : <slice> ( from to seq -- slice )
 246     dup slice? [ collapse-slice ] when
 247     check-slice
 248     slice boa ; inline
 249
 250 M: slice virtual-seq seq>> ;
 251
 252 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 253
 254 M: slice length [ to>> ] [ from>> ] bi - ;
 255
 256 : short ( seq n -- seq n' ) over length min ; inline
 257
 258 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 259
 260 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 261
 262 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 263
 264 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 265
 266 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 267
 268 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 269
 270 INSTANCE: slice virtual-sequence
 271
 272 ! One element repeated many times
 273 TUPLE: repetition { len read-only } { elt read-only } ;
 274
 275 C: <repetition> repetition
 276
 277 M: repetition length len>> ;
 278 M: repetition nth-unsafe nip elt>> ;
 279
 280 INSTANCE: repetition immutable-sequence
 281
 282 <PRIVATE
 283
 284 : check-length ( n -- n )
 285     #! Ricing.
 286     dup integer? [ "length not an integer" throw ] unless ; inline
 287
 288 : ((copy)) ( dst i src j n -- dst i src j n )
 289     dup -roll [
 290         + swap nth-unsafe -roll [
 291             + swap set-nth-unsafe
 292         ] 3keep drop
 293     ] 3keep ; inline
 294
 295 : (copy) ( dst i src j n -- dst )
 296     dup 0 <= [ 2drop 2drop ] [ 1 - ((copy)) (copy) ] if ;
 297     inline recursive
 298
 299 : prepare-subseq ( from to seq -- dst i src j n )
 300     #! The check-length call forces partial dispatch
 301     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 302     -rot drop roll length check-length ; inline
 303
 304 : check-copy ( src n dst -- )
 305     over 0 < [ bounds-error ] when
 306     [ swap length + ] dip lengthen ; inline
 307
 308 PRIVATE>
 309
 310 : subseq ( from to seq -- subseq )
 311     [ check-slice prepare-subseq (copy) ] keep like ;
 312
 313 : head ( seq n -- headseq ) (head) subseq ;
 314
 315 : tail ( seq n -- tailseq ) (tail) subseq ;
 316
 317 : rest ( seq -- tailseq ) 1 tail ;
 318
 319 : head* ( seq n -- headseq ) from-end head ;
 320
 321 : tail* ( seq n -- tailseq ) from-end tail ;
 322
 323 : but-last ( seq -- headseq ) 1 head* ;
 324
 325 : copy ( src i dst -- )
 326     #! The check-length call forces partial dispatch
 327     pick length check-length [ 3dup check-copy spin 0 ] dip
 328     (copy) drop ; inline
 329
 330 M: sequence clone-like
 331     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 332
 333 M: immutable-sequence clone-like like ;
 334
 335 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 336
 337 <PRIVATE
 338
 339 : (append) ( seq1 seq2 accum -- accum )
 340     [ [ over length ] dip copy ]
 341     [ 0 swap copy ]
 342     [ ] tri ; inline
 343
 344 PRIVATE>
 345
 346 : append-as ( seq1 seq2 exemplar -- newseq )
 347     [ over length over length + ] dip
 348     [ (append) ] new-like ; inline
 349
 350 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 351     [ 3dup [ length ] tri@ + + ] dip [
 352         [ [ 2over [ length ] bi@ + ] dip copy ]
 353         [ (append) ] bi
 354     ] new-like ; inline
 355
 356 : append ( seq1 seq2 -- newseq ) over append-as ;
 357
 358 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 359
 360 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 361
 362 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 363
 364 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 365
 366 : change-nth ( i seq quot -- )
 367     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 368
 369 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 370
 371 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 372
 373 <PRIVATE
 374
 375 : ((each)) ( seq -- n quot )
 376     [ length ] keep [ nth-unsafe ] curry ; inline
 377
 378 : (each) ( seq quot -- n quot' )
 379     [ ((each)) ] dip compose ; inline
 380
 381 : (each-index) ( seq quot -- n quot' )
 382     [ ((each)) [ keep ] curry ] dip compose ; inline
 383
 384 : (collect) ( quot into -- quot' )
 385     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 386
 387 : collect ( n quot into -- )
 388     (collect) each-integer ; inline
 389
 390 : map-into ( seq quot into -- )
 391     [ (each) ] dip collect ; inline
 392
 393 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 394     [ nth-unsafe ] bi-curry@ bi ; inline
 395
 396 : (2each) ( seq1 seq2 quot -- n quot' )
 397     [
 398         [ min-length ] 2keep
 399         [ 2nth-unsafe ] 2curry
 400     ] dip compose ; inline
 401
 402 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 403     [ nth-unsafe ] tri-curry@ tri ; inline
 404
 405 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 406     [
 407         [ [ length ] tri@ min min ]
 408         [ [ 3nth-unsafe ] 3curry ] 3bi
 409     ] dip compose ; inline
 410
 411 : finish-find ( i seq -- i elt )
 412     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 413
 414 : (find) ( seq quot quot' -- i elt )
 415     pick [ [ (each) ] dip call ] dip finish-find ; inline
 416
 417 : (find-from) ( n seq quot quot' -- i elt )
 418     [ 2dup bounds-check? ] 2dip
 419     [ (find) ] 2curry
 420     [ 2drop f f ]
 421     if ; inline
 422
 423 PRIVATE>
 424
 425 : each ( seq quot -- )
 426     (each) each-integer ; inline
 427
 428 : reduce ( seq identity quot -- result )
 429     swapd each ; inline
 430
 431 : map-integers ( len quot exemplar -- newseq )
 432     [ over ] dip [ [ collect ] keep ] new-like ; inline
 433
 434 : map-as ( seq quot exemplar -- newseq )
 435     [ (each) ] dip map-integers ; inline
 436
 437 : map ( seq quot -- newseq )
 438     over map-as ; inline
 439
 440 : replicate ( seq quot -- newseq )
 441     [ drop ] prepose map ; inline
 442
 443 : replicate-as ( seq quot exemplar -- newseq )
 444     [ [ drop ] prepose ] dip map-as ; inline
 445
 446 : change-each ( seq quot -- )
 447     over map-into ; inline
 448
 449 : accumulate ( seq identity quot -- final newseq )
 450     swapd [ [ call ] [ 2drop ] 3bi ] curry { } map-as ; inline
 451
 452 : 2each ( seq1 seq2 quot -- )
 453     (2each) each-integer ; inline
 454
 455 : 2reverse-each ( seq1 seq2 quot -- )
 456     [ [ <reversed> ] bi@ ] dip 2each ; inline
 457
 458 : 2reduce ( seq1 seq2 identity quot -- result )
 459     [ -rot ] dip 2each ; inline
 460
 461 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 462     [ (2each) ] dip map-integers ; inline
 463
 464 : 2map ( seq1 seq2 quot -- newseq )
 465     pick 2map-as ; inline
 466
 467 : 2all? ( seq1 seq2 quot -- ? )
 468     (2each) all-integers? ; inline
 469
 470 : 3each ( seq1 seq2 seq3 quot -- )
 471     (3each) each ; inline
 472
 473 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 474     [ (3each) ] dip map-integers ; inline
 475
 476 : 3map ( seq1 seq2 seq3 quot -- newseq )
 477     [ pick ] dip swap 3map-as ; inline
 478
 479 : find-from ( n seq quot -- i elt )
 480     [ (find-integer) ] (find-from) ; inline
 481
 482 : find ( seq quot -- i elt )
 483     [ find-integer ] (find) ; inline
 484
 485 : find-last-from ( n seq quot -- i elt )
 486     [ nip find-last-integer ] (find-from) ; inline
 487
 488 : find-last ( seq quot -- i elt )
 489     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 490
 491 : all? ( seq quot -- ? )
 492     (each) all-integers? ; inline
 493
 494 : push-if ( elt quot accum -- )
 495     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 496
 497 : pusher ( quot -- quot accum )
 498     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 499
 500 : filter ( seq quot -- subseq )
 501     over [ pusher [ each ] dip ] dip like ; inline
 502
 503 : push-either ( elt quot accum1 accum2 -- )
 504     [ keep swap ] 2dip ? push ; inline
 505
 506 : 2pusher ( quot -- quot accum1 accum2 )
 507     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 508
 509 : partition ( seq quot -- trueseq falseseq )
 510     over [ 2pusher [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 511
 512 : accumulator ( quot -- quot' vec )
 513     V{ } clone [ [ push ] curry compose ] keep ; inline
 514
 515 : produce-as ( pred quot exemplar -- seq )
 516     [ accumulator [ while ] dip ] dip like ; inline
 517
 518 : produce ( pred quot -- seq )
 519     { } produce-as ; inline
 520
 521 : follow ( obj quot -- seq )
 522     [ dup ] swap [ keep ] curry produce nip ; inline
 523
 524 : each-index ( seq quot -- )
 525     (each-index) each-integer ; inline
 526
 527 : interleave ( seq between quot -- )
 528     pick empty? [ 3drop ] [
 529         [ [ drop first-unsafe ] dip call ]
 530         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 531         3bi
 532     ] if ; inline
 533
 534 : map-index ( seq quot -- newseq )
 535     [ dup length iota ] dip 2map ; inline
 536
 537 : reduce-index ( seq identity quot -- )
 538     swapd each-index ; inline
 539
 540 : index ( obj seq -- n )
 541     [ = ] with find drop ;
 542
 543 : index-from ( obj i seq -- n )
 544     rot [ = ] curry find-from drop ;
 545
 546 : last-index ( obj seq -- n )
 547     [ = ] with find-last drop ;
 548
 549 : last-index-from ( obj i seq -- n )
 550     rot [ = ] curry find-last-from drop ;
 551
 552 : (indices) ( elt i obj accum -- )
 553     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 554
 555 : indices ( obj seq -- indices )
 556     swap V{ } clone
 557     [ [ (indices) ] 2curry each-index ] keep ;
 558
 559 : nths ( indices seq -- seq' )
 560     [ nth ] curry map ;
 561
 562 : any? ( seq quot -- ? )
 563     find drop >boolean ; inline
 564
 565 : member? ( elt seq -- ? )
 566     [ = ] with any? ;
 567
 568 : memq? ( elt seq -- ? )
 569     [ eq? ] with any? ;
 570
 571 : remove ( elt seq -- newseq )
 572     [ = not ] with filter ;
 573
 574 : remq ( elt seq -- newseq )
 575     [ eq? not ] with filter ;
 576
 577 : sift ( seq -- newseq )
 578     [ ] filter ;
 579
 580 : harvest ( seq -- newseq )
 581     [ empty? not ] filter ;
 582
 583 : mismatch ( seq1 seq2 -- i )
 584     [ min-length iota ] 2keep
 585     [ 2nth-unsafe = not ] 2curry
 586     find drop ; inline
 587
 588 M: sequence <=>
 589     2dup mismatch
 590     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 591
 592 : sequence= ( seq1 seq2 -- ? )
 593     2dup [ length ] bi@ =
 594     [ mismatch not ] [ 2drop f ] if ; inline
 595
 596 ERROR: assert-sequence got expected ;
 597
 598 : assert-sequence= ( a b -- )
 599     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 600
 601 : sequence-hashcode-step ( oldhash newpart -- newhash )
 602     >fixnum swap [
 603         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 604         fixnum+fast fixnum+fast
 605     ] keep fixnum-bitxor ; inline
 606
 607 : sequence-hashcode ( n seq -- x )
 608     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 609
 610 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 611
 612 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 613
 614 : move ( to from seq -- )
 615     2over =
 616     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 617
 618 <PRIVATE
 619
 620 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 621     2dup length < [
 622         [ move ] 3keep
 623         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 624         [ 1 + ] dip
 625         (filter-here)
 626     ] [ nip set-length drop ] if ; inline recursive
 627
 628 PRIVATE>
 629
 630 : filter-here ( seq quot -- )
 631     swap [ 0 0 ] dip (filter-here) ; inline
 632
 633 : delete ( elt seq -- )
 634     [ = not ] with filter-here ;
 635
 636 : delq ( elt seq -- )
 637     [ eq? not ] with filter-here ;
 638
 639 : prefix ( seq elt -- newseq )
 640     over [ over length 1 + ] dip [
 641         [ 0 swap set-nth-unsafe ] keep
 642         [ 1 swap copy ] keep
 643     ] new-like ;
 644
 645 : suffix ( seq elt -- newseq )
 646     over [ over length 1 + ] dip [
 647         [ [ over length ] dip set-nth-unsafe ] keep
 648         [ 0 swap copy ] keep
 649     ] new-like ;
 650
 651 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 652
 653 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 654
 655 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 656
 657 <PRIVATE
 658
 659 : move-backward ( shift from to seq -- )
 660     2over = [
 661         2drop 2drop
 662     ] [
 663         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 664         move-backward
 665     ] if ;
 666
 667 : move-forward ( shift from to seq -- )
 668     2over = [
 669         2drop 2drop
 670     ] [
 671         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 672         move-forward
 673     ] if ;
 674
 675 : (open-slice) ( shift from to seq ? -- )
 676     [
 677         [ [ 1 - ] bi@ ] dip move-forward
 678     ] [
 679         [ over - ] 2dip move-backward
 680     ] if ;
 681
 682 : open-slice ( shift from seq -- )
 683     pick 0 = [
 684         3drop
 685     ] [
 686         pick over length + over
 687         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 688         set-length
 689     ] if ;
 690
 691 PRIVATE>
 692
 693 : delete-slice ( from to seq -- )
 694     check-slice [ over [ - ] dip ] dip open-slice ;
 695
 696 : delete-nth ( n seq -- )
 697     [ dup 1 + ] dip delete-slice ;
 698
 699 : snip ( from to seq -- head tail )
 700     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 701
 702 : snip-slice ( from to seq -- head tail )
 703     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 704
 705 : replace-slice ( new from to seq -- seq' )
 706     snip-slice surround ;
 707
 708 : remove-nth ( n seq -- seq' )
 709     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 710
 711 : pop ( seq -- elt )
 712     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 713
 714 : exchange ( m n seq -- )
 715     [ nip bounds-check 2drop ]
 716     [ bounds-check 3drop ]
 717     [ exchange-unsafe ]
 718     3tri ;
 719
 720 : reverse-here ( seq -- )
 721     [ length 2/ iota ] [ length ] [ ] tri
 722     [ [ over - 1 - ] dip exchange-unsafe ] 2curry each ;
 723
 724 : reverse ( seq -- newseq )
 725     [
 726         dup [ length ] keep new-sequence
 727         [ 0 swap copy ] keep
 728         [ reverse-here ] keep
 729     ] keep like ;
 730
 731 : sum-lengths ( seq -- n )
 732     0 [ length + ] reduce ;
 733
 734 : concat-as ( seq exemplar -- newseq )
 735     swap [ { } ] [
 736         [ sum-lengths over new-resizable ] keep
 737         [ over push-all ] each
 738     ] if-empty swap like ;
 739
 740 : concat ( seq -- newseq )
 741     [ { } ] [ dup first concat-as ] if-empty ;
 742
 743 <PRIVATE
 744
 745 : joined-length ( seq glue -- n )
 746     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 747
 748 PRIVATE>
 749
 750 : join ( seq glue -- newseq )
 751     dup empty? [ concat-as ] [
 752         [
 753             2dup joined-length over new-resizable [
 754                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 755                 interleave
 756             ] keep
 757         ] keep like
 758     ] if ;
 759
 760 : padding ( seq n elt quot -- newseq )
 761     [
 762         [ over length [-] dup 0 = [ drop ] ] dip
 763         [ <repetition> ] curry
 764     ] dip compose if ; inline
 765
 766 : pad-head ( seq n elt -- padded )
 767     [ swap dup append-as ] padding ;
 768
 769 : pad-tail ( seq n elt -- padded )
 770     [ append ] padding ;
 771
 772 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 773
 774 : head? ( seq begin -- ? )
 775     2dup shorter? [
 776         2drop f
 777     ] [
 778         [ nip ] [ length head-slice ] 2bi sequence=
 779     ] if ;
 780
 781 : tail? ( seq end -- ? )
 782     2dup shorter? [
 783         2drop f
 784     ] [
 785         [ nip ] [ length tail-slice* ] 2bi sequence=
 786     ] if ;
 787
 788 : cut-slice ( seq n -- before-slice after-slice )
 789     [ head-slice ] [ tail-slice ] 2bi ;
 790
 791 : insert-nth ( elt n seq -- seq' )
 792     swap cut-slice [ swap suffix ] dip append ;
 793
 794 : midpoint@ ( seq -- n ) length 2/ ; inline
 795
 796 : halves ( seq -- first-slice second-slice )
 797     dup midpoint@ cut-slice ;
 798
 799 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 800     #! We can't use case here since combinators depends on
 801     #! sequences
 802     pick length dup 0 3 between? [
 803         >fixnum {
 804             [ drop nip ]
 805             [ 2drop first ]
 806             [ [ drop first2 ] dip call ]
 807             [ [ drop first3 ] dip bi@ ]
 808         } dispatch
 809     ] [
 810         drop
 811         [ halves ] 2dip
 812         [ [ binary-reduce ] 2curry bi@ ] keep
 813         call
 814     ] if ; inline recursive
 815
 816 : cut ( seq n -- before after )
 817     [ head ] [ tail ] 2bi ;
 818
 819 : cut* ( seq n -- before after )
 820     [ head* ] [ tail* ] 2bi ;
 821
 822 <PRIVATE
 823
 824 : (start) ( subseq seq n -- subseq seq ? )
 825     pick length iota [
 826         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 827     ] all? nip ; inline
 828
 829 PRIVATE>
 830
 831 : start* ( subseq seq n -- i )
 832     pick length pick length swap - 1 + iota
 833     [ (start) ] find-from
 834     swap [ 3drop ] dip ;
 835
 836 : start ( subseq seq -- i ) 0 start* ; inline
 837
 838 : subseq? ( subseq seq -- ? ) start >boolean ;
 839
 840 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 841     2dup mismatch [ 2dup min-length ] unless*
 842     [ tail-slice ] curry bi@ ;
 843
 844 : unclip ( seq -- rest first )
 845     [ rest ] [ first-unsafe ] bi ;
 846
 847 : unclip-last ( seq -- butlast last )
 848     [ but-last ] [ last ] bi ;
 849
 850 : unclip-slice ( seq -- rest-slice first )
 851     [ rest-slice ] [ first-unsafe ] bi ; inline
 852
 853 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 854     [ unclip-slice ] bi@ swapd ; inline
 855
 856 : map-reduce ( seq map-quot reduce-quot -- result )
 857     [ [ unclip-slice ] dip [ call ] keep ] dip
 858     compose reduce ; inline
 859
 860 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 861     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 862     compose 2reduce ; inline
 863
 864 <PRIVATE
 865
 866 : (map-find) ( seq quot find-quot -- result elt )
 867     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 868     [ [ drop f ] unless ] dip ; inline
 869
 870 PRIVATE>
 871
 872 : map-find ( seq quot -- result elt )
 873     [ find ] (map-find) ; inline
 874
 875 : map-find-last ( seq quot -- result elt )
 876     [ find-last ] (map-find) ; inline
 877
 878 : unclip-last-slice ( seq -- butlast-slice last )
 879     [ but-last-slice ] [ last ] bi ; inline
 880
 881 : <flat-slice> ( seq -- slice )
 882     dup slice? [ { } like ] when
 883     [ drop 0 ] [ length ] [ ] tri <slice> ;
 884     inline
 885
 886 <PRIVATE
 887
 888 : (trim-head) ( seq quot -- seq n )
 889     over [ [ not ] compose find drop ] dip
 890     [ length or ] keep swap ; inline
 891
 892 : (trim-tail) ( seq quot -- seq n )
 893     over [ [ not ] compose find-last drop ?1+ ] dip
 894     swap ; inline
 895
 896 PRIVATE>
 897
 898 : trim-head-slice ( seq quot -- slice )
 899     (trim-head) tail-slice ; inline
 900
 901 : trim-head ( seq quot -- newseq )
 902     (trim-head) tail ; inline
 903
 904 : trim-tail-slice ( seq quot -- slice )
 905     (trim-tail) head-slice ; inline
 906
 907 : trim-tail ( seq quot -- newseq )
 908     (trim-tail) head ; inline
 909
 910 : trim-slice ( seq quot -- slice )
 911     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 912
 913 : trim ( seq quot -- newseq )
 914     [ trim-slice ] [ drop ] 2bi like ; inline
 915
 916 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 917
 918 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 919
 920 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 921
 922 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 923
 924 : sigma ( seq quot -- n )
 925     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 926
 927 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 928
 929 ! We hand-optimize flip to such a degree because type hints
 930 ! cannot express that an array is an array of arrays yet, and
 931 ! this word happens to be performance-critical since the compiler
 932 ! itself uses it. Optimizing it like this reduced compile time.
 933 <PRIVATE
 934
 935 : generic-flip ( matrix -- newmatrix )
 936     [ dup first length [ length min ] reduce ] keep
 937     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 938
 939 USE: arrays
 940
 941 : array-length ( array -- len )
 942     { array } declare length>> ; inline
 943
 944 : array-flip ( matrix -- newmatrix )
 945     { array } declare
 946     [ dup first array-length [ array-length min ] reduce ] keep
 947     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 948
 949 PRIVATE>
 950
 951 : flip ( matrix -- newmatrix )
 952     dup empty? [
 953         dup array? [
 954             dup [ array? ] all?
 955             [ array-flip ] [ generic-flip ] if
 956         ] [ generic-flip ] if
 957     ] unless ;