core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 ! The f object supports the sequence protocol trivially
  95 M: f length drop 0 ; inline
  96 M: f nth-unsafe nip ; inline
  97 M: f like drop [ f ] when-empty ; inline
  98
  99 INSTANCE: f immutable-sequence
 100
 101 ! Integers used to support the sequence protocol
 102 M: integer length ; inline
 103 M: integer nth-unsafe drop ; inline
 104
 105 INSTANCE: integer immutable-sequence
 106
 107 PRIVATE>
 108
 109 ! In the future, this will replace integer sequences
 110 TUPLE: iota { n integer read-only } ;
 111
 112 : iota ( n -- iota ) \ iota boa ; inline
 113
 114 <PRIVATE
 115
 116 M: iota length n>> ; inline
 117 M: iota nth-unsafe drop ; inline
 118
 119 INSTANCE: iota immutable-sequence
 120
 121 : first-unsafe ( seq -- first )
 122     0 swap nth-unsafe ; inline
 123
 124 : first2-unsafe ( seq -- first second )
 125     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 126
 127 : first3-unsafe ( seq -- first second third )
 128     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 129
 130 : first4-unsafe ( seq -- first second third fourth )
 131     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 132
 133 : exchange-unsafe ( m n seq -- )
 134     [ [ nth-unsafe ] curry bi@ ]
 135     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 136
 137 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 138
 139 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 140
 141 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 142
 143 : (1sequence) ( obj seq -- seq )
 144     [ 0 swap set-nth-unsafe ] keep ; inline
 145
 146 : (2sequence) ( obj1 obj2 seq -- seq )
 147     [ 1 swap set-nth-unsafe ] keep
 148     (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep
 152     (2sequence) ; inline
 153
 154 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 155     [ 3 swap set-nth-unsafe ] keep
 156     (3sequence) ; inline
 157
 158 PRIVATE>
 159
 160 : 1sequence ( obj exemplar -- seq )
 161     1 swap [ (1sequence) ] new-like ; inline
 162
 163 : 2sequence ( obj1 obj2 exemplar -- seq )
 164     2 swap [ (2sequence) ] new-like ; inline
 165
 166 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 167     3 swap [ (3sequence) ] new-like ; inline
 168
 169 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 170     4 swap [ (4sequence) ] new-like ; inline
 171
 172 : first2 ( seq -- first second )
 173     1 swap bounds-check nip first2-unsafe ; flushable
 174
 175 : first3 ( seq -- first second third )
 176     2 swap bounds-check nip first3-unsafe ; flushable
 177
 178 : first4 ( seq -- first second third fourth )
 179     3 swap bounds-check nip first4-unsafe ; flushable
 180
 181 : ?nth ( n seq -- elt/f )
 182     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 183
 184 MIXIN: virtual-sequence
 185 GENERIC: virtual-seq ( seq -- seq' )
 186 GENERIC: virtual@ ( n seq -- n' seq' )
 187
 188 M: virtual-sequence nth virtual@ nth ; inline
 189 M: virtual-sequence set-nth virtual@ set-nth ; inline
 190 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 191 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 192 M: virtual-sequence like virtual-seq like ; inline
 193 M: virtual-sequence new-sequence virtual-seq new-sequence ; inline
 194
 195 INSTANCE: virtual-sequence sequence
 196
 197 ! A reversal of an underlying sequence.
 198 TUPLE: reversed { seq read-only } ;
 199
 200 C: <reversed> reversed
 201
 202 M: reversed virtual-seq seq>> ; inline
 203 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 204 M: reversed length seq>> length ; inline
 205
 206 INSTANCE: reversed virtual-sequence
 207
 208 ! A slice of another sequence.
 209 TUPLE: slice
 210 { from read-only }
 211 { to read-only }
 212 { seq read-only } ;
 213
 214 : collapse-slice ( m n slice -- m' n' seq )
 215     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 216
 217 TUPLE: slice-error from to seq reason ;
 218
 219 : slice-error ( from to seq ? string -- from to seq )
 220     [ \ slice-error boa throw ] curry when ; inline
 221
 222 : check-slice ( from to seq -- from to seq )
 223     3dup
 224     [ 2drop 0 < "start < 0" slice-error ]
 225     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 226     [ drop > "start > end" slice-error ]
 227     3tri ; inline
 228
 229 : <slice> ( from to seq -- slice )
 230     dup slice? [ collapse-slice ] when
 231     check-slice
 232     slice boa ; inline
 233
 234 M: slice virtual-seq seq>> ; inline
 235
 236 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 237
 238 M: slice length [ to>> ] [ from>> ] bi - ; inline
 239
 240 : short ( seq n -- seq n' ) over length min ; inline
 241
 242 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 243
 244 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 245
 246 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 247
 248 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 249
 250 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 251
 252 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 253
 254 INSTANCE: slice virtual-sequence
 255
 256 ! One element repeated many times
 257 TUPLE: repetition { len read-only } { elt read-only } ;
 258
 259 C: <repetition> repetition
 260
 261 M: repetition length len>> ; inline
 262 M: repetition nth-unsafe nip elt>> ; inline
 263
 264 INSTANCE: repetition immutable-sequence
 265
 266 <PRIVATE
 267
 268 ERROR: integer-length-expected obj ;
 269
 270 : check-length ( n -- n )
 271     #! Ricing.
 272     dup integer? [ integer-length-expected ] unless ; inline
 273
 274 : ((copy)) ( dst i src j n -- dst i src j n )
 275     dup -roll [
 276         + swap nth-unsafe -roll [
 277             + swap set-nth-unsafe
 278         ] 3keep drop
 279     ] 3keep ; inline
 280
 281 : (copy) ( dst i src j n -- dst )
 282     dup 0 <= [ 2drop 2drop ] [ 1 - ((copy)) (copy) ] if ;
 283     inline recursive
 284
 285 : prepare-subseq ( from to seq -- dst i src j n )
 286     #! The check-length call forces partial dispatch
 287     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 288     -rot drop roll length check-length ; inline
 289
 290 : check-copy ( src n dst -- )
 291     over 0 < [ bounds-error ] when
 292     [ swap length + ] dip lengthen ; inline
 293
 294 PRIVATE>
 295
 296 : subseq ( from to seq -- subseq )
 297     [ check-slice prepare-subseq (copy) ] keep like ;
 298
 299 : head ( seq n -- headseq ) (head) subseq ;
 300
 301 : tail ( seq n -- tailseq ) (tail) subseq ;
 302
 303 : rest ( seq -- tailseq ) 1 tail ;
 304
 305 : head* ( seq n -- headseq ) from-end head ;
 306
 307 : tail* ( seq n -- tailseq ) from-end tail ;
 308
 309 : but-last ( seq -- headseq ) 1 head* ;
 310
 311 : copy ( src i dst -- )
 312     #! The check-length call forces partial dispatch
 313     pick length check-length [ 3dup check-copy spin 0 ] dip
 314     (copy) drop ; inline
 315
 316 M: sequence clone-like
 317     [ dup length ] dip new-sequence [ 0 swap copy ] keep ; inline
 318
 319 M: immutable-sequence clone-like like ; inline
 320
 321 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 322
 323 <PRIVATE
 324
 325 : (append) ( seq1 seq2 accum -- accum )
 326     [ [ over length ] dip copy ]
 327     [ 0 swap copy ]
 328     [ ] tri ; inline
 329
 330 PRIVATE>
 331
 332 : append-as ( seq1 seq2 exemplar -- newseq )
 333     [ over length over length + ] dip
 334     [ (append) ] new-like ; inline
 335
 336 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 337     [ 3dup [ length ] tri@ + + ] dip [
 338         [ [ 2over [ length ] bi@ + ] dip copy ]
 339         [ (append) ] bi
 340     ] new-like ; inline
 341
 342 : append ( seq1 seq2 -- newseq ) over append-as ;
 343
 344 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 345
 346 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 347
 348 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 349
 350 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 351
 352 : change-nth ( i seq quot -- )
 353     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 354
 355 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 356
 357 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 358
 359 <PRIVATE
 360
 361 : ((each)) ( seq -- n quot )
 362     [ length ] keep [ nth-unsafe ] curry ; inline
 363
 364 : (each) ( seq quot -- n quot' )
 365     [ ((each)) ] dip compose ; inline
 366
 367 : (each-index) ( seq quot -- n quot' )
 368     [ ((each)) [ keep ] curry ] dip compose ; inline
 369
 370 : (collect) ( quot into -- quot' )
 371     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 372
 373 : collect ( n quot into -- )
 374     (collect) each-integer ; inline
 375
 376 : map-into ( seq quot into -- )
 377     [ (each) ] dip collect ; inline
 378
 379 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 380     [ nth-unsafe ] bi-curry@ bi ; inline
 381
 382 : (2each) ( seq1 seq2 quot -- n quot' )
 383     [
 384         [ min-length ] 2keep
 385         [ 2nth-unsafe ] 2curry
 386     ] dip compose ; inline
 387
 388 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 389     [ nth-unsafe ] tri-curry@ tri ; inline
 390
 391 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 392     [
 393         [ [ length ] tri@ min min ]
 394         [ [ 3nth-unsafe ] 3curry ] 3bi
 395     ] dip compose ; inline
 396
 397 : finish-find ( i seq -- i elt )
 398     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 399
 400 : (find) ( seq quot quot' -- i elt )
 401     pick [ [ (each) ] dip call ] dip finish-find ; inline
 402
 403 : (find-from) ( n seq quot quot' -- i elt )
 404     [ 2dup bounds-check? ] 2dip
 405     [ (find) ] 2curry
 406     [ 2drop f f ]
 407     if ; inline
 408
 409 PRIVATE>
 410
 411 : each ( seq quot -- )
 412     (each) each-integer ; inline
 413
 414 : reduce ( seq identity quot -- result )
 415     swapd each ; inline
 416
 417 : map-integers ( len quot exemplar -- newseq )
 418     [ over ] dip [ [ collect ] keep ] new-like ; inline
 419
 420 : map-as ( seq quot exemplar -- newseq )
 421     [ (each) ] dip map-integers ; inline
 422
 423 : map ( seq quot -- newseq )
 424     over map-as ; inline
 425
 426 : replicate ( seq quot -- newseq )
 427     [ drop ] prepose map ; inline
 428
 429 : replicate-as ( seq quot exemplar -- newseq )
 430     [ [ drop ] prepose ] dip map-as ; inline
 431
 432 : change-each ( seq quot -- )
 433     over map-into ; inline
 434
 435 : accumulate-as ( seq identity quot exemplar -- final newseq )
 436     [ [ swap ] dip [ curry keep ] curry ] dip map-as ; inline
 437
 438 : accumulate ( seq identity quot -- final newseq )
 439     { } accumulate-as ; inline
 440
 441 : 2each ( seq1 seq2 quot -- )
 442     (2each) each-integer ; inline
 443
 444 : 2reverse-each ( seq1 seq2 quot -- )
 445     [ [ <reversed> ] bi@ ] dip 2each ; inline
 446
 447 : 2reduce ( seq1 seq2 identity quot -- result )
 448     [ -rot ] dip 2each ; inline
 449
 450 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 451     [ (2each) ] dip map-integers ; inline
 452
 453 : 2map ( seq1 seq2 quot -- newseq )
 454     pick 2map-as ; inline
 455
 456 : 2all? ( seq1 seq2 quot -- ? )
 457     (2each) all-integers? ; inline
 458
 459 : 3each ( seq1 seq2 seq3 quot -- )
 460     (3each) each ; inline
 461
 462 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 463     [ (3each) ] dip map-integers ; inline
 464
 465 : 3map ( seq1 seq2 seq3 quot -- newseq )
 466     [ pick ] dip swap 3map-as ; inline
 467
 468 : find-from ( n seq quot -- i elt )
 469     [ (find-integer) ] (find-from) ; inline
 470
 471 : find ( seq quot -- i elt )
 472     [ find-integer ] (find) ; inline
 473
 474 : find-last-from ( n seq quot -- i elt )
 475     [ nip find-last-integer ] (find-from) ; inline
 476
 477 : find-last ( seq quot -- i elt )
 478     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 479
 480 : all? ( seq quot -- ? )
 481     (each) all-integers? ; inline
 482
 483 : push-if ( elt quot accum -- )
 484     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 485
 486 : pusher ( quot -- quot accum )
 487     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 488
 489 : filter ( seq quot -- subseq )
 490     over [ pusher [ each ] dip ] dip like ; inline
 491
 492 : push-either ( elt quot accum1 accum2 -- )
 493     [ keep swap ] 2dip ? push ; inline
 494
 495 : 2pusher ( quot -- quot accum1 accum2 )
 496     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 497
 498 : partition ( seq quot -- trueseq falseseq )
 499     over [ 2pusher [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 500
 501 : accumulator ( quot -- quot' vec )
 502     V{ } clone [ [ push ] curry compose ] keep ; inline
 503
 504 : produce-as ( pred quot exemplar -- seq )
 505     [ accumulator [ while ] dip ] dip like ; inline
 506
 507 : produce ( pred quot -- seq )
 508     { } produce-as ; inline
 509
 510 : follow ( obj quot -- seq )
 511     [ dup ] swap [ keep ] curry produce nip ; inline
 512
 513 : each-index ( seq quot -- )
 514     (each-index) each-integer ; inline
 515
 516 : interleave ( seq between quot -- )
 517     pick empty? [ 3drop ] [
 518         [ [ drop first-unsafe ] dip call ]
 519         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 520         3bi
 521     ] if ; inline
 522
 523 : map-index ( seq quot -- newseq )
 524     [ dup length iota ] dip 2map ; inline
 525
 526 : reduce-index ( seq identity quot -- )
 527     swapd each-index ; inline
 528
 529 : index ( obj seq -- n )
 530     [ = ] with find drop ;
 531
 532 : index-from ( obj i seq -- n )
 533     rot [ = ] curry find-from drop ;
 534
 535 : last-index ( obj seq -- n )
 536     [ = ] with find-last drop ;
 537
 538 : last-index-from ( obj i seq -- n )
 539     rot [ = ] curry find-last-from drop ;
 540
 541 <PRIVATE
 542
 543 : (indices) ( elt i obj accum -- )
 544     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 545
 546 PRIVATE>
 547
 548 : indices ( obj seq -- indices )
 549     swap V{ } clone
 550     [ [ (indices) ] 2curry each-index ] keep ;
 551
 552 : nths ( indices seq -- seq' )
 553     [ nth ] curry map ;
 554
 555 : any? ( seq quot -- ? )
 556     find drop >boolean ; inline
 557
 558 : member? ( elt seq -- ? )
 559     [ = ] with any? ;
 560
 561 : memq? ( elt seq -- ? )
 562     [ eq? ] with any? ;
 563
 564 : remove ( elt seq -- newseq )
 565     [ = not ] with filter ;
 566
 567 : remq ( elt seq -- newseq )
 568     [ eq? not ] with filter ;
 569
 570 : sift ( seq -- newseq )
 571     [ ] filter ;
 572
 573 : harvest ( seq -- newseq )
 574     [ empty? not ] filter ;
 575
 576 : mismatch ( seq1 seq2 -- i )
 577     [ min-length iota ] 2keep
 578     [ 2nth-unsafe = not ] 2curry
 579     find drop ; inline
 580
 581 M: sequence <=>
 582     2dup mismatch
 583     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 584
 585 : sequence= ( seq1 seq2 -- ? )
 586     2dup [ length ] bi@ =
 587     [ mismatch not ] [ 2drop f ] if ; inline
 588
 589 ERROR: assert-sequence got expected ;
 590
 591 : assert-sequence= ( a b -- )
 592     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 593
 594 : sequence-hashcode-step ( oldhash newpart -- newhash )
 595     >fixnum swap [
 596         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 597         fixnum+fast fixnum+fast
 598     ] keep fixnum-bitxor ; inline
 599
 600 : sequence-hashcode ( n seq -- x )
 601     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 602
 603 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 604
 605 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 606
 607 : move ( to from seq -- )
 608     2over =
 609     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 610
 611 <PRIVATE
 612
 613 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 614     2dup length < [
 615         [ move ] 3keep
 616         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 617         [ 1 + ] dip
 618         (filter-here)
 619     ] [ nip set-length drop ] if ; inline recursive
 620
 621 PRIVATE>
 622
 623 : filter-here ( seq quot -- )
 624     swap [ 0 0 ] dip (filter-here) ; inline
 625
 626 : delete ( elt seq -- )
 627     [ = not ] with filter-here ;
 628
 629 : delq ( elt seq -- )
 630     [ eq? not ] with filter-here ;
 631
 632 : prefix ( seq elt -- newseq )
 633     over [ over length 1 + ] dip [
 634         [ 0 swap set-nth-unsafe ] keep
 635         [ 1 swap copy ] keep
 636     ] new-like ;
 637
 638 : suffix ( seq elt -- newseq )
 639     over [ over length 1 + ] dip [
 640         [ [ over length ] dip set-nth-unsafe ] keep
 641         [ 0 swap copy ] keep
 642     ] new-like ;
 643
 644 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 645
 646 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 647
 648 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 649
 650 <PRIVATE
 651
 652 : move-backward ( shift from to seq -- )
 653     2over = [
 654         2drop 2drop
 655     ] [
 656         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 657         move-backward
 658     ] if ;
 659
 660 : move-forward ( shift from to seq -- )
 661     2over = [
 662         2drop 2drop
 663     ] [
 664         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 665         move-forward
 666     ] if ;
 667
 668 : (open-slice) ( shift from to seq ? -- )
 669     [
 670         [ [ 1 - ] bi@ ] dip move-forward
 671     ] [
 672         [ over - ] 2dip move-backward
 673     ] if ;
 674
 675 : open-slice ( shift from seq -- )
 676     pick 0 = [
 677         3drop
 678     ] [
 679         pick over length + over
 680         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 681         set-length
 682     ] if ;
 683
 684 PRIVATE>
 685
 686 : delete-slice ( from to seq -- )
 687     check-slice [ over [ - ] dip ] dip open-slice ;
 688
 689 : delete-nth ( n seq -- )
 690     [ dup 1 + ] dip delete-slice ;
 691
 692 : snip ( from to seq -- head tail )
 693     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 694
 695 : snip-slice ( from to seq -- head tail )
 696     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 697
 698 : replace-slice ( new from to seq -- seq' )
 699     snip-slice surround ;
 700
 701 : remove-nth ( n seq -- seq' )
 702     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 703
 704 : pop ( seq -- elt )
 705     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 706
 707 : exchange ( m n seq -- )
 708     [ nip bounds-check 2drop ]
 709     [ bounds-check 3drop ]
 710     [ exchange-unsafe ]
 711     3tri ;
 712
 713 : reverse-here ( seq -- )
 714     [ length 2/ iota ] [ length ] [ ] tri
 715     [ [ over - 1 - ] dip exchange-unsafe ] 2curry each ;
 716
 717 : reverse ( seq -- newseq )
 718     [
 719         dup [ length ] keep new-sequence
 720         [ 0 swap copy ] keep
 721         [ reverse-here ] keep
 722     ] keep like ;
 723
 724 : sum-lengths ( seq -- n )
 725     0 [ length + ] reduce ;
 726
 727 : concat-as ( seq exemplar -- newseq )
 728     swap [ { } ] [
 729         [ sum-lengths over new-resizable ] keep
 730         [ over push-all ] each
 731     ] if-empty swap like ;
 732
 733 : concat ( seq -- newseq )
 734     [ { } ] [ dup first concat-as ] if-empty ;
 735
 736 <PRIVATE
 737
 738 : joined-length ( seq glue -- n )
 739     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 740
 741 PRIVATE>
 742
 743 : join ( seq glue -- newseq )
 744     dup empty? [ concat-as ] [
 745         [
 746             2dup joined-length over new-resizable [
 747                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 748                 interleave
 749             ] keep
 750         ] keep like
 751     ] if ;
 752
 753 : padding ( seq n elt quot -- newseq )
 754     [
 755         [ over length [-] dup 0 = [ drop ] ] dip
 756         [ <repetition> ] curry
 757     ] dip compose if ; inline
 758
 759 : pad-head ( seq n elt -- padded )
 760     [ swap dup append-as ] padding ;
 761
 762 : pad-tail ( seq n elt -- padded )
 763     [ append ] padding ;
 764
 765 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 766
 767 : head? ( seq begin -- ? )
 768     2dup shorter? [
 769         2drop f
 770     ] [
 771         [ nip ] [ length head-slice ] 2bi sequence=
 772     ] if ;
 773
 774 : tail? ( seq end -- ? )
 775     2dup shorter? [
 776         2drop f
 777     ] [
 778         [ nip ] [ length tail-slice* ] 2bi sequence=
 779     ] if ;
 780
 781 : cut-slice ( seq n -- before-slice after-slice )
 782     [ head-slice ] [ tail-slice ] 2bi ;
 783
 784 : insert-nth ( elt n seq -- seq' )
 785     swap cut-slice [ swap suffix ] dip append ;
 786
 787 : midpoint@ ( seq -- n ) length 2/ ; inline
 788
 789 : halves ( seq -- first-slice second-slice )
 790     dup midpoint@ cut-slice ;
 791
 792 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 793     #! We can't use case here since combinators depends on
 794     #! sequences
 795     pick length dup 0 3 between? [
 796         >fixnum {
 797             [ drop nip ]
 798             [ 2drop first ]
 799             [ [ drop first2 ] dip call ]
 800             [ [ drop first3 ] dip bi@ ]
 801         } dispatch
 802     ] [
 803         drop
 804         [ halves ] 2dip
 805         [ [ binary-reduce ] 2curry bi@ ] keep
 806         call
 807     ] if ; inline recursive
 808
 809 : cut ( seq n -- before after )
 810     [ head ] [ tail ] 2bi ;
 811
 812 : cut* ( seq n -- before after )
 813     [ head* ] [ tail* ] 2bi ;
 814
 815 <PRIVATE
 816
 817 : (start) ( subseq seq n -- subseq seq ? )
 818     pick length iota [
 819         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 820     ] all? nip ; inline
 821
 822 PRIVATE>
 823
 824 : start* ( subseq seq n -- i )
 825     pick length pick length swap - 1 + iota
 826     [ (start) ] find-from
 827     swap [ 3drop ] dip ;
 828
 829 : start ( subseq seq -- i ) 0 start* ; inline
 830
 831 : subseq? ( subseq seq -- ? ) start >boolean ;
 832
 833 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 834     2dup mismatch [ 2dup min-length ] unless*
 835     [ tail-slice ] curry bi@ ;
 836
 837 : unclip ( seq -- rest first )
 838     [ rest ] [ first-unsafe ] bi ;
 839
 840 : unclip-last ( seq -- butlast last )
 841     [ but-last ] [ last ] bi ;
 842
 843 : unclip-slice ( seq -- rest-slice first )
 844     [ rest-slice ] [ first-unsafe ] bi ; inline
 845
 846 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 847     [ unclip-slice ] bi@ swapd ; inline
 848
 849 : map-reduce ( seq map-quot reduce-quot -- result )
 850     [ [ unclip-slice ] dip [ call ] keep ] dip
 851     compose reduce ; inline
 852
 853 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 854     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 855     compose 2reduce ; inline
 856
 857 <PRIVATE
 858
 859 : (map-find) ( seq quot find-quot -- result elt )
 860     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 861     [ [ drop f ] unless ] dip ; inline
 862
 863 PRIVATE>
 864
 865 : map-find ( seq quot -- result elt )
 866     [ find ] (map-find) ; inline
 867
 868 : map-find-last ( seq quot -- result elt )
 869     [ find-last ] (map-find) ; inline
 870
 871 : unclip-last-slice ( seq -- butlast-slice last )
 872     [ but-last-slice ] [ last ] bi ; inline
 873
 874 : <flat-slice> ( seq -- slice )
 875     dup slice? [ { } like ] when
 876     [ drop 0 ] [ length ] [ ] tri <slice> ;
 877     inline
 878
 879 <PRIVATE
 880
 881 : (trim-head) ( seq quot -- seq n )
 882     over [ [ not ] compose find drop ] dip
 883     [ length or ] keep swap ; inline
 884
 885 : (trim-tail) ( seq quot -- seq n )
 886     over [ [ not ] compose find-last drop ?1+ ] dip
 887     swap ; inline
 888
 889 PRIVATE>
 890
 891 : trim-head-slice ( seq quot -- slice )
 892     (trim-head) tail-slice ; inline
 893
 894 : trim-head ( seq quot -- newseq )
 895     (trim-head) tail ; inline
 896
 897 : trim-tail-slice ( seq quot -- slice )
 898     (trim-tail) head-slice ; inline
 899
 900 : trim-tail ( seq quot -- newseq )
 901     (trim-tail) head ; inline
 902
 903 : trim-slice ( seq quot -- slice )
 904     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 905
 906 : trim ( seq quot -- newseq )
 907     [ trim-slice ] [ drop ] 2bi like ; inline
 908
 909 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 910
 911 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 912
 913 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 914
 915 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 916
 917 : sigma ( seq quot -- n )
 918     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 919
 920 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 921
 922 ! We hand-optimize flip to such a degree because type hints
 923 ! cannot express that an array is an array of arrays yet, and
 924 ! this word happens to be performance-critical since the compiler
 925 ! itself uses it. Optimizing it like this reduced compile time.
 926 <PRIVATE
 927
 928 : generic-flip ( matrix -- newmatrix )
 929     [ dup first length [ length min ] reduce iota ] keep
 930     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 931
 932 USE: arrays
 933
 934 : array-length ( array -- len )
 935     { array } declare length>> ; inline
 936
 937 : array-flip ( matrix -- newmatrix )
 938     { array } declare
 939     [ dup first array-length [ array-length min ] reduce iota ] keep
 940     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 941
 942 PRIVATE>
 943
 944 : flip ( matrix -- newmatrix )
 945     dup empty? [
 946         dup array? [
 947             dup [ array? ] all?
 948             [ array-flip ] [ generic-flip ] if
 949         ] [ generic-flip ] if
 950     ] unless ;