core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over >r >r new-sequence r> call r> like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length zero? ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot1 -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot1 -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     length 1- 0 swap between? ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth (call) ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop dup empty? [ drop f ] when ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 : first2-unsafe
 105     [ 0 swap nth-unsafe 1 ] [ nth-unsafe ] bi ; inline
 106
 107 : first3-unsafe
 108     [ first2-unsafe 2 ] [ nth-unsafe ] bi ; inline
 109
 110 : first4-unsafe
 111     [ first3-unsafe 3 ] [ nth-unsafe ] bi ; inline
 112
 113 : exchange-unsafe ( m n seq -- )
 114     [ tuck nth-unsafe >r nth-unsafe r> ] 3keep tuck
 115     >r >r set-nth-unsafe r> r> set-nth-unsafe ; inline
 116
 117 : (head) ( seq n -- from to seq ) 0 spin ; inline
 118
 119 : (tail) ( seq n -- from to seq ) over length rot ; inline
 120
 121 : from-end >r dup length r> - ; inline
 122
 123 : (2sequence)
 124     tuck 1 swap set-nth-unsafe
 125     tuck 0 swap set-nth-unsafe ; inline
 126
 127 : (3sequence)
 128     tuck 2 swap set-nth-unsafe
 129     (2sequence) ; inline
 130
 131 : (4sequence)
 132     tuck 3 swap set-nth-unsafe
 133     (3sequence) ; inline
 134
 135 PRIVATE>
 136
 137 : 2sequence ( obj1 obj2 exemplar -- seq )
 138     2 swap [ (2sequence) ] new-like ; inline
 139
 140 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 141     3 swap [ (3sequence) ] new-like ; inline
 142
 143 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 144     4 swap [ (4sequence) ] new-like ; inline
 145
 146 : first2 ( seq -- first second )
 147     1 swap bounds-check nip first2-unsafe ; flushable
 148
 149 : first3 ( seq -- first second third )
 150     2 swap bounds-check nip first3-unsafe ; flushable
 151
 152 : first4 ( seq -- first second third fourth )
 153     3 swap bounds-check nip first4-unsafe ; flushable
 154
 155 : ?nth ( n seq -- elt/f )
 156     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 157
 158 MIXIN: virtual-sequence
 159 GENERIC: virtual-seq ( seq -- seq' )
 160 GENERIC: virtual@ ( n seq -- n' seq' )
 161
 162 M: virtual-sequence nth virtual@ nth ;
 163 M: virtual-sequence set-nth virtual@ set-nth ;
 164 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 165 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 166 M: virtual-sequence like virtual-seq like ;
 167 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 168
 169 INSTANCE: virtual-sequence sequence
 170
 171 ! A reversal of an underlying sequence.
 172 TUPLE: reversed { seq read-only } ;
 173
 174 C: <reversed> reversed
 175
 176 M: reversed virtual-seq seq>> ;
 177
 178 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 179
 180 M: reversed length seq>> length ;
 181
 182 INSTANCE: reversed virtual-sequence
 183
 184 ! A slice of another sequence.
 185 TUPLE: slice
 186 { from read-only }
 187 { to read-only }
 188 { seq read-only } ;
 189
 190 : collapse-slice ( m n slice -- m' n' seq )
 191     [ from>> ] [ seq>> ] bi >r tuck + >r + r> r> ; inline
 192
 193 ERROR: slice-error reason ;
 194
 195 : check-slice ( from to seq -- from to seq )
 196     pick 0 < [ "start < 0" slice-error ] when
 197     dup length pick < [ "end > sequence" slice-error ] when
 198     2over > [ "start > end" slice-error ] when ; inline
 199
 200 : <slice> ( from to seq -- slice )
 201     dup slice? [ collapse-slice ] when
 202     check-slice
 203     slice boa ; inline
 204
 205 M: slice virtual-seq seq>> ;
 206
 207 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 208
 209 M: slice length [ to>> ] [ from>> ] bi - ;
 210
 211 : short ( seq n -- seq n' ) over length min ; inline
 212
 213 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 214
 215 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 216
 217 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 218
 219 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 220
 221 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 222
 223 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 224
 225 INSTANCE: slice virtual-sequence
 226
 227 ! One element repeated many times
 228 TUPLE: repetition { len read-only } { elt read-only } ;
 229
 230 C: <repetition> repetition
 231
 232 M: repetition length len>> ;
 233 M: repetition nth-unsafe nip elt>> ;
 234
 235 INSTANCE: repetition immutable-sequence
 236
 237 <PRIVATE
 238
 239 : ((copy)) ( dst i src j n -- dst i src j n )
 240     dup -roll [
 241         + swap nth-unsafe -roll [
 242             + swap set-nth-unsafe
 243         ] 3keep drop
 244     ] 3keep ; inline
 245
 246 : (copy) ( dst i src j n -- dst )
 247     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 248     inline recursive
 249
 250 : prepare-subseq ( from to seq -- dst i src j n )
 251     [ >r swap - r> new-sequence dup 0 ] 3keep
 252     -rot drop roll length ; inline
 253
 254 : check-copy ( src n dst -- )
 255     over 0 < [ bounds-error ] when
 256     >r swap length + r> lengthen ; inline
 257
 258 PRIVATE>
 259
 260 : subseq ( from to seq -- subseq )
 261     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 262
 263 : head ( seq n -- headseq ) (head) subseq ;
 264
 265 : tail ( seq n -- tailseq ) (tail) subseq ;
 266
 267 : rest ( seq -- tailseq ) 1 tail ;
 268
 269 : head* ( seq n -- headseq ) from-end head ;
 270
 271 : tail* ( seq n -- tailseq ) from-end tail ;
 272
 273 : but-last ( seq -- headseq ) 1 head* ;
 274
 275 : copy ( src i dst -- )
 276     pick length >r 3dup check-copy spin 0 r>
 277     (copy) drop ; inline
 278
 279 M: sequence clone-like
 280     >r dup length r> new-sequence [ 0 swap copy ] keep ;
 281
 282 M: immutable-sequence clone-like like ;
 283
 284 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 285
 286 : ((append)) ( seq1 seq2 accum -- accum )
 287     [ >r over length r> copy ]
 288     [ 0 swap copy ]
 289     [ ] tri ; inline
 290
 291 : (append) ( seq1 seq2 exemplar -- newseq )
 292     >r over length over length + r>
 293     [ ((append)) ] new-like ; inline
 294
 295 : (3append) ( seq1 seq2 seq3 exemplar -- newseq )
 296     >r pick length pick length pick length + + r> [
 297         [ >r pick length pick length + r> copy ]
 298         [ ((append)) ] bi
 299     ] new-like ; inline
 300
 301 : append ( seq1 seq2 -- newseq ) over (append) ;
 302
 303 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 304
 305 : 3append ( seq1 seq2 seq3 -- newseq ) pick (3append) ;
 306
 307 : change-nth ( i seq quot -- )
 308     [ >r nth r> call ] 3keep drop set-nth ; inline
 309
 310 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 311
 312 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 313
 314 <PRIVATE
 315
 316 : (each) ( seq quot -- n quot' )
 317     >r dup length swap [ nth-unsafe ] curry r> compose ; inline
 318
 319 : (collect) ( quot into -- quot' )
 320     [ >r keep r> set-nth-unsafe ] 2curry ; inline
 321
 322 : collect ( n quot into -- )
 323     (collect) each-integer ; inline
 324
 325 : map-into ( seq quot into -- )
 326     >r (each) r> collect ; inline
 327
 328 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 329     >r over r> nth-unsafe >r nth-unsafe r> ; inline
 330
 331 : (2each) ( seq1 seq2 quot -- n quot' )
 332     >r [ min-length ] 2keep r>
 333     [ >r 2nth-unsafe r> call ] 3curry ; inline
 334
 335 : 2map-into ( seq1 seq2 quot into -- newseq )
 336     >r (2each) r> collect ; inline
 337
 338 : finish-find ( i seq -- i elt )
 339     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 340
 341 : (find) ( seq quot quot' -- i elt )
 342     pick >r >r (each) r> call r> finish-find ; inline
 343
 344 : (find-from) ( n seq quot quot' -- i elt )
 345     [ 2dup bounds-check? ] 2dip
 346     [ (find) ] 2curry
 347     [ 2drop f f ]
 348     if ; inline
 349
 350 : (monotonic) ( seq quot -- ? )
 351     [ 2dup nth-unsafe rot 1+ rot nth-unsafe ]
 352     prepose curry ; inline
 353
 354 : (interleave) ( n elt between quot -- )
 355     roll zero? [ nip ] [ swapd 2slip ] if call ; inline
 356
 357 PRIVATE>
 358
 359 : each ( seq quot -- )
 360     (each) each-integer ; inline
 361
 362 : reduce ( seq identity quot -- result )
 363     swapd each ; inline
 364
 365 : map-as ( seq quot exemplar -- newseq )
 366     >r over length r> [ [ map-into ] keep ] new-like ; inline
 367
 368 : map ( seq quot -- newseq )
 369     over map-as ; inline
 370
 371 : replicate ( seq quot -- newseq )
 372     [ drop ] prepose map ; inline
 373
 374 : replicate-as ( seq quot exemplar -- newseq )
 375     >r [ drop ] prepose r> map-as ; inline
 376
 377 : change-each ( seq quot -- )
 378     over map-into ; inline
 379
 380 : accumulate ( seq identity quot -- final newseq )
 381     swapd [ pick slip ] curry map ; inline
 382
 383 : 2each ( seq1 seq2 quot -- )
 384     (2each) each-integer ; inline
 385
 386 : 2reverse-each ( seq1 seq2 quot -- )
 387     >r [ <reversed> ] bi@ r> 2each ; inline
 388
 389 : 2reduce ( seq1 seq2 identity quot -- result )
 390     >r -rot r> 2each ; inline
 391
 392 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 393     >r 2over min-length r>
 394     [ [ 2map-into ] keep ] new-like ; inline
 395
 396 : 2map ( seq1 seq2 quot -- newseq )
 397     pick 2map-as ; inline
 398
 399 : 2change-each ( seq1 seq2 quot -- newseq )
 400     pick 2map-into ; inline
 401
 402 : 2all? ( seq1 seq2 quot -- ? )
 403     (2each) all-integers? ; inline
 404
 405 : find-from ( n seq quot -- i elt )
 406     [ (find-integer) ] (find-from) ; inline
 407
 408 : find ( seq quot -- i elt )
 409     [ find-integer ] (find) ; inline
 410
 411 : find-last-from ( n seq quot -- i elt )
 412     [ nip find-last-integer ] (find-from) ; inline
 413
 414 : find-last ( seq quot -- i elt )
 415     [ >r 1- r> find-last-integer ] (find) ; inline
 416
 417 : all? ( seq quot -- ? )
 418     (each) all-integers? ; inline
 419
 420 : push-if ( elt quot accum -- )
 421     >r keep r> rot [ push ] [ 2drop ] if  ; inline
 422
 423 : pusher ( quot -- quot accum )
 424     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 425
 426 : filter ( seq quot -- subseq )
 427     over >r pusher >r each r> r> like ; inline
 428
 429 : push-either ( elt quot accum1 accum2 -- )
 430     >r >r keep swap r> r> ? push ; inline
 431
 432 : 2pusher ( quot -- quot accum1 accum2 )
 433     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 434
 435 : partition ( seq quot -- trueseq falseseq )
 436     over >r 2pusher >r >r each r> r> r> tuck [ like ] 2bi@ ; inline
 437
 438 : monotonic? ( seq quot -- ? )
 439     >r dup length 1- swap r> (monotonic) all? ; inline
 440
 441 : interleave ( seq between quot -- )
 442     [ (interleave) ] 2curry >r dup length swap r> 2each ; inline
 443
 444 : accumulator ( quot -- quot' vec )
 445     V{ } clone [ [ push ] curry compose ] keep ; inline
 446
 447 : produce ( pred quot tail -- seq )
 448     swap accumulator >r swap while r> { } like ; inline
 449
 450 : follow ( obj quot -- seq )
 451     >r [ dup ] r> [ keep ] curry [ ] produce nip ; inline
 452
 453 : prepare-index ( seq quot -- seq n quot )
 454     >r dup length r> ; inline
 455
 456 : each-index ( seq quot -- )
 457     prepare-index 2each ; inline
 458
 459 : map-index ( seq quot -- )
 460     prepare-index 2map ; inline
 461
 462 : reduce-index ( seq identity quot -- )
 463     swapd each-index ; inline
 464
 465 : index ( obj seq -- n )
 466     [ = ] with find drop ;
 467
 468 : index-from ( obj i seq -- n )
 469     rot [ = ] curry find-from drop ;
 470
 471 : last-index ( obj seq -- n )
 472     [ = ] with find-last drop ;
 473
 474 : last-index-from ( obj i seq -- n )
 475     rot [ = ] curry find-last-from drop ;
 476
 477 : nths ( seq indices -- seq' )
 478     swap [ nth ] curry map ;
 479
 480 : contains? ( seq quot -- ? )
 481     find drop >boolean ; inline
 482
 483 : member? ( obj seq -- ? )
 484     [ = ] with contains? ;
 485
 486 : memq? ( obj seq -- ? )
 487     [ eq? ] with contains? ;
 488
 489 : remove ( obj seq -- newseq )
 490     [ = not ] with filter ;
 491
 492 : sift ( seq -- newseq )
 493     [ ] filter ;
 494
 495 : harvest ( seq -- newseq )
 496     [ empty? not ] filter ;
 497
 498 : cache-nth ( i seq quot -- elt )
 499     2over ?nth dup [
 500         >r 3drop r>
 501     ] [
 502         drop swap >r over >r call dup r> r> set-nth
 503     ] if ; inline
 504
 505 : mismatch ( seq1 seq2 -- i )
 506     [ min-length ] 2keep
 507     [ 2nth-unsafe = not ] 2curry
 508     find drop ; inline
 509
 510 M: sequence <=>
 511     2dup mismatch
 512     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 513
 514 : sequence= ( seq1 seq2 -- ? )
 515     2dup [ length ] bi@ number=
 516     [ mismatch not ] [ 2drop f ] if ; inline
 517
 518 : sequence-hashcode-step ( oldhash newpart -- newhash )
 519     >fixnum swap [
 520         dup -2 fixnum-shift-fast swap 5 fixnum-shift-fast
 521         fixnum+fast fixnum+fast
 522     ] keep fixnum-bitxor ; inline
 523
 524 : sequence-hashcode ( n seq -- x )
 525     0 -rot [ hashcode* sequence-hashcode-step ] with each ; inline
 526
 527 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 528
 529 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 530
 531 : move ( to from seq -- )
 532     2over number=
 533     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 534
 535 : (delete) ( elt store scan seq -- elt store scan seq )
 536     2dup length < [
 537         3dup move
 538         [ nth pick = ] 2keep rot
 539         [ >r >r 1+ r> r> ] unless >r 1+ r> (delete)
 540     ] when ;
 541
 542 : delete ( elt seq -- ) 0 0 rot (delete) nip set-length drop ;
 543
 544 : prefix ( seq elt -- newseq )
 545     over >r over length 1+ r> [
 546         [ 0 swap set-nth-unsafe ] keep
 547         [ 1 swap copy ] keep
 548     ] new-like ;
 549
 550 : suffix ( seq elt -- newseq )
 551     over >r over length 1+ r> [
 552         [ >r over length r> set-nth-unsafe ] keep
 553         [ 0 swap copy ] keep
 554     ] new-like ;
 555
 556 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 557
 558 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 559
 560 : move-backward ( shift from to seq -- )
 561     2over number= [
 562         2drop 2drop
 563     ] [
 564         [ >r 2over + pick r> move >r 1+ r> ] keep
 565         move-backward
 566     ] if ;
 567
 568 : move-forward ( shift from to seq -- )
 569     2over number= [
 570         2drop 2drop
 571     ] [
 572         [ >r pick >r dup dup r> + swap r> move 1- ] keep
 573         move-forward
 574     ] if ;
 575
 576 : (open-slice) ( shift from to seq ? -- )
 577     [
 578         >r [ 1- ] bi@ r> move-forward
 579     ] [
 580         >r >r over - r> r> move-backward
 581     ] if ;
 582
 583 : open-slice ( shift from seq -- )
 584     pick zero? [
 585         3drop
 586     ] [
 587         pick over length + over >r >r
 588         pick 0 > >r [ length ] keep r> (open-slice)
 589         r> r> set-length
 590     ] if ;
 591
 592 : delete-slice ( from to seq -- )
 593     check-slice >r over >r - r> r> open-slice ;
 594
 595 : delete-nth ( n seq -- )
 596     >r dup 1+ r> delete-slice ;
 597
 598 : replace-slice ( new from to seq -- )
 599     [ >r >r dup pick length + r> - over r> open-slice ] keep
 600     copy ;
 601
 602 : remove-nth ( n seq -- seq' )
 603     [ swap head-slice ] [ swap 1+ tail-slice ] 2bi append ;
 604
 605 : pop ( seq -- elt )
 606     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 607
 608 : all-equal? ( seq -- ? ) [ = ] monotonic? ;
 609
 610 : all-eq? ( seq -- ? ) [ eq? ] monotonic? ;
 611
 612 : exchange ( m n seq -- )
 613     pick over bounds-check 2drop 2dup bounds-check 2drop
 614     exchange-unsafe ;
 615
 616 : reverse-here ( seq -- )
 617     dup length dup 2/ [
 618         >r 2dup r>
 619         tuck - 1- rot exchange-unsafe
 620     ] each 2drop ;
 621
 622 : reverse ( seq -- newseq )
 623     [
 624         dup [ length ] keep new-sequence
 625         [ 0 swap copy ] keep
 626         [ reverse-here ] keep
 627     ] keep like ;
 628
 629 : sum-lengths ( seq -- n )
 630     0 [ length + ] reduce ;
 631
 632 : concat ( seq -- newseq )
 633     dup empty? [
 634         drop { }
 635     ] [
 636         [ sum-lengths ] keep
 637         [ first new-resizable ] keep
 638         [ [ over push-all ] each ] keep
 639         first like
 640     ] if ;
 641
 642 : joined-length ( seq glue -- n )
 643     >r dup sum-lengths swap length 1 [-] r> length * + ;
 644
 645 : join ( seq glue -- newseq )
 646     [
 647         2dup joined-length over new-resizable spin
 648         [ dup pick push-all ] [ pick push-all ] interleave drop
 649     ] keep like ;
 650
 651 : padding ( seq n elt quot -- newseq )
 652     [
 653         [ over length [-] dup zero? [ drop ] ] dip
 654         [ <repetition> ] curry
 655     ] dip compose if ; inline
 656
 657 : pad-left ( seq n elt -- padded )
 658     [ swap dup (append) ] padding ;
 659
 660 : pad-right ( seq n elt -- padded )
 661     [ append ] padding ;
 662
 663 : shorter? ( seq1 seq2 -- ? ) >r length r> length < ;
 664
 665 : head? ( seq begin -- ? )
 666     2dup shorter? [
 667         2drop f
 668     ] [
 669         tuck length head-slice sequence=
 670     ] if ;
 671
 672 : tail? ( seq end -- ? )
 673     2dup shorter? [
 674         2drop f
 675     ] [
 676         tuck length tail-slice* sequence=
 677     ] if ;
 678
 679 : cut-slice ( seq n -- before after )
 680     [ head-slice ] [ tail-slice ] 2bi ;
 681
 682 : insert-nth ( elt n seq -- seq' )
 683     swap cut-slice [ swap suffix ] dip append ;
 684
 685 : midpoint@ ( seq -- n ) length 2/ ; inline
 686
 687 : halves ( seq -- first second )
 688     dup midpoint@ cut-slice ;
 689
 690 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 691     #! We can't use case here since combinators depends on
 692     #! sequences
 693     pick length dup 0 3 between? [
 694         >fixnum {
 695             [ drop nip ]
 696             [ 2drop first ]
 697             [ >r drop first2 r> call ]
 698             [ >r drop first3 r> bi@ ]
 699         } dispatch
 700     ] [
 701         drop
 702         >r >r halves r> r>
 703         [ [ binary-reduce ] 2curry bi@ ] keep
 704         call
 705     ] if ; inline recursive
 706
 707 : cut ( seq n -- before after )
 708     [ head ] [ tail ] 2bi ;
 709
 710 : cut* ( seq n -- before after )
 711     [ head* ] [ tail* ] 2bi ;
 712
 713 <PRIVATE
 714
 715 : (start) ( subseq seq n -- subseq seq ? )
 716     pick length [
 717         >r 3dup r> [ + swap nth-unsafe ] keep rot nth-unsafe =
 718     ] all? nip ; inline
 719
 720 PRIVATE>
 721
 722 : start* ( subseq seq n -- i )
 723     pick length pick length swap - 1+
 724     [ (start) ] find-from
 725     swap >r 3drop r> ;
 726
 727 : start ( subseq seq -- i ) 0 start* ; inline
 728
 729 : subseq? ( subseq seq -- ? ) start >boolean ;
 730
 731 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 732     2dup mismatch [ 2dup min-length ] unless*
 733     tuck tail-slice >r tail-slice r> ;
 734
 735 : unclip ( seq -- rest first )
 736     [ rest ] [ first ] bi ;
 737
 738 : unclip-last ( seq -- butlast last )
 739     [ but-last ] [ peek ] bi ;
 740
 741 : unclip-slice ( seq -- rest first )
 742     [ rest-slice ] [ first ] bi ;
 743
 744 : unclip-last-slice ( seq -- butfirst last )
 745     [ but-last-slice ] [ peek ] bi ;
 746
 747 : <flat-slice> ( seq -- slice )
 748     dup slice? [ { } like ] when 0 over length rot <slice> ;
 749     inline
 750
 751 : trim-left-slice ( seq quot -- slice )
 752     over >r [ not ] compose find drop r> swap
 753     [ tail-slice ] [ dup length tail-slice ] if* ; inline
 754
 755 : trim-left ( seq quot -- newseq )
 756     over [ trim-left-slice ] dip like ; inline
 757
 758 : trim-right-slice ( seq quot -- slice )
 759     over >r [ not ] compose find-last drop r> swap
 760     [ 1+ head-slice ] [ 0 head-slice ] if* ; inline
 761
 762 : trim-right ( seq quot -- newseq )
 763     over [ trim-right-slice ] dip like ; inline
 764
 765 : trim-slice ( seq quot -- slice )
 766     [ trim-left-slice ] [ trim-right-slice ] bi ;
 767
 768 : trim ( seq quot -- newseq )
 769     over [ trim-slice ] dip like ; inline
 770
 771 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 772
 773 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 774
 775 : infimum ( seq -- n ) dup first [ min ] reduce ;
 776
 777 : supremum ( seq -- n ) dup first [ max ] reduce ;
 778
 779 : flip ( matrix -- newmatrix )
 780     dup empty? [
 781         dup [ length ] map infimum
 782         swap [ [ nth-unsafe ] with { } map-as ] curry { } map-as
 783     ] unless ;
 784
 785 : sigma ( seq quot -- n ) [ + ] compose 0 swap reduce ; inline
 786
 787 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline