core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop [ f ] when-empty ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 PRIVATE>
 105
 106 ! In the future, this will replace integer sequences
 107 TUPLE: iota { n integer read-only } ;
 108
 109 : iota ( n -- iota ) \ iota boa ; inline
 110
 111 <PRIVATE
 112
 113 M: iota length n>> ;
 114 M: iota nth-unsafe drop ;
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 : first-unsafe ( seq -- first )
 119     0 swap nth-unsafe ; inline
 120
 121 : first2-unsafe ( seq -- first second )
 122     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 123
 124 : first3-unsafe ( seq -- first second third )
 125     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 126
 127 : first4-unsafe ( seq -- first second third fourth )
 128     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 129
 130 : exchange-unsafe ( m n seq -- )
 131     [ [ nth-unsafe ] curry bi@ ]
 132     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 133
 134 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 135
 136 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 137
 138 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 139
 140 : (1sequence) ( obj seq -- seq )
 141     [ 0 swap set-nth-unsafe ] keep ; inline
 142
 143 : (2sequence) ( obj1 obj2 seq -- seq )
 144     [ 1 swap set-nth-unsafe ] keep
 145     (1sequence) ; inline
 146
 147 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 148     [ 2 swap set-nth-unsafe ] keep
 149     (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep
 153     (3sequence) ; inline
 154
 155 PRIVATE>
 156
 157 : 1sequence ( obj exemplar -- seq )
 158     1 swap [ (1sequence) ] new-like ; inline
 159
 160 : 2sequence ( obj1 obj2 exemplar -- seq )
 161     2 swap [ (2sequence) ] new-like ; inline
 162
 163 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 164     3 swap [ (3sequence) ] new-like ; inline
 165
 166 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 167     4 swap [ (4sequence) ] new-like ; inline
 168
 169 : first2 ( seq -- first second )
 170     1 swap bounds-check nip first2-unsafe ; flushable
 171
 172 : first3 ( seq -- first second third )
 173     2 swap bounds-check nip first3-unsafe ; flushable
 174
 175 : first4 ( seq -- first second third fourth )
 176     3 swap bounds-check nip first4-unsafe ; flushable
 177
 178 : ?nth ( n seq -- elt/f )
 179     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 180
 181 MIXIN: virtual-sequence
 182 GENERIC: virtual-seq ( seq -- seq' )
 183 GENERIC: virtual@ ( n seq -- n' seq' )
 184
 185 M: virtual-sequence nth virtual@ nth ;
 186 M: virtual-sequence set-nth virtual@ set-nth ;
 187 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 188 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 189 M: virtual-sequence like virtual-seq like ;
 190 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 191
 192 INSTANCE: virtual-sequence sequence
 193
 194 ! A reversal of an underlying sequence.
 195 TUPLE: reversed { seq read-only } ;
 196
 197 C: <reversed> reversed
 198
 199 M: reversed virtual-seq seq>> ;
 200
 201 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 202
 203 M: reversed length seq>> length ;
 204
 205 INSTANCE: reversed virtual-sequence
 206
 207 ! A slice of another sequence.
 208 TUPLE: slice
 209 { from read-only }
 210 { to read-only }
 211 { seq read-only } ;
 212
 213 : collapse-slice ( m n slice -- m' n' seq )
 214     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 215
 216 ERROR: slice-error from to seq reason ;
 217
 218 : check-slice ( from to seq -- from to seq )
 219     pick 0 < [ "start < 0" slice-error ] when
 220     dup length pick < [ "end > sequence" slice-error ] when
 221     2over > [ "start > end" slice-error ] when ; inline
 222
 223 : <slice> ( from to seq -- slice )
 224     dup slice? [ collapse-slice ] when
 225     check-slice
 226     slice boa ; inline
 227
 228 M: slice virtual-seq seq>> ;
 229
 230 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 231
 232 M: slice length [ to>> ] [ from>> ] bi - ;
 233
 234 : short ( seq n -- seq n' ) over length min ; inline
 235
 236 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 237
 238 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 239
 240 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 241
 242 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 243
 244 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 245
 246 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 247
 248 INSTANCE: slice virtual-sequence
 249
 250 ! One element repeated many times
 251 TUPLE: repetition { len read-only } { elt read-only } ;
 252
 253 C: <repetition> repetition
 254
 255 M: repetition length len>> ;
 256 M: repetition nth-unsafe nip elt>> ;
 257
 258 INSTANCE: repetition immutable-sequence
 259
 260 <PRIVATE
 261
 262 : check-length ( n -- n )
 263     #! Ricing.
 264     dup integer? [ "length not an integer" throw ] unless ; inline
 265
 266 : ((copy)) ( dst i src j n -- dst i src j n )
 267     dup -roll [
 268         + swap nth-unsafe -roll [
 269             + swap set-nth-unsafe
 270         ] 3keep drop
 271     ] 3keep ; inline
 272
 273 : (copy) ( dst i src j n -- dst )
 274     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 275     inline recursive
 276
 277 : prepare-subseq ( from to seq -- dst i src j n )
 278     #! The check-length call forces partial dispatch
 279     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 280     -rot drop roll length check-length ; inline
 281
 282 : check-copy ( src n dst -- )
 283     over 0 < [ bounds-error ] when
 284     [ swap length + ] dip lengthen ; inline
 285
 286 PRIVATE>
 287
 288 : subseq ( from to seq -- subseq )
 289     [ check-slice prepare-subseq (copy) ] keep like ;
 290
 291 : head ( seq n -- headseq ) (head) subseq ;
 292
 293 : tail ( seq n -- tailseq ) (tail) subseq ;
 294
 295 : rest ( seq -- tailseq ) 1 tail ;
 296
 297 : head* ( seq n -- headseq ) from-end head ;
 298
 299 : tail* ( seq n -- tailseq ) from-end tail ;
 300
 301 : but-last ( seq -- headseq ) 1 head* ;
 302
 303 : copy ( src i dst -- )
 304     #! The check-length call forces partial dispatch
 305     pick length check-length [ 3dup check-copy spin 0 ] dip
 306     (copy) drop ; inline
 307
 308 M: sequence clone-like
 309     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 310
 311 M: immutable-sequence clone-like like ;
 312
 313 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 314
 315 <PRIVATE
 316
 317 : (append) ( seq1 seq2 accum -- accum )
 318     [ [ over length ] dip copy ]
 319     [ 0 swap copy ]
 320     [ ] tri ; inline
 321
 322 PRIVATE>
 323
 324 : append-as ( seq1 seq2 exemplar -- newseq )
 325     [ over length over length + ] dip
 326     [ (append) ] new-like ; inline
 327
 328 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 329     [ pick length pick length pick length + + ] dip [
 330         [ [ pick length pick length + ] dip copy ]
 331         [ (append) ] bi
 332     ] new-like ; inline
 333
 334 : append ( seq1 seq2 -- newseq ) over append-as ;
 335
 336 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 337
 338 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 339
 340 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 341
 342 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 343
 344 : change-nth ( i seq quot -- )
 345     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 346
 347 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 348
 349 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 350
 351 <PRIVATE
 352
 353 : (each) ( seq quot -- n quot' )
 354     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 355
 356 : (collect) ( quot into -- quot' )
 357     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 358
 359 : collect ( n quot into -- )
 360     (collect) each-integer ; inline
 361
 362 : map-into ( seq quot into -- )
 363     [ (each) ] dip collect ; inline
 364
 365 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 366     [ nth-unsafe ] bi-curry@ bi ; inline
 367
 368 : (2each) ( seq1 seq2 quot -- n quot' )
 369     [
 370         [ min-length ] 2keep
 371         [ 2nth-unsafe ] 2curry
 372     ] dip compose ; inline
 373
 374 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 375     [ nth-unsafe ] tri-curry@ tri ; inline
 376
 377 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 378     [
 379         [ [ length ] tri@ min min ]
 380         [ [ 3nth-unsafe ] 3curry ] 3bi
 381     ] dip compose ; inline
 382
 383 : finish-find ( i seq -- i elt )
 384     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 385
 386 : (find) ( seq quot quot' -- i elt )
 387     pick [ [ (each) ] dip call ] dip finish-find ; inline
 388
 389 : (find-from) ( n seq quot quot' -- i elt )
 390     [ 2dup bounds-check? ] 2dip
 391     [ (find) ] 2curry
 392     [ 2drop f f ]
 393     if ; inline
 394
 395 PRIVATE>
 396
 397 : each ( seq quot -- )
 398     (each) each-integer ; inline
 399
 400 : reduce ( seq identity quot -- result )
 401     swapd each ; inline
 402
 403 : map-as ( seq quot exemplar -- newseq )
 404     [ over length ] dip [ [ map-into ] keep ] new-like ; inline
 405
 406 : map ( seq quot -- newseq )
 407     over map-as ; inline
 408
 409 : replicate ( seq quot -- newseq )
 410     [ drop ] prepose map ; inline
 411
 412 : replicate-as ( seq quot exemplar -- newseq )
 413     [ [ drop ] prepose ] dip map-as ; inline
 414
 415 : change-each ( seq quot -- )
 416     over map-into ; inline
 417
 418 : accumulate ( seq identity quot -- final newseq )
 419     swapd [ [ call ] [ 2drop ] 3bi ] curry map ; inline
 420
 421 : 2each ( seq1 seq2 quot -- )
 422     (2each) each-integer ; inline
 423
 424 : 2reverse-each ( seq1 seq2 quot -- )
 425     [ [ <reversed> ] bi@ ] dip 2each ; inline
 426
 427 : 2reduce ( seq1 seq2 identity quot -- result )
 428     [ -rot ] dip 2each ; inline
 429
 430 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 431     [ (2each) ] dip map-as ; inline
 432
 433 : 2map ( seq1 seq2 quot -- newseq )
 434     pick 2map-as ; inline
 435
 436 : 2all? ( seq1 seq2 quot -- ? )
 437     (2each) all-integers? ; inline
 438
 439 : 3each ( seq1 seq2 seq3 quot -- )
 440     (3each) each ; inline
 441
 442 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 443     [ (3each) ] dip map-as ; inline
 444
 445 : 3map ( seq1 seq2 seq3 quot -- newseq )
 446     [ pick ] dip swap 3map-as ; inline
 447
 448 : find-from ( n seq quot -- i elt )
 449     [ (find-integer) ] (find-from) ; inline
 450
 451 : find ( seq quot -- i elt )
 452     [ find-integer ] (find) ; inline
 453
 454 : find-last-from ( n seq quot -- i elt )
 455     [ nip find-last-integer ] (find-from) ; inline
 456
 457 : find-last ( seq quot -- i elt )
 458     [ [ 1- ] dip find-last-integer ] (find) ; inline
 459
 460 : all? ( seq quot -- ? )
 461     (each) all-integers? ; inline
 462
 463 : push-if ( elt quot accum -- )
 464     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 465
 466 : pusher ( quot -- quot accum )
 467     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 468
 469 : filter ( seq quot -- subseq )
 470     over [ pusher [ each ] dip ] dip like ; inline
 471
 472 : push-either ( elt quot accum1 accum2 -- )
 473     [ keep swap ] 2dip ? push ; inline
 474
 475 : 2pusher ( quot -- quot accum1 accum2 )
 476     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 477
 478 : partition ( seq quot -- trueseq falseseq )
 479     over [ 2pusher [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 480
 481 : accumulator ( quot -- quot' vec )
 482     V{ } clone [ [ push ] curry compose ] keep ; inline
 483
 484 : produce-as ( pred quot exemplar -- seq )
 485     [ accumulator [ while ] dip ] dip like ; inline
 486
 487 : produce ( pred quot -- seq )
 488     { } produce-as ; inline
 489
 490 : follow ( obj quot -- seq )
 491     [ dup ] swap [ keep ] curry produce nip ; inline
 492
 493 : prepare-index ( seq quot -- seq n quot )
 494     [ dup length ] dip ; inline
 495
 496 : each-index ( seq quot -- )
 497     prepare-index 2each ; inline
 498
 499 : interleave ( seq between quot -- )
 500     swap [ drop ] [ [ 2dip call ] 2curry ] 2bi
 501     [ [ 0 = ] 2dip if ] 2curry
 502     each-index ; inline
 503
 504 : map-index ( seq quot -- )
 505     prepare-index 2map ; inline
 506
 507 : reduce-index ( seq identity quot -- )
 508     swapd each-index ; inline
 509
 510 : index ( obj seq -- n )
 511     [ = ] with find drop ;
 512
 513 : index-from ( obj i seq -- n )
 514     rot [ = ] curry find-from drop ;
 515
 516 : last-index ( obj seq -- n )
 517     [ = ] with find-last drop ;
 518
 519 : last-index-from ( obj i seq -- n )
 520     rot [ = ] curry find-last-from drop ;
 521
 522 : (indices) ( elt i obj accum -- )
 523     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 524
 525 : indices ( obj seq -- indices )
 526     swap V{ } clone
 527     [ [ (indices) ] 2curry each-index ] keep ;
 528
 529 : nths ( indices seq -- seq' )
 530     [ nth ] curry map ;
 531
 532 : any? ( seq quot -- ? )
 533     find drop >boolean ; inline
 534
 535 : member? ( elt seq -- ? )
 536     [ = ] with any? ;
 537
 538 : memq? ( elt seq -- ? )
 539     [ eq? ] with any? ;
 540
 541 : remove ( elt seq -- newseq )
 542     [ = not ] with filter ;
 543
 544 : remq ( elt seq -- newseq )
 545     [ eq? not ] with filter ;
 546
 547 : sift ( seq -- newseq )
 548     [ ] filter ;
 549
 550 : harvest ( seq -- newseq )
 551     [ empty? not ] filter ;
 552
 553 : mismatch ( seq1 seq2 -- i )
 554     [ min-length ] 2keep
 555     [ 2nth-unsafe = not ] 2curry
 556     find drop ; inline
 557
 558 M: sequence <=>
 559     2dup mismatch
 560     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 561
 562 : sequence= ( seq1 seq2 -- ? )
 563     2dup [ length ] bi@ =
 564     [ mismatch not ] [ 2drop f ] if ; inline
 565
 566 : sequence-hashcode-step ( oldhash newpart -- newhash )
 567     >fixnum swap [
 568         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 569         fixnum+fast fixnum+fast
 570     ] keep fixnum-bitxor ; inline
 571
 572 : sequence-hashcode ( n seq -- x )
 573     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 574
 575 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 576
 577 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 578
 579 : move ( to from seq -- )
 580     2over =
 581     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 582
 583 <PRIVATE
 584
 585 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 586     2dup length < [
 587         [ move ] 3keep
 588         [ nth-unsafe pick call [ 1+ ] when ] 2keep
 589         [ 1+ ] dip
 590         (filter-here)
 591     ] [ nip set-length drop ] if ; inline recursive
 592
 593 PRIVATE>
 594
 595 : filter-here ( seq quot -- )
 596     swap [ 0 0 ] dip (filter-here) ; inline
 597
 598 : delete ( elt seq -- )
 599     [ = not ] with filter-here ;
 600
 601 : delq ( elt seq -- )
 602     [ eq? not ] with filter-here ;
 603
 604 : prefix ( seq elt -- newseq )
 605     over [ over length 1+ ] dip [
 606         [ 0 swap set-nth-unsafe ] keep
 607         [ 1 swap copy ] keep
 608     ] new-like ;
 609
 610 : suffix ( seq elt -- newseq )
 611     over [ over length 1+ ] dip [
 612         [ [ over length ] dip set-nth-unsafe ] keep
 613         [ 0 swap copy ] keep
 614     ] new-like ;
 615
 616 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 617
 618 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 619
 620 <PRIVATE
 621
 622 : move-backward ( shift from to seq -- )
 623     2over = [
 624         2drop 2drop
 625     ] [
 626         [ [ 2over + pick ] dip move [ 1+ ] dip ] keep
 627         move-backward
 628     ] if ;
 629
 630 : move-forward ( shift from to seq -- )
 631     2over = [
 632         2drop 2drop
 633     ] [
 634         [ [ pick [ dup dup ] dip + swap ] dip move 1- ] keep
 635         move-forward
 636     ] if ;
 637
 638 : (open-slice) ( shift from to seq ? -- )
 639     [
 640         [ [ 1- ] bi@ ] dip move-forward
 641     ] [
 642         [ over - ] 2dip move-backward
 643     ] if ;
 644
 645 : open-slice ( shift from seq -- )
 646     pick 0 = [
 647         3drop
 648     ] [
 649         pick over length + over
 650         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 651         set-length
 652     ] if ;
 653
 654 PRIVATE>
 655
 656 : delete-slice ( from to seq -- )
 657     check-slice [ over [ - ] dip ] dip open-slice ;
 658
 659 : delete-nth ( n seq -- )
 660     [ dup 1+ ] dip delete-slice ;
 661
 662 : snip ( from to seq -- head tail )
 663     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 664
 665 : snip-slice ( from to seq -- head tail )
 666     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 667
 668 : replace-slice ( new from to seq -- seq' )
 669     snip-slice surround ;
 670
 671 : remove-nth ( n seq -- seq' )
 672     [ [ { } ] dip dup 1+ ] dip replace-slice ;
 673
 674 : pop ( seq -- elt )
 675     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 676
 677 : exchange ( m n seq -- )
 678     [ nip bounds-check 2drop ]
 679     [ bounds-check 3drop ]
 680     [ exchange-unsafe ]
 681     3tri ;
 682
 683 : reverse-here ( seq -- )
 684     [ length 2/ ] [ length ] [ ] tri
 685     [ [ over - 1- ] dip exchange-unsafe ] 2curry each ;
 686
 687 : reverse ( seq -- newseq )
 688     [
 689         dup [ length ] keep new-sequence
 690         [ 0 swap copy ] keep
 691         [ reverse-here ] keep
 692     ] keep like ;
 693
 694 : sum-lengths ( seq -- n )
 695     0 [ length + ] reduce ;
 696
 697 : concat ( seq -- newseq )
 698     [ { } ] [
 699         [ sum-lengths ] keep
 700         [ first new-resizable ] keep
 701         [ [ over push-all ] each ] keep
 702         first like
 703     ] if-empty ;
 704
 705 <PRIVATE
 706
 707 : joined-length ( seq glue -- n )
 708     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 709
 710 PRIVATE>
 711
 712 : join ( seq glue -- newseq )
 713     [
 714         2dup joined-length over new-resizable [
 715             [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 716             interleave
 717         ] keep
 718     ] keep like ;
 719
 720 : padding ( seq n elt quot -- newseq )
 721     [
 722         [ over length [-] dup 0 = [ drop ] ] dip
 723         [ <repetition> ] curry
 724     ] dip compose if ; inline
 725
 726 : pad-head ( seq n elt -- padded )
 727     [ swap dup append-as ] padding ;
 728
 729 : pad-tail ( seq n elt -- padded )
 730     [ append ] padding ;
 731
 732 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 733
 734 : head? ( seq begin -- ? )
 735     2dup shorter? [
 736         2drop f
 737     ] [
 738         [ nip ] [ length head-slice ] 2bi sequence=
 739     ] if ;
 740
 741 : tail? ( seq end -- ? )
 742     2dup shorter? [
 743         2drop f
 744     ] [
 745         [ nip ] [ length tail-slice* ] 2bi sequence=
 746     ] if ;
 747
 748 : cut-slice ( seq n -- before-slice after-slice )
 749     [ head-slice ] [ tail-slice ] 2bi ;
 750
 751 : insert-nth ( elt n seq -- seq' )
 752     swap cut-slice [ swap suffix ] dip append ;
 753
 754 : midpoint@ ( seq -- n ) length 2/ ; inline
 755
 756 : halves ( seq -- first-slice second-slice )
 757     dup midpoint@ cut-slice ;
 758
 759 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 760     #! We can't use case here since combinators depends on
 761     #! sequences
 762     pick length dup 0 3 between? [
 763         >fixnum {
 764             [ drop nip ]
 765             [ 2drop first ]
 766             [ [ drop first2 ] dip call ]
 767             [ [ drop first3 ] dip bi@ ]
 768         } dispatch
 769     ] [
 770         drop
 771         [ halves ] 2dip
 772         [ [ binary-reduce ] 2curry bi@ ] keep
 773         call
 774     ] if ; inline recursive
 775
 776 : cut ( seq n -- before after )
 777     [ head ] [ tail ] 2bi ;
 778
 779 : cut* ( seq n -- before after )
 780     [ head* ] [ tail* ] 2bi ;
 781
 782 <PRIVATE
 783
 784 : (start) ( subseq seq n -- subseq seq ? )
 785     pick length [
 786         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 787     ] all? nip ; inline
 788
 789 PRIVATE>
 790
 791 : start* ( subseq seq n -- i )
 792     pick length pick length swap - 1+
 793     [ (start) ] find-from
 794     swap [ 3drop ] dip ;
 795
 796 : start ( subseq seq -- i ) 0 start* ; inline
 797
 798 : subseq? ( subseq seq -- ? ) start >boolean ;
 799
 800 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 801     2dup mismatch [ 2dup min-length ] unless*
 802     [ tail-slice ] curry bi@ ;
 803
 804 : unclip ( seq -- rest first )
 805     [ rest ] [ first-unsafe ] bi ;
 806
 807 : unclip-last ( seq -- butlast last )
 808     [ but-last ] [ peek ] bi ;
 809
 810 : unclip-slice ( seq -- rest-slice first )
 811     [ rest-slice ] [ first-unsafe ] bi ; inline
 812
 813 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 814     [ unclip-slice ] bi@ swapd ; inline
 815
 816 : map-reduce ( seq map-quot reduce-quot -- result )
 817     [ [ unclip-slice ] dip [ call ] keep ] dip
 818     compose reduce ; inline
 819
 820 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 821     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 822     compose 2reduce ; inline
 823
 824 : unclip-last-slice ( seq -- butlast-slice last )
 825     [ but-last-slice ] [ peek ] bi ; inline
 826
 827 : <flat-slice> ( seq -- slice )
 828     dup slice? [ { } like ] when
 829     [ drop 0 ] [ length ] [ ] tri <slice> ;
 830     inline
 831
 832 <PRIVATE
 833
 834 : (trim-head) ( seq quot -- seq n )
 835     over [ [ not ] compose find drop ] dip
 836     [ length or ] keep swap ; inline
 837
 838 : (trim-tail) ( seq quot -- seq n )
 839     over [ [ not ] compose find-last drop ?1+ ] dip
 840     swap ; inline
 841
 842 PRIVATE>
 843
 844 : trim-head-slice ( seq quot -- slice )
 845     (trim-head) tail-slice ; inline
 846
 847 : trim-head ( seq quot -- newseq )
 848     (trim-head) tail ; inline
 849
 850 : trim-tail-slice ( seq quot -- slice )
 851     (trim-tail) head-slice ; inline
 852
 853 : trim-tail ( seq quot -- newseq )
 854     (trim-tail) head ; inline
 855
 856 : trim-slice ( seq quot -- slice )
 857     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 858
 859 : trim ( seq quot -- newseq )
 860     [ trim-slice ] [ drop ] 2bi like ; inline
 861
 862 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 863
 864 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 865
 866 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 867
 868 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 869
 870 : sigma ( seq quot -- n )
 871     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 872
 873 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 874
 875 ! We hand-optimize flip to such a degree because type hints
 876 ! cannot express that an array is an array of arrays yet, and
 877 ! this word happens to be performance-critical since the compiler
 878 ! itself uses it. Optimizing it like this reduced compile time.
 879 <PRIVATE
 880
 881 : generic-flip ( matrix -- newmatrix )
 882     [ dup first length [ length min ] reduce ] keep
 883     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 884
 885 USE: arrays
 886
 887 : array-length ( array -- len )
 888     { array } declare length>> ; inline
 889
 890 : array-flip ( matrix -- newmatrix )
 891     { array } declare
 892     [ dup first array-length [ array-length min ] reduce ] keep
 893     [ [ array-nth ] with { } map-as ] curry { } map-as ;
 894
 895 PRIVATE>
 896
 897 : flip ( matrix -- newmatrix )
 898     dup empty? [
 899         dup array? [
 900             dup [ array? ] all?
 901             [ array-flip ] [ generic-flip ] if
 902         ] [ generic-flip ] if
 903     ] unless ;