core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  38 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  39
  40 : empty? ( seq -- ? ) length 0 = ; inline
  41
  42 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  43     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  44
  45 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  46 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  47
  48 : delete-all ( seq -- ) 0 swap set-length ;
  49
  50 : first ( seq -- first ) 0 swap nth ; inline
  51 : second ( seq -- second ) 1 swap nth ; inline
  52 : third ( seq -- third ) 2 swap nth ; inline
  53 : fourth ( seq -- fourth ) 3 swap nth ; inline
  54
  55 : set-first ( first seq -- ) 0 swap set-nth ; inline
  56 : set-second ( second seq -- ) 1 swap set-nth ; inline
  57 : set-third ( third seq -- ) 2 swap set-nth ; inline
  58 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  59
  60 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  61
  62 ERROR: bounds-error index seq ;
  63
  64 GENERIC#: bounds-check? 1 ( n seq -- ? )
  65
  66 M: integer bounds-check?
  67     dupd length < [ 0 >= ] [ drop f ] if ; inline
  68
  69 : bounds-check ( n seq -- n seq )
  70     2dup bounds-check? [ bounds-error ] unless ; inline
  71
  72 MIXIN: immutable-sequence
  73
  74 ERROR: immutable element index sequence ;
  75
  76 M: immutable-sequence set-nth immutable ;
  77
  78 INSTANCE: immutable-sequence sequence
  79
  80 <PRIVATE
  81
  82 : array-nth ( n array -- elt )
  83     swap 2 fixnum+fast slot ; inline
  84
  85 : set-array-nth ( elt n array -- )
  86     swap 2 fixnum+fast set-slot ; inline
  87
  88 : dispatch ( n array -- ) array-nth call ;
  89
  90 GENERIC: resize ( n seq -- newseq ) flushable
  91
  92 ! Unsafe sequence protocol for inner loops
  93 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  94 GENERIC: set-nth-unsafe ( elt n seq -- )
  95
  96 M: sequence nth bounds-check nth-unsafe ; inline
  97 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  98
  99 M: sequence nth-unsafe nth ; inline
 100 M: sequence set-nth-unsafe set-nth ; inline
 101
 102 PRIVATE>
 103
 104 ! The f object supports the sequence protocol trivially
 105 M: f length drop 0 ; inline
 106 M: f nth-unsafe nip ; inline
 107 M: f like drop [ f ] when-empty ; inline
 108
 109 INSTANCE: f immutable-sequence
 110
 111 ! Integer sequences
 112 TUPLE: iota { n integer read-only } ;
 113
 114 : <iota> ( n -- iota )
 115     assert-non-negative iota boa ; inline
 116
 117 M: iota length n>> ; inline
 118 M: iota nth-unsafe drop ; inline
 119
 120 INSTANCE: iota immutable-sequence
 121
 122 <PRIVATE
 123
 124 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 125 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 126 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 127 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 128
 129 : first2-unsafe ( seq -- first second )
 130     [ first-unsafe ] [ second-unsafe ] bi ; inline
 131
 132 : first3-unsafe ( seq -- first second third )
 133     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 134
 135 : first4-unsafe ( seq -- first second third fourth )
 136     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 137
 138 : exchange-unsafe ( m n seq -- )
 139     [ [ nth-unsafe ] curry bi@ ]
 140     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 141
 142 : (1sequence) ( obj seq -- seq )
 143     [ 0 swap set-nth-unsafe ] keep ; inline
 144
 145 : (2sequence) ( obj1 obj2 seq -- seq )
 146     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 147
 148 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 149     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 153
 154 PRIVATE>
 155
 156 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 157
 158 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 159
 160 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 161
 162 : 1sequence ( obj exemplar -- seq )
 163     1 swap [ (1sequence) ] new-like ; inline
 164
 165 : 2sequence ( obj1 obj2 exemplar -- seq )
 166     2 swap [ (2sequence) ] new-like ; inline
 167
 168 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 169     3 swap [ (3sequence) ] new-like ; inline
 170
 171 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 172     4 swap [ (4sequence) ] new-like ; inline
 173
 174 : first2 ( seq -- first second )
 175     1 swap bounds-check nip first2-unsafe ; inline
 176
 177 : first3 ( seq -- first second third )
 178     2 swap bounds-check nip first3-unsafe ; inline
 179
 180 : first4 ( seq -- first second third fourth )
 181     3 swap bounds-check nip first4-unsafe ; inline
 182
 183  : ?nth ( n seq -- elt/f )
 184     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 185
 186 : ?set-nth ( elt n seq -- )
 187     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 188
 189 : index-or-length ( seq n -- seq n' ) over length min ; inline
 190
 191 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 192
 193 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 194 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 195 : ?last ( seq -- elt/f )
 196     index-of-last over 0 <
 197     [ 2drop f ] [ nth-unsafe ] if ; inline
 198
 199 MIXIN: virtual-sequence
 200 GENERIC: virtual-exemplar ( seq -- seq' )
 201 GENERIC: virtual@ ( n seq -- n' seq' )
 202
 203 M: virtual-sequence nth virtual@ nth ; inline
 204 M: virtual-sequence set-nth virtual@ set-nth ; inline
 205 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 206 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 207 M: virtual-sequence like virtual-exemplar like ; inline
 208 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 209
 210 INSTANCE: virtual-sequence sequence
 211
 212 ! A reversal of an underlying sequence.
 213 TUPLE: reversed { seq read-only } ;
 214
 215 C: <reversed> reversed
 216
 217 M: reversed virtual-exemplar seq>> ; inline
 218 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 219 M: reversed length seq>> length ; inline
 220
 221 INSTANCE: reversed virtual-sequence
 222
 223 ! A slice of another sequence.
 224 TUPLE: slice
 225     { from integer read-only }
 226     { to integer read-only }
 227     { seq read-only } ;
 228
 229 : >slice< ( slice -- from to seq )
 230     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 231
 232 : collapse-slice ( m n slice -- m' n' seq )
 233     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 234
 235 ERROR: slice-error from to seq ;
 236
 237 : check-slice ( from to seq -- from to seq )
 238     pick 0 < [ slice-error ] when
 239     2dup length > [ slice-error ] when
 240     2over > [ slice-error ] when ; inline
 241
 242 <PRIVATE
 243
 244 : <slice-unsafe> ( from to seq -- slice )
 245     dup slice? [ collapse-slice ] when slice boa ; inline
 246
 247 PRIVATE>
 248
 249 : <slice> ( from to seq -- slice )
 250     check-slice <slice-unsafe> ; inline
 251
 252 M: slice virtual-exemplar seq>> ; inline
 253
 254 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 255
 256 M: slice length [ to>> ] [ from>> ] bi - ; inline
 257
 258 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 259
 260 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 261
 262 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 263
 264 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 265
 266 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 267
 268 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 269
 270 INSTANCE: slice virtual-sequence
 271
 272 ! One element repeated many times
 273 TUPLE: repetition
 274     { length integer read-only }
 275     { elt read-only } ;
 276
 277 : <repetition> ( len elt -- repetition )
 278     over 0 < [ non-negative-integer-expected ] when
 279     repetition boa ; inline
 280
 281 M: repetition length length>> ; inline
 282 M: repetition nth-unsafe nip elt>> ; inline
 283
 284 INSTANCE: repetition immutable-sequence
 285
 286 <PRIVATE
 287
 288 ERROR: integer-length-expected obj ;
 289
 290 ! The check-length call forces partial dispatch
 291 : check-length ( n -- n )
 292     dup integer? [ integer-length-expected ] unless ; inline
 293
 294 : >sequence< ( seq -- i n seq )
 295     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 296
 297 : length-sequence ( seq -- n seq )
 298     [ length check-length ] [ ] bi ; inline
 299
 300 : >underlying< ( slice/seq -- from to slice/seq )
 301     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 302
 303 TUPLE: copier
 304     { src-i integer read-only }
 305     { src read-only }
 306     { dst-i integer read-only }
 307     { dst read-only } ;
 308
 309 C: <copier> copier
 310
 311 : copy-nth-unsafe ( n copy -- )
 312     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 313     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 314
 315 : (copy) ( n copy -- dst )
 316     over 0 <= [ nip dst>> ] [
 317         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 318     ] if ; inline recursive
 319
 320 : subseq>copy ( from to seq -- n copy )
 321     [ over - check-length swap ] dip
 322     3dup nip new-sequence 0 swap <copier> ; inline
 323
 324 : bounds-check-head ( n seq -- n seq )
 325     over 0 < [ bounds-error ] when ; inline
 326
 327 : copy-unsafe ( src i dst -- )
 328     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 329
 330 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 331     [ subseq>copy (copy) ] dip like ; inline
 332
 333 : subseq-unsafe ( from to seq -- subseq )
 334     dup subseq-unsafe-as ; inline
 335
 336 : change-nth-unsafe ( i seq quot -- )
 337     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 338
 339 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 340
 341 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 342
 343 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 344     nth-of-unsafe set-nth-of-unsafe drop ; inline
 345
 346 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 347     2dup >= [
 348         4drop
 349     ] [
 350         [
 351             [ copy-nth-of-unsafe ] 4keep
 352             [ 1 + ] 2dip 1 +
 353         ] dip copy-loop
 354     ] if ; inline recursive
 355
 356 PRIVATE>
 357
 358 : subseq-as ( from to seq exemplar -- subseq )
 359     [ check-slice ] dip subseq-unsafe-as ;
 360
 361 : subseq ( from to seq -- subseq )
 362     dup subseq-as ;
 363
 364 : head ( seq n -- headseq ) head-to-index subseq ;
 365
 366 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 367
 368 : rest ( seq -- tailseq ) 1 tail ;
 369
 370 : head* ( seq n -- headseq ) from-tail head ;
 371
 372 : tail* ( seq n -- tailseq ) from-tail tail ;
 373
 374 : but-last ( seq -- headseq ) 1 head* ;
 375
 376 : copy ( src i dst -- )
 377     3dup bounds-check-head
 378     [ swap length + ] dip lengthen
 379     copy-unsafe ; inline
 380
 381 M: sequence clone-like
 382     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 383
 384 M: immutable-sequence clone-like like ; inline
 385
 386 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 387
 388 <PRIVATE
 389
 390 : (append) ( seq1 seq2 accum -- accum )
 391     [ [ over length ] dip copy-unsafe ]
 392     [ 0 swap copy-unsafe ]
 393     [ ] tri ; inline
 394
 395 PRIVATE>
 396
 397 : append-as ( seq1 seq2 exemplar -- newseq )
 398     [ 2dup 2length + ] dip
 399     [ (append) ] new-like ; inline
 400
 401 : append ( seq1 seq2 -- newseq ) over append-as ;
 402
 403 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 404
 405 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 406
 407 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 408     [ 3dup 3length + + ] dip [
 409         [ [ 2over 2length + ] dip copy-unsafe ]
 410         [ (append) ] bi
 411     ] new-like ; inline
 412
 413 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 414
 415 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 416     [ swap ] 2dip 3append-as ; inline
 417
 418 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 419
 420 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 421
 422 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 423
 424 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 425
 426 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 427
 428 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 429     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 430
 431 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 432
 433 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 434
 435 <PRIVATE
 436
 437 : sequence-operator ( seq quot -- i n quot' )
 438     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 439
 440 : length-iterator ( seq -- n quot' )
 441     length-sequence [ nth-unsafe ] curry ; inline
 442
 443 : length-operator ( seq quot -- n quot' )
 444     [ length-iterator ] dip compose ; inline
 445
 446 : collect-into ( quot into -- quot' )
 447     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 448
 449 : collect-from ( i n quot into -- )
 450     collect-into each-integer-from ; inline
 451
 452 : collect ( n quot into -- )
 453     collect-into each-integer ; inline
 454
 455 : sequence-index-operator ( seq quot -- n quot' )
 456     [ length-iterator [ keep ] curry ] dip compose ; inline
 457
 458 : map-into ( seq quot into -- )
 459     [ length-operator ] dip collect ; inline
 460
 461 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 462     [ nth-unsafe ] bi-curry@ bi ; inline
 463
 464 : 2length-iterator ( seq1 seq2 -- n quot )
 465     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 466
 467 : 2length-operator ( seq1 seq2 quot -- n quot' )
 468     [ 2length-iterator ] dip compose ; inline
 469
 470 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 471     [ nth-unsafe ] tri-curry@ tri ; inline
 472
 473 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 474     [ 3length min min check-length ]
 475     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 476
 477 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 478     [ 3length-iterator ] dip compose ; inline
 479
 480 : element/index ( i/f seq -- elt/f i/f )
 481     '[ [ _ nth ] [ f ] if* ] keep ; inline
 482
 483 : index/element ( i/f seq -- i/f elt/f )
 484     dupd '[ _ nth ] [ f ] if* ; inline
 485
 486 : (accumulate) ( seq identity quot -- identity seq quot' )
 487     swapd [ keepd ] curry ; inline
 488
 489 : (accumulate*) ( seq identity quot -- identity seq quot' )
 490     swapd [ dup ] compose ; inline
 491
 492 PRIVATE>
 493
 494 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 495     sequence-operator each-integer-from ; inline
 496
 497 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 498     -rot length-operator each-integer-from ; inline
 499
 500 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 501     swapd each ; inline
 502
 503 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 504     overd [ [ collect-from ] keep ] new-like ; inline
 505
 506 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 507     overd [ [ collect ] keep ] new-like ; inline
 508
 509 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 510     { } map-integers-as ; inline
 511
 512 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 513     [ length-operator ] dip map-integers-as ; inline
 514
 515 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 516     over map-as ; inline
 517
 518 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 519     [ [ drop ] prepose ] dip map-integers-as ; inline
 520
 521 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 522     { } replicate-as ; inline
 523
 524 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 525     over [ map-into ] keep ; inline
 526
 527 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 528     [ (accumulate) ] dip map-as ; inline
 529
 530 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 531     pick accumulate-as ; inline
 532
 533 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 534     (accumulate) map! ; inline
 535
 536 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 537     [ (accumulate*) ] dip map-as nip ; inline
 538
 539 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 540     pick accumulate*-as ; inline
 541
 542 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 543     (accumulate*) map! nip ; inline
 544
 545 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 546     2length-operator each-integer ; inline
 547
 548 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 549     -roll 2length-operator each-integer-from ; inline
 550
 551 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 552     -rotd 2each ; inline
 553
 554 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 555     [ 2length-operator ] dip map-integers-as ; inline
 556
 557 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 558     pick 2map-as ; inline
 559
 560 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 561     2length-operator all-integers? ; inline
 562
 563 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 564     negate 2all? not ; inline
 565
 566 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 567     3length-operator each-integer ; inline
 568
 569 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 570     [ 3length-operator ] dip map-integers-as ; inline
 571
 572 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 573     pickd swap 3map-as ; inline
 574
 575 <PRIVATE
 576
 577 : bounds-check-call ( n seq quot -- obj1 obj2 )
 578     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 579
 580 : do-find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 581     [ length-operator find-integer-from ] keepd ; inline
 582
 583 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 584     [ length-operator nip find-last-integer ] keepd ; inline
 585
 586 PRIVATE>
 587
 588 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 589     '[ _ do-find-from index/element ] bounds-check-call ; inline
 590
 591 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 592     [ 0 ] 2dip do-find-from index/element ; inline
 593
 594 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 595     '[ _ find-last-from-unsafe index/element ] bounds-check-call ; inline
 596
 597 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 598     [ index-of-last ] dip find-last-from ; inline
 599
 600 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 601     '[
 602         _ [ sequence-index-operator find-integer-from ] keepd
 603         index/element
 604     ] bounds-check-call ; inline
 605
 606 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 607     [ 0 ] 2dip find-index-from ; inline
 608
 609 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 610     sequence-operator all-integers-from? ; inline
 611
 612 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 613     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 614
 615 <PRIVATE
 616
 617 : (selector-as) ( quot length exemplar -- selector accum )
 618     new-resizable [ [ push-when ] 2curry ] keep ; inline
 619
 620 PRIVATE>
 621
 622 : selector-as ( quot exemplar -- selector accum )
 623     [ length ] keep (selector-as) ; inline
 624
 625 : selector ( quot -- selector accum )
 626     V{ } selector-as ; inline
 627
 628 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 629     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 630
 631 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 632     over filter-as ; inline
 633
 634 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 635     [ negate ] [ filter-as ] bi* ; inline
 636
 637 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 638     over reject-as ; inline
 639
 640 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 641     [ keep swap ] 2dip ? push ; inline
 642
 643 : 2selector ( quot -- selector accum1 accum2 )
 644     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 645
 646 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 647     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 648
 649 : collector-as ( quot exemplar -- quot' vec )
 650     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 651
 652 : collector ( quot -- quot' vec )
 653     V{ } collector-as ; inline
 654
 655 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 656     dup [ collector-as [ while ] dip ] curry dip like ; inline
 657
 658 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 659     { } produce-as ; inline
 660
 661 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 662     [ dup ] swap [ keep ] curry produce nip ; inline
 663
 664 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 665     sequence-index-operator each-integer ; inline
 666
 667 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 668     [ dup length <iota> ] 2dip 2map-as ; inline
 669
 670 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 671     over map-index-as ; inline
 672
 673 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 674     pick empty? [ 3drop ] [
 675         [ [ drop first-unsafe ] dip call ]
 676         [ [ bi* ] 2curry 1 each-from ]
 677         3bi
 678     ] if ; inline
 679
 680 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 681     swapd each-index ; inline
 682
 683 : index ( obj seq -- n )
 684     [ = ] with find drop ;
 685
 686 : index-from ( obj i seq -- n )
 687     rot [ = ] curry find-from drop ;
 688
 689 : last-index ( obj seq -- n )
 690     [ = ] with find-last drop ;
 691
 692 : last-index-from ( obj i seq -- n )
 693     rot [ = ] curry find-last-from drop ;
 694
 695 : indices ( obj seq -- indices )
 696     swap [ = ] curry [ swap ] prepose V{ } clone [
 697         [ push ] curry [ [ drop ] if ] curry compose each-index
 698     ] keep ;
 699
 700 <PRIVATE
 701
 702 : nths-unsafe ( indices seq -- seq' )
 703     [ [ nth-unsafe ] curry ] keep map-as ;
 704
 705 PRIVATE>
 706
 707 : nths ( indices seq -- seq' )
 708     [ [ nth ] curry ] keep map-as ;
 709
 710 : nths-of ( seq indices -- seq' )
 711     swap nths ; inline
 712
 713 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 714     find drop >boolean ; inline
 715
 716 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 717     any? not ; inline
 718
 719 : member? ( elt seq -- ? )
 720     [ = ] with any? ;
 721
 722 : member-eq? ( elt seq -- ? )
 723     [ eq? ] with any? ;
 724
 725 : remove ( elt seq -- newseq )
 726     [ = ] with reject ;
 727
 728 : remove-eq ( elt seq -- newseq )
 729     [ eq? ] with reject ;
 730
 731 : sift ( seq -- newseq )
 732     [ ] filter ;
 733
 734 : harvest ( seq -- newseq )
 735     [ empty? ] reject ;
 736
 737 <PRIVATE
 738
 739 : mismatch-unsafe ( n seq1 seq2 -- i )
 740     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 741
 742 PRIVATE>
 743
 744 : mismatch ( seq1 seq2 -- i )
 745     [ min-length ] 2keep mismatch-unsafe ;
 746
 747 M: sequence <=>
 748     [ mismatch ] 2keep pick
 749     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 750
 751 : sequence= ( seq1 seq2 -- ? )
 752     2dup 2length dupd =
 753     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 754
 755 ERROR: assert-sequence got expected ;
 756
 757 : assert-sequence= ( a b -- )
 758     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 759
 760 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 761
 762 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 763
 764 <PRIVATE
 765
 766 : sequence-hashcode-step ( oldhash newpart -- newhash )
 767     integer>fixnum swap [
 768         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 769         fixnum+fast fixnum+fast
 770     ] keep fixnum-bitxor ; inline
 771
 772 PRIVATE>
 773
 774 : sequence-hashcode ( n seq -- x )
 775     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 776
 777 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 778
 779 M: iota hashcode*
 780     over 0 <= [ 2drop 0 ] [
 781         nip length 0 swap [ sequence-hashcode-step ] each-integer
 782     ] if ;
 783
 784 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 785
 786 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 787
 788 : move ( to from seq -- )
 789     2over =
 790     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 791
 792 <PRIVATE
 793
 794 : move-unsafe* ( to from seq -- from-nth )
 795     2over =
 796     [ nth-unsafe nip ]
 797     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 798
 799 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 800     2over length < [
 801         [ [ move-unsafe* ] dip call ] 4keep
 802         [ swap [ 1 + ] when ] 3dip
 803         [ 1 + ] 2dip filter-from!
 804     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 805
 806 : move-unsafe ( to from seq -- )
 807     2over =
 808     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 809
 810 PRIVATE>
 811
 812 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 813     [ 0 0 ] 2dip filter-from! ; inline
 814
 815 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 816     negate filter! ; inline
 817
 818 : remove! ( elt seq -- seq )
 819     [ = ] with reject! ;
 820
 821 : remove-eq! ( elt seq -- seq )
 822     [ eq? ] with reject! ;
 823
 824 : prefix ( seq elt -- newseq )
 825     over [ over length 1 + ] dip [
 826         (1sequence) [ 1 swap copy-unsafe ] keep
 827     ] new-like ;
 828
 829 : suffix ( seq elt -- newseq )
 830     over [ over length 1 + ] dip [
 831         [ [ over length ] dip set-nth-unsafe ] keep
 832         [ 0 swap copy-unsafe ] keep
 833     ] new-like ;
 834
 835 : suffix! ( seq elt -- seq ) over push ; inline
 836
 837 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 838
 839 : last ( seq -- elt )
 840     index-of-last
 841     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 842
 843 <PRIVATE
 844
 845 : last-unsafe ( seq -- elt )
 846     index-of-last nth-unsafe ; inline
 847
 848 PRIVATE>
 849
 850 : set-last ( elt seq -- )
 851     index-of-last
 852     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 853
 854 : pop* ( seq -- ) index-of-last shorten ;
 855
 856 <PRIVATE
 857
 858 : move-backward ( shift from to seq -- )
 859     2over = [
 860         4drop
 861     ] [
 862         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 863         move-backward
 864     ] if ;
 865
 866 : open-slice ( shift from seq -- )
 867     pick 0 = [
 868         3drop
 869     ] [
 870         [ ] [ nip length + ] [ 2nip ] 3tri
 871         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 872         set-length
 873     ] if ;
 874
 875 PRIVATE>
 876
 877 : delete-slice ( from to seq -- )
 878     check-slice [ over [ - ] dip ] dip open-slice ;
 879
 880 : remove-nth! ( n seq -- seq )
 881     [ [ dup 1 + ] dip delete-slice ] keep ;
 882
 883 : snip ( from to seq -- head tail )
 884     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 885
 886 : snip-slice ( from to seq -- head tail )
 887     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 888
 889 : replace-slice ( new from to seq -- seq' )
 890     snip-slice surround ;
 891
 892 : remove-nth ( n seq -- seq' )
 893     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 894
 895 : pop ( seq -- elt )
 896     index-of-last over 0 >=
 897     [ [ nth-unsafe ] [ shorten ] 2bi ]
 898     [ bounds-error ] if ;
 899
 900 : exchange ( m n seq -- )
 901     [ nip bounds-check 2drop ]
 902     [ bounds-check 3drop ]
 903     [ exchange-unsafe ]
 904     3tri ;
 905
 906 : midpoint@ ( seq -- n ) length 2/ ; inline
 907
 908 : reverse! ( seq -- seq )
 909     [
 910         [ midpoint@ ] [ length ] [ ] tri
 911         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 912         each-integer
 913     ] keep ;
 914
 915 : reverse ( seq -- newseq )
 916     [
 917         dup [ length ] keep new-sequence
 918         [ 0 swap copy-unsafe ] keep reverse!
 919     ] keep like ;
 920
 921 GENERIC: sum-lengths ( seq -- n )
 922
 923 M: object sum-lengths
 924     0 [ length + ] reduce ;
 925
 926 M: repetition sum-lengths
 927     [ length>> ] [ elt>> length ] bi * ;
 928
 929 : concat-as ( seq exemplar -- newseq )
 930     [
 931         [ dup sum-lengths ] dip new-resizable
 932         [ [ push-all ] curry each ] keep
 933     ] keep like ; inline
 934
 935 : concat ( seq -- newseq )
 936     [ { } ] [ dup first concat-as ] if-empty ;
 937
 938 <PRIVATE
 939
 940 : joined-length ( seq glue -- n )
 941     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 942
 943 PRIVATE>
 944
 945 : join-as ( seq glue exemplar -- newseq )
 946     over empty? [ nip concat-as ] [
 947         [
 948             2dup joined-length over new-resizable [
 949                 [ [ push-all ] 2curry ]
 950                 [ nip [ push-all ] curry ] 2bi
 951                 interleave
 952             ] keep
 953         ] dip like
 954     ] if ;
 955
 956 : join ( seq glue -- newseq )
 957     dup join-as ; inline
 958
 959 <PRIVATE
 960
 961 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 962     [
 963         [ over length [-] dup 0 = [ drop ] ] dip
 964         [ <repetition> ] curry
 965     ] dip compose if ; inline
 966
 967 PRIVATE>
 968
 969 : pad-head ( seq n elt -- padded )
 970     [ swap dup append-as ] padding ;
 971
 972 : pad-tail ( seq n elt -- padded )
 973     [ append ] padding ;
 974
 975 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
 976 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
 977 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
 978 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
 979
 980 : head? ( seq begin -- ? )
 981     2dup shorter? [
 982         2drop f
 983     ] [
 984         [ length [ head-slice ] keep swap ] keep
 985         mismatch-unsafe not
 986     ] if ;
 987
 988 : tail? ( seq end -- ? )
 989     2dup shorter? [
 990         2drop f
 991     ] [
 992         [ length [ tail-slice* ] keep swap ] keep
 993         mismatch-unsafe not
 994     ] if ;
 995
 996 : cut-slice ( seq n -- before-slice after-slice )
 997     [ head-slice ] [ tail-slice ] 2bi ; inline
 998
 999 : cut-slice* ( seq n -- before-slice after-slice )
1000     [ head-slice* ] [ tail-slice* ] 2bi ;
1001
1002 : insert-nth ( elt n seq -- seq' )
1003     swap cut-slice [ swap suffix ] dip append ;
1004
1005 : halves ( seq -- first-slice second-slice )
1006     dup midpoint@ cut-slice ; inline
1007
1008 <PRIVATE
1009
1010 : nth2-unsafe ( n seq -- a b )
1011     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1012
1013 : nth3-unsafe ( n seq -- a b c )
1014     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1015
1016 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1017     ! We can't use case here since combinators depends on
1018     ! sequences
1019     dup 4 < [
1020         integer>fixnum {
1021             [ 2drop nip ]
1022             [ 2nip swap nth-unsafe ]
1023             [ -rot [ drop swap nth2-unsafe ] dip call ]
1024             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1025         } dispatch
1026     ] [
1027         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1028         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1029         pick [ 3bi ] dip call
1030     ] if ; inline recursive
1031
1032 PRIVATE>
1033
1034 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1035     pick dup slice? [
1036         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1037     ] [
1038         length 0 max 0 swap
1039     ] if (binary-reduce) ; inline
1040
1041 : cut ( seq n -- before after )
1042     [ head ] [ tail ] 2bi ;
1043
1044 : cut* ( seq n -- before after )
1045     [ head* ] [ tail* ] 2bi ;
1046
1047 : subseq-starts-at? ( i seq subseq -- ? )
1048     [ length swap ] keep
1049     '[
1050         [ + _ nth-unsafe ] keep _ nth-unsafe =
1051     ] with all-integers? ; inline
1052
1053 : subseq-index-from ( n seq subseq -- i/f )
1054     [ 2length - 1 + ] 2keep
1055     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1056
1057 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1058
1059 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1060
1061 : subseq-start-from ( subseq seq n -- i/f )
1062     spin subseq-index-from ; inline deprecated
1063
1064 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1065
1066 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1067
1068 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1069     2dup mismatch [ 2dup min-length ] unless*
1070     [ tail-slice ] curry bi@ ;
1071
1072 : unclip ( seq -- rest first )
1073     [ rest ] [ first-unsafe ] bi ;
1074
1075 : unclip-last ( seq -- butlast last )
1076     [ but-last ] [ last-unsafe ] bi ;
1077
1078 : unclip-slice ( seq -- rest-slice first )
1079     [ rest-slice ] [ first-unsafe ] bi ; inline
1080
1081 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1082     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1083     '[ swap _ dip swap @ ] 1 each-from ; inline
1084
1085 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1086     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1087     '[ rot _ dip swap @ ] 1 2each-from ; inline
1088
1089 <PRIVATE
1090
1091 : (map-find) ( seq quot find-quot -- result elt )
1092     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1093
1094 PRIVATE>
1095
1096 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1097     [ find ] (map-find) ; inline
1098
1099 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1100     [ find-last ] (map-find) ; inline
1101
1102 : unclip-last-slice ( seq -- butlast-slice last )
1103     [ but-last-slice ] [ last-unsafe ] bi ; inline
1104
1105 <PRIVATE
1106
1107 : (trim-head) ( seq quot -- seq n )
1108     over [ negate find drop ] dip swap
1109     [ dup length ] unless* ; inline
1110
1111 : (trim-tail) ( seq quot -- seq n )
1112     over [ negate find-last drop ?1+ ] dip
1113     swap ; inline
1114
1115 PRIVATE>
1116
1117 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1118     (trim-head) tail-slice ; inline
1119
1120 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1121     (trim-head) tail ; inline
1122
1123 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1124     (trim-tail) head-slice ; inline
1125
1126 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1127     (trim-tail) head ; inline
1128
1129 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1130     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1131
1132 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1133     [ trim-slice ] [ drop ] 2bi like ; inline
1134
1135 GENERIC: sum ( seq -- n )
1136 M: object sum 0 [ + ] binary-reduce ; inline
1137 M: iota sum length dup 1 - * 2/ ; inline
1138 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1139
1140 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1141
1142 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1143
1144 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1145
1146 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1147     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1148
1149 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1150     [ 1 0 ? ] compose map-sum ; inline
1151
1152 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1153     [ with each ] 2curry each ; inline
1154
1155 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1156     [ with { } map-as ] 2curry { } map-as ; inline
1157
1158 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1159     [ 2sequence ] curry cartesian-map ; inline
1160
1161 : cartesian-product ( seq1 seq2 -- newseq )
1162     dup cartesian-product-as ; inline
1163
1164 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1165     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1166
1167 <PRIVATE
1168
1169 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1170     [
1171         [ keep swap ] curry [ [ first ] dip call ] 2keep
1172         [ curry 2dip pick over ] curry
1173     ] [
1174         [ [ 2drop ] [ 2nipd ] if ] compose
1175     ] bi* compose 1 each-from drop ; inline
1176
1177 PRIVATE>
1178
1179 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1180     [ after? ] select-by ; inline
1181
1182 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1183     [ before? ] select-by ; inline
1184
1185 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1186
1187 : longest ( seqs -- elt ) [ length ] supremum-by ;
1188
1189 ! We hand-optimize flip to such a degree because type hints
1190 ! cannot express that an array is an array of arrays yet, and
1191 ! this word happens to be performance-critical since the compiler
1192 ! itself uses it. Optimizing it like this reduced compile time.
1193 <PRIVATE
1194
1195 : generic-flip ( matrix -- newmatrix )
1196     [ [ length ] [ min ] map-reduce ] keep
1197     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1198
1199 USE: arrays
1200
1201 : array-flip ( matrix -- newmatrix )
1202     { array } declare
1203     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1204     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1205
1206 PRIVATE>
1207
1208 : flip ( matrix -- newmatrix )
1209     dup empty? [
1210         dup array? [
1211             dup [ array? ] all?
1212             [ array-flip ] [ generic-flip ] if
1213         ] [ generic-flip ] if
1214     ] unless ;