core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop [ f ] when-empty ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 PRIVATE>
 105
 106 ! In the future, this will replace integer sequences
 107 TUPLE: iota { n integer read-only } ;
 108
 109 : iota ( n -- iota ) \ iota boa ; inline
 110
 111 <PRIVATE
 112
 113 M: iota length n>> ;
 114 M: iota nth-unsafe drop ;
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 : first-unsafe ( seq -- first )
 119     0 swap nth-unsafe ; inline
 120
 121 : first2-unsafe ( seq -- first second )
 122     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 123
 124 : first3-unsafe ( seq -- first second third )
 125     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 126
 127 : first4-unsafe ( seq -- first second third fourth )
 128     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 129
 130 : exchange-unsafe ( m n seq -- )
 131     [ tuck [ nth-unsafe ] 2bi@ ]
 132     [ tuck [ set-nth-unsafe ] 2bi@ ] 3bi ; inline
 133
 134 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 135
 136 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 137
 138 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep
 142     [ 0 swap set-nth-unsafe ] keep ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep
 146     (2sequence) ; inline
 147
 148 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 149     [ 3 swap set-nth-unsafe ] keep
 150     (3sequence) ; inline
 151
 152 PRIVATE>
 153
 154 : 2sequence ( obj1 obj2 exemplar -- seq )
 155     2 swap [ (2sequence) ] new-like ; inline
 156
 157 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 158     3 swap [ (3sequence) ] new-like ; inline
 159
 160 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 161     4 swap [ (4sequence) ] new-like ; inline
 162
 163 : first2 ( seq -- first second )
 164     1 swap bounds-check nip first2-unsafe ; flushable
 165
 166 : first3 ( seq -- first second third )
 167     2 swap bounds-check nip first3-unsafe ; flushable
 168
 169 : first4 ( seq -- first second third fourth )
 170     3 swap bounds-check nip first4-unsafe ; flushable
 171
 172 : ?nth ( n seq -- elt/f )
 173     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 174
 175 MIXIN: virtual-sequence
 176 GENERIC: virtual-seq ( seq -- seq' )
 177 GENERIC: virtual@ ( n seq -- n' seq' )
 178
 179 M: virtual-sequence nth virtual@ nth ;
 180 M: virtual-sequence set-nth virtual@ set-nth ;
 181 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 182 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 183 M: virtual-sequence like virtual-seq like ;
 184 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 185
 186 INSTANCE: virtual-sequence sequence
 187
 188 ! A reversal of an underlying sequence.
 189 TUPLE: reversed { seq read-only } ;
 190
 191 C: <reversed> reversed
 192
 193 M: reversed virtual-seq seq>> ;
 194
 195 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 196
 197 M: reversed length seq>> length ;
 198
 199 INSTANCE: reversed virtual-sequence
 200
 201 ! A slice of another sequence.
 202 TUPLE: slice
 203 { from read-only }
 204 { to read-only }
 205 { seq read-only } ;
 206
 207 : collapse-slice ( m n slice -- m' n' seq )
 208     [ from>> ] [ seq>> ] bi [ tuck [ + ] 2bi@ ] dip ; inline
 209
 210 ERROR: slice-error from to seq reason ;
 211
 212 : check-slice ( from to seq -- from to seq )
 213     pick 0 < [ "start < 0" slice-error ] when
 214     dup length pick < [ "end > sequence" slice-error ] when
 215     2over > [ "start > end" slice-error ] when ; inline
 216
 217 : <slice> ( from to seq -- slice )
 218     dup slice? [ collapse-slice ] when
 219     check-slice
 220     slice boa ; inline
 221
 222 M: slice virtual-seq seq>> ;
 223
 224 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 225
 226 M: slice length [ to>> ] [ from>> ] bi - ;
 227
 228 : short ( seq n -- seq n' ) over length min ; inline
 229
 230 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 231
 232 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 233
 234 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 235
 236 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 237
 238 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 239
 240 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 241
 242 INSTANCE: slice virtual-sequence
 243
 244 ! One element repeated many times
 245 TUPLE: repetition { len read-only } { elt read-only } ;
 246
 247 C: <repetition> repetition
 248
 249 M: repetition length len>> ;
 250 M: repetition nth-unsafe nip elt>> ;
 251
 252 INSTANCE: repetition immutable-sequence
 253
 254 <PRIVATE
 255
 256 : check-length ( n -- n )
 257     #! Ricing.
 258     dup integer? [ "length not an integer" throw ] unless ; inline
 259
 260 : ((copy)) ( dst i src j n -- dst i src j n )
 261     dup -roll [
 262         + swap nth-unsafe -roll [
 263             + swap set-nth-unsafe
 264         ] 3keep drop
 265     ] 3keep ; inline
 266
 267 : (copy) ( dst i src j n -- dst )
 268     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 269     inline recursive
 270
 271 : prepare-subseq ( from to seq -- dst i src j n )
 272     #! The check-length call forces partial dispatch
 273     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 274     -rot drop roll length check-length ; inline
 275
 276 : check-copy ( src n dst -- )
 277     over 0 < [ bounds-error ] when
 278     [ swap length + ] dip lengthen ; inline
 279
 280 PRIVATE>
 281
 282 : subseq ( from to seq -- subseq )
 283     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 284
 285 : head ( seq n -- headseq ) (head) subseq ;
 286
 287 : tail ( seq n -- tailseq ) (tail) subseq ;
 288
 289 : rest ( seq -- tailseq ) 1 tail ;
 290
 291 : head* ( seq n -- headseq ) from-end head ;
 292
 293 : tail* ( seq n -- tailseq ) from-end tail ;
 294
 295 : but-last ( seq -- headseq ) 1 head* ;
 296
 297 : copy ( src i dst -- )
 298     #! The check-length call forces partial dispatch
 299     pick length check-length [ 3dup check-copy spin 0 ] dip
 300     (copy) drop ; inline
 301
 302 M: sequence clone-like
 303     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 304
 305 M: immutable-sequence clone-like like ;
 306
 307 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 308
 309 <PRIVATE
 310
 311 : (append) ( seq1 seq2 accum -- accum )
 312     [ [ over length ] dip copy ]
 313     [ 0 swap copy ]
 314     [ ] tri ; inline
 315
 316 PRIVATE>
 317
 318 : append-as ( seq1 seq2 exemplar -- newseq )
 319     [ over length over length + ] dip
 320     [ (append) ] new-like ; inline
 321
 322 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 323     [ pick length pick length pick length + + ] dip [
 324         [ [ pick length pick length + ] dip copy ]
 325         [ (append) ] bi
 326     ] new-like ; inline
 327
 328 : append ( seq1 seq2 -- newseq ) over append-as ;
 329
 330 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 331
 332 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 333
 334 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 335
 336 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 337
 338 : change-nth ( i seq quot -- )
 339     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 340
 341 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 342
 343 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 344
 345 <PRIVATE
 346
 347 : (each) ( seq quot -- n quot' )
 348     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 349
 350 : (collect) ( quot into -- quot' )
 351     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 352
 353 : collect ( n quot into -- )
 354     (collect) each-integer ; inline
 355
 356 : map-into ( seq quot into -- )
 357     [ (each) ] dip collect ; inline
 358
 359 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 360     [ over ] dip [ nth-unsafe ] 2bi@ ; inline
 361
 362 : (2each) ( seq1 seq2 quot -- n quot' )
 363     [
 364         [ min-length ] 2keep
 365         [ 2nth-unsafe ] 2curry
 366     ] dip compose ; inline
 367
 368 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 369     [ over ] 2dip [ over ] dip [ nth-unsafe ] 2tri@ ; inline
 370
 371 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 372     [
 373         [ [ length ] tri@ min min ] 3keep
 374         [ 3nth-unsafe ] 3curry
 375     ] dip compose ; inline
 376
 377 : finish-find ( i seq -- i elt )
 378     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 379
 380 : (find) ( seq quot quot' -- i elt )
 381     pick [ [ (each) ] dip call ] dip finish-find ; inline
 382
 383 : (find-from) ( n seq quot quot' -- i elt )
 384     [ 2dup bounds-check? ] 2dip
 385     [ (find) ] 2curry
 386     [ 2drop f f ]
 387     if ; inline
 388
 389 : (interleave) ( n elt between quot -- )
 390     roll 0 = [ nip ] [ swapd 2slip ] if call ; inline
 391
 392 PRIVATE>
 393
 394 : each ( seq quot -- )
 395     (each) each-integer ; inline
 396
 397 : reduce ( seq identity quot -- result )
 398     swapd each ; inline
 399
 400 : map-as ( seq quot exemplar -- newseq )
 401     [ over length ] dip [ [ map-into ] keep ] new-like ; inline
 402
 403 : map ( seq quot -- newseq )
 404     over map-as ; inline
 405
 406 : replicate ( seq quot -- newseq )
 407     [ drop ] prepose map ; inline
 408
 409 : replicate-as ( seq quot exemplar -- newseq )
 410     [ [ drop ] prepose ] dip map-as ; inline
 411
 412 : change-each ( seq quot -- )
 413     over map-into ; inline
 414
 415 : accumulate ( seq identity quot -- final newseq )
 416     swapd [ pick slip ] curry map ; inline
 417
 418 : 2each ( seq1 seq2 quot -- )
 419     (2each) each-integer ; inline
 420
 421 : 2reverse-each ( seq1 seq2 quot -- )
 422     [ [ <reversed> ] bi@ ] dip 2each ; inline
 423
 424 : 2reduce ( seq1 seq2 identity quot -- result )
 425     [ -rot ] dip 2each ; inline
 426
 427 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 428     [ (2each) ] dip map-as ; inline
 429
 430 : 2map ( seq1 seq2 quot -- newseq )
 431     pick 2map-as ; inline
 432
 433 : 2all? ( seq1 seq2 quot -- ? )
 434     (2each) all-integers? ; inline
 435
 436 : 3each ( seq1 seq2 seq3 quot -- )
 437     (3each) each ; inline
 438
 439 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 440     [ (3each) ] dip map-as ; inline
 441
 442 : 3map ( seq1 seq2 seq3 quot -- newseq )
 443     [ pick ] dip swap 3map-as ; inline
 444
 445 : find-from ( n seq quot -- i elt )
 446     [ (find-integer) ] (find-from) ; inline
 447
 448 : find ( seq quot -- i elt )
 449     [ find-integer ] (find) ; inline
 450
 451 : find-last-from ( n seq quot -- i elt )
 452     [ nip find-last-integer ] (find-from) ; inline
 453
 454 : find-last ( seq quot -- i elt )
 455     [ [ 1- ] dip find-last-integer ] (find) ; inline
 456
 457 : all? ( seq quot -- ? )
 458     (each) all-integers? ; inline
 459
 460 : push-if ( elt quot accum -- )
 461     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 462
 463 : pusher ( quot -- quot accum )
 464     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 465
 466 : filter ( seq quot -- subseq )
 467     over [ pusher [ each ] dip ] dip like ; inline
 468
 469 : push-either ( elt quot accum1 accum2 -- )
 470     [ keep swap ] 2dip ? push ; inline
 471
 472 : 2pusher ( quot -- quot accum1 accum2 )
 473     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 474
 475 : partition ( seq quot -- trueseq falseseq )
 476     over [ 2pusher [ each ] 2dip ] dip tuck [ like ] 2bi@ ; inline
 477
 478 : interleave ( seq between quot -- )
 479     [ (interleave) ] 2curry [ [ length ] keep ] dip 2each ; inline
 480
 481 : accumulator ( quot -- quot' vec )
 482     V{ } clone [ [ push ] curry compose ] keep ; inline
 483
 484 : produce-as ( pred quot tail exemplar -- seq )
 485     [ swap accumulator [ swap while ] dip ] dip like ; inline
 486
 487 : produce ( pred quot tail -- seq )
 488     { } produce-as ; inline
 489
 490 : follow ( obj quot -- seq )
 491     [ dup ] swap [ keep ] curry [ ] produce nip ; inline
 492
 493 : prepare-index ( seq quot -- seq n quot )
 494     [ dup length ] dip ; inline
 495
 496 : each-index ( seq quot -- )
 497     prepare-index 2each ; inline
 498
 499 : map-index ( seq quot -- )
 500     prepare-index 2map ; inline
 501
 502 : reduce-index ( seq identity quot -- )
 503     swapd each-index ; inline
 504
 505 : index ( obj seq -- n )
 506     [ = ] with find drop ;
 507
 508 : index-from ( obj i seq -- n )
 509     rot [ = ] curry find-from drop ;
 510
 511 : last-index ( obj seq -- n )
 512     [ = ] with find-last drop ;
 513
 514 : last-index-from ( obj i seq -- n )
 515     rot [ = ] curry find-last-from drop ;
 516
 517 : (indices) ( elt i obj accum -- )
 518     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 519
 520 : indices ( obj seq -- indices )
 521     swap V{ } clone
 522     [ [ (indices) ] 2curry each-index ] keep ;
 523
 524 : nths ( indices seq -- seq' )
 525     [ nth ] curry map ;
 526
 527 : any? ( seq quot -- ? )
 528     find drop >boolean ; inline
 529
 530 : member? ( elt seq -- ? )
 531     [ = ] with any? ;
 532
 533 : memq? ( elt seq -- ? )
 534     [ eq? ] with any? ;
 535
 536 : remove ( elt seq -- newseq )
 537     [ = not ] with filter ;
 538
 539 : remq ( elt seq -- newseq )
 540     [ eq? not ] with filter ;
 541
 542 : sift ( seq -- newseq )
 543     [ ] filter ;
 544
 545 : harvest ( seq -- newseq )
 546     [ empty? not ] filter ;
 547
 548 : mismatch ( seq1 seq2 -- i )
 549     [ min-length ] 2keep
 550     [ 2nth-unsafe = not ] 2curry
 551     find drop ; inline
 552
 553 M: sequence <=>
 554     2dup mismatch
 555     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 556
 557 : sequence= ( seq1 seq2 -- ? )
 558     2dup [ length ] bi@ =
 559     [ mismatch not ] [ 2drop f ] if ; inline
 560
 561 : sequence-hashcode-step ( oldhash newpart -- newhash )
 562     >fixnum swap [
 563         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 564         fixnum+fast fixnum+fast
 565     ] keep fixnum-bitxor ; inline
 566
 567 : sequence-hashcode ( n seq -- x )
 568     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 569
 570 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 571
 572 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 573
 574 : move ( to from seq -- )
 575     2over =
 576     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 577
 578 <PRIVATE
 579
 580 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 581     2dup length < [
 582         [ move ] 3keep
 583         [ nth-unsafe pick call [ 1+ ] when ] 2keep
 584         [ 1+ ] dip
 585         (filter-here)
 586     ] [ nip set-length drop ] if ; inline recursive
 587
 588 PRIVATE>
 589
 590 : filter-here ( seq quot -- )
 591     swap [ 0 0 ] dip (filter-here) ; inline
 592
 593 : delete ( elt seq -- )
 594     [ = not ] with filter-here ;
 595
 596 : delq ( elt seq -- )
 597     [ eq? not ] with filter-here ;
 598
 599 : prefix ( seq elt -- newseq )
 600     over [ over length 1+ ] dip [
 601         [ 0 swap set-nth-unsafe ] keep
 602         [ 1 swap copy ] keep
 603     ] new-like ;
 604
 605 : suffix ( seq elt -- newseq )
 606     over [ over length 1+ ] dip [
 607         [ [ over length ] dip set-nth-unsafe ] keep
 608         [ 0 swap copy ] keep
 609     ] new-like ;
 610
 611 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 612
 613 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 614
 615 <PRIVATE
 616
 617 : move-backward ( shift from to seq -- )
 618     2over = [
 619         2drop 2drop
 620     ] [
 621         [ [ 2over + pick ] dip move [ 1+ ] dip ] keep
 622         move-backward
 623     ] if ;
 624
 625 : move-forward ( shift from to seq -- )
 626     2over = [
 627         2drop 2drop
 628     ] [
 629         [ [ pick [ dup dup ] dip + swap ] dip move 1- ] keep
 630         move-forward
 631     ] if ;
 632
 633 : (open-slice) ( shift from to seq ? -- )
 634     [
 635         [ [ 1- ] bi@ ] dip move-forward
 636     ] [
 637         [ over - ] 2dip move-backward
 638     ] if ;
 639
 640 : open-slice ( shift from seq -- )
 641     pick 0 = [
 642         3drop
 643     ] [
 644         pick over length + over
 645         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 646         set-length
 647     ] if ;
 648
 649 PRIVATE>
 650
 651 : delete-slice ( from to seq -- )
 652     check-slice [ over [ - ] dip ] dip open-slice ;
 653
 654 : delete-nth ( n seq -- )
 655     [ dup 1+ ] dip delete-slice ;
 656
 657 : replace-slice ( new from to seq -- seq' )
 658     tuck [ swap head-slice ] [ swap tail-slice ] 2bi* surround ;
 659
 660 : remove-nth ( n seq -- seq' )
 661     [ [ { } ] dip dup 1+ ] dip replace-slice ;
 662
 663 : pop ( seq -- elt )
 664     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 665
 666 : exchange ( m n seq -- )
 667     pick over bounds-check 2drop 2dup bounds-check 2drop
 668     exchange-unsafe ;
 669
 670 : reverse-here ( seq -- )
 671     dup length dup 2/ [
 672         [ 2dup ] dip
 673         tuck - 1- rot exchange-unsafe
 674     ] each 2drop ;
 675
 676 : reverse ( seq -- newseq )
 677     [
 678         dup [ length ] keep new-sequence
 679         [ 0 swap copy ] keep
 680         [ reverse-here ] keep
 681     ] keep like ;
 682
 683 : sum-lengths ( seq -- n )
 684     0 [ length + ] reduce ;
 685
 686 : concat ( seq -- newseq )
 687     [ { } ] [
 688         [ sum-lengths ] keep
 689         [ first new-resizable ] keep
 690         [ [ over push-all ] each ] keep
 691         first like
 692     ] if-empty ;
 693
 694 <PRIVATE
 695
 696 : joined-length ( seq glue -- n )
 697     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 698
 699 PRIVATE>
 700
 701 : join ( seq glue -- newseq )
 702     [
 703         2dup joined-length over new-resizable spin
 704         [ dup pick push-all ] [ pick push-all ] interleave drop
 705     ] keep like ;
 706
 707 : padding ( seq n elt quot -- newseq )
 708     [
 709         [ over length [-] dup 0 = [ drop ] ] dip
 710         [ <repetition> ] curry
 711     ] dip compose if ; inline
 712
 713 : pad-head ( seq n elt -- padded )
 714     [ swap dup append-as ] padding ;
 715
 716 : pad-tail ( seq n elt -- padded )
 717     [ append ] padding ;
 718
 719 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 720
 721 : head? ( seq begin -- ? )
 722     2dup shorter? [
 723         2drop f
 724     ] [
 725         [ nip ] [ length head-slice ] 2bi sequence=
 726     ] if ;
 727
 728 : tail? ( seq end -- ? )
 729     2dup shorter? [
 730         2drop f
 731     ] [
 732         [ nip ] [ length tail-slice* ] 2bi sequence=
 733     ] if ;
 734
 735 : cut-slice ( seq n -- before-slice after-slice )
 736     [ head-slice ] [ tail-slice ] 2bi ;
 737
 738 : insert-nth ( elt n seq -- seq' )
 739     swap cut-slice [ swap suffix ] dip append ;
 740
 741 : midpoint@ ( seq -- n ) length 2/ ; inline
 742
 743 : halves ( seq -- first-slice second-slice )
 744     dup midpoint@ cut-slice ;
 745
 746 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 747     #! We can't use case here since combinators depends on
 748     #! sequences
 749     pick length dup 0 3 between? [
 750         >fixnum {
 751             [ drop nip ]
 752             [ 2drop first ]
 753             [ [ drop first2 ] dip call ]
 754             [ [ drop first3 ] dip bi@ ]
 755         } dispatch
 756     ] [
 757         drop
 758         [ halves ] 2dip
 759         [ [ binary-reduce ] 2curry bi@ ] keep
 760         call
 761     ] if ; inline recursive
 762
 763 : cut ( seq n -- before after )
 764     [ head ] [ tail ] 2bi ;
 765
 766 : cut* ( seq n -- before after )
 767     [ head* ] [ tail* ] 2bi ;
 768
 769 <PRIVATE
 770
 771 : (start) ( subseq seq n -- subseq seq ? )
 772     pick length [
 773         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 774     ] all? nip ; inline
 775
 776 PRIVATE>
 777
 778 : start* ( subseq seq n -- i )
 779     pick length pick length swap - 1+
 780     [ (start) ] find-from
 781     swap [ 3drop ] dip ;
 782
 783 : start ( subseq seq -- i ) 0 start* ; inline
 784
 785 : subseq? ( subseq seq -- ? ) start >boolean ;
 786
 787 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 788     2dup mismatch [ 2dup min-length ] unless*
 789     tuck [ tail-slice ] 2bi@ ;
 790
 791 : unclip ( seq -- rest first )
 792     [ rest ] [ first-unsafe ] bi ;
 793
 794 : unclip-last ( seq -- butlast last )
 795     [ but-last ] [ peek ] bi ;
 796
 797 : unclip-slice ( seq -- rest-slice first )
 798     [ rest-slice ] [ first-unsafe ] bi ; inline
 799
 800 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 801     [ unclip-slice ] bi@ swapd ; inline
 802
 803 : map-reduce ( seq map-quot reduce-quot -- result )
 804     [ [ unclip-slice ] dip [ call ] keep ] dip
 805     compose reduce ; inline
 806
 807 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 808     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 809     compose 2reduce ; inline
 810
 811 : unclip-last-slice ( seq -- butlast-slice last )
 812     [ but-last-slice ] [ peek ] bi ; inline
 813
 814 : <flat-slice> ( seq -- slice )
 815     dup slice? [ { } like ] when 0 over length rot <slice> ;
 816     inline
 817
 818 : trim-head-slice ( seq quot -- slice )
 819     over [ [ not ] compose find drop ] dip swap
 820     [ tail-slice ] [ dup length tail-slice ] if* ; inline
 821
 822 : trim-head ( seq quot -- newseq )
 823     over [ trim-head-slice ] dip like ; inline
 824
 825 : trim-tail-slice ( seq quot -- slice )
 826     over [ [ not ] compose find-last drop ] dip swap
 827     [ 1+ head-slice ] [ 0 head-slice ] if* ; inline
 828
 829 : trim-tail ( seq quot -- newseq )
 830     over [ trim-tail-slice ] dip like ; inline
 831
 832 : trim-slice ( seq quot -- slice )
 833     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 834
 835 : trim ( seq quot -- newseq )
 836     over [ trim-slice ] dip like ; inline
 837
 838 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 839
 840 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 841
 842 : infimum ( seq -- n ) dup first [ min ] reduce ;
 843
 844 : supremum ( seq -- n ) dup first [ max ] reduce ;
 845
 846 : sigma ( seq quot -- n ) [ 0 ] 2dip [ rot slip + ] curry each ; inline
 847
 848 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 849
 850 ! We hand-optimize flip to such a degree because type hints
 851 ! cannot express that an array is an array of arrays yet, and
 852 ! this word happens to be performance-critical since the compiler
 853 ! itself uses it. Optimizing it like this reduced compile time.
 854 <PRIVATE
 855
 856 : generic-flip ( matrix -- newmatrix )
 857     [ dup first length [ length min ] reduce ] keep
 858     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 859
 860 USE: arrays
 861
 862 : array-length ( array -- len )
 863     { array } declare length>> ; inline
 864
 865 : array-flip ( matrix -- newmatrix )
 866     { array } declare
 867     [ dup first array-length [ array-length min ] reduce ] keep
 868     [ [ array-nth ] with { } map-as ] curry { } map-as ;
 869
 870 PRIVATE>
 871
 872 : flip ( matrix -- newmatrix )
 873     dup empty? [
 874         dup array? [
 875             dup [ array? ] all?
 876             [ array-flip ] [ generic-flip ] if
 877         ] [ generic-flip ] if
 878     ] unless ;