core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  38 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  39
  40 : empty? ( seq -- ? ) length 0 = ; inline
  41
  42 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  43     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  44
  45 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  46 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  47
  48 : delete-all ( seq -- ) 0 swap set-length ;
  49
  50 : first ( seq -- first ) 0 swap nth ; inline
  51 : second ( seq -- second ) 1 swap nth ; inline
  52 : third ( seq -- third ) 2 swap nth ; inline
  53 : fourth ( seq -- fourth ) 3 swap nth ; inline
  54
  55 : set-first ( first seq -- ) 0 swap set-nth ; inline
  56 : set-second ( second seq -- ) 1 swap set-nth ; inline
  57 : set-third ( third seq -- ) 2 swap set-nth ; inline
  58 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  59
  60 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  61
  62 ERROR: bounds-error index seq ;
  63
  64 GENERIC#: bounds-check? 1 ( n seq -- ? )
  65
  66 M: integer bounds-check?
  67     dupd length < [ 0 >= ] [ drop f ] if ; inline
  68
  69 : bounds-check ( n seq -- n seq )
  70     2dup bounds-check? [ bounds-error ] unless ; inline
  71
  72 MIXIN: immutable-sequence
  73
  74 ERROR: immutable element index sequence ;
  75
  76 M: immutable-sequence set-nth immutable ;
  77
  78 INSTANCE: immutable-sequence sequence
  79
  80 <PRIVATE
  81
  82 : array-nth ( n array -- elt )
  83     swap 2 fixnum+fast slot ; inline
  84
  85 : set-array-nth ( elt n array -- )
  86     swap 2 fixnum+fast set-slot ; inline
  87
  88 : dispatch ( n array -- ) array-nth call ;
  89
  90 GENERIC: resize ( n seq -- newseq ) flushable
  91
  92 ! Unsafe sequence protocol for inner loops
  93 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  94 GENERIC: set-nth-unsafe ( elt n seq -- )
  95
  96 M: sequence nth bounds-check nth-unsafe ; inline
  97 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  98
  99 M: sequence nth-unsafe nth ; inline
 100 M: sequence set-nth-unsafe set-nth ; inline
 101
 102 PRIVATE>
 103
 104 ! The f object supports the sequence protocol trivially
 105 M: f length drop 0 ; inline
 106 M: f nth-unsafe nip ; inline
 107 M: f like drop [ f ] when-empty ; inline
 108
 109 INSTANCE: f immutable-sequence
 110
 111 ! Integer sequences
 112 TUPLE: iota { n integer read-only } ;
 113
 114 ERROR: non-negative-integer-expected n ;
 115
 116 : ensure-non-negative ( n -- n )
 117     dup 0 < [ non-negative-integer-expected ] when ; inline
 118
 119 : <iota> ( n -- iota )
 120     ensure-non-negative iota boa ; inline
 121
 122 M: iota length n>> ; inline
 123 M: iota nth-unsafe drop ; inline
 124
 125 INSTANCE: iota immutable-sequence
 126
 127 <PRIVATE
 128
 129 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 130 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 131 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 132 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 133
 134 : first2-unsafe ( seq -- first second )
 135     [ first-unsafe ] [ second-unsafe ] bi ; inline
 136
 137 : first3-unsafe ( seq -- first second third )
 138     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 139
 140 : first4-unsafe ( seq -- first second third fourth )
 141     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 142
 143 : exchange-unsafe ( m n seq -- )
 144     [ [ nth-unsafe ] curry bi@ ]
 145     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 146
 147 : (1sequence) ( obj seq -- seq )
 148     [ 0 swap set-nth-unsafe ] keep ; inline
 149
 150 : (2sequence) ( obj1 obj2 seq -- seq )
 151     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 152
 153 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 154     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 155
 156 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 157     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 158
 159 PRIVATE>
 160
 161 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 162
 163 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 164
 165 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 166
 167 : 1sequence ( obj exemplar -- seq )
 168     1 swap [ (1sequence) ] new-like ; inline
 169
 170 : 2sequence ( obj1 obj2 exemplar -- seq )
 171     2 swap [ (2sequence) ] new-like ; inline
 172
 173 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 174     3 swap [ (3sequence) ] new-like ; inline
 175
 176 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 177     4 swap [ (4sequence) ] new-like ; inline
 178
 179 : first2 ( seq -- first second )
 180     1 swap bounds-check nip first2-unsafe ; inline
 181
 182 : first3 ( seq -- first second third )
 183     2 swap bounds-check nip first3-unsafe ; inline
 184
 185 : first4 ( seq -- first second third fourth )
 186     3 swap bounds-check nip first4-unsafe ; inline
 187
 188 : ??nth ( n seq -- elt/f ? )
 189     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 190
 191 : ?nth ( n seq -- elt/f ) ??nth drop ; inline
 192
 193 : ?set-nth ( elt n seq -- )
 194     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 195
 196 : index-or-length ( seq n -- seq n' ) over length min ; inline
 197
 198 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 199
 200 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 201 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 202 : ?last ( seq -- elt/f )
 203     index-of-last over 0 <
 204     [ 2drop f ] [ nth-unsafe ] if ; inline
 205
 206 MIXIN: virtual-sequence
 207 GENERIC: virtual-exemplar ( seq -- seq' )
 208 GENERIC: virtual@ ( n seq -- n' seq' )
 209
 210 M: virtual-sequence nth virtual@ nth ; inline
 211 M: virtual-sequence set-nth virtual@ set-nth ; inline
 212 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 213 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 214 M: virtual-sequence like virtual-exemplar like ; inline
 215 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 216
 217 INSTANCE: virtual-sequence sequence
 218
 219 ! A reversal of an underlying sequence.
 220 TUPLE: reversed { seq read-only } ;
 221
 222 C: <reversed> reversed
 223
 224 M: reversed virtual-exemplar seq>> ; inline
 225 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 226 M: reversed length seq>> length ; inline
 227
 228 INSTANCE: reversed virtual-sequence
 229
 230 ! A slice of another sequence.
 231 TUPLE: slice
 232     { from integer read-only }
 233     { to integer read-only }
 234     { seq read-only } ;
 235
 236 : >slice< ( slice -- from to seq )
 237     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 238
 239 : collapse-slice ( m n slice -- m' n' seq )
 240     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 241
 242 ERROR: slice-error from to seq ;
 243
 244 : check-slice ( from to seq -- from to seq )
 245     pick 0 < [ slice-error ] when
 246     2dup length > [ slice-error ] when
 247     2over > [ slice-error ] when ; inline
 248
 249 <PRIVATE
 250
 251 : <slice-unsafe> ( from to seq -- slice )
 252     dup slice? [ collapse-slice ] when slice boa ; inline
 253
 254 PRIVATE>
 255
 256 : <slice> ( from to seq -- slice )
 257     check-slice <slice-unsafe> ; inline
 258
 259 M: slice virtual-exemplar seq>> ; inline
 260
 261 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 262
 263 M: slice length [ to>> ] [ from>> ] bi - ; inline
 264
 265 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 266
 267 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 268
 269 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 270
 271 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 272
 273 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 274
 275 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 276
 277 INSTANCE: slice virtual-sequence
 278
 279 ! One element repeated many times
 280 TUPLE: repetition
 281     { length integer read-only }
 282     { elt read-only } ;
 283
 284 : <repetition> ( len elt -- repetition )
 285     over 0 < [ non-negative-integer-expected ] when
 286     repetition boa ; inline
 287
 288 M: repetition length length>> ; inline
 289 M: repetition nth-unsafe nip elt>> ; inline
 290
 291 INSTANCE: repetition immutable-sequence
 292
 293 <PRIVATE
 294
 295 ERROR: integer-length-expected obj ;
 296
 297 ! The check-length call forces partial dispatch
 298 : check-length ( n -- n )
 299     dup integer? [ integer-length-expected ] unless ; inline
 300
 301 : >sequence< ( seq -- i n seq )
 302     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 303
 304 : length-sequence ( seq -- n seq )
 305     [ length check-length ] [ ] bi ; inline
 306
 307 : >underlying< ( slice/seq -- from to slice/seq )
 308     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 309
 310 TUPLE: copier
 311     { src-i integer read-only }
 312     { src read-only }
 313     { dst-i integer read-only }
 314     { dst read-only } ;
 315
 316 C: <copier> copier
 317
 318 : copy-nth-unsafe ( n copy -- )
 319     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 320     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 321
 322 : (copy) ( n copy -- dst )
 323     over 0 <= [ nip dst>> ] [
 324         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 325     ] if ; inline recursive
 326
 327 : subseq>copy ( from to seq -- n copy )
 328     [ over - check-length swap ] dip
 329     3dup nip new-sequence 0 swap <copier> ; inline
 330
 331 : bounds-check-head ( n seq -- n seq )
 332     over 0 < [ bounds-error ] when ; inline
 333
 334 : check-grow-copy ( dst n src -- dst src n )
 335     over [ lengthd + lengthen ] 2keep ; inline
 336
 337 : copy-unsafe ( src i dst -- )
 338     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 339
 340 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 341     [ subseq>copy (copy) ] dip like ; inline
 342
 343 : subseq-unsafe ( from to seq -- subseq )
 344     dup subseq-unsafe-as ; inline
 345
 346 : change-nth-unsafe ( i seq quot -- )
 347     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 348
 349 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 350
 351 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 352
 353 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 354     nth-of-unsafe set-nth-of-unsafe drop ; inline
 355
 356 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 357     2dup >= [
 358         4drop
 359     ] [
 360         [
 361             [ copy-nth-of-unsafe ] 4keep
 362             [ 1 + ] 2dip 1 +
 363         ] dip copy-loop
 364     ] if ; inline recursive
 365
 366 PRIVATE>
 367
 368 : subseq-as ( from to seq exemplar -- subseq )
 369     [ check-slice ] dip subseq-unsafe-as ;
 370
 371 : subseq ( from to seq -- subseq )
 372     dup subseq-as ;
 373
 374 : head ( seq n -- headseq ) head-to-index subseq ;
 375
 376 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 377
 378 : rest ( seq -- tailseq ) 1 tail ;
 379
 380 : head* ( seq n -- headseq ) from-tail head ;
 381
 382 : tail* ( seq n -- tailseq ) from-tail tail ;
 383
 384 : but-last ( seq -- headseq ) 1 head* ;
 385
 386 : copy ( src i dst -- )
 387     3dup bounds-check-head
 388     [ swap length + ] dip lengthen
 389     copy-unsafe ; inline
 390
 391 M: sequence clone-like
 392     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 393
 394 M: immutable-sequence clone-like like ; inline
 395
 396 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 397
 398 <PRIVATE
 399
 400 : (append) ( seq1 seq2 accum -- accum )
 401     [ [ over length ] dip copy-unsafe ]
 402     [ 0 swap copy-unsafe ]
 403     [ ] tri ; inline
 404
 405 PRIVATE>
 406
 407 : append-as ( seq1 seq2 exemplar -- newseq )
 408     [ 2dup 2length + ] dip
 409     [ (append) ] new-like ; inline
 410
 411 : append ( seq1 seq2 -- newseq ) over append-as ;
 412
 413 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 414
 415 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 416
 417 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 418     [ 3dup 3length + + ] dip [
 419         [ [ 2over 2length + ] dip copy-unsafe ]
 420         [ (append) ] bi
 421     ] new-like ; inline
 422
 423 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 424
 425 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 426     [ swap ] 2dip 3append-as ; inline
 427
 428 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 429
 430 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 431
 432 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 433
 434 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 435
 436 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 437
 438 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 439     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 440
 441 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 442
 443 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 444
 445 <PRIVATE
 446
 447 : sequence-operator ( seq quot -- i n quot' )
 448     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 449
 450 : length-iterator ( seq -- n quot' )
 451     length-sequence [ nth-unsafe ] curry ; inline
 452
 453 : length-operator ( seq quot -- n quot' )
 454     [ length-iterator ] dip compose ; inline
 455
 456 : collect-into ( quot into -- quot' )
 457     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 458
 459 : collect-from ( i n quot into -- )
 460     collect-into each-integer-from ; inline
 461
 462 : collect ( n quot into -- )
 463     collect-into each-integer ; inline
 464
 465 : sequence-index-operator ( seq quot -- n quot' )
 466     [ length-iterator [ keep ] curry ] dip compose ; inline
 467
 468 : map-into ( seq quot into -- )
 469     [ length-operator ] dip collect ; inline
 470
 471 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 472     [ nth-unsafe ] bi-curry@ bi ; inline
 473
 474 : 2length-iterator ( seq1 seq2 -- n quot )
 475     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 476
 477 : 2length-operator ( seq1 seq2 quot -- n quot' )
 478     [ 2length-iterator ] dip compose ; inline
 479
 480 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 481     [ nth-unsafe ] tri-curry@ tri ; inline
 482
 483 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 484     [ 3length min min check-length ]
 485     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 486
 487 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 488     [ 3length-iterator ] dip compose ; inline
 489
 490 : element/index ( i/f seq -- elt/f i/f )
 491     '[ [ _ nth ] [ f ] if* ] keep ; inline
 492
 493 : index/element ( i/f seq -- i/f elt/f )
 494     dupd '[ _ nth ] [ f ] if* ; inline
 495
 496 : (accumulate) ( seq identity quot -- identity seq quot' )
 497     swapd [ keepd ] curry ; inline
 498
 499 : (accumulate*) ( seq identity quot -- identity seq quot' )
 500     swapd [ dup ] compose ; inline
 501
 502 PRIVATE>
 503
 504 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 505     sequence-operator each-integer-from ; inline
 506
 507 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 508     -rot length-operator each-integer-from ; inline
 509
 510 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 511     swapd each ; inline
 512
 513 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 514     overd [ [ collect-from ] keep ] new-like ; inline
 515
 516 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 517     overd [ [ collect ] keep ] new-like ; inline
 518
 519 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 520     { } map-integers-as ; inline
 521
 522 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 523     [ length-operator ] dip map-integers-as ; inline
 524
 525 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 526     over map-as ; inline
 527
 528 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 529     [ [ drop ] prepose ] dip map-integers-as ; inline
 530
 531 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 532     { } replicate-as ; inline
 533
 534 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 535     over [ map-into ] keep ; inline
 536
 537 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 538     [ (accumulate) ] dip map-as ; inline
 539
 540 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 541     pick accumulate-as ; inline
 542
 543 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 544     (accumulate) map! ; inline
 545
 546 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 547     [ (accumulate*) ] dip map-as nip ; inline
 548
 549 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 550     pick accumulate*-as ; inline
 551
 552 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 553     (accumulate*) map! nip ; inline
 554
 555 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 556     2length-operator each-integer ; inline
 557
 558 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 559     -roll 2length-operator each-integer-from ; inline
 560
 561 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 562     -rotd 2each ; inline
 563
 564 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 565     [ 2length-operator ] dip map-integers-as ; inline
 566
 567 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 568     pick 2map-as ; inline
 569
 570 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 571     2length-operator all-integers? ; inline
 572
 573 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 574     negate 2all? not ; inline
 575
 576 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 577     3length-operator each-integer ; inline
 578
 579 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 580     [ 3length-operator ] dip map-integers-as ; inline
 581
 582 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 583     pickd swap 3map-as ; inline
 584
 585 <PRIVATE
 586
 587 : bounds-check-call ( n seq quot -- obj1 obj2 )
 588     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 589
 590 : do-find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 591     [ length-operator find-integer-from ] keepd ; inline
 592
 593 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 594     [ length-operator nip find-last-integer ] keepd ; inline
 595
 596 PRIVATE>
 597
 598 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 599     '[ _ do-find-from index/element ] bounds-check-call ; inline
 600
 601 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 602     [ 0 ] 2dip do-find-from index/element ; inline
 603
 604 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 605     '[ _ find-last-from-unsafe index/element ] bounds-check-call ; inline
 606
 607 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 608     [ index-of-last ] dip find-last-from ; inline
 609
 610 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 611     '[
 612         _ [ sequence-index-operator find-integer-from ] keepd
 613         index/element
 614     ] bounds-check-call ; inline
 615
 616 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 617     [ 0 ] 2dip find-index-from ; inline
 618
 619 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 620     '[ _ do-find-from element/index ] bounds-check-call ; inline
 621
 622 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 623     [ 0 ] 2dip do-find-from element/index ; inline
 624
 625 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 626     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
 627
 628 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 629     [ index-of-last ] dip find-last-from* ; inline
 630
 631 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 632     '[
 633         _ [ sequence-index-operator find-integer-from ] keepd
 634         element/index
 635     ] bounds-check-call ; inline
 636
 637 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 638     [ 0 ] 2dip find-index-from* ; inline
 639
 640 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 641     sequence-operator all-integers-from? ; inline
 642
 643 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 644     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 645
 646 <PRIVATE
 647
 648 : (selector-as) ( quot length exemplar -- selector accum )
 649     new-resizable [ [ push-when ] 2curry ] keep ; inline
 650
 651 PRIVATE>
 652
 653 : selector-as ( quot exemplar -- selector accum )
 654     [ length ] keep (selector-as) ; inline
 655
 656 : selector ( quot -- selector accum )
 657     V{ } selector-as ; inline
 658
 659 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 660     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 661
 662 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 663     over filter-as ; inline
 664
 665 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 666     [ negate ] [ filter-as ] bi* ; inline
 667
 668 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 669     over reject-as ; inline
 670
 671 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 672     [ keep swap ] 2dip ? push ; inline
 673
 674 : 2selector ( quot -- selector accum1 accum2 )
 675     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 676
 677 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 678     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 679
 680 : collector-as ( quot exemplar -- quot' vec )
 681     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 682
 683 : collector ( quot -- quot' vec )
 684     V{ } collector-as ; inline
 685
 686 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 687     dup [ collector-as [ while ] dip ] curry dip like ; inline
 688
 689 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 690     { } produce-as ; inline
 691
 692 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 693     [ dup ] swap [ keep ] curry produce nip ; inline
 694
 695 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 696     sequence-index-operator each-integer ; inline
 697
 698 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 699     [ dup length <iota> ] 2dip 2map-as ; inline
 700
 701 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 702     over map-index-as ; inline
 703
 704 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 705     pick empty? [ 3drop ] [
 706         [ [ drop first-unsafe ] dip call ]
 707         [ [ bi* ] 2curry 1 each-from ]
 708         3bi
 709     ] if ; inline
 710
 711 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 712     swapd each-index ; inline
 713
 714 : index ( obj seq -- n )
 715     [ = ] with find drop ;
 716
 717 : index-from ( obj i seq -- n )
 718     rot [ = ] curry find-from drop ;
 719
 720 : last-index ( obj seq -- n )
 721     [ = ] with find-last drop ;
 722
 723 : last-index-from ( obj i seq -- n )
 724     rot [ = ] curry find-last-from drop ;
 725
 726 : indices ( obj seq -- indices )
 727     swap [ = ] curry [ swap ] prepose V{ } clone [
 728         [ push ] curry [ [ drop ] if ] curry compose each-index
 729     ] keep ;
 730
 731 <PRIVATE
 732
 733 : nths-unsafe ( indices seq -- seq' )
 734     [ [ nth-unsafe ] curry ] keep map-as ;
 735
 736 PRIVATE>
 737
 738 : nths ( indices seq -- seq' )
 739     [ [ nth ] curry ] keep map-as ;
 740
 741 : nths-of ( seq indices -- seq' )
 742     swap nths ; inline
 743
 744 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 745     find drop >boolean ; inline
 746
 747 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 748     any? not ; inline
 749
 750 : member? ( elt seq -- ? )
 751     [ = ] with any? ;
 752
 753 : member-eq? ( elt seq -- ? )
 754     [ eq? ] with any? ;
 755
 756 : remove ( elt seq -- newseq )
 757     [ = ] with reject ;
 758
 759 : remove-eq ( elt seq -- newseq )
 760     [ eq? ] with reject ;
 761
 762 : sift ( seq -- newseq )
 763     [ ] filter ;
 764
 765 : harvest ( seq -- newseq )
 766     [ empty? ] reject ;
 767
 768 <PRIVATE
 769
 770 : mismatch-unsafe ( n seq1 seq2 -- i )
 771     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 772
 773 PRIVATE>
 774
 775 : mismatch ( seq1 seq2 -- i )
 776     [ min-length ] 2keep mismatch-unsafe ;
 777
 778 M: sequence <=>
 779     [ mismatch ] 2keep pick
 780     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 781
 782 : sequence= ( seq1 seq2 -- ? )
 783     2dup 2length dupd =
 784     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 785
 786 ERROR: assert-sequence got expected ;
 787
 788 : assert-sequence= ( a b -- )
 789     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 790
 791 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 792
 793 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 794
 795 <PRIVATE
 796
 797 : sequence-hashcode-step ( oldhash newpart -- newhash )
 798     integer>fixnum swap [
 799         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 800         fixnum+fast fixnum+fast
 801     ] keep fixnum-bitxor ; inline
 802
 803 PRIVATE>
 804
 805 : sequence-hashcode ( n seq -- x )
 806     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 807
 808 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 809
 810 M: iota hashcode*
 811     over 0 <= [ 2drop 0 ] [
 812         nip length 0 swap [ sequence-hashcode-step ] each-integer
 813     ] if ;
 814
 815 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 816
 817 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 818
 819 : move ( to from seq -- )
 820     2over =
 821     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 822
 823 <PRIVATE
 824
 825 : move-unsafe* ( to from seq -- from-nth )
 826     2over =
 827     [ nth-unsafe nip ]
 828     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 829
 830 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 831     2over length < [
 832         [ [ move-unsafe* ] dip call ] 4keep
 833         [ swap [ 1 + ] when ] 3dip
 834         [ 1 + ] 2dip filter-from!
 835     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 836
 837 : move-unsafe ( to from seq -- )
 838     2over =
 839     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 840
 841 PRIVATE>
 842
 843 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 844     [ 0 0 ] 2dip filter-from! ; inline
 845
 846 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 847     negate filter! ; inline
 848
 849 : remove! ( elt seq -- seq )
 850     [ = ] with reject! ;
 851
 852 : remove-eq! ( elt seq -- seq )
 853     [ eq? ] with reject! ;
 854
 855 : prefix ( seq elt -- newseq )
 856     over [ over length 1 + ] dip [
 857         (1sequence) [ 1 swap copy-unsafe ] keep
 858     ] new-like ;
 859
 860 : suffix ( seq elt -- newseq )
 861     over [ over length 1 + ] dip [
 862         [ [ over length ] dip set-nth-unsafe ] keep
 863         [ 0 swap copy-unsafe ] keep
 864     ] new-like ;
 865
 866 : suffix! ( seq elt -- seq ) over push ; inline
 867
 868 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 869
 870 : last ( seq -- elt )
 871     index-of-last
 872     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 873
 874 <PRIVATE
 875
 876 : last-unsafe ( seq -- elt )
 877     index-of-last nth-unsafe ; inline
 878
 879 PRIVATE>
 880
 881 : set-last ( elt seq -- )
 882     index-of-last
 883     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 884
 885 : pop* ( seq -- ) index-of-last shorten ;
 886
 887 <PRIVATE
 888
 889 : move-backward ( shift from to seq -- )
 890     2over = [
 891         4drop
 892     ] [
 893         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 894         move-backward
 895     ] if ;
 896
 897 : open-slice ( shift from seq -- )
 898     pick 0 = [
 899         3drop
 900     ] [
 901         [ ] [ nip length + ] [ 2nip ] 3tri
 902         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 903         set-length
 904     ] if ;
 905
 906 PRIVATE>
 907
 908 : delete-slice ( from to seq -- )
 909     check-slice [ over [ - ] dip ] dip open-slice ;
 910
 911 : remove-nth! ( n seq -- seq )
 912     [ [ dup 1 + ] dip delete-slice ] keep ;
 913
 914 : snip ( from to seq -- head tail )
 915     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 916
 917 : snip-slice ( from to seq -- head tail )
 918     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 919
 920 : replace-slice ( new from to seq -- seq' )
 921     snip-slice surround ;
 922
 923 : remove-nth ( n seq -- seq' )
 924     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 925
 926 : pop ( seq -- elt )
 927     index-of-last over 0 >=
 928     [ [ nth-unsafe ] [ shorten ] 2bi ]
 929     [ bounds-error ] if ;
 930
 931 : exchange ( m n seq -- )
 932     [ nip bounds-check 2drop ]
 933     [ bounds-check 3drop ]
 934     [ exchange-unsafe ]
 935     3tri ;
 936
 937 : midpoint@ ( seq -- n ) length 2/ ; inline
 938
 939 : reverse! ( seq -- seq )
 940     [
 941         [ midpoint@ ] [ length ] [ ] tri
 942         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 943         each-integer
 944     ] keep ;
 945
 946 : reverse ( seq -- newseq )
 947     [
 948         dup [ length ] keep new-sequence
 949         [ 0 swap copy-unsafe ] keep reverse!
 950     ] keep like ;
 951
 952 GENERIC: sum-lengths ( seq -- n )
 953
 954 M: object sum-lengths
 955     0 [ length + ] reduce ;
 956
 957 M: repetition sum-lengths
 958     [ length>> ] [ elt>> length ] bi * ;
 959
 960 : concat-as ( seq exemplar -- newseq )
 961     [
 962         [ dup sum-lengths ] dip new-resizable
 963         [ [ push-all ] curry each ] keep
 964     ] keep like ; inline
 965
 966 : concat ( seq -- newseq )
 967     [ { } ] [ dup first concat-as ] if-empty ;
 968
 969 <PRIVATE
 970
 971 : joined-length ( seq glue -- n )
 972     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 973
 974 PRIVATE>
 975
 976 : join-as ( seq glue exemplar -- newseq )
 977     over empty? [ nip concat-as ] [
 978         [
 979             2dup joined-length over new-resizable [
 980                 [ [ push-all ] 2curry ]
 981                 [ nip [ push-all ] curry ] 2bi
 982                 interleave
 983             ] keep
 984         ] dip like
 985     ] if ;
 986
 987 : join ( seq glue -- newseq )
 988     dup join-as ; inline
 989
 990 <PRIVATE
 991
 992 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 993     [
 994         [ over length [-] dup 0 = [ drop ] ] dip
 995         [ <repetition> ] curry
 996     ] dip compose if ; inline
 997
 998 PRIVATE>
 999
1000 : pad-head ( seq n elt -- padded )
1001     [ swap dup append-as ] padding ;
1002
1003 : pad-tail ( seq n elt -- padded )
1004     [ append ] padding ;
1005
1006 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
1007 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
1008 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
1009 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
1010
1011 : head? ( seq begin -- ? )
1012     2dup shorter? [
1013         2drop f
1014     ] [
1015         [ length [ head-slice ] keep swap ] keep
1016         mismatch-unsafe not
1017     ] if ;
1018
1019 : tail? ( seq end -- ? )
1020     2dup shorter? [
1021         2drop f
1022     ] [
1023         [ length [ tail-slice* ] keep swap ] keep
1024         mismatch-unsafe not
1025     ] if ;
1026
1027 : cut-slice ( seq n -- before-slice after-slice )
1028     [ head-slice ] [ tail-slice ] 2bi ; inline
1029
1030 : cut-slice* ( seq n -- before-slice after-slice )
1031     [ head-slice* ] [ tail-slice* ] 2bi ;
1032
1033 : insert-nth ( elt n seq -- seq' )
1034     swap cut-slice [ swap suffix ] dip append ;
1035
1036 : halves ( seq -- first-slice second-slice )
1037     dup midpoint@ cut-slice ; inline
1038
1039 <PRIVATE
1040
1041 : nth2-unsafe ( n seq -- a b )
1042     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1043
1044 : nth3-unsafe ( n seq -- a b c )
1045     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1046
1047 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1048     ! We can't use case here since combinators depends on
1049     ! sequences
1050     dup 4 < [
1051         integer>fixnum {
1052             [ 2drop nip ]
1053             [ 2nip swap nth-unsafe ]
1054             [ -rot [ drop swap nth2-unsafe ] dip call ]
1055             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1056         } dispatch
1057     ] [
1058         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1059         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1060         pick [ 3bi ] dip call
1061     ] if ; inline recursive
1062
1063 PRIVATE>
1064
1065 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1066     pick dup slice? [
1067         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1068     ] [
1069         length 0 max 0 swap
1070     ] if (binary-reduce) ; inline
1071
1072 : cut ( seq n -- before after )
1073     [ head ] [ tail ] 2bi ;
1074
1075 : cut* ( seq n -- before after )
1076     [ head* ] [ tail* ] 2bi ;
1077
1078 : subseq-starts-at? ( i seq subseq -- ? )
1079     [ length swap ] keep
1080     '[
1081         [ + _ nth-unsafe ] keep _ nth-unsafe =
1082     ] with all-integers? ; inline
1083
1084 : subseq-index-from ( n seq subseq -- i/f )
1085     [ 2length - 1 + ] 2keep
1086     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1087
1088 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1089
1090 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1091
1092 : subseq-start-from ( subseq seq n -- i/f )
1093     spin subseq-index-from ; inline deprecated
1094
1095 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1096
1097 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1098
1099 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1100     2dup mismatch [ 2dup min-length ] unless*
1101     [ tail-slice ] curry bi@ ;
1102
1103 : unclip ( seq -- rest first )
1104     [ rest ] [ first-unsafe ] bi ;
1105
1106 : unclip-last ( seq -- butlast last )
1107     [ but-last ] [ last-unsafe ] bi ;
1108
1109 : unclip-slice ( seq -- rest-slice first )
1110     [ rest-slice ] [ first-unsafe ] bi ; inline
1111
1112 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1113     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1114     '[ swap _ dip swap @ ] 1 each-from ; inline
1115
1116 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1117     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1118     '[ rot _ dip swap @ ] 1 2each-from ; inline
1119
1120 <PRIVATE
1121
1122 : (map-find) ( seq quot find-quot -- result elt )
1123     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1124
1125 PRIVATE>
1126
1127 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1128     [ find ] (map-find) ; inline
1129
1130 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1131     [ find-last ] (map-find) ; inline
1132
1133 : unclip-last-slice ( seq -- butlast-slice last )
1134     [ but-last-slice ] [ last-unsafe ] bi ; inline
1135
1136 <PRIVATE
1137
1138 : (trim-head) ( seq quot -- seq n )
1139     over [ negate find drop ] dip swap
1140     [ dup length ] unless* ; inline
1141
1142 : (trim-tail) ( seq quot -- seq n )
1143     over [ negate find-last drop ?1+ ] dip
1144     swap ; inline
1145
1146 PRIVATE>
1147
1148 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1149     (trim-head) tail-slice ; inline
1150
1151 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1152     (trim-head) tail ; inline
1153
1154 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1155     (trim-tail) head-slice ; inline
1156
1157 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1158     (trim-tail) head ; inline
1159
1160 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1161     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1162
1163 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1164     [ trim-slice ] [ drop ] 2bi like ; inline
1165
1166 GENERIC: sum ( seq -- n )
1167 M: object sum 0 [ + ] binary-reduce ; inline
1168 M: iota sum length dup 1 - * 2/ ; inline
1169 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1170
1171 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1172
1173 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1174
1175 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1176
1177 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1178     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1179
1180 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1181     [ 1 0 ? ] compose map-sum ; inline
1182
1183 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1184     [ with each ] 2curry each ; inline
1185
1186 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1187     [ with { } map-as ] 2curry { } map-as ; inline
1188
1189 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1190     [ 2sequence ] curry cartesian-map ; inline
1191
1192 : cartesian-product ( seq1 seq2 -- newseq )
1193     dup cartesian-product-as ; inline
1194
1195 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1196     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1197
1198 <PRIVATE
1199
1200 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1201     [
1202         [ keep swap ] curry [ [ first ] dip call ] 2keep
1203         [ curry 2dip pick over ] curry
1204     ] [
1205         [ [ 2drop ] [ 2nipd ] if ] compose
1206     ] bi* compose 1 each-from drop ; inline
1207
1208 PRIVATE>
1209
1210 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1211     [ after? ] select-by ; inline
1212
1213 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1214     [ before? ] select-by ; inline
1215
1216 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1217
1218 : longest ( seqs -- elt ) [ length ] supremum-by ;
1219
1220 ! We hand-optimize flip to such a degree because type hints
1221 ! cannot express that an array is an array of arrays yet, and
1222 ! this word happens to be performance-critical since the compiler
1223 ! itself uses it. Optimizing it like this reduced compile time.
1224 <PRIVATE
1225
1226 : generic-flip ( matrix -- newmatrix )
1227     [ [ length ] [ min ] map-reduce ] keep
1228     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1229
1230 USE: arrays
1231
1232 : array-flip ( matrix -- newmatrix )
1233     { array } declare
1234     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1235     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1236
1237 PRIVATE>
1238
1239 : flip ( matrix -- newmatrix )
1240     dup empty? [
1241         dup array? [
1242             dup [ array? ] all?
1243             [ array-flip ] [ generic-flip ] if
1244         ] [ generic-flip ] if
1245     ] unless ;