core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition
 265     { length integer read-only }
 266     { elt read-only } ;
 267
 268 : <repetition> ( len elt -- repetition )
 269     over 0 < [ non-negative-integer-expected ] when
 270     repetition boa ; inline
 271
 272 M: repetition length length>> ; inline
 273 M: repetition nth-unsafe nip elt>> ; inline
 274
 275 INSTANCE: repetition immutable-sequence
 276
 277 <PRIVATE
 278
 279 ERROR: integer-length-expected obj ;
 280
 281 ! The check-length call forces partial dispatch
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i integer read-only }
 287     { src read-only }
 288     { dst-i integer read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : copy-nth-unsafe ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 315
 316 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 317     [ subseq>copy (copy) ] dip like ;
 318
 319 : subseq-unsafe ( from to seq -- subseq )
 320     dup subseq-unsafe-as ; inline
 321
 322 PRIVATE>
 323
 324 : subseq-as ( from to seq exemplar -- subseq )
 325     [ check-slice ] dip subseq-unsafe-as ;
 326
 327 : subseq ( from to seq -- subseq )
 328     dup subseq-as ; inline
 329
 330 : head ( seq n -- headseq ) (head) subseq ;
 331
 332 : tail ( seq n -- tailseq ) (tail) subseq ;
 333
 334 : rest ( seq -- tailseq ) 1 tail ;
 335
 336 : head* ( seq n -- headseq ) from-end head ;
 337
 338 : tail* ( seq n -- tailseq ) from-end tail ;
 339
 340 : but-last ( seq -- headseq ) 1 head* ;
 341
 342 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 343
 344 M: sequence clone-like
 345     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 346
 347 M: immutable-sequence clone-like like ; inline
 348
 349 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 350
 351 <PRIVATE
 352
 353 : (append) ( seq1 seq2 accum -- accum )
 354     [ [ over length ] dip copy-unsafe ]
 355     [ 0 swap copy-unsafe ]
 356     [ ] tri ; inline
 357
 358 PRIVATE>
 359
 360 : append-as ( seq1 seq2 exemplar -- newseq )
 361     [ 2dup [ length ] bi@ + ] dip
 362     [ (append) ] new-like ; inline
 363
 364 : append ( seq1 seq2 -- newseq ) over append-as ;
 365
 366 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 367
 368 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 369
 370 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 371     [ 3dup [ length ] tri@ + + ] dip [
 372         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 373         [ (append) ] bi
 374     ] new-like ; inline
 375
 376 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 377
 378 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 379     [ swap ] 2dip 3append-as ; inline
 380
 381 : surround ( seq1 seq2 seq3 -- newseq ) pick surround-as ; inline
 382
 383 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 384
 385 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 386
 387 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 388     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 389
 390 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 391
 392 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 393
 394 <PRIVATE
 395
 396 : setup-each ( seq -- n quot )
 397     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 398
 399 : (each) ( seq quot -- n quot' )
 400     [ setup-each ] dip compose ; inline
 401
 402 : (each-index) ( seq quot -- n quot' )
 403     [ setup-each [ keep ] curry ] dip compose ; inline
 404
 405 : (collect) ( quot into -- quot' )
 406     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 407
 408 : collect ( n quot into -- )
 409     (collect) each-integer ; inline
 410
 411 : map-into ( seq quot into -- )
 412     [ (each) ] dip collect ; inline
 413
 414 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 415     [ nth-unsafe ] bi-curry@ bi ; inline
 416
 417 : setup-2each ( seq1 seq2 -- n quot )
 418     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 419
 420 : (2each) ( seq1 seq2 quot -- n quot' )
 421     [ setup-2each ] dip compose ; inline
 422
 423 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 424     [ nth-unsafe ] tri-curry@ tri ; inline
 425
 426 : setup-3each ( seq1 seq2 seq3 -- n quot )
 427     [ [ length ] tri@ min min check-length ]
 428     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 429
 430 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 431     [ setup-3each ] dip compose ; inline
 432
 433 : finish-find ( i seq -- i elt )
 434     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 435
 436 : (find) ( seq quot quot' -- i elt )
 437     pick [ [ (each) ] dip call ] dip finish-find ; inline
 438
 439 : (find-from) ( n seq quot quot' -- i elt )
 440     [ 2dup bounds-check? ] 2dip
 441     [ (find) ] 2curry
 442     [ 2drop f f ]
 443     if ; inline
 444
 445 : (find-index) ( seq quot quot' -- i elt )
 446     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 447
 448 : (find-index-from) ( n seq quot quot' -- i elt )
 449     [ 2dup bounds-check? ] 2dip
 450     [ (find-index) ] 2curry
 451     [ 2drop f f ]
 452     if ; inline
 453
 454 : (accumulate) ( seq identity quot -- identity seq quot )
 455     swapd [ keepd ] curry ; inline
 456
 457 : (accumulate*) ( seq identity quot -- identity seq quot )
 458     swapd [ dup ] compose ; inline
 459
 460 PRIVATE>
 461
 462 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 463     (each) each-integer ; inline
 464
 465 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 466     -rot (each) (each-integer) ; inline
 467
 468 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 469     swapd each ; inline
 470
 471 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 472     overd [ [ collect ] keep ] new-like ; inline
 473
 474 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 475     [ (each) ] dip map-integers ; inline
 476
 477 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 478     over map-as ; inline
 479
 480 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 481     [ [ drop ] prepose ] dip map-integers ; inline
 482
 483 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 484     { } replicate-as ; inline
 485
 486 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 487     over [ map-into ] keep ; inline
 488
 489 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 490     [ (accumulate) ] dip map-as ; inline
 491
 492 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 493     pick accumulate-as ; inline
 494
 495 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 496     (accumulate) map! ; inline
 497
 498 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 499     [ (accumulate*) ] dip map-as nip ; inline
 500
 501 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 502     pick accumulate*-as ; inline
 503
 504 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 505     (accumulate*) map! nip ; inline
 506
 507 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 508     (2each) each-integer ; inline
 509
 510 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 511     [ (2each) ] dip -rot (each-integer) ; inline
 512
 513 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 514     -rotd 2each ; inline
 515
 516 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 517     [ (2each) ] dip map-integers ; inline
 518
 519 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 520     pick 2map-as ; inline
 521
 522 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 523     (2each) all-integers? ; inline
 524
 525 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 526     (3each) each-integer ; inline
 527
 528 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 529     [ (3each) ] dip map-integers ; inline
 530
 531 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 532     pickd swap 3map-as ; inline
 533
 534 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 535     [ (find-integer) ] (find-from) ; inline
 536
 537 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 538     [ find-integer ] (find) ; inline
 539
 540 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 541     [ nip find-last-integer ] (find-from) ; inline
 542
 543 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 544     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 545
 546 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 547     [ (find-integer) ] (find-index-from) ; inline
 548
 549 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 550     [ find-integer ] (find-index) ; inline
 551
 552 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 553     (each) all-integers? ; inline
 554
 555 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 556     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 557
 558 <PRIVATE
 559
 560 : (selector-as) ( quot length exemplar -- selector accum )
 561     new-resizable [ [ push-if ] 2curry ] keep ; inline
 562
 563 PRIVATE>
 564
 565 : selector-as ( quot exemplar -- selector accum )
 566     [ length ] keep (selector-as) ; inline
 567
 568 : selector ( quot -- selector accum )
 569     V{ } selector-as ; inline
 570
 571 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 572     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 573
 574 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 575     over filter-as ; inline
 576
 577 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 578     [ [ not ] compose ] [ filter-as ] bi* ; inline
 579
 580 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 581     over reject-as ; inline
 582
 583 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 584     [ keep swap ] 2dip ? push ; inline
 585
 586 : 2selector ( quot -- selector accum1 accum2 )
 587     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 588
 589 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 590     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 591
 592 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 593     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 594
 595 : collector-as ( quot exemplar -- quot' vec )
 596     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 597
 598 : collector-for ( seq quot -- seq quot' vec )
 599     V{ } collector-for-as ; inline
 600
 601 : collector ( quot -- quot' vec )
 602     V{ } collector-as ; inline
 603
 604 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 605     dup [ collector-as [ while ] dip ] curry dip like ; inline
 606
 607 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 608     { } produce-as ; inline
 609
 610 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 611     [ dup ] swap [ keep ] curry produce nip ; inline
 612
 613 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 614     (each-index) each-integer ; inline
 615
 616 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 617     [ dup length <iota> ] 2dip 2map-as ; inline
 618
 619 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 620     { } map-index-as ; inline
 621
 622 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 623     pick empty? [ 3drop ] [
 624         [ [ drop first-unsafe ] dip call ]
 625         [ [ bi* ] 2curry 1 each-from ]
 626         3bi
 627     ] if ; inline
 628
 629 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 630     swapd each-index ; inline
 631
 632 : index ( obj seq -- n )
 633     [ = ] with find drop ;
 634
 635 : index-from ( obj i seq -- n )
 636     rot [ = ] curry find-from drop ;
 637
 638 : last-index ( obj seq -- n )
 639     [ = ] with find-last drop ;
 640
 641 : last-index-from ( obj i seq -- n )
 642     rot [ = ] curry find-last-from drop ;
 643
 644 : indices ( obj seq -- indices )
 645     swap [ = ] curry [ swap ] prepose V{ } clone [
 646         [ push ] curry [ [ drop ] if ] curry compose each-index
 647     ] keep ;
 648
 649 <PRIVATE
 650
 651 : nths-unsafe ( indices seq -- seq' )
 652     [ [ nth-unsafe ] curry ] keep map-as ;
 653
 654 PRIVATE>
 655
 656 : nths ( indices seq -- seq' )
 657     [ [ nth ] curry ] keep map-as ;
 658
 659 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 660     find drop >boolean ; inline
 661
 662 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 663     any? not ; inline
 664
 665 : member? ( elt seq -- ? )
 666     [ = ] with any? ;
 667
 668 : member-eq? ( elt seq -- ? )
 669     [ eq? ] with any? ;
 670
 671 : remove ( elt seq -- newseq )
 672     [ = ] with reject ;
 673
 674 : remove-eq ( elt seq -- newseq )
 675     [ eq? ] with reject ;
 676
 677 : sift ( seq -- newseq )
 678     [ ] filter ;
 679
 680 : harvest ( seq -- newseq )
 681     [ empty? ] reject ;
 682
 683 <PRIVATE
 684
 685 : mismatch-unsafe ( n seq1 seq2 -- i )
 686     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 687
 688 PRIVATE>
 689
 690 : mismatch ( seq1 seq2 -- i )
 691     [ min-length ] 2keep mismatch-unsafe ; inline
 692
 693 M: sequence <=>
 694     [ mismatch ] 2keep pick
 695     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 696
 697 : sequence= ( seq1 seq2 -- ? )
 698     2dup [ length ] bi@ dupd =
 699     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 700
 701 ERROR: assert-sequence got expected ;
 702
 703 : assert-sequence= ( a b -- )
 704     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 705
 706 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 707
 708 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 709
 710 <PRIVATE
 711
 712 : sequence-hashcode-step ( oldhash newpart -- newhash )
 713     integer>fixnum swap [
 714         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 715         fixnum+fast fixnum+fast
 716     ] keep fixnum-bitxor ; inline
 717
 718 PRIVATE>
 719
 720 : sequence-hashcode ( n seq -- x )
 721     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 722
 723 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 724
 725 M: iota hashcode*
 726     over 0 <= [ 2drop 0 ] [
 727         nip length 0 swap [ sequence-hashcode-step ] each-integer
 728     ] if ;
 729
 730 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 731
 732 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 733
 734 : move ( to from seq -- )
 735     2over =
 736     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 737
 738 <PRIVATE
 739
 740 : move-unsafe ( to from seq -- )
 741     2over =
 742     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 743
 744 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 745     2dup length < [
 746         [ move-unsafe ] 3keep
 747         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 748         [ 1 + ] dip
 749         (filter!)
 750     ] [ nip set-length drop ] if ; inline recursive
 751
 752 PRIVATE>
 753
 754 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 755     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 756
 757 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 758     [ not ] compose filter! ; inline
 759
 760 : remove! ( elt seq -- seq )
 761     [ = ] with reject! ;
 762
 763 : remove-eq! ( elt seq -- seq )
 764     [ eq? ] with reject! ;
 765
 766 : prefix ( seq elt -- newseq )
 767     over [ over length 1 + ] dip [
 768         (1sequence) [ 1 swap copy-unsafe ] keep
 769     ] new-like ;
 770
 771 : suffix ( seq elt -- newseq )
 772     over [ over length 1 + ] dip [
 773         [ [ over length ] dip set-nth-unsafe ] keep
 774         [ 0 swap copy-unsafe ] keep
 775     ] new-like ;
 776
 777 : suffix! ( seq elt -- seq ) over push ; inline
 778
 779 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 780
 781 : last ( seq -- elt )
 782     [ length 1 - ] keep
 783     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 784
 785 <PRIVATE
 786
 787 : last-unsafe ( seq -- elt )
 788     [ length 1 - ] [ nth-unsafe ] bi ; inline
 789
 790 PRIVATE>
 791
 792 : set-last ( elt seq -- )
 793     [ length 1 - ] keep
 794     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 795
 796 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 797
 798 <PRIVATE
 799
 800 : move-backward ( shift from to seq -- )
 801     2over = [
 802         4drop
 803     ] [
 804         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 805         move-backward
 806     ] if ;
 807
 808 : move-forward ( shift from to seq -- )
 809     2over = [
 810         4drop
 811     ] [
 812         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 813         move-forward
 814     ] if ;
 815
 816 : (open-slice) ( shift from to seq ? -- )
 817     [
 818         [ [ 1 - ] bi@ ] dip move-forward
 819     ] [
 820         [ over - ] 2dip move-backward
 821     ] if ;
 822
 823 : open-slice ( shift from seq -- )
 824     pick 0 = [
 825         3drop
 826     ] [
 827         [ ] [ nip length + ] [ 2nip ] 3tri
 828         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 829         set-length
 830     ] if ;
 831
 832 PRIVATE>
 833
 834 : delete-slice ( from to seq -- )
 835     check-slice [ over [ - ] dip ] dip open-slice ;
 836
 837 : remove-nth! ( n seq -- seq )
 838     [ [ dup 1 + ] dip delete-slice ] keep ;
 839
 840 : snip ( from to seq -- head tail )
 841     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 842
 843 : snip-slice ( from to seq -- head tail )
 844     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 845
 846 : replace-slice ( new from to seq -- seq' )
 847     snip-slice surround ;
 848
 849 : remove-nth ( n seq -- seq' )
 850     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 851
 852 : pop ( seq -- elt )
 853     [ length 1 - ] keep over 0 >=
 854     [ [ nth-unsafe ] [ shorten ] 2bi ]
 855     [ bounds-error ] if ;
 856
 857 : exchange ( m n seq -- )
 858     [ nip bounds-check 2drop ]
 859     [ bounds-check 3drop ]
 860     [ exchange-unsafe ]
 861     3tri ;
 862
 863 : midpoint@ ( seq -- n ) length 2/ ; inline
 864
 865 : reverse! ( seq -- seq )
 866     [
 867         [ midpoint@ ] [ length ] [ ] tri
 868         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 869         each-integer
 870     ] keep ;
 871
 872 : reverse ( seq -- newseq )
 873      [
 874         dup [ length ] keep new-sequence
 875         [ 0 swap copy-unsafe ] keep reverse!
 876     ] keep like ;
 877
 878 GENERIC: sum-lengths ( seq -- n )
 879
 880 M: object sum-lengths
 881     0 [ length + ] reduce ;
 882
 883 M: repetition sum-lengths
 884     [ length>> ] [ elt>> length ] bi * ;
 885
 886 : concat-as ( seq exemplar -- newseq )
 887     [
 888         [ dup sum-lengths ] dip new-resizable
 889         [ [ push-all ] curry each ] keep
 890     ] keep like ; inline
 891
 892 : concat ( seq -- newseq )
 893     [ { } ] [ dup first concat-as ] if-empty ;
 894
 895 <PRIVATE
 896
 897 : joined-length ( seq glue -- n )
 898     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 899
 900 PRIVATE>
 901
 902 : join-as ( seq glue exemplar -- newseq )
 903     over empty? [ nip concat-as ] [
 904         [
 905             2dup joined-length over new-resizable [
 906                 [ [ push-all ] 2curry ]
 907                 [ nip [ push-all ] curry ] 2bi
 908                 interleave
 909             ] keep
 910         ] dip like
 911     ] if ;
 912
 913 : join ( seq glue -- newseq )
 914     dup join-as ; inline
 915
 916 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 917     [
 918         [ over length [-] dup 0 = [ drop ] ] dip
 919         [ <repetition> ] curry
 920     ] dip compose if ; inline
 921
 922 : pad-head ( seq n elt -- padded )
 923     [ swap dup append-as ] padding ;
 924
 925 : pad-tail ( seq n elt -- padded )
 926     [ append ] padding ;
 927
 928 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 929 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 930 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 931 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 932
 933 : head? ( seq begin -- ? )
 934     2dup shorter? [
 935         2drop f
 936     ] [
 937         [ length [ head-slice ] keep swap ] keep
 938         mismatch-unsafe not
 939     ] if ;
 940
 941 : tail? ( seq end -- ? )
 942     2dup shorter? [
 943         2drop f
 944     ] [
 945         [ length [ tail-slice* ] keep swap ] keep
 946         mismatch-unsafe not
 947     ] if ;
 948
 949 : cut-slice ( seq n -- before-slice after-slice )
 950     [ head-slice ] [ tail-slice ] 2bi ; inline
 951
 952 : insert-nth ( elt n seq -- seq' )
 953     swap cut-slice [ swap suffix ] dip append ;
 954
 955 : halves ( seq -- first-slice second-slice )
 956     dup midpoint@ cut-slice ; inline
 957
 958 <PRIVATE
 959
 960 : nth2-unsafe ( n seq -- a b )
 961     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 962
 963 : nth3-unsafe ( n seq -- a b c )
 964     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 965
 966 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 967     ! We can't use case here since combinators depends on
 968     ! sequences
 969     dup 4 < [
 970         integer>fixnum {
 971             [ 2drop nip ]
 972             [ 2nip swap nth-unsafe ]
 973             [ -rot [ drop swap nth2-unsafe ] dip call ]
 974             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 975         } dispatch
 976     ] [
 977         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 978         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 979         pick [ 3bi ] dip call
 980     ] if ; inline recursive
 981
 982 PRIVATE>
 983
 984 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 985     pick length 0 max 0 swap (binary-reduce) ; inline
 986
 987 : cut ( seq n -- before after )
 988     [ head ] [ tail ] 2bi ;
 989
 990 : cut* ( seq n -- before after )
 991     [ head* ] [ tail* ] 2bi ;
 992
 993 <PRIVATE
 994
 995 : (subseq-start-from) ( subseq seq n length -- subseq seq ? )
 996     [
 997         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 998     ] all-integers? nip ; inline
 999
1000 PRIVATE>
1001
1002 : subseq-start-from ( subseq seq n -- i )
1003     pick length [ pick length swap - 1 + ] keep
1004     [ (subseq-start-from) ] curry (find-integer) 2nip ;
1005
1006 : subseq-start ( subseq seq -- i ) 0 subseq-start-from ; inline
1007
1008 : subseq? ( subseq seq -- ? ) subseq-start >boolean ;
1009
1010 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1011     2dup mismatch [ 2dup min-length ] unless*
1012     [ tail-slice ] curry bi@ ;
1013
1014 : unclip ( seq -- rest first )
1015     [ rest ] [ first-unsafe ] bi ;
1016
1017 : unclip-last ( seq -- butlast last )
1018     [ but-last ] [ last-unsafe ] bi ;
1019
1020 : unclip-slice ( seq -- rest-slice first )
1021     [ rest-slice ] [ first-unsafe ] bi ; inline
1022
1023 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
1024     [ [ [ first ] keep ] dip [ dip ] keep ] dip compose 1 each-from ; inline
1025
1026 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
1027     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip compose 1 2each-from ; inline
1028
1029 <PRIVATE
1030
1031 : (map-find) ( seq quot find-quot -- result elt )
1032     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1033
1034 PRIVATE>
1035
1036 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1037     [ find ] (map-find) ; inline
1038
1039 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1040     [ find-last ] (map-find) ; inline
1041
1042 : unclip-last-slice ( seq -- butlast-slice last )
1043     [ but-last-slice ] [ last-unsafe ] bi ; inline
1044
1045 <PRIVATE
1046
1047 : (trim-head) ( seq quot -- seq n )
1048     over [ [ not ] compose find drop ] dip swap
1049     [ dup length ] unless* ; inline
1050
1051 : (trim-tail) ( seq quot -- seq n )
1052     over [ [ not ] compose find-last drop ?1+ ] dip
1053     swap ; inline
1054
1055 PRIVATE>
1056
1057 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1058     (trim-head) tail-slice ; inline
1059
1060 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1061     (trim-head) tail ; inline
1062
1063 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1064     (trim-tail) head-slice ; inline
1065
1066 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1067     (trim-tail) head ; inline
1068
1069 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1070     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1071
1072 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1073     [ trim-slice ] [ drop ] 2bi like ; inline
1074
1075 GENERIC: sum ( seq -- n )
1076 M: object sum 0 [ + ] binary-reduce ; inline
1077 M: iota sum length dup 1 - * 2/ ; inline
1078 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1079
1080 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1081
1082 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1083
1084 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1085
1086 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1087     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1088
1089 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1090     [ 1 0 ? ] compose map-sum ; inline
1091
1092 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1093     [ with each ] 2curry each ; inline
1094
1095 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1096     [ with map ] 2curry map ; inline
1097
1098 : cartesian-product ( seq1 seq2 -- newseq )
1099     [ { } 2sequence ] cartesian-map ;
1100
1101 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1102     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1103
1104 <PRIVATE
1105
1106 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1107     [
1108         [ keep swap ] curry [ [ first ] dip call ] 2keep
1109         [ curry 2dip pick over ] curry
1110     ] [
1111         [ [ 2drop ] [ 2nipd ] if ] compose
1112     ] bi* compose 1 each-from drop ; inline
1113
1114 PRIVATE>
1115
1116 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1117     [ after? ] select-by ; inline
1118
1119 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1120     [ before? ] select-by ; inline
1121
1122 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1123
1124 : longest ( seqs -- elt ) [ length ] supremum-by ;
1125
1126 ! We hand-optimize flip to such a degree because type hints
1127 ! cannot express that an array is an array of arrays yet, and
1128 ! this word happens to be performance-critical since the compiler
1129 ! itself uses it. Optimizing it like this reduced compile time.
1130 <PRIVATE
1131
1132 : generic-flip ( matrix -- newmatrix )
1133     [
1134         [ first-unsafe length 1 ] keep
1135         [ length min ] (each) (each-integer) <iota>
1136     ] keep
1137     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1138
1139 USE: arrays
1140
1141 : array-length ( array -- len )
1142     { array } declare length>> ; inline
1143
1144 : array-flip ( matrix -- newmatrix )
1145     { array } declare
1146     [
1147         [ first-unsafe array-length 1 ] keep
1148         [ array-length min ] (each) (each-integer) <iota>
1149     ] keep
1150     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1151
1152 PRIVATE>
1153
1154 : flip ( matrix -- newmatrix )
1155     dup empty? [
1156         dup array? [
1157             dup [ array? ] all?
1158             [ array-flip ] [ generic-flip ] if
1159         ] [ generic-flip ] if
1160     ] unless ;