core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 PRIVATE>
  95
  96 ! The f object supports the sequence protocol trivially
  97 M: f length drop 0 ; inline
  98 M: f nth-unsafe nip ; inline
  99 M: f like drop [ f ] when-empty ; inline
 100
 101 INSTANCE: f immutable-sequence
 102
 103 ! Integer sequences
 104 TUPLE: iota { n integer read-only } ;
 105
 106 : iota ( n -- iota ) \ iota boa ; inline
 107
 108 M: iota length n>> ; inline
 109 M: iota nth-unsafe drop ; inline
 110
 111 INSTANCE: iota immutable-sequence
 112
 113 <PRIVATE
 114
 115 : first-unsafe ( seq -- first )
 116     0 swap nth-unsafe ; inline
 117
 118 : first2-unsafe ( seq -- first second )
 119     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 120
 121 : first3-unsafe ( seq -- first second third )
 122     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 123
 124 : first4-unsafe ( seq -- first second third fourth )
 125     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 126
 127 : exchange-unsafe ( m n seq -- )
 128     [ [ nth-unsafe ] curry bi@ ]
 129     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 130
 131 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 132
 133 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 134
 135 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 136
 137 : (1sequence) ( obj seq -- seq )
 138     [ 0 swap set-nth-unsafe ] keep ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep
 142     (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep
 146     (2sequence) ; inline
 147
 148 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 149     [ 3 swap set-nth-unsafe ] keep
 150     (3sequence) ; inline
 151
 152 PRIVATE>
 153
 154 : 1sequence ( obj exemplar -- seq )
 155     1 swap [ (1sequence) ] new-like ; inline
 156
 157 : 2sequence ( obj1 obj2 exemplar -- seq )
 158     2 swap [ (2sequence) ] new-like ; inline
 159
 160 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 161     3 swap [ (3sequence) ] new-like ; inline
 162
 163 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 164     4 swap [ (4sequence) ] new-like ; inline
 165
 166 : first2 ( seq -- first second )
 167     1 swap bounds-check nip first2-unsafe ; inline
 168
 169 : first3 ( seq -- first second third )
 170     2 swap bounds-check nip first3-unsafe ; inline
 171
 172 : first4 ( seq -- first second third fourth )
 173     3 swap bounds-check nip first4-unsafe ; inline
 174
 175 : ?nth ( n seq -- elt/f )
 176     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 177
 178 MIXIN: virtual-sequence
 179 GENERIC: virtual-exemplar ( seq -- seq' )
 180 GENERIC: virtual@ ( n seq -- n' seq' )
 181
 182 M: virtual-sequence nth virtual@ nth ; inline
 183 M: virtual-sequence set-nth virtual@ set-nth ; inline
 184 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 185 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 186 M: virtual-sequence like virtual-exemplar like ; inline
 187 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 188
 189 INSTANCE: virtual-sequence sequence
 190
 191 ! A reversal of an underlying sequence.
 192 TUPLE: reversed { seq read-only } ;
 193
 194 C: <reversed> reversed
 195
 196 M: reversed virtual-exemplar seq>> ; inline
 197 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 198 M: reversed length seq>> length ; inline
 199
 200 INSTANCE: reversed virtual-sequence
 201
 202 ! A slice of another sequence.
 203 TUPLE: slice
 204 { from read-only }
 205 { to read-only }
 206 { seq read-only } ;
 207
 208 : collapse-slice ( m n slice -- m' n' seq )
 209     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 210
 211 TUPLE: slice-error from to seq reason ;
 212
 213 : slice-error ( from to seq ? string -- from to seq )
 214     [ \ slice-error boa throw ] curry when ; inline
 215
 216 : check-slice ( from to seq -- from to seq )
 217     3dup
 218     [ 2drop 0 < "start < 0" slice-error ]
 219     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 220     [ drop > "start > end" slice-error ]
 221     3tri ; inline
 222
 223 : <slice> ( from to seq -- slice )
 224     check-slice
 225     dup slice? [ collapse-slice ] when
 226     slice boa ; inline
 227
 228 M: slice virtual-exemplar seq>> ; inline
 229
 230 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 231
 232 M: slice length [ to>> ] [ from>> ] bi - ; inline
 233
 234 : short ( seq n -- seq n' ) over length min ; inline
 235
 236 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 237
 238 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 239
 240 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 241
 242 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 243
 244 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 245
 246 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 247
 248 INSTANCE: slice virtual-sequence
 249
 250 ! One element repeated many times
 251 TUPLE: repetition { len read-only } { elt read-only } ;
 252
 253 C: <repetition> repetition
 254
 255 M: repetition length len>> ; inline
 256 M: repetition nth-unsafe nip elt>> ; inline
 257
 258 INSTANCE: repetition immutable-sequence
 259
 260 <PRIVATE
 261
 262 ERROR: integer-length-expected obj ;
 263
 264 : check-length ( n -- n )
 265     dup integer? [ integer-length-expected ] unless ; inline
 266
 267 TUPLE: copy-state
 268     { src-i read-only }
 269     { src read-only }
 270     { dst-i read-only }
 271     { dst read-only } ;
 272
 273 C: <copy> copy-state
 274
 275 : ((copy)) ( n copy -- )
 276     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 277     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 278
 279 : (copy) ( n copy -- dst )
 280     over 0 <= [ nip dst>> ] [ [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi ] if ;
 281     inline recursive
 282
 283 : subseq>copy ( from to seq -- n copy )
 284     [ over - check-length swap ] dip
 285     3dup nip new-sequence 0 swap <copy> ; inline
 286
 287 : check-copy ( src n dst -- src n dst )
 288     3dup over 0 < [ bounds-error ] when
 289     [ swap length + ] dip lengthen ; inline
 290
 291 PRIVATE>
 292
 293 : subseq ( from to seq -- subseq )
 294     [ check-slice subseq>copy (copy) ] keep like ;
 295
 296 : head ( seq n -- headseq ) (head) subseq ;
 297
 298 : tail ( seq n -- tailseq ) (tail) subseq ;
 299
 300 : rest ( seq -- tailseq ) 1 tail ;
 301
 302 : head* ( seq n -- headseq ) from-end head ;
 303
 304 : tail* ( seq n -- tailseq ) from-end tail ;
 305
 306 : but-last ( seq -- headseq ) 1 head* ;
 307
 308 : copy ( src i dst -- )
 309     #! The check-length call forces partial dispatch
 310     [ [ length check-length 0 ] keep ] 2dip
 311     check-copy <copy> (copy) drop ; inline
 312
 313 M: sequence clone-like
 314     [ dup length ] dip new-sequence [ 0 swap copy ] keep ; inline
 315
 316 M: immutable-sequence clone-like like ; inline
 317
 318 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 319
 320 <PRIVATE
 321
 322 : (append) ( seq1 seq2 accum -- accum )
 323     [ [ over length ] dip copy ]
 324     [ 0 swap copy ]
 325     [ ] tri ; inline
 326
 327 PRIVATE>
 328
 329 : append-as ( seq1 seq2 exemplar -- newseq )
 330     [ over length over length + ] dip
 331     [ (append) ] new-like ; inline
 332
 333 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 334     [ 3dup [ length ] tri@ + + ] dip [
 335         [ [ 2over [ length ] bi@ + ] dip copy ]
 336         [ (append) ] bi
 337     ] new-like ; inline
 338
 339 : append ( seq1 seq2 -- newseq ) over append-as ;
 340
 341 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 342
 343 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 344
 345 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 346
 347 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 348
 349 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 350     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 351
 352 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 353
 354 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 355
 356 <PRIVATE
 357
 358 : ((each)) ( seq -- n quot )
 359     [ length ] keep [ nth-unsafe ] curry ; inline
 360
 361 : (each) ( seq quot -- n quot' )
 362     [ ((each)) ] dip compose ; inline
 363
 364 : (each-index) ( seq quot -- n quot' )
 365     [ ((each)) [ keep ] curry ] dip compose ; inline
 366
 367 : (collect) ( quot into -- quot' )
 368     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 369
 370 : collect ( n quot into -- )
 371     (collect) each-integer ; inline
 372
 373 : map-into ( seq quot into -- )
 374     [ (each) ] dip collect ; inline
 375
 376 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 377     [ nth-unsafe ] bi-curry@ bi ; inline
 378
 379 : (2each) ( seq1 seq2 quot -- n quot' )
 380     [
 381         [ min-length ] 2keep
 382         [ 2nth-unsafe ] 2curry
 383     ] dip compose ; inline
 384
 385 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 386     [ nth-unsafe ] tri-curry@ tri ; inline
 387
 388 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 389     [
 390         [ [ length ] tri@ min min ]
 391         [ [ 3nth-unsafe ] 3curry ] 3bi
 392     ] dip compose ; inline
 393
 394 : finish-find ( i seq -- i elt )
 395     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 396
 397 : (find) ( seq quot quot' -- i elt )
 398     pick [ [ (each) ] dip call ] dip finish-find ; inline
 399
 400 : (find-from) ( n seq quot quot' -- i elt )
 401     [ 2dup bounds-check? ] 2dip
 402     [ (find) ] 2curry
 403     [ 2drop f f ]
 404     if ; inline
 405
 406 : (accumulate) ( seq identity quot -- identity seq quot )
 407     [ swap ] dip [ curry keep ] curry ; inline
 408
 409 PRIVATE>
 410
 411 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 412     (each) each-integer ; inline
 413
 414 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 415     swapd each ; inline
 416
 417 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 418     [ over ] dip [ [ collect ] keep ] new-like ; inline
 419
 420 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 421     [ (each) ] dip map-integers ; inline
 422
 423 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 424     over map-as ; inline
 425
 426 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 427     [ [ drop ] prepose ] dip map-integers ; inline
 428
 429 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 430     { } replicate-as ; inline
 431
 432 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 433     over [ map-into ] keep ; inline
 434
 435 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 436     [ (accumulate) ] dip map-as ; inline
 437
 438 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 439     pick accumulate-as ; inline
 440
 441 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 442     (accumulate) map! ; inline
 443
 444 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 445     (2each) each-integer ; inline
 446
 447 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 448     [ -rot ] dip 2each ; inline
 449
 450 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 451     [ (2each) ] dip map-integers ; inline
 452
 453 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 454     pick 2map-as ; inline
 455
 456 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 457     (2each) all-integers? ; inline
 458
 459 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 460     (3each) each-integer ; inline
 461
 462 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 463     [ (3each) ] dip map-integers ; inline
 464
 465 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 466     [ pick ] dip swap 3map-as ; inline
 467
 468 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 469     [ (find-integer) ] (find-from) ; inline
 470
 471 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 472     [ find-integer ] (find) ; inline
 473
 474 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 475     [ nip find-last-integer ] (find-from) ; inline
 476
 477 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 478     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 479
 480 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 481     (each) all-integers? ; inline
 482
 483 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 484     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 485
 486 : selector-for ( quot exemplar -- selector accum )
 487     [ length ] keep new-resizable [ [ push-if ] 2curry ] keep ; inline
 488
 489 : selector ( quot -- selector accum )
 490     V{ } selector-for ; inline
 491
 492 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 493     dup [ selector-for [ each ] dip ] curry dip like ; inline
 494
 495 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 496     over filter-as ; inline
 497
 498 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 499     [ keep swap ] 2dip ? push ; inline
 500
 501 : 2selector ( quot -- selector accum1 accum2 )
 502     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 503
 504 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 505     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 506
 507 : collector-for ( quot exemplar -- quot' vec )
 508     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 509
 510 : collector ( quot -- quot' vec )
 511     V{ } collector-for ; inline
 512
 513 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 514     dup [ collector-for [ while ] dip ] curry dip like ; inline
 515
 516 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 517     { } produce-as ; inline
 518
 519 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 520     [ dup ] swap [ keep ] curry produce nip ; inline
 521
 522 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 523     (each-index) each-integer ; inline
 524
 525 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 526     pick empty? [ 3drop ] [
 527         [ [ drop first-unsafe ] dip call ]
 528         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 529         3bi
 530     ] if ; inline
 531
 532 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 533     [ dup length iota ] dip 2map ; inline
 534
 535 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 536     swapd each-index ; inline
 537
 538 : index ( obj seq -- n )
 539     [ = ] with find drop ;
 540
 541 : index-from ( obj i seq -- n )
 542     rot [ = ] curry find-from drop ;
 543
 544 : last-index ( obj seq -- n )
 545     [ = ] with find-last drop ;
 546
 547 : last-index-from ( obj i seq -- n )
 548     rot [ = ] curry find-last-from drop ;
 549
 550 <PRIVATE
 551
 552 : (indices) ( elt i obj accum -- )
 553     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 554
 555 PRIVATE>
 556
 557 : indices ( obj seq -- indices )
 558     swap V{ } clone
 559     [ [ (indices) ] 2curry each-index ] keep ;
 560
 561 : nths ( indices seq -- seq' )
 562     [ [ nth ] curry ] keep map-as ;
 563
 564 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 565     find drop >boolean ; inline
 566
 567 : member? ( elt seq -- ? )
 568     [ = ] with any? ;
 569
 570 : member-eq? ( elt seq -- ? )
 571     [ eq? ] with any? ;
 572
 573 : remove ( elt seq -- newseq )
 574     [ = not ] with filter ;
 575
 576 : remove-eq ( elt seq -- newseq )
 577     [ eq? not ] with filter ;
 578
 579 : sift ( seq -- newseq )
 580     [ ] filter ;
 581
 582 : harvest ( seq -- newseq )
 583     [ empty? not ] filter ;
 584
 585 : mismatch ( seq1 seq2 -- i )
 586     [ min-length ] 2keep
 587     [ 2nth-unsafe = not ] 2curry
 588     find-integer ; inline
 589
 590 M: sequence <=>
 591     [ mismatch ] 2keep pick
 592     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 593
 594 : sequence= ( seq1 seq2 -- ? )
 595     2dup [ length ] bi@ =
 596     [ mismatch not ] [ 2drop f ] if ; inline
 597
 598 ERROR: assert-sequence got expected ;
 599
 600 : assert-sequence= ( a b -- )
 601     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 602
 603 : sequence-hashcode ( depth seq -- hash )
 604     [
 605         [ drop 1000003 HEX: 345678 ] dip length
 606         [ dup fixnum+fast 82520 fixnum+fast ] [ iota ] bi
 607     ] 2keep [
 608         swapd nth-unsafe hashcode* rot fixnum-bitxor
 609         pick fixnum*fast [ [ fixnum+fast ] keep ] dip swap
 610     ] 2curry each drop nip 97531 fixnum+fast ; inline
 611
 612 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 613
 614 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 615
 616 : move ( to from seq -- )
 617     2over =
 618     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 619
 620 <PRIVATE
 621
 622 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 623     2dup length < [
 624         [ move ] 3keep
 625         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 626         [ 1 + ] dip
 627         (filter!)
 628     ] [ nip set-length drop ] if ; inline recursive
 629
 630 PRIVATE>
 631
 632 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 633     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 634
 635 : remove! ( elt seq -- seq )
 636     [ = not ] with filter! ;
 637
 638 : remove-eq! ( elt seq -- seq )
 639     [ eq? not ] with filter! ;
 640
 641 : prefix ( seq elt -- newseq )
 642     over [ over length 1 + ] dip [
 643         [ 0 swap set-nth-unsafe ] keep
 644         [ 1 swap copy ] keep
 645     ] new-like ;
 646
 647 : suffix ( seq elt -- newseq )
 648     over [ over length 1 + ] dip [
 649         [ [ over length ] dip set-nth-unsafe ] keep
 650         [ 0 swap copy ] keep
 651     ] new-like ;
 652
 653 : suffix! ( seq elt -- seq ) over push ; inline
 654
 655 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 656
 657 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 658
 659 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 660
 661 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 662
 663 <PRIVATE
 664
 665 : move-backward ( shift from to seq -- )
 666     2over = [
 667         2drop 2drop
 668     ] [
 669         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 670         move-backward
 671     ] if ;
 672
 673 : move-forward ( shift from to seq -- )
 674     2over = [
 675         2drop 2drop
 676     ] [
 677         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 678         move-forward
 679     ] if ;
 680
 681 : (open-slice) ( shift from to seq ? -- )
 682     [
 683         [ [ 1 - ] bi@ ] dip move-forward
 684     ] [
 685         [ over - ] 2dip move-backward
 686     ] if ;
 687
 688 : open-slice ( shift from seq -- )
 689     pick 0 = [
 690         3drop
 691     ] [
 692         pick over length + over
 693         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 694         set-length
 695     ] if ;
 696
 697 PRIVATE>
 698
 699 : delete-slice ( from to seq -- )
 700     check-slice [ over [ - ] dip ] dip open-slice ;
 701
 702 : remove-nth! ( n seq -- seq )
 703     [ [ dup 1 + ] dip delete-slice ] keep ;
 704
 705 : snip ( from to seq -- head tail )
 706     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 707
 708 : snip-slice ( from to seq -- head tail )
 709     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 710
 711 : replace-slice ( new from to seq -- seq' )
 712     snip-slice surround ;
 713
 714 : remove-nth ( n seq -- seq' )
 715     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 716
 717 : pop ( seq -- elt )
 718     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 719
 720 : exchange ( m n seq -- )
 721     [ nip bounds-check 2drop ]
 722     [ bounds-check 3drop ]
 723     [ exchange-unsafe ]
 724     3tri ;
 725
 726 : reverse! ( seq -- seq )
 727     [
 728         [ length 2/ iota ] [ length ] [ ] tri
 729         [ [ over - 1 - ] dip exchange-unsafe ] 2curry each
 730     ] keep ;
 731
 732 : reverse ( seq -- newseq )
 733     [
 734         dup [ length ] keep new-sequence
 735         [ 0 swap copy ] keep reverse!
 736     ] keep like ;
 737
 738 : sum-lengths ( seq -- n )
 739     0 [ length + ] reduce ;
 740
 741 : concat-as ( seq exemplar -- newseq )
 742     swap [ { } ] [
 743         [ sum-lengths over new-resizable ] keep
 744         [ append! ] each
 745     ] if-empty swap like ;
 746
 747 : concat ( seq -- newseq )
 748     [ { } ] [ dup first concat-as ] if-empty ;
 749
 750 <PRIVATE
 751
 752 : joined-length ( seq glue -- n )
 753     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 754
 755 PRIVATE>
 756
 757 : join ( seq glue -- newseq )
 758     dup empty? [ concat-as ] [
 759         [
 760             2dup joined-length over new-resizable [
 761                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 762                 interleave
 763             ] keep
 764         ] keep like
 765     ] if ;
 766
 767 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 768     [
 769         [ over length [-] dup 0 = [ drop ] ] dip
 770         [ <repetition> ] curry
 771     ] dip compose if ; inline
 772
 773 : pad-head ( seq n elt -- padded )
 774     [ swap dup append-as ] padding ;
 775
 776 : pad-tail ( seq n elt -- padded )
 777     [ append ] padding ;
 778
 779 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 780
 781 : head? ( seq begin -- ? )
 782     2dup shorter? [
 783         2drop f
 784     ] [
 785         [ nip ] [ length head-slice ] 2bi sequence=
 786     ] if ;
 787
 788 : tail? ( seq end -- ? )
 789     2dup shorter? [
 790         2drop f
 791     ] [
 792         [ nip ] [ length tail-slice* ] 2bi sequence=
 793     ] if ;
 794
 795 : cut-slice ( seq n -- before-slice after-slice )
 796     [ head-slice ] [ tail-slice ] 2bi ;
 797
 798 : insert-nth ( elt n seq -- seq' )
 799     swap cut-slice [ swap suffix ] dip append ;
 800
 801 : midpoint@ ( seq -- n ) length 2/ ; inline
 802
 803 : halves ( seq -- first-slice second-slice )
 804     dup midpoint@ cut-slice ;
 805
 806 : binary-reduce ( ... seq start quot: ( ... elt1 elt2 -- ... newelt ) -- ... value )
 807     #! We can't use case here since combinators depends on
 808     #! sequences
 809     pick length dup 0 3 between? [
 810         >fixnum {
 811             [ drop nip ]
 812             [ 2drop first ]
 813             [ [ drop first2 ] dip call ]
 814             [ [ drop first3 ] dip bi@ ]
 815         } dispatch
 816     ] [
 817         drop
 818         [ halves ] 2dip
 819         [ [ binary-reduce ] 2curry bi@ ] keep
 820         call
 821     ] if ; inline recursive
 822
 823 : cut ( seq n -- before after )
 824     [ head ] [ tail ] 2bi ;
 825
 826 : cut* ( seq n -- before after )
 827     [ head* ] [ tail* ] 2bi ;
 828
 829 <PRIVATE
 830
 831 : (start) ( subseq seq n -- subseq seq ? )
 832     pick length iota [
 833         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 834     ] all? nip ; inline
 835
 836 : prepare-2map-reduce ( seq1 seq2 map-quot -- initial length seq1 seq2 )
 837     [ drop min-length dup 1 < [ "Empty sequence" throw ] when 1 - ]
 838     [ drop [ [ 1 + ] 2dip 2nth-unsafe ] 2curry ]
 839     [ [ [ first-unsafe ] bi@ ] dip call ]
 840     3tri -rot ; inline
 841
 842 PRIVATE>
 843
 844 : start* ( subseq seq n -- i )
 845     pick length pick length swap - 1 + iota
 846     [ (start) ] find-from
 847     swap [ 3drop ] dip ;
 848
 849 : start ( subseq seq -- i ) 0 start* ; inline
 850
 851 : subseq? ( subseq seq -- ? ) start >boolean ;
 852
 853 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 854     2dup mismatch [ 2dup min-length ] unless*
 855     [ tail-slice ] curry bi@ ;
 856
 857 : unclip ( seq -- rest first )
 858     [ rest ] [ first-unsafe ] bi ;
 859
 860 : unclip-last ( seq -- butlast last )
 861     [ but-last ] [ last ] bi ;
 862
 863 : unclip-slice ( seq -- rest-slice first )
 864     [ rest-slice ] [ first-unsafe ] bi ; inline
 865
 866 : map-reduce ( ..a seq map-quot: ( ..a x -- ..b elt ) reduce-quot: ( ..b prev elt -- ..a next ) -- ..a result )
 867     [ [ unclip-slice ] dip [ call ] keep ] dip
 868     compose reduce ; inline
 869
 870 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 871     [ [ prepare-2map-reduce ] keep ] dip
 872     compose compose each-integer ; inline
 873
 874 <PRIVATE
 875
 876 : (map-find) ( seq quot find-quot -- result elt )
 877     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 878     [ [ drop f ] unless ] dip ; inline
 879
 880 PRIVATE>
 881
 882 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 883     [ find ] (map-find) ; inline
 884
 885 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 886     [ find-last ] (map-find) ; inline
 887
 888 : unclip-last-slice ( seq -- butlast-slice last )
 889     [ but-last-slice ] [ last ] bi ; inline
 890
 891 <PRIVATE
 892
 893 : (trim-head) ( seq quot -- seq n )
 894     over [ [ not ] compose find drop ] dip
 895     [ length or ] keep swap ; inline
 896
 897 : (trim-tail) ( seq quot -- seq n )
 898     over [ [ not ] compose find-last drop ?1+ ] dip
 899     swap ; inline
 900
 901 PRIVATE>
 902
 903 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 904     (trim-head) tail-slice ; inline
 905
 906 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 907     (trim-head) tail ; inline
 908
 909 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 910     (trim-tail) head-slice ; inline
 911
 912 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 913     (trim-tail) head ; inline
 914
 915 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 916     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 917
 918 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 919     [ trim-slice ] [ drop ] 2bi like ; inline
 920
 921 GENERIC: sum ( seq -- n )
 922 M: object sum 0 [ + ] binary-reduce ; inline
 923
 924 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 925
 926 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 927
 928 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 929
 930 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 931     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 932
 933 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n ) [ 1 0 ? ] compose map-sum ; inline
 934
 935 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 936     [ with each ] 2curry each ; inline
 937
 938 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 939     [ with map ] 2curry map ; inline
 940
 941 : cartesian-product ( seq1 seq2 -- newseq )
 942     [ { } 2sequence ] cartesian-map ;
 943
 944 ! We hand-optimize flip to such a degree because type hints
 945 ! cannot express that an array is an array of arrays yet, and
 946 ! this word happens to be performance-critical since the compiler
 947 ! itself uses it. Optimizing it like this reduced compile time.
 948 <PRIVATE
 949
 950 : generic-flip ( matrix -- newmatrix )
 951     [ dup first length [ length min ] reduce iota ] keep
 952     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 953
 954 USE: arrays
 955
 956 : array-length ( array -- len )
 957     { array } declare length>> ; inline
 958
 959 : array-flip ( matrix -- newmatrix )
 960     { array } declare
 961     [ dup first array-length [ array-length min ] reduce iota ] keep
 962     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 963
 964 PRIVATE>
 965
 966 : flip ( matrix -- newmatrix )
 967     dup empty? [
 968         dup array? [
 969             dup [ array? ] all?
 970             [ array-flip ] [ generic-flip ] if
 971         ] [ generic-flip ] if
 972     ] unless ;