core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop [ f ] when-empty ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 : first-unsafe ( seq -- first )
 105     0 swap nth-unsafe ; inline
 106
 107 : first2-unsafe ( seq -- first second )
 108     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 109
 110 : first3-unsafe ( seq -- first second third )
 111     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 112
 113 : first4-unsafe ( seq -- first second third fourth )
 114     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 115
 116 : exchange-unsafe ( m n seq -- )
 117     [ tuck [ nth-unsafe ] 2bi@ ]
 118     [ tuck [ set-nth-unsafe ] 2bi@ ] 3bi ; inline
 119
 120 : (head) ( seq n -- from to seq ) 0 spin ; inline
 121
 122 : (tail) ( seq n -- from to seq ) over length rot ; inline
 123
 124 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 125
 126 : (2sequence) ( obj1 obj2 seq -- seq )
 127     tuck 1 swap set-nth-unsafe
 128     tuck 0 swap set-nth-unsafe ; inline
 129
 130 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 131     tuck 2 swap set-nth-unsafe
 132     (2sequence) ; inline
 133
 134 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 135     tuck 3 swap set-nth-unsafe
 136     (3sequence) ; inline
 137
 138 PRIVATE>
 139
 140 : 2sequence ( obj1 obj2 exemplar -- seq )
 141     2 swap [ (2sequence) ] new-like ; inline
 142
 143 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 144     3 swap [ (3sequence) ] new-like ; inline
 145
 146 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 147     4 swap [ (4sequence) ] new-like ; inline
 148
 149 : first2 ( seq -- first second )
 150     1 swap bounds-check nip first2-unsafe ; flushable
 151
 152 : first3 ( seq -- first second third )
 153     2 swap bounds-check nip first3-unsafe ; flushable
 154
 155 : first4 ( seq -- first second third fourth )
 156     3 swap bounds-check nip first4-unsafe ; flushable
 157
 158 : ?nth ( n seq -- elt/f )
 159     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 160
 161 MIXIN: virtual-sequence
 162 GENERIC: virtual-seq ( seq -- seq' )
 163 GENERIC: virtual@ ( n seq -- n' seq' )
 164
 165 M: virtual-sequence nth virtual@ nth ;
 166 M: virtual-sequence set-nth virtual@ set-nth ;
 167 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 168 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 169 M: virtual-sequence like virtual-seq like ;
 170 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 171
 172 INSTANCE: virtual-sequence sequence
 173
 174 ! A reversal of an underlying sequence.
 175 TUPLE: reversed { seq read-only } ;
 176
 177 C: <reversed> reversed
 178
 179 M: reversed virtual-seq seq>> ;
 180
 181 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 182
 183 M: reversed length seq>> length ;
 184
 185 INSTANCE: reversed virtual-sequence
 186
 187 ! A slice of another sequence.
 188 TUPLE: slice
 189 { from read-only }
 190 { to read-only }
 191 { seq read-only } ;
 192
 193 : collapse-slice ( m n slice -- m' n' seq )
 194     [ from>> ] [ seq>> ] bi [ tuck [ + ] 2bi@ ] dip ; inline
 195
 196 ERROR: slice-error from to seq reason ;
 197
 198 : check-slice ( from to seq -- from to seq )
 199     pick 0 < [ "start < 0" slice-error ] when
 200     dup length pick < [ "end > sequence" slice-error ] when
 201     2over > [ "start > end" slice-error ] when ; inline
 202
 203 : <slice> ( from to seq -- slice )
 204     dup slice? [ collapse-slice ] when
 205     check-slice
 206     slice boa ; inline
 207
 208 M: slice virtual-seq seq>> ;
 209
 210 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 211
 212 M: slice length [ to>> ] [ from>> ] bi - ;
 213
 214 : short ( seq n -- seq n' ) over length min ; inline
 215
 216 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 217
 218 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 219
 220 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 221
 222 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 223
 224 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 225
 226 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 227
 228 INSTANCE: slice virtual-sequence
 229
 230 ! One element repeated many times
 231 TUPLE: repetition { len read-only } { elt read-only } ;
 232
 233 C: <repetition> repetition
 234
 235 M: repetition length len>> ;
 236 M: repetition nth-unsafe nip elt>> ;
 237
 238 INSTANCE: repetition immutable-sequence
 239
 240 <PRIVATE
 241
 242 : check-length ( n -- n )
 243     #! Ricing.
 244     dup integer? [ "length not an integer" throw ] unless ; inline
 245
 246 : ((copy)) ( dst i src j n -- dst i src j n )
 247     dup -roll [
 248         + swap nth-unsafe -roll [
 249             + swap set-nth-unsafe
 250         ] 3keep drop
 251     ] 3keep ; inline
 252
 253 : (copy) ( dst i src j n -- dst )
 254     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 255     inline recursive
 256
 257 : prepare-subseq ( from to seq -- dst i src j n )
 258     #! The check-length call forces partial dispatch
 259     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 260     -rot drop roll length check-length ; inline
 261
 262 : check-copy ( src n dst -- )
 263     over 0 < [ bounds-error ] when
 264     [ swap length + ] dip lengthen ; inline
 265
 266 PRIVATE>
 267
 268 : subseq ( from to seq -- subseq )
 269     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 270
 271 : head ( seq n -- headseq ) (head) subseq ;
 272
 273 : tail ( seq n -- tailseq ) (tail) subseq ;
 274
 275 : rest ( seq -- tailseq ) 1 tail ;
 276
 277 : head* ( seq n -- headseq ) from-end head ;
 278
 279 : tail* ( seq n -- tailseq ) from-end tail ;
 280
 281 : but-last ( seq -- headseq ) 1 head* ;
 282
 283 : copy ( src i dst -- )
 284     #! The check-length call forces partial dispatch
 285     pick length check-length [ 3dup check-copy spin 0 ] dip
 286     (copy) drop ; inline
 287
 288 M: sequence clone-like
 289     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 290
 291 M: immutable-sequence clone-like like ;
 292
 293 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 294
 295 <PRIVATE
 296
 297 : (append) ( seq1 seq2 accum -- accum )
 298     [ [ over length ] dip copy ]
 299     [ 0 swap copy ]
 300     [ ] tri ; inline
 301
 302 PRIVATE>
 303
 304 : append-as ( seq1 seq2 exemplar -- newseq )
 305     [ over length over length + ] dip
 306     [ (append) ] new-like ; inline
 307
 308 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 309     [ pick length pick length pick length + + ] dip [
 310         [ [ pick length pick length + ] dip copy ]
 311         [ (append) ] bi
 312     ] new-like ; inline
 313
 314 : append ( seq1 seq2 -- newseq ) over append-as ;
 315
 316 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 317
 318 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 319
 320 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 321
 322 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 323
 324 : change-nth ( i seq quot -- )
 325     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 326
 327 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 328
 329 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 330
 331 <PRIVATE
 332
 333 : (each) ( seq quot -- n quot' )
 334     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 335
 336 : (collect) ( quot into -- quot' )
 337     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 338
 339 : collect ( n quot into -- )
 340     (collect) each-integer ; inline
 341
 342 : map-into ( seq quot into -- )
 343     [ (each) ] dip collect ; inline
 344
 345 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 346     [ over ] dip [ nth-unsafe ] 2bi@ ; inline
 347
 348 : (2each) ( seq1 seq2 quot -- n quot' )
 349     [ [ min-length ] 2keep ] dip
 350     [ [ 2nth-unsafe ] dip call ] 3curry ; inline
 351
 352 : 2map-into ( seq1 seq2 quot into -- newseq )
 353     [ (2each) ] dip collect ; inline
 354
 355 : finish-find ( i seq -- i elt )
 356     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 357
 358 : (find) ( seq quot quot' -- i elt )
 359     pick [ [ (each) ] dip call ] dip finish-find ; inline
 360
 361 : (find-from) ( n seq quot quot' -- i elt )
 362     [ 2dup bounds-check? ] 2dip
 363     [ (find) ] 2curry
 364     [ 2drop f f ]
 365     if ; inline
 366
 367 : (monotonic) ( seq quot -- ? )
 368     [ 2dup nth-unsafe rot 1+ rot nth-unsafe ]
 369     prepose curry ; inline
 370
 371 : (interleave) ( n elt between quot -- )
 372     roll 0 = [ nip ] [ swapd 2slip ] if call ; inline
 373
 374 PRIVATE>
 375
 376 : each ( seq quot -- )
 377     (each) each-integer ; inline
 378
 379 : reduce ( seq identity quot -- result )
 380     swapd each ; inline
 381
 382 : map-as ( seq quot exemplar -- newseq )
 383     [ over length ] dip [ [ map-into ] keep ] new-like ; inline
 384
 385 : map ( seq quot -- newseq )
 386     over map-as ; inline
 387
 388 : replicate ( seq quot -- newseq )
 389     [ drop ] prepose map ; inline
 390
 391 : replicate-as ( seq quot exemplar -- newseq )
 392     [ [ drop ] prepose ] dip map-as ; inline
 393
 394 : change-each ( seq quot -- )
 395     over map-into ; inline
 396
 397 : accumulate ( seq identity quot -- final newseq )
 398     swapd [ pick slip ] curry map ; inline
 399
 400 : 2each ( seq1 seq2 quot -- )
 401     (2each) each-integer ; inline
 402
 403 : 2reverse-each ( seq1 seq2 quot -- )
 404     [ [ <reversed> ] bi@ ] dip 2each ; inline
 405
 406 : 2reduce ( seq1 seq2 identity quot -- result )
 407     [ -rot ] dip 2each ; inline
 408
 409 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 410     [ 2over min-length ] dip
 411     [ [ 2map-into ] keep ] new-like ; inline
 412
 413 : 2map ( seq1 seq2 quot -- newseq )
 414     pick 2map-as ; inline
 415
 416 : 2change-each ( seq1 seq2 quot -- )
 417     pick 2map-into ; inline
 418
 419 : 2all? ( seq1 seq2 quot -- ? )
 420     (2each) all-integers? ; inline
 421
 422 : find-from ( n seq quot -- i elt )
 423     [ (find-integer) ] (find-from) ; inline
 424
 425 : find ( seq quot -- i elt )
 426     [ find-integer ] (find) ; inline
 427
 428 : find-last-from ( n seq quot -- i elt )
 429     [ nip find-last-integer ] (find-from) ; inline
 430
 431 : find-last ( seq quot -- i elt )
 432     [ [ 1- ] dip find-last-integer ] (find) ; inline
 433
 434 : all? ( seq quot -- ? )
 435     (each) all-integers? ; inline
 436
 437 : push-if ( elt quot accum -- )
 438     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 439
 440 : pusher ( quot -- quot accum )
 441     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 442
 443 : filter ( seq quot -- subseq )
 444     over [ pusher [ each ] dip ] dip like ; inline
 445
 446 : push-either ( elt quot accum1 accum2 -- )
 447     [ keep swap ] 2dip ? push ; inline
 448
 449 : 2pusher ( quot -- quot accum1 accum2 )
 450     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 451
 452 : partition ( seq quot -- trueseq falseseq )
 453     over [ 2pusher [ each ] 2dip ] dip tuck [ like ] 2bi@ ; inline
 454
 455 : monotonic? ( seq quot -- ? )
 456     [ [ length 1- ] keep ] dip (monotonic) all? ; inline
 457
 458 : interleave ( seq between quot -- )
 459     [ (interleave) ] 2curry [ [ length ] keep ] dip 2each ; inline
 460
 461 : accumulator ( quot -- quot' vec )
 462     V{ } clone [ [ push ] curry compose ] keep ; inline
 463
 464 : produce-as ( pred quot tail exemplar -- seq )
 465     [ swap accumulator [ swap while ] dip ] dip like ; inline
 466
 467 : produce ( pred quot tail -- seq )
 468     { } produce-as ; inline
 469
 470 : follow ( obj quot -- seq )
 471     [ dup ] swap [ keep ] curry [ ] produce nip ; inline
 472
 473 : prepare-index ( seq quot -- seq n quot )
 474     [ dup length ] dip ; inline
 475
 476 : each-index ( seq quot -- )
 477     prepare-index 2each ; inline
 478
 479 : map-index ( seq quot -- )
 480     prepare-index 2map ; inline
 481
 482 : reduce-index ( seq identity quot -- )
 483     swapd each-index ; inline
 484
 485 : index ( obj seq -- n )
 486     [ = ] with find drop ;
 487
 488 : index-from ( obj i seq -- n )
 489     rot [ = ] curry find-from drop ;
 490
 491 : last-index ( obj seq -- n )
 492     [ = ] with find-last drop ;
 493
 494 : last-index-from ( obj i seq -- n )
 495     rot [ = ] curry find-last-from drop ;
 496
 497 : indices ( obj seq -- indices )
 498     V{ } clone spin
 499     [ rot = [ over push ] [ drop ] if ]
 500     curry each-index ;
 501
 502 : nths ( indices seq -- seq' )
 503     [ nth ] curry map ;
 504
 505 : contains? ( seq quot -- ? )
 506     find drop >boolean ; inline
 507
 508 : member? ( elt seq -- ? )
 509     [ = ] with contains? ;
 510
 511 : memq? ( elt seq -- ? )
 512     [ eq? ] with contains? ;
 513
 514 : remove ( elt seq -- newseq )
 515     [ = not ] with filter ;
 516
 517 : remq ( elt seq -- newseq )
 518     [ eq? not ] with filter ;
 519
 520 : sift ( seq -- newseq )
 521     [ ] filter ;
 522
 523 : harvest ( seq -- newseq )
 524     [ empty? not ] filter ;
 525
 526 : mismatch ( seq1 seq2 -- i )
 527     [ min-length ] 2keep
 528     [ 2nth-unsafe = not ] 2curry
 529     find drop ; inline
 530
 531 M: sequence <=>
 532     2dup mismatch
 533     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 534
 535 : sequence= ( seq1 seq2 -- ? )
 536     2dup [ length ] bi@ =
 537     [ mismatch not ] [ 2drop f ] if ; inline
 538
 539 : sequence-hashcode-step ( oldhash newpart -- newhash )
 540     >fixnum swap [
 541         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 542         fixnum+fast fixnum+fast
 543     ] keep fixnum-bitxor ; inline
 544
 545 : sequence-hashcode ( n seq -- x )
 546     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 547
 548 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 549
 550 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 551
 552 : move ( to from seq -- )
 553     2over =
 554     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 555
 556 <PRIVATE
 557
 558 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 559     2dup length < [
 560         [ move ] 3keep
 561         [ nth-unsafe pick call [ 1+ ] when ] 2keep
 562         [ 1+ ] dip
 563         (filter-here)
 564     ] [ nip set-length drop ] if ; inline recursive
 565
 566 PRIVATE>
 567
 568 : filter-here ( seq quot -- )
 569     0 0 roll (filter-here) ; inline
 570
 571 : delete ( elt seq -- )
 572     [ = not ] with filter-here ;
 573
 574 : delq ( elt seq -- )
 575     [ eq? not ] with filter-here ;
 576
 577 : prefix ( seq elt -- newseq )
 578     over [ over length 1+ ] dip [
 579         [ 0 swap set-nth-unsafe ] keep
 580         [ 1 swap copy ] keep
 581     ] new-like ;
 582
 583 : suffix ( seq elt -- newseq )
 584     over [ over length 1+ ] dip [
 585         [ [ over length ] dip set-nth-unsafe ] keep
 586         [ 0 swap copy ] keep
 587     ] new-like ;
 588
 589 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 590
 591 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 592
 593 <PRIVATE
 594
 595 : move-backward ( shift from to seq -- )
 596     2over = [
 597         2drop 2drop
 598     ] [
 599         [ [ 2over + pick ] dip move [ 1+ ] dip ] keep
 600         move-backward
 601     ] if ;
 602
 603 : move-forward ( shift from to seq -- )
 604     2over = [
 605         2drop 2drop
 606     ] [
 607         [ [ pick [ dup dup ] dip + swap ] dip move 1- ] keep
 608         move-forward
 609     ] if ;
 610
 611 : (open-slice) ( shift from to seq ? -- )
 612     [
 613         [ [ 1- ] bi@ ] dip move-forward
 614     ] [
 615         [ over - ] 2dip move-backward
 616     ] if ;
 617
 618 PRIVATE>
 619
 620 : open-slice ( shift from seq -- )
 621     pick 0 = [
 622         3drop
 623     ] [
 624         pick over length + over
 625         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 626         set-length
 627     ] if ;
 628
 629 : delete-slice ( from to seq -- )
 630     check-slice [ over [ - ] dip ] dip open-slice ;
 631
 632 : delete-nth ( n seq -- )
 633     [ dup 1+ ] dip delete-slice ;
 634
 635 : replace-slice ( new from to seq -- )
 636     [ [ [ dup pick length + ] dip - over ] dip open-slice ] keep
 637     copy ;
 638
 639 : remove-nth ( n seq -- seq' )
 640     [ swap head-slice ] [ swap 1+ tail-slice ] 2bi append ;
 641
 642 : pop ( seq -- elt )
 643     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 644
 645 : all-equal? ( seq -- ? ) [ = ] monotonic? ;
 646
 647 : all-eq? ( seq -- ? ) [ eq? ] monotonic? ;
 648
 649 : exchange ( m n seq -- )
 650     pick over bounds-check 2drop 2dup bounds-check 2drop
 651     exchange-unsafe ;
 652
 653 : reverse-here ( seq -- )
 654     dup length dup 2/ [
 655         [ 2dup ] dip
 656         tuck - 1- rot exchange-unsafe
 657     ] each 2drop ;
 658
 659 : reverse ( seq -- newseq )
 660     [
 661         dup [ length ] keep new-sequence
 662         [ 0 swap copy ] keep
 663         [ reverse-here ] keep
 664     ] keep like ;
 665
 666 : sum-lengths ( seq -- n )
 667     0 [ length + ] reduce ;
 668
 669 : concat ( seq -- newseq )
 670     [
 671         { }
 672     ] [
 673         [ sum-lengths ] keep
 674         [ first new-resizable ] keep
 675         [ [ over push-all ] each ] keep
 676         first like
 677     ] if-empty ;
 678
 679 <PRIVATE
 680
 681 : joined-length ( seq glue -- n )
 682     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 683
 684 PRIVATE>
 685
 686 : join ( seq glue -- newseq )
 687     [
 688         2dup joined-length over new-resizable spin
 689         [ dup pick push-all ] [ pick push-all ] interleave drop
 690     ] keep like ;
 691
 692 : padding ( seq n elt quot -- newseq )
 693     [
 694         [ over length [-] dup 0 = [ drop ] ] dip
 695         [ <repetition> ] curry
 696     ] dip compose if ; inline
 697
 698 : pad-left ( seq n elt -- padded )
 699     [ swap dup append-as ] padding ;
 700
 701 : pad-right ( seq n elt -- padded )
 702     [ append ] padding ;
 703
 704 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 705
 706 : head? ( seq begin -- ? )
 707     2dup shorter? [
 708         2drop f
 709     ] [
 710         tuck length head-slice sequence=
 711     ] if ;
 712
 713 : tail? ( seq end -- ? )
 714     2dup shorter? [
 715         2drop f
 716     ] [
 717         tuck length tail-slice* sequence=
 718     ] if ;
 719
 720 : cut-slice ( seq n -- before-slice after-slice )
 721     [ head-slice ] [ tail-slice ] 2bi ;
 722
 723 : insert-nth ( elt n seq -- seq' )
 724     swap cut-slice [ swap suffix ] dip append ;
 725
 726 : midpoint@ ( seq -- n ) length 2/ ; inline
 727
 728 : halves ( seq -- first-slice second-slice )
 729     dup midpoint@ cut-slice ;
 730
 731 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 732     #! We can't use case here since combinators depends on
 733     #! sequences
 734     pick length dup 0 3 between? [
 735         >fixnum {
 736             [ drop nip ]
 737             [ 2drop first ]
 738             [ [ drop first2 ] dip call ]
 739             [ [ drop first3 ] dip bi@ ]
 740         } dispatch
 741     ] [
 742         drop
 743         [ halves ] 2dip
 744         [ [ binary-reduce ] 2curry bi@ ] keep
 745         call
 746     ] if ; inline recursive
 747
 748 : cut ( seq n -- before after )
 749     [ head ] [ tail ] 2bi ;
 750
 751 : cut* ( seq n -- before after )
 752     [ head* ] [ tail* ] 2bi ;
 753
 754 <PRIVATE
 755
 756 : (start) ( subseq seq n -- subseq seq ? )
 757     pick length [
 758         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 759     ] all? nip ; inline
 760
 761 PRIVATE>
 762
 763 : start* ( subseq seq n -- i )
 764     pick length pick length swap - 1+
 765     [ (start) ] find-from
 766     swap [ 3drop ] dip ;
 767
 768 : start ( subseq seq -- i ) 0 start* ; inline
 769
 770 : subseq? ( subseq seq -- ? ) start >boolean ;
 771
 772 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 773     2dup mismatch [ 2dup min-length ] unless*
 774     tuck [ tail-slice ] 2bi@ ;
 775
 776 : unclip ( seq -- rest first )
 777     [ rest ] [ first-unsafe ] bi ;
 778
 779 : unclip-last ( seq -- butlast last )
 780     [ but-last ] [ peek ] bi ;
 781
 782 : unclip-slice ( seq -- rest-slice first )
 783     [ rest-slice ] [ first-unsafe ] bi ; inline
 784
 785 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 786     [ unclip-slice ] bi@ swapd ; inline
 787
 788 : map-reduce ( seq map-quot reduce-quot -- result )
 789     [ [ unclip-slice ] dip [ call ] keep ] dip
 790     compose reduce ; inline
 791
 792 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 793     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 794     compose 2reduce ; inline
 795
 796 : unclip-last-slice ( seq -- butlast-slice last )
 797     [ but-last-slice ] [ peek ] bi ; inline
 798
 799 : <flat-slice> ( seq -- slice )
 800     dup slice? [ { } like ] when 0 over length rot <slice> ;
 801     inline
 802
 803 : trim-left-slice ( seq quot -- slice )
 804     over [ [ not ] compose find drop ] dip swap
 805     [ tail-slice ] [ dup length tail-slice ] if* ; inline
 806
 807 : trim-left ( seq quot -- newseq )
 808     over [ trim-left-slice ] dip like ; inline
 809
 810 : trim-right-slice ( seq quot -- slice )
 811     over [ [ not ] compose find-last drop ] dip swap
 812     [ 1+ head-slice ] [ 0 head-slice ] if* ; inline
 813
 814 : trim-right ( seq quot -- newseq )
 815     over [ trim-right-slice ] dip like ; inline
 816
 817 : trim-slice ( seq quot -- slice )
 818     [ trim-left-slice ] [ trim-right-slice ] bi ; inline
 819
 820 : trim ( seq quot -- newseq )
 821     over [ trim-slice ] dip like ; inline
 822
 823 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 824
 825 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 826
 827 : infimum ( seq -- n ) dup first [ min ] reduce ;
 828
 829 : supremum ( seq -- n ) dup first [ max ] reduce ;
 830
 831 : sigma ( seq quot -- n ) [ + ] compose 0 swap reduce ; inline
 832
 833 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 834
 835 ! We hand-optimize flip to such a degree because type hints
 836 ! cannot express that an array is an array of arrays yet, and
 837 ! this word happens to be performance-critical since the compiler
 838 ! itself uses it. Optimizing it like this reduced compile time.
 839 <PRIVATE
 840
 841 : generic-flip ( matrix -- newmatrix )
 842     [ dup first length [ length min ] reduce ] keep
 843     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 844
 845 USE: arrays
 846
 847 : array-length ( array -- len )
 848     { array } declare length>> ; inline
 849
 850 : array-flip ( matrix -- newmatrix )
 851     { array } declare
 852     [ dup first array-length [ array-length min ] reduce ] keep
 853     [ [ array-nth ] with { } map-as ] curry { } map-as ;
 854
 855 PRIVATE>
 856
 857 : flip ( matrix -- newmatrix )
 858     dup empty? [
 859         dup array? [
 860             dup [ array? ] all?
 861             [ array-flip ] [ generic-flip ] if
 862         ] [ generic-flip ] if
 863     ] unless ;