core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  38 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  39
  40 : empty? ( seq -- ? ) length 0 = ; inline
  41
  42 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  43     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  44
  45 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  46 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  47
  48 : delete-all ( seq -- ) 0 swap set-length ;
  49
  50 : first ( seq -- first ) 0 swap nth ; inline
  51 : second ( seq -- second ) 1 swap nth ; inline
  52 : third ( seq -- third ) 2 swap nth ; inline
  53 : fourth ( seq -- fourth ) 3 swap nth ; inline
  54
  55 : set-first ( first seq -- ) 0 swap set-nth ; inline
  56 : set-second ( second seq -- ) 1 swap set-nth ; inline
  57 : set-third ( third seq -- ) 2 swap set-nth ; inline
  58 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  59
  60 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  61
  62 ERROR: bounds-error index seq ;
  63
  64 GENERIC#: bounds-check? 1 ( n seq -- ? )
  65
  66 M: integer bounds-check?
  67     dupd length < [ 0 >= ] [ drop f ] if ; inline
  68
  69 : bounds-check ( n seq -- n seq )
  70     2dup bounds-check? [ bounds-error ] unless ; inline
  71
  72 MIXIN: immutable-sequence
  73
  74 ERROR: immutable element index sequence ;
  75
  76 M: immutable-sequence set-nth immutable ;
  77
  78 INSTANCE: immutable-sequence sequence
  79
  80 <PRIVATE
  81
  82 : array-nth ( n array -- elt )
  83     swap 2 fixnum+fast slot ; inline
  84
  85 : set-array-nth ( elt n array -- )
  86     swap 2 fixnum+fast set-slot ; inline
  87
  88 : dispatch ( n array -- ) array-nth call ;
  89
  90 GENERIC: resize ( n seq -- newseq ) flushable
  91
  92 ! Unsafe sequence protocol for inner loops
  93 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  94 GENERIC: set-nth-unsafe ( elt n seq -- )
  95
  96 M: sequence nth bounds-check nth-unsafe ; inline
  97 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  98
  99 M: sequence nth-unsafe nth ; inline
 100 M: sequence set-nth-unsafe set-nth ; inline
 101
 102 PRIVATE>
 103
 104 ! The f object supports the sequence protocol trivially
 105 M: f length drop 0 ; inline
 106 M: f nth-unsafe nip ; inline
 107 M: f like drop [ f ] when-empty ; inline
 108
 109 INSTANCE: f immutable-sequence
 110
 111 ! Integer sequences
 112 TUPLE: iota { n integer read-only } ;
 113
 114 : <iota> ( n -- iota )
 115     assert-non-negative iota boa ; inline
 116
 117 M: iota length n>> ; inline
 118 M: iota nth-unsafe drop ; inline
 119
 120 INSTANCE: iota immutable-sequence
 121
 122 <PRIVATE
 123
 124 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 125 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 126 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 127 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 128
 129 : first2-unsafe ( seq -- first second )
 130     [ first-unsafe ] [ second-unsafe ] bi ; inline
 131
 132 : first3-unsafe ( seq -- first second third )
 133     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 134
 135 : first4-unsafe ( seq -- first second third fourth )
 136     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 137
 138 : exchange-unsafe ( m n seq -- )
 139     [ [ nth-unsafe ] curry bi@ ]
 140     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 141
 142 : (1sequence) ( obj seq -- seq )
 143     [ 0 swap set-nth-unsafe ] keep ; inline
 144
 145 : (2sequence) ( obj1 obj2 seq -- seq )
 146     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 147
 148 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 149     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 153
 154 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 155
 156 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 157
 158 PRIVATE>
 159
 160 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 161
 162 : 1sequence ( obj exemplar -- seq )
 163     1 swap [ (1sequence) ] new-like ; inline
 164
 165 : 2sequence ( obj1 obj2 exemplar -- seq )
 166     2 swap [ (2sequence) ] new-like ; inline
 167
 168 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 169     3 swap [ (3sequence) ] new-like ; inline
 170
 171 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 172     4 swap [ (4sequence) ] new-like ; inline
 173
 174 : first2 ( seq -- first second )
 175     1 swap bounds-check nip first2-unsafe ; inline
 176
 177 : first3 ( seq -- first second third )
 178     2 swap bounds-check nip first3-unsafe ; inline
 179
 180 : first4 ( seq -- first second third fourth )
 181     3 swap bounds-check nip first4-unsafe ; inline
 182
 183 : ?nth ( n seq -- elt/f )
 184     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 185
 186 : ?set-nth ( elt n seq -- )
 187     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 188
 189 : index-or-length ( seq n -- seq n' ) over length min ; inline
 190
 191 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 192
 193 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 194 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 195 : ?last ( seq -- elt/f )
 196     index-of-last over 0 <
 197     [ 2drop f ] [ nth-unsafe ] if ; inline
 198
 199 MIXIN: virtual-sequence
 200 GENERIC: virtual-exemplar ( seq -- seq' )
 201 GENERIC: virtual@ ( n seq -- n' seq' )
 202
 203 M: virtual-sequence nth virtual@ nth ; inline
 204 M: virtual-sequence set-nth virtual@ set-nth ; inline
 205 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 206 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 207 M: virtual-sequence like virtual-exemplar like ; inline
 208 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 209
 210 INSTANCE: virtual-sequence sequence
 211
 212 ! all wrapped-sequence instances need to define a slot `seq` that is a sequence
 213 MIXIN: wrapped-sequence
 214 M: wrapped-sequence virtual-exemplar seq>> ; inline
 215 M: wrapped-sequence virtual@ seq>> ; inline
 216 M: wrapped-sequence length seq>> length ; inline
 217 INSTANCE: wrapped-sequence virtual-sequence
 218 TUPLE: sequence-view { seq sequence read-only } ;
 219
 220 INSTANCE: sequence-view wrapped-sequence
 221
 222 ! A reversal of an underlying sequence.
 223 TUPLE: reversed < sequence-view ;
 224
 225 C: <reversed> reversed
 226
 227 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 228
 229 ! A slice of another sequence.
 230 TUPLE: slice
 231     { from integer read-only }
 232     { to integer read-only }
 233     { seq read-only } ;
 234
 235 : >slice< ( slice -- from to seq )
 236     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 237
 238 : collapse-slice ( m n slice -- m' n' seq )
 239     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 240
 241 ERROR: slice-error from to seq ;
 242
 243 : check-slice ( from to seq -- from to seq )
 244     pick 0 < [ slice-error ] when
 245     2dup length > [ slice-error ] when
 246     2over > [ slice-error ] when ; inline
 247
 248 <PRIVATE
 249
 250 : <slice-unsafe> ( from to seq -- slice )
 251     dup slice? [ collapse-slice ] when slice boa ; inline
 252
 253 PRIVATE>
 254
 255 : <slice> ( from to seq -- slice )
 256     check-slice <slice-unsafe> ; inline
 257
 258 M: slice virtual-exemplar seq>> ; inline
 259
 260 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 261
 262 M: slice length [ to>> ] [ from>> ] bi - ; inline
 263
 264 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 265
 266 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 267
 268 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 269
 270 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 271
 272 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 273
 274 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 275
 276 INSTANCE: slice virtual-sequence
 277
 278 ! One element repeated many times
 279 TUPLE: repetition
 280     { length integer read-only }
 281     { elt read-only } ;
 282
 283 : <repetition> ( len elt -- repetition )
 284     [ assert-non-negative ] dip repetition boa ; inline
 285
 286 M: repetition length length>> ; inline
 287 M: repetition nth-unsafe nip elt>> ; inline
 288
 289 INSTANCE: repetition immutable-sequence
 290
 291 <PRIVATE
 292
 293 ERROR: integer-length-expected obj ;
 294
 295 ! The check-length call forces partial dispatch
 296 : check-length ( n -- n )
 297     dup integer? [ integer-length-expected ] unless ; inline
 298
 299 : >sequence< ( seq -- i n seq )
 300     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 301
 302 : length-sequence ( seq -- n seq )
 303     [ length check-length ] [ ] bi ; inline
 304
 305 : >underlying< ( slice/seq -- from to slice/seq )
 306     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 307
 308 TUPLE: copier
 309     { src-i integer read-only }
 310     { src read-only }
 311     { dst-i integer read-only }
 312     { dst read-only } ;
 313
 314 C: <copier> copier
 315
 316 : copy-nth-unsafe ( n copy -- )
 317     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 318     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 319
 320 : (copy) ( n copy -- dst )
 321     over 0 <= [ nip dst>> ] [
 322         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 323     ] if ; inline recursive
 324
 325 : subseq>copy ( from to seq -- n copy )
 326     [ over - check-length swap ] dip
 327     3dup nip new-sequence 0 swap <copier> ; inline
 328
 329 : bounds-check-head ( n seq -- n seq )
 330     over 0 < [ bounds-error ] when ; inline
 331
 332 : copy-unsafe ( src i dst -- )
 333     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 334
 335 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 336     [ subseq>copy (copy) ] dip like ; inline
 337
 338 : subseq-unsafe ( from to seq -- subseq )
 339     dup subseq-unsafe-as ; inline
 340
 341 : change-nth-unsafe ( i seq quot -- )
 342     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 343
 344 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 345
 346 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 347
 348 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 349     nth-of-unsafe set-nth-of-unsafe drop ; inline
 350
 351 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 352     2dup >= [
 353         4drop
 354     ] [
 355         [
 356             [ copy-nth-of-unsafe ] 4keep
 357             [ 1 + ] 2dip 1 +
 358         ] dip copy-loop
 359     ] if ; inline recursive
 360
 361 PRIVATE>
 362
 363 : subseq-as ( from to seq exemplar -- subseq )
 364     [ check-slice ] dip subseq-unsafe-as ;
 365
 366 : subseq ( from to seq -- subseq )
 367     dup subseq-as ;
 368
 369 : head ( seq n -- headseq ) head-to-index subseq ;
 370
 371 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 372
 373 : rest ( seq -- tailseq ) 1 tail ;
 374
 375 : head* ( seq n -- headseq ) from-tail head ;
 376
 377 : tail* ( seq n -- tailseq ) from-tail tail ;
 378
 379 : but-last ( seq -- headseq ) 1 head* ;
 380
 381 : copy ( src i dst -- )
 382     3dup bounds-check-head
 383     [ swap length + ] dip lengthen
 384     copy-unsafe ; inline
 385
 386 M: sequence clone-like
 387     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 388
 389 M: immutable-sequence clone-like like ; inline
 390
 391 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 392
 393 <PRIVATE
 394
 395 : (append) ( seq1 seq2 accum -- accum )
 396     [ [ over length ] dip copy-unsafe ]
 397     [ 0 swap copy-unsafe ]
 398     [ ] tri ; inline
 399
 400 PRIVATE>
 401
 402 : append-as ( seq1 seq2 exemplar -- newseq )
 403     [ 2dup 2length + ] dip
 404     [ (append) ] new-like ; inline
 405
 406 : append ( seq1 seq2 -- newseq ) over append-as ;
 407
 408 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 409
 410 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 411
 412 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 413     [ 3dup 3length + + ] dip [
 414         [ [ 2over 2length + ] dip copy-unsafe ]
 415         [ (append) ] bi
 416     ] new-like ; inline
 417
 418 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 419
 420 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 421     [ swap ] 2dip 3append-as ; inline
 422
 423 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 424
 425 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 426
 427 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 428
 429 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 430
 431 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 432
 433 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 434     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 435
 436 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 437
 438 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 439
 440 <PRIVATE
 441
 442 : sequence-operator ( seq quot -- i n quot' )
 443     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 444
 445 : length-iterator ( seq -- n quot' )
 446     length-sequence [ nth-unsafe ] curry ; inline
 447
 448 : length-operator ( seq quot -- n quot' )
 449     [ length-iterator ] dip compose ; inline
 450
 451 : collect-into ( quot into -- quot' )
 452     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 453
 454 : collect-from ( i n quot into -- )
 455     collect-into each-integer-from ; inline
 456
 457 : collect ( n quot into -- )
 458     collect-into each-integer ; inline
 459
 460 : sequence-index-operator ( seq quot -- n quot' )
 461     [ length-iterator [ keep ] curry ] dip compose ; inline
 462
 463 : map-into ( seq quot into -- )
 464     [ length-operator ] dip collect ; inline
 465
 466 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 467     [ nth-unsafe ] bi-curry@ bi ; inline
 468
 469 : 2length-iterator ( seq1 seq2 -- n quot )
 470     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 471
 472 : 2length-operator ( seq1 seq2 quot -- n quot' )
 473     [ 2length-iterator ] dip compose ; inline
 474
 475 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 476     [ nth-unsafe ] tri-curry@ tri ; inline
 477
 478 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 479     [ 3length min min check-length ]
 480     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 481
 482 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 483     [ 3length-iterator ] dip compose ; inline
 484
 485 : element/index ( i/f seq -- elt/f i/f )
 486     '[ [ _ nth ] [ f ] if* ] keep ; inline
 487
 488 : index/element ( i/f seq -- i/f elt/f )
 489     dupd '[ _ nth ] [ f ] if* ; inline
 490
 491 : (accumulate) ( seq identity quot -- identity seq quot' )
 492     swapd [ keepd ] curry ; inline
 493
 494 : (accumulate*) ( seq identity quot -- identity seq quot' )
 495     swapd [ dup ] compose ; inline
 496
 497 PRIVATE>
 498
 499 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 500     sequence-operator each-integer-from ; inline
 501
 502 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 503     -rot length-operator each-integer-from ; inline
 504
 505 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 506     swapd each ; inline
 507
 508 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 509     overd [ [ collect-from ] keep ] new-like ; inline
 510
 511 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 512     overd [ [ collect ] keep ] new-like ; inline
 513
 514 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 515     { } map-integers-as ; inline
 516
 517 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 518     [ length-operator ] dip map-integers-as ; inline
 519
 520 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 521     over map-as ; inline
 522
 523 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 524     [ [ drop ] prepose ] dip map-integers-as ; inline
 525
 526 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 527     { } replicate-as ; inline
 528
 529 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 530     over [ map-into ] keep ; inline
 531
 532 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 533     [ (accumulate) ] dip map-as ; inline
 534
 535 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 536     pick accumulate-as ; inline
 537
 538 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 539     (accumulate) map! ; inline
 540
 541 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 542     [ (accumulate*) ] dip map-as nip ; inline
 543
 544 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 545     pick accumulate*-as ; inline
 546
 547 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 548     (accumulate*) map! nip ; inline
 549
 550 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 551     2length-operator each-integer ; inline
 552
 553 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 554     -roll 2length-operator each-integer-from ; inline
 555
 556 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 557     -rotd 2each ; inline
 558
 559 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 560     [ 2length-operator ] dip map-integers-as ; inline
 561
 562 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 563     pick 2map-as ; inline
 564
 565 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 566     2length-operator all-integers? ; inline
 567
 568 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 569     negate 2all? not ; inline
 570
 571 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 572     3length-operator each-integer ; inline
 573
 574 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 575     [ 3length-operator ] dip map-integers-as ; inline
 576
 577 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 578     pickd swap 3map-as ; inline
 579
 580 <PRIVATE
 581
 582 : bounds-check-call ( n seq quot -- obj1 obj2 )
 583     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 584
 585 : do-find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 586     [ length-operator find-integer-from ] keepd ; inline
 587
 588 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 589     [ length-operator nip find-last-integer ] keepd ; inline
 590
 591 PRIVATE>
 592
 593 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 594     '[ _ do-find-from index/element ] bounds-check-call ; inline
 595
 596 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 597     [ 0 ] 2dip do-find-from index/element ; inline
 598
 599 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 600     '[ _ find-last-from-unsafe index/element ] bounds-check-call ; inline
 601
 602 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 603     [ index-of-last ] dip find-last-from ; inline
 604
 605 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 606     '[
 607         _ [ sequence-index-operator find-integer-from ] keepd
 608         index/element
 609     ] bounds-check-call ; inline
 610
 611 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 612     [ 0 ] 2dip find-index-from ; inline
 613
 614 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 615     sequence-operator all-integers-from? ; inline
 616
 617 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 618     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 619
 620 <PRIVATE
 621
 622 : (selector-as) ( quot length exemplar -- selector accum )
 623     new-resizable [ [ push-when ] 2curry ] keep ; inline
 624
 625 PRIVATE>
 626
 627 : selector-as ( quot exemplar -- selector accum )
 628     [ length ] keep (selector-as) ; inline
 629
 630 : selector ( quot -- selector accum )
 631     V{ } selector-as ; inline
 632
 633 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 634     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 635
 636 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 637     over filter-as ; inline
 638
 639 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 640     [ negate ] [ filter-as ] bi* ; inline
 641
 642 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 643     over reject-as ; inline
 644
 645 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 646     [ keep swap ] 2dip ? push ; inline
 647
 648 : 2selector ( quot -- selector accum1 accum2 )
 649     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 650
 651 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 652     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 653
 654 : collector-as ( quot exemplar -- quot' vec )
 655     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 656
 657 : collector ( quot -- quot' vec )
 658     V{ } collector-as ; inline
 659
 660 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 661     dup [ collector-as [ while ] dip ] curry dip like ; inline
 662
 663 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 664     { } produce-as ; inline
 665
 666 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 667     [ dup ] swap [ keep ] curry produce nip ; inline
 668
 669 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 670     sequence-index-operator each-integer ; inline
 671
 672 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 673     [ dup length <iota> ] 2dip 2map-as ; inline
 674
 675 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 676     over map-index-as ; inline
 677
 678 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 679     pick empty? [ 3drop ] [
 680         [ [ drop first-unsafe ] dip call ]
 681         [ [ bi* ] 2curry 1 each-from ]
 682         3bi
 683     ] if ; inline
 684
 685 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 686     swapd each-index ; inline
 687
 688 : index ( obj seq -- n )
 689     [ = ] with find drop ;
 690
 691 : index-from ( obj i seq -- n )
 692     rot [ = ] curry find-from drop ;
 693
 694 : last-index ( obj seq -- n )
 695     [ = ] with find-last drop ;
 696
 697 : last-index-from ( obj i seq -- n )
 698     rot [ = ] curry find-last-from drop ;
 699
 700 : indices ( obj seq -- indices )
 701     swap [ = ] curry [ swap ] prepose V{ } clone [
 702         [ push ] curry [ [ drop ] if ] curry compose each-index
 703     ] keep ;
 704
 705 <PRIVATE
 706
 707 : nths-unsafe ( indices seq -- seq' )
 708     [ [ nth-unsafe ] curry ] keep map-as ;
 709
 710 PRIVATE>
 711
 712 : nths ( indices seq -- seq' )
 713     [ [ nth ] curry ] keep map-as ;
 714
 715 : nths-of ( seq indices -- seq' )
 716     swap nths ; inline
 717
 718 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 719     find drop >boolean ; inline
 720
 721 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 722     any? not ; inline
 723
 724 : member? ( elt seq -- ? )
 725     [ = ] with any? ;
 726
 727 : member-eq? ( elt seq -- ? )
 728     [ eq? ] with any? ;
 729
 730 : remove ( elt seq -- newseq )
 731     [ = ] with reject ;
 732
 733 : remove-eq ( elt seq -- newseq )
 734     [ eq? ] with reject ;
 735
 736 : sift ( seq -- newseq )
 737     [ ] filter ;
 738
 739 : harvest ( seq -- newseq )
 740     [ empty? ] reject ;
 741
 742 <PRIVATE
 743
 744 : mismatch-unsafe ( n seq1 seq2 -- i )
 745     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 746
 747 PRIVATE>
 748
 749 : mismatch ( seq1 seq2 -- i )
 750     [ min-length ] 2keep mismatch-unsafe ;
 751
 752 M: sequence <=>
 753     [ mismatch ] 2keep pick
 754     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 755
 756 : sequence= ( seq1 seq2 -- ? )
 757     2dup 2length dupd =
 758     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 759
 760 ERROR: assert-sequence got expected ;
 761
 762 : assert-sequence= ( a b -- )
 763     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 764
 765 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 766
 767 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 768
 769 <PRIVATE
 770
 771 : sequence-hashcode-step ( oldhash newpart -- newhash )
 772     integer>fixnum swap [
 773         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 774         fixnum+fast fixnum+fast
 775     ] keep fixnum-bitxor ; inline
 776
 777 PRIVATE>
 778
 779 : sequence-hashcode ( n seq -- x )
 780     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 781
 782 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 783
 784 M: iota hashcode*
 785     over 0 <= [ 2drop 0 ] [
 786         nip length 0 swap [ sequence-hashcode-step ] each-integer
 787     ] if ;
 788
 789 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 790
 791 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 792
 793 : move ( to from seq -- )
 794     2over =
 795     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 796
 797 <PRIVATE
 798
 799 : move-unsafe* ( to from seq -- from-nth )
 800     2over =
 801     [ nth-unsafe nip ]
 802     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 803
 804 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 805     2over length < [
 806         [ [ move-unsafe* ] dip call ] 4keep
 807         [ swap [ 1 + ] when ] 3dip
 808         [ 1 + ] 2dip filter-from!
 809     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 810
 811 : move-unsafe ( to from seq -- )
 812     2over =
 813     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 814
 815 PRIVATE>
 816
 817 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 818     [ 0 0 ] 2dip filter-from! ; inline
 819
 820 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 821     negate filter! ; inline
 822
 823 : remove! ( elt seq -- seq )
 824     [ = ] with reject! ;
 825
 826 : remove-eq! ( elt seq -- seq )
 827     [ eq? ] with reject! ;
 828
 829 : prefix ( seq elt -- newseq )
 830     over [ over length 1 + ] dip [
 831         (1sequence) [ 1 swap copy-unsafe ] keep
 832     ] new-like ;
 833
 834 : suffix ( seq elt -- newseq )
 835     over [ over length 1 + ] dip [
 836         [ [ over length ] dip set-nth-unsafe ] keep
 837         [ 0 swap copy-unsafe ] keep
 838     ] new-like ;
 839
 840 : suffix! ( seq elt -- seq ) over push ; inline
 841
 842 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 843
 844 : last ( seq -- elt )
 845     index-of-last
 846     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 847
 848 <PRIVATE
 849
 850 : last-unsafe ( seq -- elt )
 851     index-of-last nth-unsafe ; inline
 852
 853 PRIVATE>
 854
 855 : set-last ( elt seq -- )
 856     index-of-last
 857     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 858
 859 : pop* ( seq -- ) index-of-last shorten ;
 860
 861 <PRIVATE
 862
 863 : move-backward ( shift from to seq -- )
 864     2over = [
 865         4drop
 866     ] [
 867         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 868         move-backward
 869     ] if ;
 870
 871 : open-slice ( shift from seq -- )
 872     pick 0 = [
 873         3drop
 874     ] [
 875         [ ] [ nip length + ] [ 2nip ] 3tri
 876         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 877         set-length
 878     ] if ;
 879
 880 PRIVATE>
 881
 882 : delete-slice ( from to seq -- )
 883     check-slice [ over [ - ] dip ] dip open-slice ;
 884
 885 : remove-nth! ( n seq -- seq )
 886     [ [ dup 1 + ] dip delete-slice ] keep ;
 887
 888 : snip ( from to seq -- head tail )
 889     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 890
 891 : snip-slice ( from to seq -- head tail )
 892     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 893
 894 : replace-slice ( new from to seq -- seq' )
 895     snip-slice surround ;
 896
 897 : remove-nth ( n seq -- seq' )
 898     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 899
 900 : pop ( seq -- elt )
 901     index-of-last over 0 >=
 902     [ [ nth-unsafe ] [ shorten ] 2bi ]
 903     [ bounds-error ] if ;
 904
 905 : exchange ( m n seq -- )
 906     [ nip bounds-check 2drop ]
 907     [ bounds-check 3drop ]
 908     [ exchange-unsafe ]
 909     3tri ;
 910
 911 : midpoint@ ( seq -- n ) length 2/ ; inline
 912
 913 : reverse! ( seq -- seq )
 914     [
 915         [ midpoint@ ] [ length ] [ ] tri
 916         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 917         each-integer
 918     ] keep ;
 919
 920 : reverse ( seq -- newseq )
 921     [
 922         dup [ length ] keep new-sequence
 923         [ 0 swap copy-unsafe ] keep reverse!
 924     ] keep like ;
 925
 926 GENERIC: sum-lengths ( seq -- n )
 927
 928 M: object sum-lengths
 929     0 [ length + ] reduce ;
 930
 931 M: repetition sum-lengths
 932     [ length>> ] [ elt>> length ] bi * ;
 933
 934 : concat-as ( seq exemplar -- newseq )
 935     [
 936         [ dup sum-lengths ] dip new-resizable
 937         [ [ push-all ] curry each ] keep
 938     ] keep like ; inline
 939
 940 : concat ( seq -- newseq )
 941     [ { } ] [ dup first concat-as ] if-empty ;
 942
 943 <PRIVATE
 944
 945 : joined-length ( seq glue -- n )
 946     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 947
 948 PRIVATE>
 949
 950 : join-as ( seq glue exemplar -- newseq )
 951     over empty? [ nip concat-as ] [
 952         [
 953             2dup joined-length over new-resizable [
 954                 [ [ push-all ] 2curry ]
 955                 [ nip [ push-all ] curry ] 2bi
 956                 interleave
 957             ] keep
 958         ] dip like
 959     ] if ;
 960
 961 : join ( seq glue -- newseq )
 962     dup join-as ; inline
 963
 964 <PRIVATE
 965
 966 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 967     [
 968         [ over length [-] dup 0 = [ drop ] ] dip
 969         [ <repetition> ] curry
 970     ] dip compose if ; inline
 971
 972 PRIVATE>
 973
 974 : pad-head ( seq n elt -- padded )
 975     [ swap dup append-as ] padding ;
 976
 977 : pad-tail ( seq n elt -- padded )
 978     [ append ] padding ;
 979
 980 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
 981 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
 982 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
 983 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
 984
 985 : head? ( seq begin -- ? )
 986     2dup shorter? [
 987         2drop f
 988     ] [
 989         [ length [ head-slice ] keep swap ] keep
 990         mismatch-unsafe not
 991     ] if ;
 992
 993 : tail? ( seq end -- ? )
 994     2dup shorter? [
 995         2drop f
 996     ] [
 997         [ length [ tail-slice* ] keep swap ] keep
 998         mismatch-unsafe not
 999     ] if ;
1000
1001 : cut-slice ( seq n -- before-slice after-slice )
1002     [ head-slice ] [ tail-slice ] 2bi ; inline
1003
1004 : cut-slice* ( seq n -- before-slice after-slice )
1005     [ head-slice* ] [ tail-slice* ] 2bi ;
1006
1007 : insert-nth ( elt n seq -- seq' )
1008     swap cut-slice [ swap suffix ] dip append ;
1009
1010 : halves ( seq -- first-slice second-slice )
1011     dup midpoint@ cut-slice ; inline
1012
1013 <PRIVATE
1014
1015 : nth2-unsafe ( n seq -- a b )
1016     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1017
1018 : nth3-unsafe ( n seq -- a b c )
1019     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1020
1021 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1022     ! We can't use case here since combinators depends on
1023     ! sequences
1024     dup 4 < [
1025         integer>fixnum {
1026             [ 2drop nip ]
1027             [ 2nip swap nth-unsafe ]
1028             [ -rot [ drop swap nth2-unsafe ] dip call ]
1029             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1030         } dispatch
1031     ] [
1032         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1033         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1034         pick [ 3bi ] dip call
1035     ] if ; inline recursive
1036
1037 PRIVATE>
1038
1039 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1040     pick dup slice? [
1041         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1042     ] [
1043         length 0 max 0 swap
1044     ] if (binary-reduce) ; inline
1045
1046 : cut ( seq n -- before after )
1047     [ head ] [ tail ] 2bi ;
1048
1049 : cut* ( seq n -- before after )
1050     [ head* ] [ tail* ] 2bi ;
1051
1052 : subseq-starts-at? ( i seq subseq -- ? )
1053     [ length swap ] keep
1054     '[
1055         [ + _ nth-unsafe ] keep _ nth-unsafe =
1056     ] with all-integers? ; inline
1057
1058 : subseq-index-from ( n seq subseq -- i/f )
1059     [ 2length - 1 + ] 2keep
1060     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1061
1062 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1063
1064 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1065
1066 : subseq-start-from ( subseq seq n -- i/f )
1067     spin subseq-index-from ; inline deprecated
1068
1069 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1070
1071 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1072
1073 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1074     2dup mismatch [ 2dup min-length ] unless*
1075     [ tail-slice ] curry bi@ ;
1076
1077 : unclip ( seq -- rest first )
1078     [ rest ] [ first-unsafe ] bi ;
1079
1080 : unclip-last ( seq -- butlast last )
1081     [ but-last ] [ last-unsafe ] bi ;
1082
1083 : unclip-slice ( seq -- rest-slice first )
1084     [ rest-slice ] [ first-unsafe ] bi ; inline
1085
1086 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1087     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1088     '[ swap _ dip swap @ ] 1 each-from ; inline
1089
1090 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1091     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1092     '[ rot _ dip swap @ ] 1 2each-from ; inline
1093
1094 <PRIVATE
1095
1096 : (map-find) ( seq quot find-quot -- result elt )
1097     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1098
1099 PRIVATE>
1100
1101 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1102     [ find ] (map-find) ; inline
1103
1104 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1105     [ find-last ] (map-find) ; inline
1106
1107 : unclip-last-slice ( seq -- butlast-slice last )
1108     [ but-last-slice ] [ last-unsafe ] bi ; inline
1109
1110 <PRIVATE
1111
1112 : (trim-head) ( seq quot -- seq n )
1113     over [ negate find drop ] dip swap
1114     [ dup length ] unless* ; inline
1115
1116 : (trim-tail) ( seq quot -- seq n )
1117     over [ negate find-last drop ?1+ ] dip
1118     swap ; inline
1119
1120 PRIVATE>
1121
1122 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1123     (trim-head) tail-slice ; inline
1124
1125 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1126     (trim-head) tail ; inline
1127
1128 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1129     (trim-tail) head-slice ; inline
1130
1131 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1132     (trim-tail) head ; inline
1133
1134 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1135     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1136
1137 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1138     [ trim-slice ] [ drop ] 2bi like ; inline
1139
1140 GENERIC: sum ( seq -- n )
1141 M: object sum 0 [ + ] binary-reduce ; inline
1142 M: iota sum length dup 1 - * 2/ ; inline
1143 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1144
1145 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1146
1147 GENERIC: infimum ( seq -- elt )
1148 M: object infimum [ ] [ min ] map-reduce ;
1149 M: iota infimum first ;
1150 M: reversed infimum seq>> infimum ;
1151
1152 GENERIC: supremum ( seq -- elt )
1153 M: object supremum [ ] [ max ] map-reduce ;
1154 M: iota supremum last ;
1155 M: reversed supremum seq>> supremum ;
1156
1157 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1158     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1159
1160 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1161     [ 1 0 ? ] compose map-sum ; inline
1162
1163 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1164     [ with each ] 2curry each ; inline
1165
1166 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1167     [ with { } map-as ] 2curry { } map-as ; inline
1168
1169 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1170     [ 2sequence ] curry cartesian-map ; inline
1171
1172 : cartesian-product ( seq1 seq2 -- newseq )
1173     dup cartesian-product-as ; inline
1174
1175 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1176     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1177
1178 <PRIVATE
1179
1180 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1181     [
1182         [ keep swap ] curry [ [ first ] dip call ] 2keep
1183         [ curry 2dip pick over ] curry
1184     ] [
1185         [ [ 2drop ] [ 2nipd ] if ] compose
1186     ] bi* compose 1 each-from drop ; inline
1187
1188 PRIVATE>
1189
1190 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1191     [ after? ] select-by ; inline
1192
1193 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1194     [ before? ] select-by ; inline
1195
1196 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1197
1198 : longest ( seqs -- elt ) [ length ] supremum-by ;
1199
1200 ! We hand-optimize flip to such a degree because type hints
1201 ! cannot express that an array is an array of arrays yet, and
1202 ! this word happens to be performance-critical since the compiler
1203 ! itself uses it. Optimizing it like this reduced compile time.
1204 <PRIVATE
1205
1206 : generic-flip ( matrix -- newmatrix )
1207     [ [ length ] [ min ] map-reduce ] keep
1208     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1209
1210 USE: arrays
1211
1212 : array-flip ( matrix -- newmatrix )
1213     { array } declare
1214     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1215     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1216
1217 PRIVATE>
1218
1219 : flip ( matrix -- newmatrix )
1220     dup empty? [
1221         dup array? [
1222             dup [ array? ] all?
1223             [ array-flip ] [ generic-flip ] if
1224         ] [ generic-flip ] if
1225     ] unless ;