core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 PRIVATE>
  95
  96 ! The f object supports the sequence protocol trivially
  97 M: f length drop 0 ; inline
  98 M: f nth-unsafe nip ; inline
  99 M: f like drop [ f ] when-empty ; inline
 100
 101 INSTANCE: f immutable-sequence
 102
 103 ! Integer sequences
 104 TUPLE: iota { n integer read-only } ;
 105
 106 : iota ( n -- iota ) \ iota boa ; inline
 107
 108 M: iota length n>> ; inline
 109 M: iota nth-unsafe drop ; inline
 110
 111 INSTANCE: iota immutable-sequence
 112
 113 <PRIVATE
 114
 115 : first-unsafe ( seq -- first )
 116     0 swap nth-unsafe ; inline
 117
 118 : first2-unsafe ( seq -- first second )
 119     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 120
 121 : first3-unsafe ( seq -- first second third )
 122     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 123
 124 : first4-unsafe ( seq -- first second third fourth )
 125     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 126
 127 : exchange-unsafe ( m n seq -- )
 128     [ [ nth-unsafe ] curry bi@ ]
 129     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 130
 131 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 132
 133 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 134
 135 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 136
 137 : (1sequence) ( obj seq -- seq )
 138     [ 0 swap set-nth-unsafe ] keep ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep
 142     (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep
 146     (2sequence) ; inline
 147
 148 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 149     [ 3 swap set-nth-unsafe ] keep
 150     (3sequence) ; inline
 151
 152 PRIVATE>
 153
 154 : 1sequence ( obj exemplar -- seq )
 155     1 swap [ (1sequence) ] new-like ; inline
 156
 157 : 2sequence ( obj1 obj2 exemplar -- seq )
 158     2 swap [ (2sequence) ] new-like ; inline
 159
 160 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 161     3 swap [ (3sequence) ] new-like ; inline
 162
 163 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 164     4 swap [ (4sequence) ] new-like ; inline
 165
 166 : first2 ( seq -- first second )
 167     1 swap bounds-check nip first2-unsafe ; inline
 168
 169 : first3 ( seq -- first second third )
 170     2 swap bounds-check nip first3-unsafe ; inline
 171
 172 : first4 ( seq -- first second third fourth )
 173     3 swap bounds-check nip first4-unsafe ; inline
 174
 175 : ?nth ( n seq -- elt/f )
 176     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 177
 178 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 179 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 180 : ?last ( seq -- elt/f ) [ length 1 - ] [ ?nth ] bi ; inline
 181
 182 MIXIN: virtual-sequence
 183 GENERIC: virtual-exemplar ( seq -- seq' )
 184 GENERIC: virtual@ ( n seq -- n' seq' )
 185
 186 M: virtual-sequence nth virtual@ nth ; inline
 187 M: virtual-sequence set-nth virtual@ set-nth ; inline
 188 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 189 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 190 M: virtual-sequence like virtual-exemplar like ; inline
 191 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 192
 193 INSTANCE: virtual-sequence sequence
 194
 195 ! A reversal of an underlying sequence.
 196 TUPLE: reversed { seq read-only } ;
 197
 198 C: <reversed> reversed
 199
 200 M: reversed virtual-exemplar seq>> ; inline
 201 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 202 M: reversed length seq>> length ; inline
 203
 204 INSTANCE: reversed virtual-sequence
 205
 206 ! A slice of another sequence.
 207 TUPLE: slice
 208 { from read-only }
 209 { to read-only }
 210 { seq read-only } ;
 211
 212 : collapse-slice ( m n slice -- m' n' seq )
 213     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 214
 215 TUPLE: slice-error from to seq reason ;
 216
 217 : slice-error ( from to seq ? string -- from to seq )
 218     [ \ slice-error boa throw ] curry when ; inline
 219
 220 : check-slice ( from to seq -- from to seq )
 221     3dup
 222     [ 2drop 0 < "start < 0" slice-error ]
 223     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 224     [ drop > "start > end" slice-error ]
 225     3tri ; inline
 226
 227 <PRIVATE
 228
 229 : <slice-unsafe> ( from to seq -- slice )
 230     slice boa ; inline
 231
 232 PRIVATE>
 233
 234 : <slice> ( from to seq -- slice )
 235     check-slice
 236     dup slice? [ collapse-slice ] when
 237     <slice-unsafe> ; inline
 238
 239 M: slice virtual-exemplar seq>> ; inline
 240
 241 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 242
 243 M: slice length [ to>> ] [ from>> ] bi - ; inline
 244
 245 : short ( seq n -- seq n' ) over length min ; inline
 246
 247 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 248
 249 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 250
 251 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 252
 253 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 254
 255 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 256
 257 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 258
 259 INSTANCE: slice virtual-sequence
 260
 261 ! One element repeated many times
 262 TUPLE: repetition { len read-only } { elt read-only } ;
 263
 264 C: <repetition> repetition
 265
 266 M: repetition length len>> ; inline
 267 M: repetition nth-unsafe nip elt>> ; inline
 268
 269 INSTANCE: repetition immutable-sequence
 270
 271 <PRIVATE
 272
 273 ERROR: integer-length-expected obj ;
 274
 275 : check-length ( n -- n )
 276     dup integer? [ integer-length-expected ] unless ; inline
 277
 278 TUPLE: copy-state
 279     { src-i read-only }
 280     { src read-only }
 281     { dst-i read-only }
 282     { dst read-only } ;
 283
 284 C: <copy> copy-state
 285
 286 : ((copy)) ( n copy -- )
 287     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 288     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 289
 290 : (copy) ( n copy -- dst )
 291     over 0 <= [ nip dst>> ] [ [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi ] if ;
 292     inline recursive
 293
 294 : subseq>copy ( from to seq -- n copy )
 295     [ over - check-length swap ] dip
 296     3dup nip new-sequence 0 swap <copy> ; inline
 297
 298 : bounds-check-head ( n seq -- n seq )
 299     over 0 < [ bounds-error ] when ; inline
 300
 301 : check-copy ( src n dst -- src n dst )
 302     3dup bounds-check-head
 303     [ swap length + ] dip lengthen ; inline
 304
 305 PRIVATE>
 306
 307 : subseq ( from to seq -- subseq )
 308     [ check-slice subseq>copy (copy) ] keep like ;
 309
 310 : head ( seq n -- headseq ) (head) subseq ;
 311
 312 : tail ( seq n -- tailseq ) (tail) subseq ;
 313
 314 : rest ( seq -- tailseq ) 1 tail ;
 315
 316 : head* ( seq n -- headseq ) from-end head ;
 317
 318 : tail* ( seq n -- tailseq ) from-end tail ;
 319
 320 : but-last ( seq -- headseq ) 1 head* ;
 321
 322 : copy ( src i dst -- )
 323     #! The check-length call forces partial dispatch
 324     [ [ length check-length 0 ] keep ] 2dip
 325     check-copy <copy> (copy) drop ; inline
 326
 327 M: sequence clone-like
 328     [ dup length ] dip new-sequence [ 0 swap copy ] keep ; inline
 329
 330 M: immutable-sequence clone-like like ; inline
 331
 332 : push-all ( src dest -- ) [ length ] [ copy ] bi ; inline
 333
 334 <PRIVATE
 335
 336 : (append) ( seq1 seq2 accum -- accum )
 337     [ [ over length ] dip copy ]
 338     [ 0 swap copy ]
 339     [ ] tri ; inline
 340
 341 PRIVATE>
 342
 343 : append-as ( seq1 seq2 exemplar -- newseq )
 344     [ 2dup [ length ] bi@ + ] dip
 345     [ (append) ] new-like ; inline
 346
 347 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 348     [ 3dup [ length ] tri@ + + ] dip [
 349         [ [ 2over [ length ] bi@ + ] dip copy ]
 350         [ (append) ] bi
 351     ] new-like ; inline
 352
 353 : append ( seq1 seq2 -- newseq ) over append-as ;
 354
 355 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 356
 357 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 358
 359 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 360
 361 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 362
 363 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 364
 365 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 366     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 367
 368 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 369
 370 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 371
 372 <PRIVATE
 373
 374 : ((each)) ( seq -- n quot )
 375     [ length ] keep [ nth-unsafe ] curry ; inline
 376
 377 : (each) ( seq quot -- n quot' )
 378     [ ((each)) ] dip compose ; inline
 379
 380 : (each-index) ( seq quot -- n quot' )
 381     [ ((each)) [ keep ] curry ] dip compose ; inline
 382
 383 : (collect) ( quot into -- quot' )
 384     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 385
 386 : collect ( n quot into -- )
 387     (collect) each-integer ; inline
 388
 389 : map-into ( seq quot into -- )
 390     [ (each) ] dip collect ; inline
 391
 392 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 393     [ nth-unsafe ] bi-curry@ bi ; inline
 394
 395 : (2each) ( seq1 seq2 quot -- n quot' )
 396     [
 397         [ min-length ] 2keep
 398         [ 2nth-unsafe ] 2curry
 399     ] dip compose ; inline
 400
 401 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 402     [ nth-unsafe ] tri-curry@ tri ; inline
 403
 404 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 405     [
 406         [ [ length ] tri@ min min ]
 407         [ [ 3nth-unsafe ] 3curry ] 3bi
 408     ] dip compose ; inline
 409
 410 : finish-find ( i seq -- i elt )
 411     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 412
 413 : (find) ( seq quot quot' -- i elt )
 414     pick [ [ (each) ] dip call ] dip finish-find ; inline
 415
 416 : (find-from) ( n seq quot quot' -- i elt )
 417     [ 2dup bounds-check? ] 2dip
 418     [ (find) ] 2curry
 419     [ 2drop f f ]
 420     if ; inline
 421
 422 : (find-index) ( seq quot quot' -- i elt )
 423     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 424
 425 : (find-index-from) ( n seq quot quot' -- i elt )
 426     [ 2dup bounds-check? ] 2dip
 427     [ (find-index) ] 2curry
 428     [ 2drop f f ]
 429     if ; inline
 430
 431 : (accumulate) ( seq identity quot -- identity seq quot )
 432     swapd [ curry keep ] curry ; inline
 433
 434 PRIVATE>
 435
 436 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 437     (each) each-integer ; inline
 438
 439 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 440     swapd each ; inline
 441
 442 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 443     [ over ] dip [ [ collect ] keep ] new-like ; inline
 444
 445 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 446     [ (each) ] dip map-integers ; inline
 447
 448 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 449     over map-as ; inline
 450
 451 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 452     [ [ drop ] prepose ] dip map-integers ; inline
 453
 454 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 455     { } replicate-as ; inline
 456
 457 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 458     over [ map-into ] keep ; inline
 459
 460 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 461     [ (accumulate) ] dip map-as ; inline
 462
 463 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 464     pick accumulate-as ; inline
 465
 466 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 467     (accumulate) map! ; inline
 468
 469 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 470     (2each) each-integer ; inline
 471
 472 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 473     [ -rot ] dip 2each ; inline
 474
 475 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 476     [ (2each) ] dip map-integers ; inline
 477
 478 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 479     pick 2map-as ; inline
 480
 481 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 482     (2each) all-integers? ; inline
 483
 484 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 485     (3each) each-integer ; inline
 486
 487 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 488     [ (3each) ] dip map-integers ; inline
 489
 490 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 491     [ pick ] dip swap 3map-as ; inline
 492
 493 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 494     [ (find-integer) ] (find-from) ; inline
 495
 496 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 497     [ find-integer ] (find) ; inline
 498
 499 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 500     [ nip find-last-integer ] (find-from) ; inline
 501
 502 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 503     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 504
 505 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 506     [ (find-integer) ] (find-index-from) ; inline
 507
 508 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 509     [ find-integer ] (find-index) ; inline
 510
 511 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 512     (each) all-integers? ; inline
 513
 514 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 515     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 516
 517 : selector-for ( quot exemplar -- selector accum )
 518     [ length ] keep new-resizable [ [ push-if ] 2curry ] keep ; inline
 519
 520 : selector ( quot -- selector accum )
 521     V{ } selector-for ; inline
 522
 523 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 524     dup [ selector-for [ each ] dip ] curry dip like ; inline
 525
 526 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 527     over filter-as ; inline
 528
 529 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 530     [ keep swap ] 2dip ? push ; inline
 531
 532 : 2selector ( quot -- selector accum1 accum2 )
 533     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 534
 535 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 536     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 537
 538 : collector-for ( quot exemplar -- quot' vec )
 539     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 540
 541 : collector ( quot -- quot' vec )
 542     V{ } collector-for ; inline
 543
 544 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 545     dup [ collector-for [ while ] dip ] curry dip like ; inline
 546
 547 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 548     { } produce-as ; inline
 549
 550 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 551     [ dup ] swap [ keep ] curry produce nip ; inline
 552
 553 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 554     (each-index) each-integer ; inline
 555
 556 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 557     pick empty? [ 3drop ] [
 558         [ [ drop first-unsafe ] dip call ]
 559         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 560         3bi
 561     ] if ; inline
 562
 563 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 564     [ dup length iota ] dip 2map ; inline
 565
 566 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 567     swapd each-index ; inline
 568
 569 : index ( obj seq -- n )
 570     [ = ] with find drop ;
 571
 572 : index-from ( obj i seq -- n )
 573     rot [ = ] curry find-from drop ;
 574
 575 : last-index ( obj seq -- n )
 576     [ = ] with find-last drop ;
 577
 578 : last-index-from ( obj i seq -- n )
 579     rot [ = ] curry find-last-from drop ;
 580
 581 <PRIVATE
 582
 583 : (indices) ( elt i obj accum -- )
 584     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 585
 586 PRIVATE>
 587
 588 : indices ( obj seq -- indices )
 589     swap V{ } clone
 590     [ [ (indices) ] 2curry each-index ] keep ;
 591
 592 : nths ( indices seq -- seq' )
 593     [ [ nth ] curry ] keep map-as ;
 594
 595 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 596     find drop >boolean ; inline
 597
 598 : member? ( elt seq -- ? )
 599     [ = ] with any? ;
 600
 601 : member-eq? ( elt seq -- ? )
 602     [ eq? ] with any? ;
 603
 604 : remove ( elt seq -- newseq )
 605     [ = not ] with filter ;
 606
 607 : remove-eq ( elt seq -- newseq )
 608     [ eq? not ] with filter ;
 609
 610 : sift ( seq -- newseq )
 611     [ ] filter ;
 612
 613 : harvest ( seq -- newseq )
 614     [ empty? not ] filter ;
 615
 616 : mismatch ( seq1 seq2 -- i )
 617     [ min-length ] 2keep
 618     [ 2nth-unsafe = not ] 2curry
 619     find-integer ; inline
 620
 621 M: sequence <=>
 622     [ mismatch ] 2keep pick
 623     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 624
 625 : sequence= ( seq1 seq2 -- ? )
 626     2dup [ length ] same?
 627     [ mismatch not ] [ 2drop f ] if ; inline
 628
 629 ERROR: assert-sequence got expected ;
 630
 631 : assert-sequence= ( a b -- )
 632     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 633
 634 <PRIVATE
 635
 636 : sequence-hashcode-step ( oldhash newpart -- newhash )
 637     >fixnum swap [
 638         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 639         fixnum+fast fixnum+fast
 640     ] keep fixnum-bitxor ; inline
 641
 642 PRIVATE>
 643
 644 : sequence-hashcode ( n seq -- x )
 645     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 646
 647 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 648
 649 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 650
 651 : move ( to from seq -- )
 652     2over =
 653     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 654
 655 <PRIVATE
 656
 657 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 658     2dup length < [
 659         [ move ] 3keep
 660         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 661         [ 1 + ] dip
 662         (filter!)
 663     ] [ nip set-length drop ] if ; inline recursive
 664
 665 PRIVATE>
 666
 667 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 668     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 669
 670 : remove! ( elt seq -- seq )
 671     [ = not ] with filter! ;
 672
 673 : remove-eq! ( elt seq -- seq )
 674     [ eq? not ] with filter! ;
 675
 676 : prefix ( seq elt -- newseq )
 677     over [ over length 1 + ] dip [
 678         (1sequence) [ 1 swap copy ] keep
 679     ] new-like ;
 680
 681 : suffix ( seq elt -- newseq )
 682     over [ over length 1 + ] dip [
 683         [ [ over length ] dip set-nth-unsafe ] keep
 684         [ 0 swap copy ] keep
 685     ] new-like ;
 686
 687 : suffix! ( seq elt -- seq ) over push ; inline
 688
 689 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 690
 691 : last ( seq -- elt )
 692     [ length 1 - ] keep
 693     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 694
 695 : set-last ( elt seq -- )
 696     [ length 1 - ] keep
 697     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 698
 699 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 700
 701 <PRIVATE
 702
 703 : move-backward ( shift from to seq -- )
 704     2over = [
 705         2drop 2drop
 706     ] [
 707         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 708         move-backward
 709     ] if ;
 710
 711 : move-forward ( shift from to seq -- )
 712     2over = [
 713         2drop 2drop
 714     ] [
 715         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 716         move-forward
 717     ] if ;
 718
 719 : (open-slice) ( shift from to seq ? -- )
 720     [
 721         [ [ 1 - ] bi@ ] dip move-forward
 722     ] [
 723         [ over - ] 2dip move-backward
 724     ] if ;
 725
 726 : open-slice ( shift from seq -- )
 727     pick 0 = [
 728         3drop
 729     ] [
 730         pick over length + over
 731         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 732         set-length
 733     ] if ;
 734
 735 PRIVATE>
 736
 737 : delete-slice ( from to seq -- )
 738     check-slice [ over [ - ] dip ] dip open-slice ;
 739
 740 : remove-nth! ( n seq -- seq )
 741     [ [ dup 1 + ] dip delete-slice ] keep ;
 742
 743 : snip ( from to seq -- head tail )
 744     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 745
 746 : snip-slice ( from to seq -- head tail )
 747     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 748
 749 : replace-slice ( new from to seq -- seq' )
 750     snip-slice surround ;
 751
 752 : remove-nth ( n seq -- seq' )
 753     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 754
 755 : pop ( seq -- elt )
 756     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 757
 758 : exchange ( m n seq -- )
 759     [ nip bounds-check 2drop ]
 760     [ bounds-check 3drop ]
 761     [ exchange-unsafe ]
 762     3tri ;
 763
 764 : midpoint@ ( seq -- n ) length 2/ ; inline
 765
 766 : reverse! ( seq -- seq )
 767     [
 768         [ midpoint@ iota ] [ length ] [ ] tri
 769         [ [ over - 1 - ] dip exchange-unsafe ] 2curry each
 770     ] keep ;
 771
 772 : reverse ( seq -- newseq )
 773     [
 774         dup [ length ] keep new-sequence
 775         [ 0 swap copy ] keep reverse!
 776     ] keep like ;
 777
 778 : sum-lengths ( seq -- n )
 779     0 [ length + ] reduce ;
 780
 781 : concat-as ( seq exemplar -- newseq )
 782     swap [ { } ] [
 783         [ sum-lengths over new-resizable ] keep
 784         [ append! ] each
 785     ] if-empty swap like ;
 786
 787 : concat ( seq -- newseq )
 788     [ { } ] [ dup first concat-as ] if-empty ;
 789
 790 <PRIVATE
 791
 792 : joined-length ( seq glue -- n )
 793     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 794
 795 PRIVATE>
 796
 797 : join ( seq glue -- newseq )
 798     dup empty? [ concat-as ] [
 799         [
 800             2dup joined-length over new-resizable [
 801                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 802                 interleave
 803             ] keep
 804         ] keep like
 805     ] if ;
 806
 807 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 808     [
 809         [ over length [-] dup 0 = [ drop ] ] dip
 810         [ <repetition> ] curry
 811     ] dip compose if ; inline
 812
 813 : pad-head ( seq n elt -- padded )
 814     [ swap dup append-as ] padding ;
 815
 816 : pad-tail ( seq n elt -- padded )
 817     [ append ] padding ;
 818
 819 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 820
 821 : head? ( seq begin -- ? )
 822     2dup shorter? [
 823         2drop f
 824     ] [
 825         [ nip ] [ length head-slice ] 2bi sequence=
 826     ] if ;
 827
 828 : tail? ( seq end -- ? )
 829     2dup shorter? [
 830         2drop f
 831     ] [
 832         [ nip ] [ length tail-slice* ] 2bi sequence=
 833     ] if ;
 834
 835 : cut-slice ( seq n -- before-slice after-slice )
 836     [ head-slice ] [ tail-slice ] 2bi ;
 837
 838 : insert-nth ( elt n seq -- seq' )
 839     swap cut-slice [ swap suffix ] dip append ;
 840
 841 : halves ( seq -- first-slice second-slice )
 842     dup midpoint@ cut-slice ;
 843
 844 : binary-reduce ( ... seq start quot: ( ... elt1 elt2 -- ... newelt ) -- ... value )
 845     #! We can't use case here since combinators depends on
 846     #! sequences
 847     pick length dup 0 3 between? [
 848         >fixnum {
 849             [ drop nip ]
 850             [ 2drop first ]
 851             [ [ drop first2 ] dip call ]
 852             [ [ drop first3 ] dip bi@ ]
 853         } dispatch
 854     ] [
 855         drop
 856         [ halves ] 2dip
 857         [ [ binary-reduce ] 2curry bi@ ] keep
 858         call
 859     ] if ; inline recursive
 860
 861 : cut ( seq n -- before after )
 862     [ head ] [ tail ] 2bi ;
 863
 864 : cut* ( seq n -- before after )
 865     [ head* ] [ tail* ] 2bi ;
 866
 867 <PRIVATE
 868
 869 : (start) ( subseq seq n -- subseq seq ? )
 870     pick length iota [
 871         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 872     ] all? nip ; inline
 873
 874 PRIVATE>
 875
 876 : start* ( subseq seq n -- i )
 877     pick length pick length swap - 1 + iota
 878     [ (start) ] find-from
 879     swap [ 3drop ] dip ;
 880
 881 : start ( subseq seq -- i ) 0 start* ; inline
 882
 883 : subseq? ( subseq seq -- ? ) start >boolean ;
 884
 885 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 886     2dup mismatch [ 2dup min-length ] unless*
 887     [ tail-slice ] curry bi@ ;
 888
 889 : unclip ( seq -- rest first )
 890     [ rest ] [ first-unsafe ] bi ;
 891
 892 : unclip-last ( seq -- butlast last )
 893     [ but-last ] [ last ] bi ;
 894
 895 : unclip-slice ( seq -- rest-slice first )
 896     [ rest-slice ] [ first-unsafe ] bi ; inline
 897
 898 : map-reduce ( ..a seq map-quot: ( ..a x -- ..b elt ) reduce-quot: ( ..b prev elt -- ..a next ) -- ..a result )
 899     [ [ dup first ] dip [ call ] keep ] dip compose
 900     swapd [ 1 ] 2dip (each) (each-integer) ; inline
 901
 902 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 903     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 904     [ -rot ] dip [ 1 ] 3dip (2each) (each-integer) ; inline
 905
 906 <PRIVATE
 907
 908 : (map-find) ( seq quot find-quot -- result elt )
 909     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 910     [ [ drop f ] unless ] dip ; inline
 911
 912 PRIVATE>
 913
 914 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 915     [ find ] (map-find) ; inline
 916
 917 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 918     [ find-last ] (map-find) ; inline
 919
 920 : unclip-last-slice ( seq -- butlast-slice last )
 921     [ but-last-slice ] [ last ] bi ; inline
 922
 923 <PRIVATE
 924
 925 : (trim-head) ( seq quot -- seq n )
 926     over [ [ not ] compose find drop ] dip
 927     [ length or ] keep swap ; inline
 928
 929 : (trim-tail) ( seq quot -- seq n )
 930     over [ [ not ] compose find-last drop ?1+ ] dip
 931     swap ; inline
 932
 933 PRIVATE>
 934
 935 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 936     (trim-head) tail-slice ; inline
 937
 938 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 939     (trim-head) tail ; inline
 940
 941 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 942     (trim-tail) head-slice ; inline
 943
 944 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 945     (trim-tail) head ; inline
 946
 947 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 948     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 949
 950 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 951     [ trim-slice ] [ drop ] 2bi like ; inline
 952
 953 GENERIC: sum ( seq -- n )
 954 M: object sum 0 [ + ] binary-reduce ; inline
 955
 956 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 957
 958 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 959
 960 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 961
 962 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 963     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 964
 965 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n ) [ 1 0 ? ] compose map-sum ; inline
 966
 967 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 968     [ with each ] 2curry each ; inline
 969
 970 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 971     [ with map ] 2curry map ; inline
 972
 973 : cartesian-product ( seq1 seq2 -- newseq )
 974     [ { } 2sequence ] cartesian-map ;
 975
 976 ! We hand-optimize flip to such a degree because type hints
 977 ! cannot express that an array is an array of arrays yet, and
 978 ! this word happens to be performance-critical since the compiler
 979 ! itself uses it. Optimizing it like this reduced compile time.
 980 <PRIVATE
 981
 982 : generic-flip ( matrix -- newmatrix )
 983     [ dup first length [ length min ] reduce iota ] keep
 984     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 985
 986 USE: arrays
 987
 988 : array-length ( array -- len )
 989     { array } declare length>> ; inline
 990
 991 : array-flip ( matrix -- newmatrix )
 992     { array } declare
 993     [ dup first array-length [ array-length min ] reduce iota ] keep
 994     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 995
 996 PRIVATE>
 997
 998 : flip ( matrix -- newmatrix )
 999     dup empty? [
1000         dup array? [
1001             dup [ array? ] all?
1002             [ array-flip ] [ generic-flip ] if
1003         ] [ generic-flip ] if
1004     ] unless ;