core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (1sequence) ( obj seq -- seq )
 139     [ 0 swap set-nth-unsafe ] keep ; inline
 140
 141 : (2sequence) ( obj1 obj2 seq -- seq )
 142     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 146
 147 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 148     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 149
 150 PRIVATE>
 151
 152 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 153
 154 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 155
 156 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : maybe-nth ( i/f seq -- elt/f )
 186     over [ nth ] [ 2drop f ] if ; inline
 187
 188 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 189 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 190 : ?last ( seq -- elt/f )
 191     [ length 1 - ] keep over 0 <
 192     [ 2drop f ] [ nth-unsafe ] if ; inline
 193
 194 MIXIN: virtual-sequence
 195 GENERIC: virtual-exemplar ( seq -- seq' )
 196 GENERIC: virtual@ ( n seq -- n' seq' )
 197
 198 M: virtual-sequence nth virtual@ nth ; inline
 199 M: virtual-sequence set-nth virtual@ set-nth ; inline
 200 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 201 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 202 M: virtual-sequence like virtual-exemplar like ; inline
 203 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 204
 205 INSTANCE: virtual-sequence sequence
 206
 207 ! A reversal of an underlying sequence.
 208 TUPLE: reversed { seq read-only } ;
 209
 210 C: <reversed> reversed
 211
 212 M: reversed virtual-exemplar seq>> ; inline
 213 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 214 M: reversed length seq>> length ; inline
 215
 216 INSTANCE: reversed virtual-sequence
 217
 218 ! A slice of another sequence.
 219 TUPLE: slice
 220     { from integer read-only }
 221     { to integer read-only }
 222     { seq read-only } ;
 223
 224 : >slice< ( slice -- from to seq )
 225     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 226
 227 : collapse-slice ( m n slice -- m' n' seq )
 228     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 229
 230 ERROR: slice-error from to seq ;
 231
 232 : check-slice ( from to seq -- from to seq )
 233     pick 0 < [ slice-error ] when
 234     2dup length > [ slice-error ] when
 235     2over > [ slice-error ] when ; inline
 236
 237 <PRIVATE
 238
 239 : <slice-unsafe> ( from to seq -- slice )
 240     dup slice? [ collapse-slice ] when slice boa ; inline
 241
 242 PRIVATE>
 243
 244 : <slice> ( from to seq -- slice )
 245     check-slice <slice-unsafe> ; inline
 246
 247 M: slice virtual-exemplar seq>> ; inline
 248
 249 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 250
 251 M: slice length [ to>> ] [ from>> ] bi - ; inline
 252
 253 : bound ( seq n -- seq n' ) over length min ; inline
 254
 255 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 256
 257 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 258
 259 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 260
 261 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 262
 263 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 264
 265 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 266
 267 INSTANCE: slice virtual-sequence
 268
 269 ! One element repeated many times
 270 TUPLE: repetition
 271     { length integer read-only }
 272     { elt read-only } ;
 273
 274 : <repetition> ( len elt -- repetition )
 275     over 0 < [ non-negative-integer-expected ] when
 276     repetition boa ; inline
 277
 278 M: repetition length length>> ; inline
 279 M: repetition nth-unsafe nip elt>> ; inline
 280
 281 INSTANCE: repetition immutable-sequence
 282
 283 <PRIVATE
 284
 285 ERROR: integer-length-expected obj ;
 286
 287 ! The check-length call forces partial dispatch
 288 : check-length ( n -- n )
 289     dup integer? [ integer-length-expected ] unless ; inline
 290
 291 : >sequence< ( seq -- i n seq )
 292     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 293
 294 : length-sequence ( seq -- n seq )
 295     [ length check-length ] [ ] bi ; inline
 296
 297 : >underlying< ( slice/seq -- i n slice/seq )
 298     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 299
 300 TUPLE: copier
 301     { src-i integer read-only }
 302     { src read-only }
 303     { dst-i integer read-only }
 304     { dst read-only } ;
 305
 306 C: <copier> copier
 307
 308 : copy-nth-unsafe ( n copy -- )
 309     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 310     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 311
 312 : (copy) ( n copy -- dst )
 313     over 0 <= [ nip dst>> ] [
 314         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 315     ] if ; inline recursive
 316
 317 : subseq>copy ( from to seq -- n copy )
 318     [ over - check-length swap ] dip
 319     3dup nip new-sequence 0 swap <copier> ; inline
 320
 321 : bounds-check-head ( n seq -- n seq )
 322     over 0 < [ bounds-error ] when ; inline
 323
 324 : check-copy ( src n dst -- src n dst )
 325     3dup bounds-check-head
 326     [ swap length + ] dip lengthen ; inline
 327
 328 : copy-unsafe ( src i dst -- )
 329     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 330
 331 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 332     [ subseq>copy (copy) ] dip like ; inline
 333
 334 : subseq-unsafe ( from to seq -- subseq )
 335     dup subseq-unsafe-as ; inline
 336
 337 PRIVATE>
 338
 339 : subseq-as ( from to seq exemplar -- subseq )
 340     [ check-slice ] dip subseq-unsafe-as ;
 341
 342 : subseq ( from to seq -- subseq )
 343     dup subseq-as ;
 344
 345 : head ( seq n -- headseq ) head-to-index subseq ;
 346
 347 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 348
 349 : rest ( seq -- tailseq ) 1 tail ;
 350
 351 : head* ( seq n -- headseq ) from-tail head ;
 352
 353 : tail* ( seq n -- tailseq ) from-tail tail ;
 354
 355 : but-last ( seq -- headseq ) 1 head* ;
 356
 357 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 358
 359 M: sequence clone-like
 360     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 361
 362 M: immutable-sequence clone-like like ; inline
 363
 364 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 365
 366 <PRIVATE
 367
 368 : (append) ( seq1 seq2 accum -- accum )
 369     [ [ over length ] dip copy-unsafe ]
 370     [ 0 swap copy-unsafe ]
 371     [ ] tri ; inline
 372
 373 PRIVATE>
 374
 375 : append-as ( seq1 seq2 exemplar -- newseq )
 376     [ 2dup [ length ] bi@ + ] dip
 377     [ (append) ] new-like ; inline
 378
 379 : append ( seq1 seq2 -- newseq ) over append-as ;
 380
 381 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 382
 383 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 384
 385 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 386     [ 3dup [ length ] tri@ + + ] dip [
 387         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 388         [ (append) ] bi
 389     ] new-like ; inline
 390
 391 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 392
 393 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 394     [ swap ] 2dip 3append-as ; inline
 395
 396 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 397
 398 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 399
 400 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 401
 402 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 403
 404 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 405
 406 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 407     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 408
 409 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 410
 411 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 412
 413 <PRIVATE
 414
 415 : sequence-operator ( seq quot -- i n quot' )
 416     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 417
 418 : length-iterator ( seq -- n quot' )
 419     length-sequence [ nth-unsafe ] curry ; inline
 420
 421 : length-operator ( seq quot -- n quot' )
 422     [ length-iterator ] dip compose ; inline
 423
 424 : length-operator-last ( seq quot -- n quot' )
 425     length-operator [ 1 - ] dip ; inline
 426
 427 : sequence-operator-from ( seq quot i -- i n quot' )
 428     -rot length-operator ; inline
 429
 430 : sequence-operator-last-from ( seq quot i -- n quot' )
 431     -rot length-operator-last nip ; inline
 432
 433 : collect ( n quot into -- )
 434     [ [ keep ] dip set-nth-unsafe ] 2curry each-integer ; inline
 435
 436 : sequence-index-operator ( seq quot -- n quot' )
 437     [ length-iterator [ keep ] curry ] dip compose ; inline
 438
 439 : map-into ( seq quot into -- )
 440     [ length-operator ] dip collect ; inline
 441
 442 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 443     [ nth-unsafe ] bi-curry@ bi ; inline
 444
 445 : setup-2each ( seq1 seq2 -- n quot )
 446     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 447
 448 : (2each) ( seq1 seq2 quot -- n quot' )
 449     [ setup-2each ] dip compose ; inline
 450
 451 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 452     [ nth-unsafe ] tri-curry@ tri ; inline
 453
 454 : setup-3each ( seq1 seq2 seq3 -- n quot )
 455     [ [ length ] tri@ min min check-length ]
 456     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 457
 458 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 459     [ setup-3each ] dip compose ; inline
 460
 461 : element/index ( i/f seq -- elt/f i/f )
 462     [ maybe-nth ] [ drop ] 2bi ; inline
 463
 464 : index/element ( i/f seq -- elt/f i/f )
 465     [ drop ] [ maybe-nth ] 2bi ; inline
 466
 467 : (accumulate) ( seq identity quot -- identity seq quot' )
 468     swapd [ keepd ] curry ; inline
 469
 470 : (accumulate*) ( seq identity quot -- identity seq quot' )
 471     swapd [ dup ] compose ; inline
 472
 473 PRIVATE>
 474
 475 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 476     sequence-operator each-integer-from ; inline
 477
 478 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 479     sequence-operator-from each-integer-from ; inline
 480
 481 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 482     swapd each ; inline
 483
 484 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 485     overd [ [ collect ] keep ] new-like ; inline
 486
 487 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 488     { } map-integers-as ; inline
 489
 490 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 491     [ length-operator ] dip map-integers-as ; inline
 492
 493 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 494     over map-as ; inline
 495
 496 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 497     [ [ drop ] prepose ] dip map-integers-as ; inline
 498
 499 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 500     { } replicate-as ; inline
 501
 502 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 503     over [ map-into ] keep ; inline
 504
 505 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 506     [ (accumulate) ] dip map-as ; inline
 507
 508 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 509     pick accumulate-as ; inline
 510
 511 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 512     (accumulate) map! ; inline
 513
 514 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 515     [ (accumulate*) ] dip map-as nip ; inline
 516
 517 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 518     pick accumulate*-as ; inline
 519
 520 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 521     (accumulate*) map! nip ; inline
 522
 523 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 524     (2each) each-integer ; inline
 525
 526 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 527     [ (2each) ] dip -rot each-integer-from ; inline
 528
 529 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 530     -rotd 2each ; inline
 531
 532 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 533     [ (2each) ] dip map-integers-as ; inline
 534
 535 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 536     pick 2map-as ; inline
 537
 538 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 539     (2each) all-integers? ; inline
 540
 541 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 542     negate 2all? not ; inline
 543
 544 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 545     (3each) each-integer ; inline
 546
 547 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 548     [ (3each) ] dip map-integers-as ; inline
 549
 550 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 551     pickd swap 3map-as ; inline
 552
 553 : bounds-check-find ( n seq quot -- elt i )
 554     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 555
 556 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 557     '[
 558         _ [ rot sequence-operator-from find-integer-from ] keepd
 559         index/element
 560     ] bounds-check-find ; inline
 561
 562 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 563     [ 0 ] 2dip find-from ; inline
 564
 565 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 566     '[
 567         _ [ rot sequence-operator-last-from find-last-integer ] keepd
 568         index/element
 569     ] bounds-check-find ; inline
 570
 571 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 572     [ [ length 1 - ] keep ] dip find-last-from ; inline
 573
 574 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 575     '[
 576         _ [ sequence-index-operator find-integer-from ] keepd
 577         index/element
 578     ] bounds-check-find ; inline
 579
 580 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 581     [ 0 ] 2dip find-index-from ; inline
 582
 583 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 584     sequence-operator all-integers-from? ; inline
 585
 586 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 587     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 588
 589 <PRIVATE
 590
 591 : (selector-as) ( quot length exemplar -- selector accum )
 592     new-resizable [ [ push-if ] 2curry ] keep ; inline
 593
 594 PRIVATE>
 595
 596 : selector-as ( quot exemplar -- selector accum )
 597     [ length ] keep (selector-as) ; inline
 598
 599 : selector ( quot -- selector accum )
 600     V{ } selector-as ; inline
 601
 602 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 603     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 604
 605 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 606     over filter-as ; inline
 607
 608 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 609     [ negate ] [ filter-as ] bi* ; inline
 610
 611 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 612     over reject-as ; inline
 613
 614 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 615     [ keep swap ] 2dip ? push ; inline
 616
 617 : 2selector ( quot -- selector accum1 accum2 )
 618     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 619
 620 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 621     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 622
 623 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 624     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 625
 626 : collector-as ( quot exemplar -- quot' vec )
 627     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 628
 629 : collector-for ( seq quot -- seq quot' vec )
 630     V{ } collector-for-as ; inline
 631
 632 : collector ( quot -- quot' vec )
 633     V{ } collector-as ; inline
 634
 635 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 636     dup [ collector-as [ while ] dip ] curry dip like ; inline
 637
 638 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 639     { } produce-as ; inline
 640
 641 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 642     [ dup ] swap [ keep ] curry produce nip ; inline
 643
 644 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 645     sequence-index-operator each-integer ; inline
 646
 647 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 648     [ dup length <iota> ] 2dip 2map-as ; inline
 649
 650 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 651     over map-index-as ; inline
 652
 653 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 654     pick empty? [ 3drop ] [
 655         [ [ drop first-unsafe ] dip call ]
 656         [ [ bi* ] 2curry 1 each-from ]
 657         3bi
 658     ] if ; inline
 659
 660 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 661     swapd each-index ; inline
 662
 663 : index ( obj seq -- n )
 664     [ = ] with find drop ;
 665
 666 : index-from ( obj i seq -- n )
 667     rot [ = ] curry find-from drop ;
 668
 669 : last-index ( obj seq -- n )
 670     [ = ] with find-last drop ;
 671
 672 : last-index-from ( obj i seq -- n )
 673     rot [ = ] curry find-last-from drop ;
 674
 675 : indices ( obj seq -- indices )
 676     swap [ = ] curry [ swap ] prepose V{ } clone [
 677         [ push ] curry [ [ drop ] if ] curry compose each-index
 678     ] keep ;
 679
 680 <PRIVATE
 681
 682 : nths-unsafe ( indices seq -- seq' )
 683     [ [ nth-unsafe ] curry ] keep map-as ;
 684
 685 PRIVATE>
 686
 687 : nths ( indices seq -- seq' )
 688     [ [ nth ] curry ] keep map-as ;
 689
 690 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 691     find drop >boolean ; inline
 692
 693 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 694     any? not ; inline
 695
 696 : member? ( elt seq -- ? )
 697     [ = ] with any? ;
 698
 699 : member-of? ( seq elt -- ? )
 700     [ = ] curry any? ;
 701
 702 : member-eq? ( elt seq -- ? )
 703     [ eq? ] with any? ;
 704
 705 : member-eq-of? ( seq elt -- ? )
 706     [ eq? ] curry any? ;
 707
 708 : remove ( elt seq -- newseq )
 709     [ = ] with reject ;
 710
 711 : remove-of ( seq elt -- newseq )
 712     [ = ] curry reject ;
 713
 714 : remove-eq ( elt seq -- newseq )
 715     [ eq? ] with reject ;
 716
 717 : remove-eq-of ( seq elt -- newseq )
 718     [ eq? ] curry reject ;
 719
 720 : sift ( seq -- newseq )
 721     [ ] filter ;
 722
 723 : harvest ( seq -- newseq )
 724     [ empty? ] reject ;
 725
 726 <PRIVATE
 727
 728 : mismatch-unsafe ( n seq1 seq2 -- i )
 729     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 730
 731 PRIVATE>
 732
 733 : mismatch ( seq1 seq2 -- i )
 734     [ min-length ] 2keep mismatch-unsafe ;
 735
 736 M: sequence <=>
 737     [ mismatch ] 2keep pick
 738     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 739
 740 : sequence= ( seq1 seq2 -- ? )
 741     2dup [ length ] bi@ dupd =
 742     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 743
 744 ERROR: assert-sequence got expected ;
 745
 746 : assert-sequence= ( a b -- )
 747     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 748
 749 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 750
 751 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 752
 753 <PRIVATE
 754
 755 : sequence-hashcode-step ( oldhash newpart -- newhash )
 756     integer>fixnum swap [
 757         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 758         fixnum+fast fixnum+fast
 759     ] keep fixnum-bitxor ; inline
 760
 761 PRIVATE>
 762
 763 : sequence-hashcode ( n seq -- x )
 764     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 765
 766 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 767
 768 M: iota hashcode*
 769     over 0 <= [ 2drop 0 ] [
 770         nip length 0 swap [ sequence-hashcode-step ] each-integer
 771     ] if ;
 772
 773 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 774
 775 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 776
 777 : move ( to from seq -- )
 778     2over =
 779     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 780
 781 <PRIVATE
 782
 783 : move-unsafe ( to from seq -- )
 784     2over =
 785     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 786
 787 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 788     2dup length < [
 789         [ move-unsafe ] 3keep
 790         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 791         [ 1 + ] dip
 792         (filter!)
 793     ] [ nip set-length drop ] if ; inline recursive
 794
 795 PRIVATE>
 796
 797 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 798     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 799
 800 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 801     negate filter! ; inline
 802
 803 : remove! ( elt seq -- seq )
 804     [ = ] with reject! ;
 805
 806 : remove-eq! ( elt seq -- seq )
 807     [ eq? ] with reject! ;
 808
 809 : prefix ( seq elt -- newseq )
 810     over [ over length 1 + ] dip [
 811         (1sequence) [ 1 swap copy-unsafe ] keep
 812     ] new-like ;
 813
 814 : suffix ( seq elt -- newseq )
 815     over [ over length 1 + ] dip [
 816         [ [ over length ] dip set-nth-unsafe ] keep
 817         [ 0 swap copy-unsafe ] keep
 818     ] new-like ;
 819
 820 : suffix! ( seq elt -- seq ) over push ; inline
 821
 822 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 823
 824 : last ( seq -- elt )
 825     [ length 1 - ] keep
 826     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 827
 828 <PRIVATE
 829
 830 : last-unsafe ( seq -- elt )
 831     [ length 1 - ] [ nth-unsafe ] bi ; inline
 832
 833 PRIVATE>
 834
 835 : set-last ( elt seq -- )
 836     [ length 1 - ] keep
 837     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 838
 839 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 840
 841 <PRIVATE
 842
 843 : move-backward ( shift from to seq -- )
 844     2over = [
 845         4drop
 846     ] [
 847         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 848         move-backward
 849     ] if ;
 850
 851 : move-forward ( shift from to seq -- )
 852     2over = [
 853         4drop
 854     ] [
 855         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 856         move-forward
 857     ] if ;
 858
 859 : (open-slice) ( shift from to seq ? -- )
 860     [
 861         [ [ 1 - ] bi@ ] dip move-forward
 862     ] [
 863         [ over - ] 2dip move-backward
 864     ] if ;
 865
 866 : open-slice ( shift from seq -- )
 867     pick 0 = [
 868         3drop
 869     ] [
 870         [ ] [ nip length + ] [ 2nip ] 3tri
 871         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 872         set-length
 873     ] if ;
 874
 875 PRIVATE>
 876
 877 : delete-slice ( from to seq -- )
 878     check-slice [ over [ - ] dip ] dip open-slice ;
 879
 880 : remove-nth! ( n seq -- seq )
 881     [ [ dup 1 + ] dip delete-slice ] keep ;
 882
 883 : snip ( from to seq -- head tail )
 884     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 885
 886 : snip-slice ( from to seq -- head tail )
 887     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 888
 889 : replace-slice ( new from to seq -- seq' )
 890     snip-slice surround ;
 891
 892 : remove-nth ( n seq -- seq' )
 893     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 894
 895 : pop ( seq -- elt )
 896     [ length 1 - ] keep over 0 >=
 897     [ [ nth-unsafe ] [ shorten ] 2bi ]
 898     [ bounds-error ] if ;
 899
 900 : exchange ( m n seq -- )
 901     [ nip bounds-check 2drop ]
 902     [ bounds-check 3drop ]
 903     [ exchange-unsafe ]
 904     3tri ;
 905
 906 : midpoint@ ( seq -- n ) length 2/ ; inline
 907
 908 : reverse! ( seq -- seq )
 909     [
 910         [ midpoint@ ] [ length ] [ ] tri
 911         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 912         each-integer
 913     ] keep ;
 914
 915 : reverse ( seq -- newseq )
 916      [
 917         dup [ length ] keep new-sequence
 918         [ 0 swap copy-unsafe ] keep reverse!
 919     ] keep like ;
 920
 921 GENERIC: sum-lengths ( seq -- n )
 922
 923 M: object sum-lengths
 924     0 [ length + ] reduce ;
 925
 926 M: repetition sum-lengths
 927     [ length>> ] [ elt>> length ] bi * ;
 928
 929 : concat-as ( seq exemplar -- newseq )
 930     [
 931         [ dup sum-lengths ] dip new-resizable
 932         [ [ push-all ] curry each ] keep
 933     ] keep like ; inline
 934
 935 : concat ( seq -- newseq )
 936     [ { } ] [ dup first concat-as ] if-empty ;
 937
 938 <PRIVATE
 939
 940 : joined-length ( seq glue -- n )
 941     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 942
 943 PRIVATE>
 944
 945 : join-as ( seq glue exemplar -- newseq )
 946     over empty? [ nip concat-as ] [
 947         [
 948             2dup joined-length over new-resizable [
 949                 [ [ push-all ] 2curry ]
 950                 [ nip [ push-all ] curry ] 2bi
 951                 interleave
 952             ] keep
 953         ] dip like
 954     ] if ;
 955
 956 : join ( seq glue -- newseq )
 957     dup join-as ; inline
 958
 959 <PRIVATE
 960
 961 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 962     [
 963         [ over length [-] dup 0 = [ drop ] ] dip
 964         [ <repetition> ] curry
 965     ] dip compose if ; inline
 966
 967 PRIVATE>
 968
 969 : pad-head ( seq n elt -- padded )
 970     [ swap dup append-as ] padding ;
 971
 972 : pad-tail ( seq n elt -- padded )
 973     [ append ] padding ;
 974
 975 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 976 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 977 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 978 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 979
 980 : head? ( seq begin -- ? )
 981     2dup shorter? [
 982         2drop f
 983     ] [
 984         [ length [ head-slice ] keep swap ] keep
 985         mismatch-unsafe not
 986     ] if ;
 987
 988 : tail? ( seq end -- ? )
 989     2dup shorter? [
 990         2drop f
 991     ] [
 992         [ length [ tail-slice* ] keep swap ] keep
 993         mismatch-unsafe not
 994     ] if ;
 995
 996 : cut-slice ( seq n -- before-slice after-slice )
 997     [ head-slice ] [ tail-slice ] 2bi ; inline
 998
 999 : cut-slice* ( seq n -- before-slice after-slice )
1000     [ head-slice* ] [ tail-slice* ] 2bi ;
1001
1002 : insert-nth ( elt n seq -- seq' )
1003     swap cut-slice [ swap suffix ] dip append ;
1004
1005 : halves ( seq -- first-slice second-slice )
1006     dup midpoint@ cut-slice ; inline
1007
1008 <PRIVATE
1009
1010 : nth2-unsafe ( n seq -- a b )
1011     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1012
1013 : nth3-unsafe ( n seq -- a b c )
1014     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1015
1016 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1017     ! We can't use case here since combinators depends on
1018     ! sequences
1019     dup 4 < [
1020         integer>fixnum {
1021             [ 2drop nip ]
1022             [ 2nip swap nth-unsafe ]
1023             [ -rot [ drop swap nth2-unsafe ] dip call ]
1024             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1025         } dispatch
1026     ] [
1027         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1028         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1029         pick [ 3bi ] dip call
1030     ] if ; inline recursive
1031
1032 PRIVATE>
1033
1034 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1035     pick dup slice? [
1036         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1037     ] [
1038         length 0 max 0 swap
1039     ] if (binary-reduce) ; inline
1040
1041 : cut ( seq n -- before after )
1042     [ head ] [ tail ] 2bi ;
1043
1044 : cut* ( seq n -- before after )
1045     [ head* ] [ tail* ] 2bi ;
1046
1047 : subseq-starts-at? ( i seq subseq -- ? )
1048     [ length swap ] keep
1049     '[
1050         [ + _ nth-unsafe ] keep _ nth-unsafe =
1051     ] with all-integers? ; inline
1052
1053 : find-subseq-from ( n seq subseq -- i/f )
1054     [ [ length ] bi@ - 1 + ] 2keep
1055     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1056
1057 : subseq-start-from ( subseq seq n -- i/f ) spin find-subseq-from ; inline
1058
1059 : find-subseq ( seq subseq -- i/f ) [ 0 ] 2dip find-subseq-from ; inline
1060
1061 : find-subseq? ( seq subseq -- ? ) find-subseq >boolean ; inline
1062
1063 : subseq-start ( subseq seq -- i/f ) swap find-subseq ; inline
1064
1065 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline
1066
1067 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1068     2dup mismatch [ 2dup min-length ] unless*
1069     [ tail-slice ] curry bi@ ;
1070
1071 : unclip ( seq -- rest first )
1072     [ rest ] [ first-unsafe ] bi ;
1073
1074 : unclip-last ( seq -- butlast last )
1075     [ but-last ] [ last-unsafe ] bi ;
1076
1077 : unclip-slice ( seq -- rest-slice first )
1078     [ rest-slice ] [ first-unsafe ] bi ; inline
1079
1080 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1081     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1082     '[ swap _ dip swap @ ] 1 each-from ; inline
1083
1084 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1085     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1086     '[ rot _ dip swap @ ] 1 2each-from ; inline
1087
1088 <PRIVATE
1089
1090 : (map-find) ( seq quot find-quot -- result elt )
1091     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1092
1093 PRIVATE>
1094
1095 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1096     [ find ] (map-find) ; inline
1097
1098 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1099     [ find-last ] (map-find) ; inline
1100
1101 : unclip-last-slice ( seq -- butlast-slice last )
1102     [ but-last-slice ] [ last-unsafe ] bi ; inline
1103
1104 <PRIVATE
1105
1106 : (trim-head) ( seq quot -- seq n )
1107     over [ negate find drop ] dip swap
1108     [ dup length ] unless* ; inline
1109
1110 : (trim-tail) ( seq quot -- seq n )
1111     over [ negate find-last drop ?1+ ] dip
1112     swap ; inline
1113
1114 PRIVATE>
1115
1116 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1117     (trim-head) tail-slice ; inline
1118
1119 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1120     (trim-head) tail ; inline
1121
1122 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1123     (trim-tail) head-slice ; inline
1124
1125 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1126     (trim-tail) head ; inline
1127
1128 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1129     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1130
1131 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1132     [ trim-slice ] [ drop ] 2bi like ; inline
1133
1134 GENERIC: sum ( seq -- n )
1135 M: object sum 0 [ + ] binary-reduce ; inline
1136 M: iota sum length dup 1 - * 2/ ; inline
1137 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1138
1139 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1140
1141 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1142
1143 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1144
1145 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1146     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1147
1148 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1149     [ 1 0 ? ] compose map-sum ; inline
1150
1151 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1152     [ with each ] 2curry each ; inline
1153
1154 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1155     [ with { } map-as ] 2curry { } map-as ; inline
1156
1157 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1158     [ 2sequence ] curry cartesian-map ; inline
1159
1160 : cartesian-product ( seq1 seq2 -- newseq )
1161     dup cartesian-product-as ; inline
1162
1163 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1164     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1165
1166 <PRIVATE
1167
1168 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1169     [
1170         [ keep swap ] curry [ [ first ] dip call ] 2keep
1171         [ curry 2dip pick over ] curry
1172     ] [
1173         [ [ 2drop ] [ 2nipd ] if ] compose
1174     ] bi* compose 1 each-from drop ; inline
1175
1176 PRIVATE>
1177
1178 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1179     [ after? ] select-by ; inline
1180
1181 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1182     [ before? ] select-by ; inline
1183
1184 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1185
1186 : longest ( seqs -- elt ) [ length ] supremum-by ;
1187
1188 ! We hand-optimize flip to such a degree because type hints
1189 ! cannot express that an array is an array of arrays yet, and
1190 ! this word happens to be performance-critical since the compiler
1191 ! itself uses it. Optimizing it like this reduced compile time.
1192 <PRIVATE
1193
1194 : generic-flip ( matrix -- newmatrix )
1195     [ [ length ] [ min ] map-reduce ] keep
1196     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1197
1198 USE: arrays
1199
1200 : array-flip ( matrix -- newmatrix )
1201     { array } declare
1202     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1203     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1204
1205 PRIVATE>
1206
1207 : flip ( matrix -- newmatrix )
1208     dup empty? [
1209         dup array? [
1210             dup [ array? ] all?
1211             [ array-flip ] [ generic-flip ] if
1212         ] [ generic-flip ] if
1213     ] unless ;