core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over >r >r new-sequence r> call r> like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24
  25 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  26
  27 : empty? ( seq -- ? ) length zero? ; inline
  28 : delete-all ( seq -- ) 0 swap set-length ;
  29
  30 : first ( seq -- first ) 0 swap nth ; inline
  31 : second ( seq -- second ) 1 swap nth ; inline
  32 : third ( seq -- third ) 2 swap nth ; inline
  33 : fourth  ( seq -- fourth ) 3 swap nth ; inline
  34
  35 : set-first ( first seq -- ) 0 swap set-nth ; inline
  36 : set-second ( second seq -- ) 1 swap set-nth ; inline
  37 : set-third ( third seq -- ) 2 swap set-nth ; inline
  38 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  39
  40 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  41
  42 : bounds-check? ( n seq -- ? )
  43     length 1- 0 swap between? ; inline
  44
  45 ERROR: bounds-error index seq ;
  46
  47 : bounds-check ( n seq -- n seq )
  48     2dup bounds-check? [ bounds-error ] unless ; inline
  49
  50 MIXIN: immutable-sequence
  51
  52 ERROR: immutable seq ;
  53
  54 M: immutable-sequence set-nth immutable ;
  55
  56 INSTANCE: immutable-sequence sequence
  57
  58 <PRIVATE
  59
  60 : array-capacity ( array -- n )
  61     1 slot { array-capacity } declare ; inline
  62
  63 : array-nth ( n array -- elt )
  64     swap 2 fixnum+fast slot ; inline
  65
  66 : set-array-nth ( elt n array -- )
  67     swap 2 fixnum+fast set-slot ; inline
  68
  69 : dispatch ( n array -- ) array-nth (call) ;
  70
  71 GENERIC: resize ( n seq -- newseq ) flushable
  72
  73 ! Unsafe sequence protocol for inner loops
  74 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  75 GENERIC: set-nth-unsafe ( elt n seq -- )
  76
  77 M: sequence nth bounds-check nth-unsafe ;
  78 M: sequence set-nth bounds-check set-nth-unsafe ;
  79
  80 M: sequence nth-unsafe nth ;
  81 M: sequence set-nth-unsafe set-nth ;
  82
  83 ! The f object supports the sequence protocol trivially
  84 M: f length drop 0 ;
  85 M: f nth-unsafe nip ;
  86 M: f like drop dup empty? [ drop f ] when ;
  87
  88 INSTANCE: f immutable-sequence
  89
  90 ! Integers support the sequence protocol
  91 M: integer length ;
  92 M: integer nth-unsafe drop ;
  93
  94 INSTANCE: integer immutable-sequence
  95
  96 : first2-unsafe
  97     [ 0 swap nth-unsafe 1 ] [ nth-unsafe ] bi ; inline
  98
  99 : first3-unsafe
 100     [ first2-unsafe 2 ] [ nth-unsafe ] bi ; inline
 101
 102 : first4-unsafe
 103     [ first3-unsafe 3 ] [ nth-unsafe ] bi ; inline
 104
 105 : exchange-unsafe ( m n seq -- )
 106     [ tuck nth-unsafe >r nth-unsafe r> ] 3keep tuck
 107     >r >r set-nth-unsafe r> r> set-nth-unsafe ; inline
 108
 109 : (head) ( seq n -- from to seq ) 0 spin ; inline
 110
 111 : (tail) ( seq n -- from to seq ) over length rot ; inline
 112
 113 : from-end >r dup length r> - ; inline
 114
 115 : (2sequence)
 116     tuck 1 swap set-nth-unsafe
 117     tuck 0 swap set-nth-unsafe ; inline
 118
 119 : (3sequence)
 120     tuck 2 swap set-nth-unsafe
 121     (2sequence) ; inline
 122
 123 : (4sequence)
 124     tuck 3 swap set-nth-unsafe
 125     (3sequence) ; inline
 126
 127 PRIVATE>
 128
 129 : 2sequence ( obj1 obj2 exemplar -- seq )
 130     2 swap [ (2sequence) ] new-like ; inline
 131
 132 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 133     3 swap [ (3sequence) ] new-like ; inline
 134
 135 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 136     4 swap [ (4sequence) ] new-like ; inline
 137
 138 : first2 ( seq -- first second )
 139     1 swap bounds-check nip first2-unsafe ; flushable
 140
 141 : first3 ( seq -- first second third )
 142     2 swap bounds-check nip first3-unsafe ; flushable
 143
 144 : first4 ( seq -- first second third fourth )
 145     3 swap bounds-check nip first4-unsafe ; flushable
 146
 147 : ?nth ( n seq -- elt/f )
 148     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 149
 150 MIXIN: virtual-sequence
 151 GENERIC: virtual-seq ( seq -- seq' )
 152 GENERIC: virtual@ ( n seq -- n' seq' )
 153
 154 M: virtual-sequence nth virtual@ nth ;
 155 M: virtual-sequence set-nth virtual@ set-nth ;
 156 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 157 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 158 M: virtual-sequence like virtual-seq like ;
 159 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 160
 161 INSTANCE: virtual-sequence sequence
 162
 163 ! A reversal of an underlying sequence.
 164 TUPLE: reversed { seq read-only } ;
 165
 166 C: <reversed> reversed
 167
 168 M: reversed virtual-seq seq>> ;
 169
 170 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 171
 172 M: reversed length seq>> length ;
 173
 174 INSTANCE: reversed virtual-sequence
 175
 176 : reverse ( seq -- newseq ) [ <reversed> ] [ like ] bi ;
 177
 178 ! A slice of another sequence.
 179 TUPLE: slice
 180 { from read-only }
 181 { to read-only }
 182 { seq read-only } ;
 183
 184 : collapse-slice ( m n slice -- m' n' seq )
 185     [ from>> ] [ seq>> ] bi >r tuck + >r + r> r> ; inline
 186
 187 ERROR: slice-error reason ;
 188
 189 : check-slice ( from to seq -- from to seq )
 190     pick 0 < [ "start < 0" slice-error ] when
 191     dup length pick < [ "end > sequence" slice-error ] when
 192     2over > [ "start > end" slice-error ] when ; inline
 193
 194 : <slice> ( from to seq -- slice )
 195     dup slice? [ collapse-slice ] when
 196     check-slice
 197     slice boa ; inline
 198
 199 M: slice virtual-seq seq>> ;
 200
 201 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 202
 203 M: slice length [ to>> ] [ from>> ] bi - ;
 204
 205 : short ( seq n -- seq n' ) over length min ; inline
 206
 207 : head-slice ( seq n -- slice ) (head) <slice> ;
 208
 209 : tail-slice ( seq n -- slice ) (tail) <slice> ;
 210
 211 : rest-slice ( seq -- slice ) 1 tail-slice ;
 212
 213 : head-slice* ( seq n -- slice ) from-end head-slice ;
 214
 215 : tail-slice* ( seq n -- slice ) from-end tail-slice ;
 216
 217 : but-last-slice ( seq -- slice ) 1 head-slice* ;
 218
 219 INSTANCE: slice virtual-sequence
 220
 221 ! One element repeated many times
 222 TUPLE: repetition { len read-only } { elt read-only } ;
 223
 224 C: <repetition> repetition
 225
 226 M: repetition length len>> ;
 227 M: repetition nth-unsafe nip elt>> ;
 228
 229 INSTANCE: repetition immutable-sequence
 230
 231 <PRIVATE
 232
 233 : ((copy)) ( dst i src j n -- dst i src j n )
 234     dup -roll [
 235         + swap nth-unsafe -roll [
 236             + swap set-nth-unsafe
 237         ] 3keep drop
 238     ] 3keep ; inline
 239
 240 : (copy) ( dst i src j n -- dst )
 241     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ; inline
 242
 243 : prepare-subseq ( from to seq -- dst i src j n )
 244     [ >r swap - r> new-sequence dup 0 ] 3keep
 245     -rot drop roll length ; inline
 246
 247 : check-copy ( src n dst -- )
 248     over 0 < [ bounds-error ] when
 249     >r swap length + r> lengthen ; inline
 250
 251 PRIVATE>
 252
 253 : subseq ( from to seq -- subseq )
 254     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 255
 256 : head ( seq n -- headseq ) (head) subseq ;
 257
 258 : tail ( seq n -- tailseq ) (tail) subseq ;
 259
 260 : rest ( seq -- tailseq ) 1 tail ;
 261
 262 : head* ( seq n -- headseq ) from-end head ;
 263
 264 : tail* ( seq n -- tailseq ) from-end tail ;
 265
 266 : but-last ( seq -- headseq ) 1 head* ;
 267
 268 : copy ( src i dst -- )
 269     pick length >r 3dup check-copy spin 0 r>
 270     (copy) drop ; inline
 271
 272 M: sequence clone-like
 273     >r dup length r> new-sequence [ 0 swap copy ] keep ;
 274
 275 M: immutable-sequence clone-like like ;
 276
 277 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 278
 279 : ((append)) ( seq1 seq2 accum -- accum )
 280     [ >r over length r> copy ]
 281     [ 0 swap copy ]
 282     [ ] tri ; inline
 283
 284 : (append) ( seq1 seq2 exemplar -- newseq )
 285     >r over length over length + r>
 286     [ ((append)) ] new-like ; inline
 287
 288 : (3append) ( seq1 seq2 seq3 exemplar -- newseq )
 289     >r pick length pick length pick length + + r> [
 290         [ >r pick length pick length + r> copy ]
 291         [ ((append)) ] bi
 292     ] new-like ; inline
 293
 294 : append ( seq1 seq2 -- newseq ) over (append) ;
 295
 296 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 297
 298 : 3append ( seq1 seq2 seq3 -- newseq ) pick (3append) ;
 299
 300 : change-nth ( i seq quot -- )
 301     [ >r nth r> call ] 3keep drop set-nth ; inline
 302
 303 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 304
 305 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 306
 307 <PRIVATE
 308
 309 : (each) ( seq quot -- n quot' )
 310     >r dup length swap [ nth-unsafe ] curry r> compose ; inline
 311
 312 : (collect) ( quot into -- quot' )
 313     [ >r keep r> set-nth-unsafe ] 2curry ; inline
 314
 315 : collect ( n quot into -- )
 316     (collect) each-integer ; inline
 317
 318 : map-into ( seq quot into -- )
 319     >r (each) r> collect ; inline
 320
 321 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 322     >r over r> nth-unsafe >r nth-unsafe r> ; inline
 323
 324 : (2each) ( seq1 seq2 quot -- n quot' )
 325     >r [ min-length ] 2keep r>
 326     [ >r 2nth-unsafe r> call ] 3curry ; inline
 327
 328 : finish-find ( i seq -- i elt )
 329     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 330
 331 : (find) ( seq quot quot' -- i elt )
 332     pick >r >r (each) r> call r> finish-find ; inline
 333
 334 : (find-from) ( n seq quot quot' -- i elt )
 335     >r >r 2dup bounds-check? [
 336         r> r> (find)
 337     ] [
 338         r> r> 2drop 2drop f f
 339     ] if ; inline
 340
 341 : (monotonic) ( seq quot -- ? )
 342     [ 2dup nth-unsafe rot 1+ rot nth-unsafe ]
 343     prepose curry ; inline
 344
 345 : (interleave) ( n elt between quot -- )
 346     roll zero? [ nip ] [ swapd 2slip ] if call ; inline
 347
 348 PRIVATE>
 349
 350 : each ( seq quot -- )
 351     (each) each-integer ; inline
 352
 353 : reduce ( seq identity quot -- result )
 354     swapd each ; inline
 355
 356 : map-as ( seq quot exemplar -- newseq )
 357     >r over length r> [ [ map-into ] keep ] new-like ; inline
 358
 359 : map ( seq quot -- newseq )
 360     over map-as ; inline
 361
 362 : replicate ( seq quot -- newseq )
 363     [ drop ] prepose map ; inline
 364
 365 : replicate-as ( seq quot exemplar -- newseq )
 366     >r [ drop ] prepose r> map-as ; inline
 367
 368 : change-each ( seq quot -- )
 369     over map-into ; inline
 370
 371 : accumulate ( seq identity quot -- final newseq )
 372     swapd [ pick slip ] curry map ; inline
 373
 374 : 2each ( seq1 seq2 quot -- )
 375     (2each) each-integer ; inline
 376
 377 : 2reverse-each ( seq1 seq2 quot -- )
 378     >r [ <reversed> ] bi@ r> 2each ; inline
 379
 380 : 2reduce ( seq1 seq2 identity quot -- result )
 381     >r -rot r> 2each ; inline
 382
 383 : 2map ( seq1 seq2 quot -- newseq )
 384     pick >r (2each) over r>
 385     [ [ collect ] keep ] new-like ; inline
 386
 387 : 2all? ( seq1 seq2 quot -- ? )
 388     (2each) all-integers? ; inline
 389
 390 : find-from ( n seq quot -- i elt )
 391     [ (find-integer) ] (find-from) ; inline
 392
 393 : find ( seq quot -- i elt )
 394     [ find-integer ] (find) ; inline
 395
 396 : find-last-from ( n seq quot -- i elt )
 397     [ nip find-last-integer ] (find-from) ; inline
 398
 399 : find-last ( seq quot -- i elt )
 400     [ >r 1- r> find-last-integer ] (find) ; inline
 401
 402 : all? ( seq quot -- ? )
 403     (each) all-integers? ; inline
 404
 405 : push-if ( elt quot accum -- )
 406     >r keep r> rot [ push ] [ 2drop ] if  ; inline
 407
 408 : pusher ( quot -- quot accum )
 409     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 410
 411 : filter ( seq quot -- subseq )
 412     over >r pusher >r each r> r> like ; inline
 413
 414 : monotonic? ( seq quot -- ? )
 415     >r dup length 1- swap r> (monotonic) all? ; inline
 416
 417 : interleave ( seq between quot -- )
 418     [ (interleave) ] 2curry >r dup length swap r> 2each ; inline
 419
 420 : accumulator ( quot -- quot' vec )
 421     V{ } clone [ [ push ] curry compose ] keep ; inline
 422
 423 : unfold ( pred quot tail -- seq )
 424     swap accumulator >r swap while r> { } like ; inline
 425
 426 : follow ( obj quot -- seq )
 427     >r [ dup ] r> [ keep ] curry [ ] unfold nip ; inline
 428
 429 : index ( obj seq -- n )
 430     [ = ] with find drop ;
 431
 432 : index-from ( obj i seq -- n )
 433     rot [ = ] curry find-from drop ;
 434
 435 : last-index ( obj seq -- n )
 436     [ = ] with find-last drop ;
 437
 438 : last-index-from ( obj i seq -- n )
 439     rot [ = ] curry find-last-from drop ;
 440
 441 : contains? ( seq quot -- ? )
 442     find drop >boolean ; inline
 443
 444 : member? ( obj seq -- ? )
 445     [ = ] with contains? ;
 446
 447 : memq? ( obj seq -- ? )
 448     [ eq? ] with contains? ;
 449
 450 : remove ( obj seq -- newseq )
 451     [ = not ] with filter ;
 452
 453 : sift ( seq -- newseq )
 454     [ ] filter ;
 455
 456 : harvest ( seq -- newseq )
 457     [ empty? not ] filter ;
 458
 459 : cache-nth ( i seq quot -- elt )
 460     2over ?nth dup [
 461         >r 3drop r>
 462     ] [
 463         drop swap >r over >r call dup r> r> set-nth
 464     ] if ; inline
 465
 466 : mismatch ( seq1 seq2 -- i )
 467     [ min-length ] 2keep
 468     [ 2nth-unsafe = not ] 2curry
 469     find drop ; inline
 470
 471 M: sequence <=>
 472     2dup mismatch
 473     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 474
 475 : sequence= ( seq1 seq2 -- ? )
 476     2dup [ length ] bi@ number=
 477     [ mismatch not ] [ 2drop f ] if ; inline
 478
 479 : sequence-hashcode-step ( oldhash newpart -- newhash )
 480     swap [
 481         dup -2 fixnum-shift-fast swap 5 fixnum-shift-fast
 482         fixnum+fast fixnum+fast
 483     ] keep fixnum-bitxor ; inline
 484
 485 : sequence-hashcode ( n seq -- x )
 486     0 -rot [
 487         hashcode* >fixnum sequence-hashcode-step
 488     ] with each ; inline
 489
 490 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 491
 492 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 493
 494 : move ( to from seq -- )
 495     2over number=
 496     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 497
 498 : (delete) ( elt store scan seq -- elt store scan seq )
 499     2dup length < [
 500         3dup move
 501         [ nth pick = ] 2keep rot
 502         [ >r >r 1+ r> r> ] unless >r 1+ r> (delete)
 503     ] when ;
 504
 505 : delete ( elt seq -- ) 0 0 rot (delete) nip set-length drop ;
 506
 507 : prefix ( seq elt -- newseq )
 508     over >r over length 1+ r> [
 509         [ 0 swap set-nth-unsafe ] keep
 510         [ 1 swap copy ] keep
 511     ] new-like ;
 512
 513 : suffix ( seq elt -- newseq )
 514     over >r over length 1+ r> [
 515         [ >r over length r> set-nth-unsafe ] keep
 516         [ 0 swap copy ] keep
 517     ] new-like ;
 518
 519 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 520
 521 : pop* ( seq -- ) [ length 1- ] [ set-length ] bi ;
 522
 523 : move-backward ( shift from to seq -- )
 524     2over number= [
 525         2drop 2drop
 526     ] [
 527         [ >r 2over + pick r> move >r 1+ r> ] keep
 528         move-backward
 529     ] if ;
 530
 531 : move-forward ( shift from to seq -- )
 532     2over number= [
 533         2drop 2drop
 534     ] [
 535         [ >r pick >r dup dup r> + swap r> move 1- ] keep
 536         move-forward
 537     ] if ;
 538
 539 : (open-slice) ( shift from to seq ? -- )
 540     [
 541         >r [ 1- ] bi@ r> move-forward
 542     ] [
 543         >r >r over - r> r> move-backward
 544     ] if ;
 545
 546 : open-slice ( shift from seq -- )
 547     pick zero? [
 548         3drop
 549     ] [
 550         pick over length + over >r >r
 551         pick 0 > >r [ length ] keep r> (open-slice)
 552         r> r> set-length
 553     ] if ;
 554
 555 : delete-slice ( from to seq -- )
 556     check-slice >r over >r - r> r> open-slice ;
 557
 558 : delete-nth ( n seq -- )
 559     >r dup 1+ r> delete-slice ;
 560
 561 : replace-slice ( new from to seq -- )
 562     [ >r >r dup pick length + r> - over r> open-slice ] keep
 563     copy ;
 564
 565 : pop ( seq -- elt )
 566     [ length 1- ] [ [ nth ] [ set-length ] 2bi ] bi ;
 567
 568 : all-equal? ( seq -- ? ) [ = ] monotonic? ;
 569
 570 : all-eq? ( seq -- ? ) [ eq? ] monotonic? ;
 571
 572 : exchange ( m n seq -- )
 573     pick over bounds-check 2drop 2dup bounds-check 2drop
 574     exchange-unsafe ;
 575
 576 : reverse-here ( seq -- )
 577     dup length dup 2/ [
 578         >r 2dup r>
 579         tuck - 1- rot exchange-unsafe
 580     ] each 2drop ;
 581
 582 : sum-lengths ( seq -- n )
 583     0 [ length + ] reduce ;
 584
 585 : concat ( seq -- newseq )
 586     dup empty? [
 587         drop { }
 588     ] [
 589         [ sum-lengths ] keep
 590         [ first new-resizable ] keep
 591         [ [ over push-all ] each ] keep
 592         first like
 593     ] if ;
 594
 595 : joined-length ( seq glue -- n )
 596     >r dup sum-lengths swap length 1 [-] r> length * + ;
 597
 598 : join ( seq glue -- newseq )
 599     [
 600         2dup joined-length over new-resizable spin
 601         [ dup pick push-all ] [ pick push-all ] interleave drop
 602     ] keep like ;
 603
 604 : padding ( seq n elt quot -- newseq )
 605     >r >r over length [-] dup zero?
 606     [ r> r> 3drop ] [ r> <repetition> r> call ] if ; inline
 607
 608 : pad-left ( seq n elt -- padded )
 609     [ swap dup (append) ] padding ;
 610
 611 : pad-right ( seq n elt -- padded )
 612     [ append ] padding ;
 613
 614 : shorter? ( seq1 seq2 -- ? ) >r length r> length < ;
 615
 616 : head? ( seq begin -- ? )
 617     2dup shorter? [
 618         2drop f
 619     ] [
 620         tuck length head-slice sequence=
 621     ] if ;
 622
 623 : tail? ( seq end -- ? )
 624     2dup shorter? [
 625         2drop f
 626     ] [
 627         tuck length tail-slice* sequence=
 628     ] if ;
 629
 630 : cut-slice ( seq n -- before after )
 631     [ head-slice ] [ tail-slice ] 2bi ;
 632
 633 : midpoint@ ( seq -- n ) length 2/ ; inline
 634
 635 : halves ( seq -- first second )
 636     dup midpoint@ cut-slice ;
 637
 638 : binary-reduce ( seq start quot -- value )
 639     #! We can't use case here since combinators depends on
 640     #! sequences
 641     pick length dup 0 3 between? [
 642         >fixnum {
 643             [ drop nip ]
 644             [ 2drop first ]
 645             [ >r drop first2 r> call ]
 646             [ >r drop first3 r> bi@ ]
 647         } dispatch
 648     ] [
 649         drop
 650         >r >r halves r> r>
 651         [ [ binary-reduce ] 2curry bi@ ] keep
 652         call
 653     ] if ; inline
 654
 655 : cut ( seq n -- before after )
 656     [ head ] [ tail ] 2bi ;
 657
 658 : cut* ( seq n -- before after )
 659     [ head* ] [ tail* ] 2bi ;
 660
 661 <PRIVATE
 662
 663 : (start) ( subseq seq n -- subseq seq ? )
 664     pick length [
 665         >r 3dup r> [ + swap nth-unsafe ] keep rot nth-unsafe =
 666     ] all? nip ; inline
 667
 668 PRIVATE>
 669
 670 : start* ( subseq seq n -- i )
 671     pick length pick length swap - 1+
 672     [ (start) ] find-from
 673     swap >r 3drop r> ;
 674
 675 : start ( subseq seq -- i ) 0 start* ; inline
 676
 677 : subseq? ( subseq seq -- ? ) start >boolean ;
 678
 679 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 680     2dup mismatch [ 2dup min-length ] unless*
 681     tuck tail-slice >r tail-slice r> ;
 682
 683 : unclip ( seq -- rest first )
 684     [ rest ] [ first ] bi ;
 685
 686 : unclip-last ( seq -- butlast last )
 687     [ but-last ] [ peek ] bi ;
 688
 689 : unclip-slice ( seq -- rest first )
 690     [ rest-slice ] [ first ] bi ;
 691
 692 : unclip-last-slice ( seq -- butfirst last )
 693     [ but-last-slice ] [ peek ] bi ;
 694
 695 : <flat-slice> ( seq -- slice )
 696     dup slice? [ { } like ] when 0 over length rot <slice> ;
 697     inline
 698
 699 : left-trim ( seq quot -- newseq )
 700     over >r [ not ] compose find drop r> swap
 701     [ tail ] [ dup length tail ] if* ; inline
 702
 703 : right-trim ( seq quot -- newseq )
 704     over >r [ not ] compose find-last drop r> swap
 705     [ 1+ head ] [ 0 head ] if* ; inline
 706
 707 : trim ( seq quot -- newseq )
 708     [ left-trim ] [ right-trim ] bi ; inline
 709
 710 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 711 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 712
 713 : infimum ( seq -- n ) dup first [ min ] reduce ;
 714 : supremum ( seq -- n ) dup first [ max ] reduce ;
 715
 716 : flip ( matrix -- newmatrix )
 717     dup empty? [
 718         dup [ length ] map infimum
 719         swap [ [ nth-unsafe ] with { } map-as ] curry { } map-as
 720     ] unless ;
 721
 722 : sigma ( seq quot -- n ) [ + ] compose 0 swap reduce ; inline
 723
 724 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 725