core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  19     [ length ] dip new-sequence ; inline
  20
  21 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  22     [ length ] dip new-resizable ; inline
  23
  24 : new-like ( len exemplar quot -- seq )
  25     over [ [ new-sequence ] dip call ] dip like ; inline
  26
  27 M: sequence like drop ; inline
  28
  29 GENERIC: lengthen ( n seq -- )
  30 GENERIC: shorten ( n seq -- )
  31
  32 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  33 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  34
  35 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  36 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  37
  38 : empty? ( seq -- ? ) length 0 = ; inline
  39
  40 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  41     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  42
  43 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  44 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  45
  46 : delete-all ( seq -- ) 0 swap set-length ;
  47
  48 : first ( seq -- first ) 0 swap nth ; inline
  49 : second ( seq -- second ) 1 swap nth ; inline
  50 : third ( seq -- third ) 2 swap nth ; inline
  51 : fourth ( seq -- fourth ) 3 swap nth ; inline
  52
  53 : set-first ( first seq -- ) 0 swap set-nth ; inline
  54 : set-second ( second seq -- ) 1 swap set-nth ; inline
  55 : set-third ( third seq -- ) 2 swap set-nth ; inline
  56 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  57
  58 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  59
  60 ERROR: bounds-error index seq ;
  61
  62 GENERIC#: bounds-check? 1 ( n seq -- ? )
  63
  64 M: integer bounds-check?
  65     dupd length < [ 0 >= ] [ drop f ] if ; inline
  66
  67 : bounds-check ( n seq -- n seq )
  68     2dup bounds-check? [ bounds-error ] unless ; inline
  69
  70 MIXIN: immutable-sequence
  71
  72 ERROR: immutable element index sequence ;
  73
  74 M: immutable-sequence set-nth immutable ;
  75
  76 INSTANCE: immutable-sequence sequence
  77
  78 <PRIVATE
  79
  80 : array-nth ( n array -- elt )
  81     swap 2 fixnum+fast slot ; inline
  82
  83 : set-array-nth ( elt n array -- )
  84     swap 2 fixnum+fast set-slot ; inline
  85
  86 : dispatch ( n array -- ) array-nth call ;
  87
  88 GENERIC: resize ( n seq -- newseq ) flushable
  89
  90 ! Unsafe sequence protocol for inner loops
  91 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  92 GENERIC: set-nth-unsafe ( elt n seq -- )
  93
  94 M: sequence nth bounds-check nth-unsafe ; inline
  95 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  96
  97 M: sequence nth-unsafe nth ; inline
  98 M: sequence set-nth-unsafe set-nth ; inline
  99
 100 : change-nth-unsafe ( i seq quot -- )
 101     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 102
 103 PRIVATE>
 104
 105 ! The f object supports the sequence protocol trivially
 106 M: f length drop 0 ; inline
 107 M: f nth-unsafe nip ; inline
 108 M: f like drop [ f ] when-empty ; inline
 109
 110 INSTANCE: f immutable-sequence
 111
 112 ! Integer sequences
 113 TUPLE: iota { n integer read-only } ;
 114
 115 ERROR: non-negative-integer-expected n ;
 116
 117 : <iota> ( n -- iota )
 118     dup 0 < [ non-negative-integer-expected ] when
 119     iota boa ; inline
 120
 121 M: iota length n>> ; inline
 122 M: iota nth-unsafe drop ; inline
 123
 124 INSTANCE: iota immutable-sequence
 125
 126 <PRIVATE
 127
 128 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 129 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 130 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 131 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 132
 133 : first2-unsafe ( seq -- first second )
 134     [ first-unsafe ] [ second-unsafe ] bi ; inline
 135
 136 : first3-unsafe ( seq -- first second third )
 137     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 138
 139 : first4-unsafe ( seq -- first second third fourth )
 140     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 141
 142 : exchange-unsafe ( m n seq -- )
 143     [ [ nth-unsafe ] curry bi@ ]
 144     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 145
 146 : (1sequence) ( obj seq -- seq )
 147     [ 0 swap set-nth-unsafe ] keep ; inline
 148
 149 : (2sequence) ( obj1 obj2 seq -- seq )
 150     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 151
 152 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 153     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 154
 155 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 156     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 157
 158 PRIVATE>
 159
 160 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 161
 162 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 163
 164 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 165
 166 : 1sequence ( obj exemplar -- seq )
 167     1 swap [ (1sequence) ] new-like ; inline
 168
 169 : 2sequence ( obj1 obj2 exemplar -- seq )
 170     2 swap [ (2sequence) ] new-like ; inline
 171
 172 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 173     3 swap [ (3sequence) ] new-like ; inline
 174
 175 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 176     4 swap [ (4sequence) ] new-like ; inline
 177
 178 : first2 ( seq -- first second )
 179     1 swap bounds-check nip first2-unsafe ; inline
 180
 181 : first3 ( seq -- first second third )
 182     2 swap bounds-check nip first3-unsafe ; inline
 183
 184 : first4 ( seq -- first second third fourth )
 185     3 swap bounds-check nip first4-unsafe ; inline
 186
 187 : ?nth ( n seq -- elt/f )
 188     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 189
 190 : ?set-nth ( elt n seq -- )
 191     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 192
 193 : index-or-length ( seq n -- seq n' ) over length min ; inline
 194
 195 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 196
 197 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 198 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 199 : ?last ( seq -- elt/f )
 200     index-of-last over 0 <
 201     [ 2drop f ] [ nth-unsafe ] if ; inline
 202
 203 MIXIN: virtual-sequence
 204 GENERIC: virtual-exemplar ( seq -- seq' )
 205 GENERIC: virtual@ ( n seq -- n' seq' )
 206
 207 M: virtual-sequence nth virtual@ nth ; inline
 208 M: virtual-sequence set-nth virtual@ set-nth ; inline
 209 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 210 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 211 M: virtual-sequence like virtual-exemplar like ; inline
 212 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 213
 214 INSTANCE: virtual-sequence sequence
 215
 216 ! A reversal of an underlying sequence.
 217 TUPLE: reversed { seq read-only } ;
 218
 219 C: <reversed> reversed
 220
 221 M: reversed virtual-exemplar seq>> ; inline
 222 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 223 M: reversed length seq>> length ; inline
 224
 225 INSTANCE: reversed virtual-sequence
 226
 227 ! A slice of another sequence.
 228 TUPLE: slice
 229     { from integer read-only }
 230     { to integer read-only }
 231     { seq read-only } ;
 232
 233 : >slice< ( slice -- from to seq )
 234     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 235
 236 : collapse-slice ( m n slice -- m' n' seq )
 237     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 238
 239 ERROR: slice-error from to seq ;
 240
 241 : check-slice ( from to seq -- from to seq )
 242     pick 0 < [ slice-error ] when
 243     2dup length > [ slice-error ] when
 244     2over > [ slice-error ] when ; inline
 245
 246 <PRIVATE
 247
 248 : <slice-unsafe> ( from to seq -- slice )
 249     dup slice? [ collapse-slice ] when slice boa ; inline
 250
 251 PRIVATE>
 252
 253 : <slice> ( from to seq -- slice )
 254     check-slice <slice-unsafe> ; inline
 255
 256 M: slice virtual-exemplar seq>> ; inline
 257
 258 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 259
 260 M: slice length [ to>> ] [ from>> ] bi - ; inline
 261
 262 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 263
 264 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 265
 266 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 267
 268 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 269
 270 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 271
 272 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 273
 274 INSTANCE: slice virtual-sequence
 275
 276 ! One element repeated many times
 277 TUPLE: repetition
 278     { length integer read-only }
 279     { elt read-only } ;
 280
 281 : <repetition> ( len elt -- repetition )
 282     over 0 < [ non-negative-integer-expected ] when
 283     repetition boa ; inline
 284
 285 M: repetition length length>> ; inline
 286 M: repetition nth-unsafe nip elt>> ; inline
 287
 288 INSTANCE: repetition immutable-sequence
 289
 290 <PRIVATE
 291
 292 ERROR: integer-length-expected obj ;
 293
 294 ! The check-length call forces partial dispatch
 295 : check-length ( n -- n )
 296     dup integer? [ integer-length-expected ] unless ; inline
 297
 298 : >sequence< ( seq -- i n seq )
 299     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 300
 301 : length-sequence ( seq -- n seq )
 302     [ length check-length ] [ ] bi ; inline
 303
 304 : >underlying< ( slice/seq -- from to slice/seq )
 305     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 306
 307 TUPLE: copier
 308     { src-i integer read-only }
 309     { src read-only }
 310     { dst-i integer read-only }
 311     { dst read-only } ;
 312
 313 C: <copier> copier
 314
 315 : copy-nth-unsafe ( n copy -- )
 316     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 317     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 318
 319 : (copy) ( n copy -- dst )
 320     over 0 <= [ nip dst>> ] [
 321         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 322     ] if ; inline recursive
 323
 324 : subseq>copy ( from to seq -- n copy )
 325     [ over - check-length swap ] dip
 326     3dup nip new-sequence 0 swap <copier> ; inline
 327
 328 : bounds-check-head ( n seq -- n seq )
 329     over 0 < [ bounds-error ] when ; inline
 330
 331 : check-copy ( src n dst -- src n dst )
 332     3dup bounds-check-head
 333     [ swap length + ] dip lengthen ; inline
 334
 335 : copy-unsafe ( src i dst -- )
 336     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 337
 338 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 339     [ subseq>copy (copy) ] dip like ; inline
 340
 341 : subseq-unsafe ( from to seq -- subseq )
 342     dup subseq-unsafe-as ; inline
 343
 344 PRIVATE>
 345
 346 : subseq-as ( from to seq exemplar -- subseq )
 347     [ check-slice ] dip subseq-unsafe-as ;
 348
 349 : subseq ( from to seq -- subseq )
 350     dup subseq-as ;
 351
 352 : head ( seq n -- headseq ) head-to-index subseq ;
 353
 354 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 355
 356 : rest ( seq -- tailseq ) 1 tail ;
 357
 358 : head* ( seq n -- headseq ) from-tail head ;
 359
 360 : tail* ( seq n -- tailseq ) from-tail tail ;
 361
 362 : but-last ( seq -- headseq ) 1 head* ;
 363
 364 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 365
 366 M: sequence clone-like
 367     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 368
 369 M: immutable-sequence clone-like like ; inline
 370
 371 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 372
 373 <PRIVATE
 374
 375 : (append) ( seq1 seq2 accum -- accum )
 376     [ [ over length ] dip copy-unsafe ]
 377     [ 0 swap copy-unsafe ]
 378     [ ] tri ; inline
 379
 380 PRIVATE>
 381
 382 : append-as ( seq1 seq2 exemplar -- newseq )
 383     [ 2dup 2length + ] dip
 384     [ (append) ] new-like ; inline
 385
 386 : append ( seq1 seq2 -- newseq ) over append-as ;
 387
 388 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 389
 390 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 391
 392 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 393     [ 3dup 3length + + ] dip [
 394         [ [ 2over 2length + ] dip copy-unsafe ]
 395         [ (append) ] bi
 396     ] new-like ; inline
 397
 398 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 399
 400 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 401     [ swap ] 2dip 3append-as ; inline
 402
 403 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 404
 405 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 406
 407 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 408
 409 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 410
 411 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 412
 413 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 414     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 415
 416 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 417
 418 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 419
 420 <PRIVATE
 421
 422 : sequence-operator ( seq quot -- i n quot' )
 423     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 424
 425 : length-iterator ( seq -- n quot' )
 426     length-sequence [ nth-unsafe ] curry ; inline
 427
 428 : length-operator ( seq quot -- n quot' )
 429     [ length-iterator ] dip compose ; inline
 430
 431 : collect-into ( quot into -- quot' )
 432     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 433
 434 : collect-from ( i n quot into -- )
 435     collect-into each-integer-from ; inline
 436
 437 : collect ( n quot into -- )
 438     collect-into each-integer ; inline
 439
 440 : sequence-index-operator ( seq quot -- n quot' )
 441     [ length-iterator [ keep ] curry ] dip compose ; inline
 442
 443 : map-into ( seq quot into -- )
 444     [ length-operator ] dip collect ; inline
 445
 446 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 447     [ nth-unsafe ] bi-curry@ bi ; inline
 448
 449 : setup-2each ( seq1 seq2 -- n quot )
 450     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 451
 452 : (2each) ( seq1 seq2 quot -- n quot' )
 453     [ setup-2each ] dip compose ; inline
 454
 455 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 456     [ nth-unsafe ] tri-curry@ tri ; inline
 457
 458 : setup-3each ( seq1 seq2 seq3 -- n quot )
 459     [ [ length ] tri@ min min check-length ]
 460     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 461
 462 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 463     [ setup-3each ] dip compose ; inline
 464
 465 : element/index ( i/f seq -- elt/f i/f )
 466     '[ [ _ nth ] [ f ] if* ] keep ; inline
 467
 468 : index/element ( i/f seq -- i/f elt/f )
 469     dupd '[ _ nth ] [ f ] if* ; inline
 470
 471 : (accumulate) ( seq identity quot -- identity seq quot' )
 472     swapd [ keepd ] curry ; inline
 473
 474 : (accumulate*) ( seq identity quot -- identity seq quot' )
 475     swapd [ dup ] compose ; inline
 476
 477 PRIVATE>
 478
 479 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 480     sequence-operator each-integer-from ; inline
 481
 482 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 483     -rot length-operator each-integer-from ; inline
 484
 485 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 486     swapd each ; inline
 487
 488 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 489     overd [ [ collect-from ] keep ] new-like ; inline
 490
 491 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 492     overd [ [ collect ] keep ] new-like ; inline
 493
 494 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 495     { } map-integers-as ; inline
 496
 497 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 498     [ length-operator ] dip map-integers-as ; inline
 499
 500 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 501     over map-as ; inline
 502
 503 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 504     [ [ drop ] prepose ] dip map-integers-as ; inline
 505
 506 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 507     { } replicate-as ; inline
 508
 509 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 510     over [ map-into ] keep ; inline
 511
 512 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 513     [ (accumulate) ] dip map-as ; inline
 514
 515 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 516     pick accumulate-as ; inline
 517
 518 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 519     (accumulate) map! ; inline
 520
 521 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 522     [ (accumulate*) ] dip map-as nip ; inline
 523
 524 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 525     pick accumulate*-as ; inline
 526
 527 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 528     (accumulate*) map! nip ; inline
 529
 530 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 531     (2each) each-integer ; inline
 532
 533 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 534     [ (2each) ] dip -rot each-integer-from ; inline
 535
 536 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 537     -rotd 2each ; inline
 538
 539 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 540     [ (2each) ] dip map-integers-as ; inline
 541
 542 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 543     pick 2map-as ; inline
 544
 545 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 546     (2each) all-integers? ; inline
 547
 548 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 549     negate 2all? not ; inline
 550
 551 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 552     (3each) each-integer ; inline
 553
 554 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 555     [ (3each) ] dip map-integers-as ; inline
 556
 557 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 558     pickd swap 3map-as ; inline
 559
 560 <PRIVATE
 561
 562 : bounds-check-call ( n seq quot -- elt i )
 563     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 564
 565 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 566     [ length-operator find-integer-from ] keepd
 567     index/element ; inline
 568
 569 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 570     [ length-operator nip find-last-integer ] keepd
 571     index/element ; inline
 572
 573 PRIVATE>
 574
 575 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 576     '[ _ find-from-unsafe ] bounds-check-call ; inline
 577
 578 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 579     [ 0 ] 2dip find-from-unsafe ; inline
 580
 581 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 582     '[ _ find-last-from-unsafe ] bounds-check-call ; inline
 583
 584 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 585     [ index-of-last ] dip find-last-from ; inline
 586
 587 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 588     '[
 589         _ [ sequence-index-operator find-integer-from ] keepd
 590         index/element
 591     ] bounds-check-call ; inline
 592
 593 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 594     [ 0 ] 2dip find-index-from ; inline
 595
 596 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 597     sequence-operator all-integers-from? ; inline
 598
 599 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 600     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 601
 602 : keep-push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 603     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 604
 605 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
 606     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 607
 608 <PRIVATE
 609
 610 : (selector-as) ( quot length exemplar -- selector accum )
 611     new-resizable [ [ push-when ] 2curry ] keep ; inline
 612
 613 PRIVATE>
 614
 615 : selector-as ( quot exemplar -- selector accum )
 616     [ length ] keep (selector-as) ; inline
 617
 618 : selector ( quot -- selector accum )
 619     V{ } selector-as ; inline
 620
 621 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 622     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 623
 624 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 625     over filter-as ; inline
 626
 627 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 628     [ negate ] [ filter-as ] bi* ; inline
 629
 630 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 631     over reject-as ; inline
 632
 633 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 634     [ keep swap ] 2dip ? push ; inline
 635
 636 : 2selector ( quot -- selector accum1 accum2 )
 637     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 638
 639 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 640     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 641
 642 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 643     overd new-resizable-like [ [ push ] curry compose ] keep ; inline
 644
 645 : collector-as ( quot exemplar -- quot' vec )
 646     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 647
 648 : collector-for ( seq quot -- seq quot' vec )
 649     V{ } collector-for-as ; inline
 650
 651 : collector ( quot -- quot' vec )
 652     V{ } collector-as ; inline
 653
 654 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 655     dup [ collector-as [ while ] dip ] curry dip like ; inline
 656
 657 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 658     { } produce-as ; inline
 659
 660 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 661     [ dup ] swap [ keep ] curry produce nip ; inline
 662
 663 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 664     sequence-index-operator each-integer ; inline
 665
 666 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 667     [ dup length <iota> ] 2dip 2map-as ; inline
 668
 669 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 670     over map-index-as ; inline
 671
 672 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 673     pick empty? [ 3drop ] [
 674         [ [ drop first-unsafe ] dip call ]
 675         [ [ bi* ] 2curry 1 each-from ]
 676         3bi
 677     ] if ; inline
 678
 679 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 680     swapd each-index ; inline
 681
 682 : index ( obj seq -- n )
 683     [ = ] with find drop ;
 684
 685 : index-from ( obj i seq -- n )
 686     rot [ = ] curry find-from drop ;
 687
 688 : last-index ( obj seq -- n )
 689     [ = ] with find-last drop ;
 690
 691 : last-index-from ( obj i seq -- n )
 692     rot [ = ] curry find-last-from drop ;
 693
 694 : indices ( obj seq -- indices )
 695     swap [ = ] curry [ swap ] prepose V{ } clone [
 696         [ push ] curry [ [ drop ] if ] curry compose each-index
 697     ] keep ;
 698
 699 <PRIVATE
 700
 701 : nths-unsafe ( indices seq -- seq' )
 702     [ [ nth-unsafe ] curry ] keep map-as ;
 703
 704 PRIVATE>
 705
 706 : nths ( indices seq -- seq' )
 707     [ [ nth ] curry ] keep map-as ;
 708
 709 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 710     find drop >boolean ; inline
 711
 712 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 713     any? not ; inline
 714
 715 : member? ( elt seq -- ? )
 716     [ = ] with any? ;
 717
 718 : member-eq? ( elt seq -- ? )
 719     [ eq? ] with any? ;
 720
 721 : remove ( elt seq -- newseq )
 722     [ = ] with reject ;
 723
 724 : remove-eq ( elt seq -- newseq )
 725     [ eq? ] with reject ;
 726
 727 : sift ( seq -- newseq )
 728     [ ] filter ;
 729
 730 : harvest ( seq -- newseq )
 731     [ empty? ] reject ;
 732
 733 <PRIVATE
 734
 735 : mismatch-unsafe ( n seq1 seq2 -- i )
 736     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 737
 738 PRIVATE>
 739
 740 : mismatch ( seq1 seq2 -- i )
 741     [ min-length ] 2keep mismatch-unsafe ;
 742
 743 M: sequence <=>
 744     [ mismatch ] 2keep pick
 745     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 746
 747 : sequence= ( seq1 seq2 -- ? )
 748     2dup [ length ] bi@ dupd =
 749     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 750
 751 ERROR: assert-sequence got expected ;
 752
 753 : assert-sequence= ( a b -- )
 754     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 755
 756 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 757
 758 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 759
 760 <PRIVATE
 761
 762 : sequence-hashcode-step ( oldhash newpart -- newhash )
 763     integer>fixnum swap [
 764         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 765         fixnum+fast fixnum+fast
 766     ] keep fixnum-bitxor ; inline
 767
 768 PRIVATE>
 769
 770 : sequence-hashcode ( n seq -- x )
 771     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 772
 773 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 774
 775 M: iota hashcode*
 776     over 0 <= [ 2drop 0 ] [
 777         nip length 0 swap [ sequence-hashcode-step ] each-integer
 778     ] if ;
 779
 780 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 781
 782 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 783
 784 : move ( to from seq -- )
 785     2over =
 786     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 787
 788 <PRIVATE
 789
 790 : move-unsafe* ( to from seq -- from-nth )
 791     2over =
 792     [ nth-unsafe nip ]
 793     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 794
 795 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 796     2over length < [
 797         [ [ move-unsafe* ] dip call ] 4keep
 798         [ swap [ 1 + ] when ] 3dip
 799         [ 1 + ] 2dip filter-from!
 800     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 801
 802 : move-unsafe ( to from seq -- )
 803     2over =
 804     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 805
 806 PRIVATE>
 807
 808 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 809     [ 0 0 ] 2dip filter-from! ; inline
 810
 811 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 812     negate filter! ; inline
 813
 814 : remove! ( elt seq -- seq )
 815     [ = ] with reject! ;
 816
 817 : remove-eq! ( elt seq -- seq )
 818     [ eq? ] with reject! ;
 819
 820 : prefix ( seq elt -- newseq )
 821     over [ over length 1 + ] dip [
 822         (1sequence) [ 1 swap copy-unsafe ] keep
 823     ] new-like ;
 824
 825 : suffix ( seq elt -- newseq )
 826     over [ over length 1 + ] dip [
 827         [ [ over length ] dip set-nth-unsafe ] keep
 828         [ 0 swap copy-unsafe ] keep
 829     ] new-like ;
 830
 831 : suffix! ( seq elt -- seq ) over push ; inline
 832
 833 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 834
 835 : last ( seq -- elt )
 836     index-of-last
 837     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 838
 839 <PRIVATE
 840
 841 : last-unsafe ( seq -- elt )
 842     index-of-last nth-unsafe ; inline
 843
 844 PRIVATE>
 845
 846 : set-last ( elt seq -- )
 847     index-of-last
 848     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 849
 850 : pop* ( seq -- ) index-of-last shorten ;
 851
 852 <PRIVATE
 853
 854 : move-backward ( shift from to seq -- )
 855     2over = [
 856         4drop
 857     ] [
 858         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 859         move-backward
 860     ] if ;
 861
 862 : move-forward ( shift from to seq -- )
 863     2over = [
 864         4drop
 865     ] [
 866         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 867         move-forward
 868     ] if ;
 869
 870 : (open-slice) ( shift from to seq ? -- )
 871     [
 872         [ [ 1 - ] bi@ ] dip move-forward
 873     ] [
 874         [ over - ] 2dip move-backward
 875     ] if ;
 876
 877 : open-slice ( shift from seq -- )
 878     pick 0 = [
 879         3drop
 880     ] [
 881         [ ] [ nip length + ] [ 2nip ] 3tri
 882         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 883         set-length
 884     ] if ;
 885
 886 PRIVATE>
 887
 888 : delete-slice ( from to seq -- )
 889     check-slice [ over [ - ] dip ] dip open-slice ;
 890
 891 : remove-nth! ( n seq -- seq )
 892     [ [ dup 1 + ] dip delete-slice ] keep ;
 893
 894 : snip ( from to seq -- head tail )
 895     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 896
 897 : snip-slice ( from to seq -- head tail )
 898     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 899
 900 : replace-slice ( new from to seq -- seq' )
 901     snip-slice surround ;
 902
 903 : remove-nth ( n seq -- seq' )
 904     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 905
 906 : pop ( seq -- elt )
 907     index-of-last over 0 >=
 908     [ [ nth-unsafe ] [ shorten ] 2bi ]
 909     [ bounds-error ] if ;
 910
 911 : exchange ( m n seq -- )
 912     [ nip bounds-check 2drop ]
 913     [ bounds-check 3drop ]
 914     [ exchange-unsafe ]
 915     3tri ;
 916
 917 : midpoint@ ( seq -- n ) length 2/ ; inline
 918
 919 : reverse! ( seq -- seq )
 920     [
 921         [ midpoint@ ] [ length ] [ ] tri
 922         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 923         each-integer
 924     ] keep ;
 925
 926 : reverse ( seq -- newseq )
 927     [
 928         dup [ length ] keep new-sequence
 929         [ 0 swap copy-unsafe ] keep reverse!
 930     ] keep like ;
 931
 932 GENERIC: sum-lengths ( seq -- n )
 933
 934 M: object sum-lengths
 935     0 [ length + ] reduce ;
 936
 937 M: repetition sum-lengths
 938     [ length>> ] [ elt>> length ] bi * ;
 939
 940 : concat-as ( seq exemplar -- newseq )
 941     [
 942         [ dup sum-lengths ] dip new-resizable
 943         [ [ push-all ] curry each ] keep
 944     ] keep like ; inline
 945
 946 : concat ( seq -- newseq )
 947     [ { } ] [ dup first concat-as ] if-empty ;
 948
 949 <PRIVATE
 950
 951 : joined-length ( seq glue -- n )
 952     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 953
 954 PRIVATE>
 955
 956 : join-as ( seq glue exemplar -- newseq )
 957     over empty? [ nip concat-as ] [
 958         [
 959             2dup joined-length over new-resizable [
 960                 [ [ push-all ] 2curry ]
 961                 [ nip [ push-all ] curry ] 2bi
 962                 interleave
 963             ] keep
 964         ] dip like
 965     ] if ;
 966
 967 : join ( seq glue -- newseq )
 968     dup join-as ; inline
 969
 970 <PRIVATE
 971
 972 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 973     [
 974         [ over length [-] dup 0 = [ drop ] ] dip
 975         [ <repetition> ] curry
 976     ] dip compose if ; inline
 977
 978 PRIVATE>
 979
 980 : pad-head ( seq n elt -- padded )
 981     [ swap dup append-as ] padding ;
 982
 983 : pad-tail ( seq n elt -- padded )
 984     [ append ] padding ;
 985
 986 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 987 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 988 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 989 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 990
 991 : head? ( seq begin -- ? )
 992     2dup shorter? [
 993         2drop f
 994     ] [
 995         [ length [ head-slice ] keep swap ] keep
 996         mismatch-unsafe not
 997     ] if ;
 998
 999 : tail? ( seq end -- ? )
1000     2dup shorter? [
1001         2drop f
1002     ] [
1003         [ length [ tail-slice* ] keep swap ] keep
1004         mismatch-unsafe not
1005     ] if ;
1006
1007 : cut-slice ( seq n -- before-slice after-slice )
1008     [ head-slice ] [ tail-slice ] 2bi ; inline
1009
1010 : cut-slice* ( seq n -- before-slice after-slice )
1011     [ head-slice* ] [ tail-slice* ] 2bi ;
1012
1013 : insert-nth ( elt n seq -- seq' )
1014     swap cut-slice [ swap suffix ] dip append ;
1015
1016 : halves ( seq -- first-slice second-slice )
1017     dup midpoint@ cut-slice ; inline
1018
1019 <PRIVATE
1020
1021 : nth2-unsafe ( n seq -- a b )
1022     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1023
1024 : nth3-unsafe ( n seq -- a b c )
1025     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1026
1027 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1028     ! We can't use case here since combinators depends on
1029     ! sequences
1030     dup 4 < [
1031         integer>fixnum {
1032             [ 2drop nip ]
1033             [ 2nip swap nth-unsafe ]
1034             [ -rot [ drop swap nth2-unsafe ] dip call ]
1035             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1036         } dispatch
1037     ] [
1038         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1039         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1040         pick [ 3bi ] dip call
1041     ] if ; inline recursive
1042
1043 PRIVATE>
1044
1045 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1046     pick dup slice? [
1047         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1048     ] [
1049         length 0 max 0 swap
1050     ] if (binary-reduce) ; inline
1051
1052 : cut ( seq n -- before after )
1053     [ head ] [ tail ] 2bi ;
1054
1055 : cut* ( seq n -- before after )
1056     [ head* ] [ tail* ] 2bi ;
1057
1058 : subseq-starts-at? ( i seq subseq -- ? )
1059     [ length swap ] keep
1060     '[
1061         [ + _ nth-unsafe ] keep _ nth-unsafe =
1062     ] with all-integers? ; inline
1063
1064 : subseq-index-from ( n seq subseq -- i/f )
1065     [ [ length ] bi@ - 1 + ] 2keep
1066     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1067
1068 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1069
1070 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1071
1072 : subseq-start-from ( subseq seq n -- i/f )
1073     spin subseq-index-from ; inline deprecated
1074
1075 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1076
1077 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1078
1079 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1080     2dup mismatch [ 2dup min-length ] unless*
1081     [ tail-slice ] curry bi@ ;
1082
1083 : unclip ( seq -- rest first )
1084     [ rest ] [ first-unsafe ] bi ;
1085
1086 : unclip-last ( seq -- butlast last )
1087     [ but-last ] [ last-unsafe ] bi ;
1088
1089 : unclip-slice ( seq -- rest-slice first )
1090     [ rest-slice ] [ first-unsafe ] bi ; inline
1091
1092 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1093     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1094     '[ swap _ dip swap @ ] 1 each-from ; inline
1095
1096 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1097     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1098     '[ rot _ dip swap @ ] 1 2each-from ; inline
1099
1100 <PRIVATE
1101
1102 : (map-find) ( seq quot find-quot -- result elt )
1103     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1104
1105 PRIVATE>
1106
1107 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1108     [ find ] (map-find) ; inline
1109
1110 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1111     [ find-last ] (map-find) ; inline
1112
1113 : unclip-last-slice ( seq -- butlast-slice last )
1114     [ but-last-slice ] [ last-unsafe ] bi ; inline
1115
1116 <PRIVATE
1117
1118 : (trim-head) ( seq quot -- seq n )
1119     over [ negate find drop ] dip swap
1120     [ dup length ] unless* ; inline
1121
1122 : (trim-tail) ( seq quot -- seq n )
1123     over [ negate find-last drop ?1+ ] dip
1124     swap ; inline
1125
1126 PRIVATE>
1127
1128 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1129     (trim-head) tail-slice ; inline
1130
1131 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1132     (trim-head) tail ; inline
1133
1134 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1135     (trim-tail) head-slice ; inline
1136
1137 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1138     (trim-tail) head ; inline
1139
1140 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1141     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1142
1143 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1144     [ trim-slice ] [ drop ] 2bi like ; inline
1145
1146 GENERIC: sum ( seq -- n )
1147 M: object sum 0 [ + ] binary-reduce ; inline
1148 M: iota sum length dup 1 - * 2/ ; inline
1149 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1150
1151 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1152
1153 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1154
1155 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1156
1157 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1158     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1159
1160 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1161     [ 1 0 ? ] compose map-sum ; inline
1162
1163 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1164     [ with each ] 2curry each ; inline
1165
1166 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1167     [ with { } map-as ] 2curry { } map-as ; inline
1168
1169 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1170     [ 2sequence ] curry cartesian-map ; inline
1171
1172 : cartesian-product ( seq1 seq2 -- newseq )
1173     dup cartesian-product-as ; inline
1174
1175 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1176     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1177
1178 <PRIVATE
1179
1180 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1181     [
1182         [ keep swap ] curry [ [ first ] dip call ] 2keep
1183         [ curry 2dip pick over ] curry
1184     ] [
1185         [ [ 2drop ] [ 2nipd ] if ] compose
1186     ] bi* compose 1 each-from drop ; inline
1187
1188 PRIVATE>
1189
1190 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1191     [ after? ] select-by ; inline
1192
1193 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1194     [ before? ] select-by ; inline
1195
1196 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1197
1198 : longest ( seqs -- elt ) [ length ] supremum-by ;
1199
1200 ! We hand-optimize flip to such a degree because type hints
1201 ! cannot express that an array is an array of arrays yet, and
1202 ! this word happens to be performance-critical since the compiler
1203 ! itself uses it. Optimizing it like this reduced compile time.
1204 <PRIVATE
1205
1206 : generic-flip ( matrix -- newmatrix )
1207     [ [ length ] [ min ] map-reduce ] keep
1208     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1209
1210 USE: arrays
1211
1212 : array-flip ( matrix -- newmatrix )
1213     { array } declare
1214     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1215     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1216
1217 PRIVATE>
1218
1219 : flip ( matrix -- newmatrix )
1220     dup empty? [
1221         dup array? [
1222             dup [ array? ] all?
1223             [ array-flip ] [ generic-flip ] if
1224         ] [ generic-flip ] if
1225     ] unless ;