core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 GENERIC#: seq-lengthen 1 ( seq n -- seq )
  38 GENERIC#: seq-shorten 1 ( seq n -- seq )
  39
  40 : seq-set-length ( seq n -- seq ) [ swap set-length ] keepd ; inline
  41 : nth-of ( seq n -- elt ) swap nth ; inline
  42 : set-nth-of ( seq n elt -- seq ) swap rot [ set-nth ] keep ; inline
  43
  44 M: sequence seq-lengthen 2dup lengthd < [ seq-set-length ] [ drop ] if ; inline
  45 M: sequence seq-shorten 2dup lengthd > [ seq-set-length ] [ drop ] if ; inline
  46
  47 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  48 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  49
  50 : empty? ( seq -- ? ) length 0 = ; inline
  51
  52 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  53     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  54
  55 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  56 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  57
  58 : delete-all ( seq -- ) 0 swap set-length ;
  59
  60 : first ( seq -- first ) 0 swap nth ; inline
  61 : second ( seq -- second ) 1 swap nth ; inline
  62 : third ( seq -- third ) 2 swap nth ; inline
  63 : fourth ( seq -- fourth ) 3 swap nth ; inline
  64
  65 : set-first ( first seq -- ) 0 swap set-nth ; inline
  66 : set-second ( second seq -- ) 1 swap set-nth ; inline
  67 : set-third ( third seq -- ) 2 swap set-nth ; inline
  68 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  69
  70 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  71
  72 : seq-push ( seq elt -- seq ) [ dup length ] dip set-nth-of ;
  73
  74 ERROR: bounds-error index seq ;
  75
  76 GENERIC#: bounds-check? 1 ( n seq -- ? )
  77
  78 M: integer bounds-check?
  79     dupd length < [ 0 >= ] [ drop f ] if ; inline
  80
  81 GENERIC: seq-bounds-check? ( seq n -- ? )
  82
  83 M: integer seq-bounds-check?
  84     tuck lengthd > [ 0 >= ] [ drop f ] if ; inline
  85
  86 : bounds-check ( n seq -- n seq )
  87     2dup bounds-check? [ bounds-error ] unless ; inline
  88
  89 : seq-bounds-check ( seq n -- seq n )
  90     2dup seq-bounds-check? [ swap bounds-error ] unless ; inline
  91
  92 MIXIN: immutable-sequence
  93
  94 ERROR: immutable element index sequence ;
  95
  96 M: immutable-sequence set-nth immutable ;
  97
  98 INSTANCE: immutable-sequence sequence
  99
 100 <PRIVATE
 101
 102 : array-nth ( n array -- elt )
 103     swap 2 fixnum+fast slot ; inline
 104
 105 : set-array-nth ( elt n array -- )
 106     swap 2 fixnum+fast set-slot ; inline
 107
 108 : dispatch ( n array -- ) array-nth call ;
 109
 110 GENERIC: resize ( n seq -- newseq ) flushable
 111
 112 ! Unsafe sequence protocol for inner loops
 113 GENERIC: nth-unsafe ( n seq -- elt ) flushable
 114 GENERIC: set-nth-unsafe ( elt n seq -- )
 115
 116 M: sequence nth bounds-check nth-unsafe ; inline
 117 M: sequence set-nth bounds-check set-nth-unsafe ; inline
 118
 119 M: sequence nth-unsafe nth ; inline
 120 M: sequence set-nth-unsafe set-nth ; inline
 121
 122 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 123
 124 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 125
 126 : change-nth-unsafe ( i seq quot -- )
 127     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 128
 129 : change-nth-of-unsafe ( seq i quot -- seq )
 130     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 131
 132 PRIVATE>
 133
 134 ! The f object supports the sequence protocol trivially
 135 M: f length drop 0 ; inline
 136 M: f nth-unsafe nip ; inline
 137 M: f like drop [ f ] when-empty ; inline
 138
 139 INSTANCE: f immutable-sequence
 140
 141 ! Integer sequences
 142 TUPLE: iota { n integer read-only } ;
 143
 144 ERROR: non-negative-integer-expected n ;
 145
 146 : ensure-non-negative ( n -- n )
 147     dup 0 < [ non-negative-integer-expected ] when ; inline
 148
 149 : <iota> ( n -- iota )
 150     ensure-non-negative iota boa ; inline
 151
 152 M: iota length n>> ; inline
 153 M: iota nth-unsafe drop ; inline
 154
 155 INSTANCE: iota immutable-sequence
 156
 157 <PRIVATE
 158
 159 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 160 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 161 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 162 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 163
 164 : first2-unsafe ( seq -- first second )
 165     [ first-unsafe ] [ second-unsafe ] bi ; inline
 166
 167 : first3-unsafe ( seq -- first second third )
 168     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 169
 170 : first4-unsafe ( seq -- first second third fourth )
 171     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 172
 173 : exchange-unsafe ( m n seq -- )
 174     [ [ nth-unsafe ] curry bi@ ]
 175     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 176
 177 : (1sequence) ( obj seq -- seq )
 178     [ 0 swap set-nth-unsafe ] keep ; inline
 179
 180 : (2sequence) ( obj1 obj2 seq -- seq )
 181     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 182
 183 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 184     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 185
 186 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 187     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 188
 189 PRIVATE>
 190
 191 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 192
 193 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 194
 195 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 196
 197 : 1sequence ( obj exemplar -- seq )
 198     1 swap [ (1sequence) ] new-like ; inline
 199
 200 : 2sequence ( obj1 obj2 exemplar -- seq )
 201     2 swap [ (2sequence) ] new-like ; inline
 202
 203 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 204     3 swap [ (3sequence) ] new-like ; inline
 205
 206 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 207     4 swap [ (4sequence) ] new-like ; inline
 208
 209 : first2 ( seq -- first second )
 210     1 swap bounds-check nip first2-unsafe ; inline
 211
 212 : first3 ( seq -- first second third )
 213     2 swap bounds-check nip first3-unsafe ; inline
 214
 215 : first4 ( seq -- first second third fourth )
 216     3 swap bounds-check nip first4-unsafe ; inline
 217
 218 : ??nth ( n seq -- elt/f ? )
 219     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 220
 221 : ?nth ( n seq -- elt/f )
 222     ??nth drop ; inline
 223
 224 : ?set-nth ( elt n seq -- )
 225     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 226
 227 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 228
 229 : ??nth-of ( seq n -- elt ? ) swap ??nth ; inline
 230
 231 : index-or-length ( seq n -- seq n' ) over length min ; inline
 232
 233 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 234
 235 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 236 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 237 : ?last ( seq -- elt/f )
 238     index-of-last over 0 <
 239     [ 2drop f ] [ nth-unsafe ] if ; inline
 240
 241 MIXIN: virtual-sequence
 242 GENERIC: virtual-exemplar ( seq -- seq' )
 243 GENERIC: virtual@ ( n seq -- n' seq' )
 244
 245 M: virtual-sequence nth virtual@ nth ; inline
 246 M: virtual-sequence set-nth virtual@ set-nth ; inline
 247 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 248 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 249 M: virtual-sequence like virtual-exemplar like ; inline
 250 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 251
 252 INSTANCE: virtual-sequence sequence
 253
 254 ! A reversal of an underlying sequence.
 255 TUPLE: reversed { seq read-only } ;
 256
 257 C: <reversed> reversed
 258
 259 M: reversed virtual-exemplar seq>> ; inline
 260 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 261 M: reversed length seq>> length ; inline
 262
 263 INSTANCE: reversed virtual-sequence
 264
 265 ! A slice of another sequence.
 266 TUPLE: slice
 267     { from integer read-only }
 268     { to integer read-only }
 269     { seq read-only } ;
 270
 271 : >slice< ( slice -- from to seq )
 272     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 273
 274 : collapse-slice ( m n slice -- m' n' seq )
 275     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 276
 277 ERROR: slice-error from to seq ;
 278
 279 : check-slice ( from to seq -- from to seq )
 280     pick 0 < [ slice-error ] when
 281     2dup length > [ slice-error ] when
 282     2over > [ slice-error ] when ; inline
 283
 284 <PRIVATE
 285
 286 : <slice-unsafe> ( from to seq -- slice )
 287     dup slice? [ collapse-slice ] when slice boa ; inline
 288
 289 PRIVATE>
 290
 291 : <slice> ( from to seq -- slice )
 292     check-slice <slice-unsafe> ; inline
 293
 294 M: slice virtual-exemplar seq>> ; inline
 295
 296 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 297
 298 M: slice length [ to>> ] [ from>> ] bi - ; inline
 299
 300 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 301
 302 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 303
 304 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 305
 306 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 307
 308 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 309
 310 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 311
 312 INSTANCE: slice virtual-sequence
 313
 314 ! One element repeated many times
 315 TUPLE: repetition
 316     { length integer read-only }
 317     { elt read-only } ;
 318
 319 : <repetition> ( len elt -- repetition )
 320     over 0 < [ non-negative-integer-expected ] when
 321     repetition boa ; inline
 322
 323 M: repetition length length>> ; inline
 324 M: repetition nth-unsafe nip elt>> ; inline
 325
 326 INSTANCE: repetition immutable-sequence
 327
 328 <PRIVATE
 329
 330 ERROR: integer-length-expected obj ;
 331
 332 ! The check-length call forces partial dispatch
 333 : check-length ( n -- n )
 334     dup integer? [ integer-length-expected ] unless ; inline
 335
 336 : >sequence< ( seq -- i n seq )
 337     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 338
 339 : length-sequence ( seq -- n seq )
 340     [ length check-length ] [ ] bi ; inline
 341
 342 : >underlying< ( slice/seq -- from to slice/seq )
 343     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 344
 345 TUPLE: copier
 346     { src-i integer read-only }
 347     { src read-only }
 348     { dst-i integer read-only }
 349     { dst read-only } ;
 350
 351 C: <copier> copier
 352
 353 : copy-nth-unsafe ( n copy -- )
 354     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 355     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 356
 357 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 358     nth-of-unsafe set-nth-of-unsafe drop ; inline
 359
 360 : (copy) ( n copy -- dst )
 361     over 0 <= [ nip dst>> ] [
 362         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 363     ] if ; inline recursive
 364
 365 : seq-copy-loop ( dst dst-i src src-i src-stop -- dst )
 366     2dup >= [
 367         4drop
 368     ] [
 369         [
 370             [ copy-nth-of-unsafe ] 4keep
 371             [ 1 + ] 2dip 1 +
 372         ] dip seq-copy-loop
 373     ] if ; inline recursive
 374
 375 : subseq>copy ( from to seq -- n copy )
 376     [ over - check-length swap ] dip
 377     3dup nip new-sequence 0 swap <copier> ; inline
 378
 379 : bounds-check-head ( n seq -- n seq )
 380     over 0 < [ bounds-error ] when ; inline
 381
 382 : check-grow-copy ( dst n src -- dst src n )
 383     over [ lengthd + lengthen ] 2keep ; inline
 384
 385 : seq-grow-copy ( dst n -- dst dst-n )
 386     [ over length + seq-lengthen ] keep 1 - ; inline
 387
 388 : copy-unsafe ( src i dst -- )
 389     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 390
 391 : seq-copy-unsafe ( dst dst-i src -- dst )
 392     0 over length check-length seq-copy-loop ; inline
 393
 394 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 395     [ subseq>copy (copy) ] dip like ; inline
 396
 397 : subseq-unsafe ( from to seq -- subseq )
 398     dup subseq-unsafe-as ; inline
 399
 400 PRIVATE>
 401
 402 : subseq-as ( from to seq exemplar -- subseq )
 403     [ check-slice ] dip subseq-unsafe-as ;
 404
 405 : subseq ( from to seq -- subseq )
 406     dup subseq-as ;
 407
 408 : head ( seq n -- headseq ) head-to-index subseq ;
 409
 410 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 411
 412 : rest ( seq -- tailseq ) 1 tail ;
 413
 414 : head* ( seq n -- headseq ) from-tail head ;
 415
 416 : tail* ( seq n -- tailseq ) from-tail tail ;
 417
 418 : but-last ( seq -- headseq ) 1 head* ;
 419
 420 : copy ( src i dst -- )
 421     3dup bounds-check-head
 422     [ swap length + ] dip lengthen
 423     copy-unsafe ; inline
 424
 425 : seq-copy ( dst dst-n src -- dst ) check-grow-copy seq-copy-unsafe ; inline
 426
 427 M: sequence clone-like
 428     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 429
 430 M: immutable-sequence clone-like like ; inline
 431
 432 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 433
 434 : seq-push-all ( dst src -- dst ) [ length seq-grow-copy ] keep seq-copy-unsafe ; inline
 435
 436 <PRIVATE
 437
 438 : (append) ( seq1 seq2 accum -- accum )
 439     [ [ over length ] dip copy-unsafe ]
 440     [ 0 swap copy-unsafe ]
 441     [ ] tri ; inline
 442
 443 : (seq-append) ( accum seq1 seq2 -- accum )
 444     [
 445         [ 0 ] dip [ seq-copy-unsafe ] [ length ] bi
 446     ] dip seq-copy-unsafe ; inline
 447
 448 PRIVATE>
 449
 450 : seq-append-as ( seq1 seq2 exemplar -- newseq )
 451     [ 2dup 2length + ] dip
 452     [ -rot (seq-append) ] new-like ; inline
 453
 454 : append-as ( seq1 seq2 exemplar -- newseq )
 455     [ 2dup 2length + ] dip
 456     [ (append) ] new-like ; inline
 457
 458 : append ( seq1 seq2 -- newseq ) over append-as ;
 459
 460 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 461
 462 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 463
 464 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 465     [ 3dup 3length + + ] dip [
 466         [ [ 2over 2length + ] dip copy-unsafe ]
 467         [ (append) ] bi
 468     ] new-like ; inline
 469
 470 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 471
 472 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 473     [ swap ] 2dip 3append-as ; inline
 474
 475 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 476
 477 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 478
 479 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 480
 481 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 482
 483 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 484
 485 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 486     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 487
 488 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 489
 490 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 491
 492 <PRIVATE
 493
 494 : sequence-operator ( seq quot -- i n quot' )
 495     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 496
 497 : length-iterator ( seq -- n quot' )
 498     length-sequence [ nth-unsafe ] curry ; inline
 499
 500 : length-operator ( seq quot -- n quot' )
 501     [ length-iterator ] dip compose ; inline
 502
 503 : collect-into ( quot into -- quot' )
 504     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 505
 506 : collect-from ( i n quot into -- )
 507     collect-into each-integer-from ; inline
 508
 509 : collect ( n quot into -- )
 510     collect-into each-integer ; inline
 511
 512 : sequence-index-operator ( seq quot -- n quot' )
 513     [ length-iterator [ keep ] curry ] dip compose ; inline
 514
 515 : map-into ( seq quot into -- )
 516     [ length-operator ] dip collect ; inline
 517
 518 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 519     [ nth-unsafe ] bi-curry@ bi ; inline
 520
 521 : 2length-iterator ( seq1 seq2 -- n quot )
 522     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 523
 524 : 2length-operator ( seq1 seq2 quot -- n quot' )
 525     [ 2length-iterator ] dip compose ; inline
 526
 527 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 528     [ nth-unsafe ] tri-curry@ tri ; inline
 529
 530 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 531     [ 3length min min check-length ]
 532     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 533
 534 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 535     [ 3length-iterator ] dip compose ; inline
 536
 537 : element/index ( i/f seq -- elt/f i/f )
 538     '[ [ _ nth ] [ f ] if* ] keep ; inline
 539
 540 : index/element ( i/f seq -- i/f elt/f )
 541     dupd '[ _ nth ] [ f ] if* ; inline
 542
 543 : (accumulate) ( seq identity quot -- identity seq quot' )
 544     swapd [ keepd ] curry ; inline
 545
 546 : (accumulate*) ( seq identity quot -- identity seq quot' )
 547     swapd [ dup ] compose ; inline
 548
 549 PRIVATE>
 550
 551 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 552     sequence-operator each-integer-from ; inline
 553
 554 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 555     -rot length-operator each-integer-from ; inline
 556
 557 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 558     swapd each ; inline
 559
 560 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 561     overd [ [ collect-from ] keep ] new-like ; inline
 562
 563 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 564     overd [ [ collect ] keep ] new-like ; inline
 565
 566 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 567     { } map-integers-as ; inline
 568
 569 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 570     [ length-operator ] dip map-integers-as ; inline
 571
 572 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 573     over map-as ; inline
 574
 575 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 576     [ [ drop ] prepose ] dip map-integers-as ; inline
 577
 578 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 579     { } replicate-as ; inline
 580
 581 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 582     over [ map-into ] keep ; inline
 583
 584 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 585     [ (accumulate) ] dip map-as ; inline
 586
 587 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 588     pick accumulate-as ; inline
 589
 590 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 591     (accumulate) map! ; inline
 592
 593 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 594     [ (accumulate*) ] dip map-as nip ; inline
 595
 596 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 597     pick accumulate*-as ; inline
 598
 599 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 600     (accumulate*) map! nip ; inline
 601
 602 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 603     2length-operator each-integer ; inline
 604
 605 : 2each-from ( ... from seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 606     2length-operator each-integer-from ; inline
 607
 608 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 609     -rotd 2each ; inline
 610
 611 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 612     [ 2length-operator ] dip map-integers-as ; inline
 613
 614 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 615     pick 2map-as ; inline
 616
 617 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 618     2length-operator all-integers? ; inline
 619
 620 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 621     negate 2all? not ; inline
 622
 623 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 624     3length-operator each-integer ; inline
 625
 626 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 627     [ 3length-operator ] dip map-integers-as ; inline
 628
 629 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 630     pickd swap 3map-as ; inline
 631
 632 <PRIVATE
 633
 634 : bounds-check-call ( n seq quot -- elt i )
 635     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 636
 637 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 638     [ length-operator find-integer-from ] keepd
 639     index/element ; inline
 640
 641 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 642     [ length-operator nip find-last-integer ] keepd
 643     index/element ; inline
 644
 645 PRIVATE>
 646
 647 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 648     '[ _ find-from-unsafe ] bounds-check-call ; inline
 649
 650 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 651     [ 0 ] 2dip find-from-unsafe ; inline
 652
 653 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 654     '[ _ find-last-from-unsafe ] bounds-check-call ; inline
 655
 656 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 657     [ index-of-last ] dip find-last-from ; inline
 658
 659 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 660     '[
 661         _ [ sequence-index-operator find-integer-from ] keepd
 662         index/element
 663     ] bounds-check-call ; inline
 664
 665 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 666     [ 0 ] 2dip find-index-from ; inline
 667
 668 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 669     sequence-operator all-integers-from? ; inline
 670
 671 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 672     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 673
 674 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
 675     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 676
 677 <PRIVATE
 678
 679 : (selector-as) ( quot length exemplar -- selector accum )
 680     new-resizable [ [ push-when ] 2curry ] keep ; inline
 681
 682 PRIVATE>
 683
 684 : selector-as ( quot exemplar -- selector accum )
 685     [ length ] keep (selector-as) ; inline
 686
 687 : selector ( quot -- selector accum )
 688     V{ } selector-as ; inline
 689
 690 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 691     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 692
 693 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 694     over filter-as ; inline
 695
 696 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 697     [ negate ] [ filter-as ] bi* ; inline
 698
 699 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 700     over reject-as ; inline
 701
 702 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 703     [ keep swap ] 2dip ? push ; inline
 704
 705 : 2selector ( quot -- selector accum1 accum2 )
 706     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 707
 708 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 709     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 710
 711 : collector-as ( quot exemplar -- quot' vec )
 712     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 713
 714 : collector ( quot -- quot' vec )
 715     V{ } collector-as ; inline
 716
 717 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 718     dup [ collector-as [ while ] dip ] curry dip like ; inline
 719
 720 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 721     { } produce-as ; inline
 722
 723 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 724     [ dup ] swap [ keep ] curry produce nip ; inline
 725
 726 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 727     sequence-index-operator each-integer ; inline
 728
 729 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 730     [ dup length <iota> ] 2dip 2map-as ; inline
 731
 732 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 733     over map-index-as ; inline
 734
 735 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 736     pick empty? [ 3drop ] [
 737         [ [ drop first-unsafe ] dip call ]
 738         [ [ bi* ] 2curry 1 each-from ]
 739         3bi
 740     ] if ; inline
 741
 742 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 743     swapd each-index ; inline
 744
 745 : index ( obj seq -- n )
 746     [ = ] with find drop ;
 747
 748 : index-from ( obj i seq -- n )
 749     rot [ = ] curry find-from drop ;
 750
 751 : last-index ( obj seq -- n )
 752     [ = ] with find-last drop ;
 753
 754 : last-index-from ( obj i seq -- n )
 755     rot [ = ] curry find-last-from drop ;
 756
 757 : with-assoc ( assoc quot: ( ..a value key assoc -- ..b ) -- quot: ( ..a key value -- ..b ) )
 758     curry [ swap ] prepose ; inline
 759
 760 : indices ( obj seq -- indices )
 761     swap [ = ] with-assoc V{ } clone [
 762         [ push ] curry [ [ drop ] if ] curry compose each-index
 763     ] keep ;
 764
 765 <PRIVATE
 766
 767 : nths-unsafe ( indices seq -- seq' )
 768     [ [ nth-unsafe ] curry ] keep map-as ;
 769
 770 PRIVATE>
 771
 772 : nths ( indices seq -- seq' )
 773     [ [ nth ] curry ] keep map-as ;
 774
 775 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 776     find drop >boolean ; inline
 777
 778 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 779     any? not ; inline
 780
 781 : member? ( elt seq -- ? )
 782     [ = ] with any? ;
 783
 784 : member-eq? ( elt seq -- ? )
 785     [ eq? ] with any? ;
 786
 787 : remove ( elt seq -- newseq )
 788     [ = ] with reject ;
 789
 790 : remove-eq ( elt seq -- newseq )
 791     [ eq? ] with reject ;
 792
 793 : sift ( seq -- newseq )
 794     [ ] filter ;
 795
 796 : harvest ( seq -- newseq )
 797     [ empty? ] reject ;
 798
 799 <PRIVATE
 800
 801 : mismatch-unsafe ( n seq1 seq2 -- i )
 802     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 803
 804 PRIVATE>
 805
 806 : mismatch ( seq1 seq2 -- i )
 807     [ min-length ] 2keep mismatch-unsafe ;
 808
 809 M: sequence <=>
 810     [ mismatch ] 2keep pick
 811     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 812
 813 : sequence= ( seq1 seq2 -- ? )
 814     2dup 2length dupd =
 815     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 816
 817 ERROR: assert-sequence got expected ;
 818
 819 : assert-sequence= ( a b -- )
 820     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 821
 822 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 823
 824 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 825
 826 <PRIVATE
 827
 828 : sequence-hashcode-step ( oldhash newpart -- newhash )
 829     integer>fixnum swap [
 830         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 831         fixnum+fast fixnum+fast
 832     ] keep fixnum-bitxor ; inline
 833
 834 PRIVATE>
 835
 836 : sequence-hashcode ( n seq -- x )
 837     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 838
 839 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 840
 841 M: iota hashcode*
 842     over 0 <= [ 2drop 0 ] [
 843         nip length 0 swap [ sequence-hashcode-step ] each-integer
 844     ] if ;
 845
 846 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 847
 848 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 849
 850 : move ( to from seq -- )
 851     2over =
 852     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 853
 854 <PRIVATE
 855
 856 : move-unsafe* ( to from seq -- from-nth )
 857     2over =
 858     [ nth-unsafe nip ]
 859     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 860
 861 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 862     2over length < [
 863         [ [ move-unsafe* ] dip call ] 4keep
 864         [ swap [ 1 + ] when ] 3dip
 865         [ 1 + ] 2dip filter-from!
 866     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 867
 868 : move-unsafe ( to from seq -- )
 869     2over =
 870     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 871
 872 PRIVATE>
 873
 874 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 875     [ 0 0 ] 2dip filter-from! ; inline
 876
 877 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 878     negate filter! ; inline
 879
 880 : remove! ( elt seq -- seq )
 881     [ = ] with reject! ;
 882
 883 : remove-eq! ( elt seq -- seq )
 884     [ eq? ] with reject! ;
 885
 886 : prefix ( seq elt -- newseq )
 887     over [ over length 1 + ] dip [
 888         (1sequence) [ 1 swap copy-unsafe ] keep
 889     ] new-like ;
 890
 891 : suffix ( seq elt -- newseq )
 892     over [ over length 1 + ] dip [
 893         [ [ over length ] dip set-nth-unsafe ] keep
 894         [ 0 swap copy-unsafe ] keep
 895     ] new-like ;
 896
 897 : suffix! ( seq elt -- seq ) over push ; inline
 898
 899 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 900
 901 : last ( seq -- elt )
 902     index-of-last
 903     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 904
 905 <PRIVATE
 906
 907 : last-unsafe ( seq -- elt )
 908     index-of-last nth-unsafe ; inline
 909
 910 PRIVATE>
 911
 912 : set-last ( elt seq -- )
 913     index-of-last
 914     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 915
 916 : pop* ( seq -- ) index-of-last shorten ;
 917
 918 <PRIVATE
 919
 920 : move-backward ( shift from to seq -- )
 921     2over = [
 922         4drop
 923     ] [
 924         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 925         move-backward
 926     ] if ;
 927
 928 : move-forward ( shift from to seq -- )
 929     2over = [
 930         4drop
 931     ] [
 932         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 933         move-forward
 934     ] if ;
 935
 936 : (open-slice) ( shift from to seq ? -- )
 937     [
 938         [ [ 1 - ] bi@ ] dip move-forward
 939     ] [
 940         [ over - ] 2dip move-backward
 941     ] if ;
 942
 943 : open-slice ( shift from seq -- )
 944     pick 0 = [
 945         3drop
 946     ] [
 947         [ ] [ nip length + ] [ 2nip ] 3tri
 948         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 949         set-length
 950     ] if ;
 951
 952 PRIVATE>
 953
 954 : delete-slice ( from to seq -- )
 955     check-slice [ over [ - ] dip ] dip open-slice ;
 956
 957 : remove-nth! ( n seq -- seq )
 958     [ [ dup 1 + ] dip delete-slice ] keep ;
 959
 960 : snip ( from to seq -- head tail )
 961     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 962
 963 : snip-slice ( from to seq -- head tail )
 964     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 965
 966 : replace-slice ( new from to seq -- seq' )
 967     snip-slice surround ;
 968
 969 : remove-nth ( n seq -- seq' )
 970     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 971
 972 : pop ( seq -- elt )
 973     index-of-last over 0 >=
 974     [ [ nth-unsafe ] [ shorten ] 2bi ]
 975     [ bounds-error ] if ;
 976
 977 : exchange ( m n seq -- )
 978     [ nip bounds-check 2drop ]
 979     [ bounds-check 3drop ]
 980     [ exchange-unsafe ]
 981     3tri ;
 982
 983 : midpoint@ ( seq -- n ) length 2/ ; inline
 984
 985 : reverse! ( seq -- seq )
 986     [
 987         [ midpoint@ ] [ length ] [ ] tri
 988         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 989         each-integer
 990     ] keep ;
 991
 992 : reverse ( seq -- newseq )
 993     [
 994         dup [ length ] keep new-sequence
 995         [ 0 swap copy-unsafe ] keep reverse!
 996     ] keep like ;
 997
 998 GENERIC: sum-lengths ( seq -- n )
 999
1000 M: object sum-lengths
1001     0 [ length + ] reduce ;
1002
1003 M: repetition sum-lengths
1004     [ length>> ] [ elt>> length ] bi * ;
1005
1006 : concat-as ( seq exemplar -- newseq )
1007     [
1008         [ dup sum-lengths ] dip new-resizable
1009         [ [ push-all ] curry each ] keep
1010     ] keep like ; inline
1011
1012 : concat ( seq -- newseq )
1013     [ { } ] [ dup first concat-as ] if-empty ;
1014
1015 <PRIVATE
1016
1017 : joined-length ( seq glue -- n )
1018     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
1019
1020 PRIVATE>
1021
1022 : join-as ( seq glue exemplar -- newseq )
1023     over empty? [ nip concat-as ] [
1024         [
1025             2dup joined-length over new-resizable [
1026                 [ [ push-all ] 2curry ]
1027                 [ nip [ push-all ] curry ] 2bi
1028                 interleave
1029             ] keep
1030         ] dip like
1031     ] if ;
1032
1033 : join ( seq glue -- newseq )
1034     dup join-as ; inline
1035
1036 <PRIVATE
1037
1038 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
1039     [
1040         [ over length [-] dup 0 = [ drop ] ] dip
1041         [ <repetition> ] curry
1042     ] dip compose if ; inline
1043
1044 PRIVATE>
1045
1046 : pad-head ( seq n elt -- padded )
1047     [ swap dup append-as ] padding ;
1048
1049 : pad-tail ( seq n elt -- padded )
1050     [ append ] padding ;
1051
1052 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
1053 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
1054 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
1055 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
1056
1057 : head? ( seq begin -- ? )
1058     2dup shorter? [
1059         2drop f
1060     ] [
1061         [ length [ head-slice ] keep swap ] keep
1062         mismatch-unsafe not
1063     ] if ;
1064
1065 : tail? ( seq end -- ? )
1066     2dup shorter? [
1067         2drop f
1068     ] [
1069         [ length [ tail-slice* ] keep swap ] keep
1070         mismatch-unsafe not
1071     ] if ;
1072
1073 : cut-slice ( seq n -- before-slice after-slice )
1074     [ head-slice ] [ tail-slice ] 2bi ; inline
1075
1076 : cut-slice* ( seq n -- before-slice after-slice )
1077     [ head-slice* ] [ tail-slice* ] 2bi ;
1078
1079 : insert-nth ( elt n seq -- seq' )
1080     swap cut-slice [ swap suffix ] dip append ;
1081
1082 : halves ( seq -- first-slice second-slice )
1083     dup midpoint@ cut-slice ; inline
1084
1085 <PRIVATE
1086
1087 : nth2-unsafe ( n seq -- a b )
1088     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1089
1090 : nth3-unsafe ( n seq -- a b c )
1091     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1092
1093 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1094     ! We can't use case here since combinators depends on
1095     ! sequences
1096     dup 4 < [
1097         integer>fixnum {
1098             [ 2drop nip ]
1099             [ 2nip swap nth-unsafe ]
1100             [ -rot [ drop swap nth2-unsafe ] dip call ]
1101             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1102         } dispatch
1103     ] [
1104         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1105         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1106         pick [ 3bi ] dip call
1107     ] if ; inline recursive
1108
1109 PRIVATE>
1110
1111 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1112     pick dup slice? [
1113         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1114     ] [
1115         length 0 max 0 swap
1116     ] if (binary-reduce) ; inline
1117
1118 : cut ( seq n -- before after )
1119     [ head ] [ tail ] 2bi ;
1120
1121 : cut* ( seq n -- before after )
1122     [ head* ] [ tail* ] 2bi ;
1123
1124 : subseq-starts-at? ( i seq subseq -- ? )
1125     [ length swap ] keep
1126     '[
1127         [ + _ nth-unsafe ] keep _ nth-unsafe =
1128     ] with all-integers? ; inline
1129
1130 : subseq-index-from ( n seq subseq -- i/f )
1131     [ 2length - 1 + ] 2keep
1132     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1133
1134 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1135
1136 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1137
1138 : subseq-start-from ( subseq seq n -- i/f )
1139     spin subseq-index-from ; inline deprecated
1140
1141 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1142
1143 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1144
1145 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1146     2dup mismatch [ 2dup min-length ] unless*
1147     [ tail-slice ] curry bi@ ;
1148
1149 : unclip ( seq -- rest first )
1150     [ rest ] [ first-unsafe ] bi ;
1151
1152 : unclip-last ( seq -- butlast last )
1153     [ but-last ] [ last-unsafe ] bi ;
1154
1155 : unclip-slice ( seq -- rest-slice first )
1156     [ rest-slice ] [ first-unsafe ] bi ; inline
1157
1158 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1159     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1160     '[ swap _ dip swap @ ] 1 each-from ; inline
1161
1162 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1163     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1164     '[ rot _ dip swap @ ] 1 -roll 2each-from ; inline
1165
1166 <PRIVATE
1167
1168 : (map-find) ( seq quot find-quot -- result elt )
1169     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1170
1171 PRIVATE>
1172
1173 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1174     [ find ] (map-find) ; inline
1175
1176 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1177     [ find-last ] (map-find) ; inline
1178
1179 : unclip-last-slice ( seq -- butlast-slice last )
1180     [ but-last-slice ] [ last-unsafe ] bi ; inline
1181
1182 <PRIVATE
1183
1184 : (trim-head) ( seq quot -- seq n )
1185     over [ negate find drop ] dip swap
1186     [ dup length ] unless* ; inline
1187
1188 : (trim-tail) ( seq quot -- seq n )
1189     over [ negate find-last drop ?1+ ] dip
1190     swap ; inline
1191
1192 PRIVATE>
1193
1194 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1195     (trim-head) tail-slice ; inline
1196
1197 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1198     (trim-head) tail ; inline
1199
1200 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1201     (trim-tail) head-slice ; inline
1202
1203 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1204     (trim-tail) head ; inline
1205
1206 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1207     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1208
1209 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1210     [ trim-slice ] [ drop ] 2bi like ; inline
1211
1212 GENERIC: sum ( seq -- n )
1213 M: object sum 0 [ + ] binary-reduce ; inline
1214 M: iota sum length dup 1 - * 2/ ; inline
1215 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1216
1217 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1218
1219 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1220
1221 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1222
1223 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1224     [ 0 ] 2dip [ dip + ] with-assoc each ; inline
1225
1226 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1227     [ 1 0 ? ] compose map-sum ; inline
1228
1229 : count-by ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1230     [ 1 0 ? ] compose map-sum ; inline
1231
1232 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1233     [ with each ] 2curry each ; inline
1234
1235 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1236     [ with { } map-as ] 2curry { } map-as ; inline
1237
1238 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1239     [ 2sequence ] curry cartesian-map ; inline
1240
1241 : cartesian-product ( seq1 seq2 -- newseq )
1242     dup cartesian-product-as ; inline
1243
1244 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1245     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1246
1247 <PRIVATE
1248
1249 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1250     [
1251         [ keep swap ] curry [ [ first ] dip call ] 2keep
1252         [ curry 2dip pick over ] curry
1253     ] [
1254         [ [ 2drop ] [ 2nipd ] if ] compose
1255     ] bi* compose 1 each-from drop ; inline
1256
1257 PRIVATE>
1258
1259 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1260     [ after? ] select-by ; inline
1261
1262 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1263     [ before? ] select-by ; inline
1264
1265 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1266
1267 : longest ( seqs -- elt ) [ length ] supremum-by ;
1268
1269 ! We hand-optimize flip to such a degree because type hints
1270 ! cannot express that an array is an array of arrays yet, and
1271 ! this word happens to be performance-critical since the compiler
1272 ! itself uses it. Optimizing it like this reduced compile time.
1273 <PRIVATE
1274
1275 : generic-flip ( matrix -- newmatrix )
1276     [ [ length ] [ min ] map-reduce ] keep
1277     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1278
1279 USE: arrays
1280
1281 : array-flip ( matrix -- newmatrix )
1282     { array } declare
1283     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1284     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1285
1286 PRIVATE>
1287
1288 : flip ( matrix -- newmatrix )
1289     dup empty? [
1290         dup array? [
1291             dup [ array? ] all?
1292             [ array-flip ] [ generic-flip ] if
1293         ] [ generic-flip ] if
1294     ] unless ;