core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC# bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check? ( n seq -- ? )
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota-tuple { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : iota ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota-tuple boa ; inline
 112
 113 M: iota-tuple length n>> ; inline
 114 M: iota-tuple nth-unsafe drop ; inline
 115
 116 INSTANCE: iota-tuple immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition
 265     { length integer read-only }
 266     { elt read-only } ;
 267
 268 : <repetition> ( len elt -- repetition )
 269     over 0 < [ non-negative-integer-expected ] when
 270     repetition boa ; inline
 271
 272 M: repetition length length>> ; inline
 273 M: repetition nth-unsafe nip elt>> ; inline
 274
 275 INSTANCE: repetition immutable-sequence
 276
 277 <PRIVATE
 278
 279 ERROR: integer-length-expected obj ;
 280
 281 ! The check-length call forces partial dispatch
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i read-only }
 287     { src read-only }
 288     { dst-i read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : copy-nth-unsafe ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 315
 316 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 317     [ subseq>copy (copy) ] dip like ;
 318
 319 : subseq-unsafe ( from to seq -- subseq )
 320     dup subseq-unsafe-as ; inline
 321
 322 PRIVATE>
 323
 324 : subseq-as ( from to seq exemplar -- subseq )
 325     [ check-slice ] dip subseq-unsafe-as ;
 326
 327 : subseq ( from to seq -- subseq )
 328     dup subseq-as ; inline
 329
 330 : head ( seq n -- headseq ) (head) subseq ;
 331
 332 : tail ( seq n -- tailseq ) (tail) subseq ;
 333
 334 : rest ( seq -- tailseq ) 1 tail ;
 335
 336 : head* ( seq n -- headseq ) from-end head ;
 337
 338 : tail* ( seq n -- tailseq ) from-end tail ;
 339
 340 : but-last ( seq -- headseq ) 1 head* ;
 341
 342 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 343
 344 M: sequence clone-like
 345     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 346
 347 M: immutable-sequence clone-like like ; inline
 348
 349 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 350
 351 <PRIVATE
 352
 353 : (append) ( seq1 seq2 accum -- accum )
 354     [ [ over length ] dip copy-unsafe ]
 355     [ 0 swap copy-unsafe ]
 356     [ ] tri ; inline
 357
 358 PRIVATE>
 359
 360 : append-as ( seq1 seq2 exemplar -- newseq )
 361     [ 2dup [ length ] bi@ + ] dip
 362     [ (append) ] new-like ; inline
 363
 364 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 365     [ 3dup [ length ] tri@ + + ] dip [
 366         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 367         [ (append) ] bi
 368     ] new-like ; inline
 369
 370 : append ( seq1 seq2 -- newseq ) over append-as ;
 371
 372 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 373
 374 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 375
 376 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 377
 378 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 379
 380 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 381
 382 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 383     [ [ nth ] dip call ] 3keep drop set-nth-unsafe ; inline
 384
 385 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 386
 387 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 388
 389 <PRIVATE
 390
 391 : (setup-each) ( seq -- n quot )
 392     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 393
 394 : setup-each ( seq quot -- n quot' )
 395     [ (setup-each) ] dip compose ; inline
 396
 397 : (each-index) ( seq quot -- n quot' )
 398     [ (setup-each) [ keep ] curry ] dip compose ; inline
 399
 400 : (collect) ( quot into -- quot' )
 401     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 402
 403 : collect ( n quot into -- )
 404     (collect) each-integer ; inline
 405
 406 : map-into ( seq quot into -- )
 407     [ setup-each ] dip collect ; inline
 408
 409 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 410     [ nth-unsafe ] bi-curry@ bi ; inline
 411
 412 : setup-2each ( seq1 seq2 -- n quot )
 413     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 414
 415 : (2each) ( seq1 seq2 quot -- n quot' )
 416     [ setup-2each ] dip compose ; inline
 417
 418 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 419     [ nth-unsafe ] tri-curry@ tri ; inline
 420
 421 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 422     [
 423         [ [ length ] tri@ min min check-length ]
 424         [ [ 3nth-unsafe ] 3curry ] 3bi
 425     ] dip compose ; inline
 426
 427 : finish-find ( i seq -- i elt )
 428     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 429
 430 : (find) ( seq quot quot' -- i elt )
 431     pick [ [ setup-each ] dip call ] dip finish-find ; inline
 432
 433 : (find-from) ( n seq quot quot' -- i elt )
 434     [ 2dup bounds-check? ] 2dip
 435     [ (find) ] 2curry
 436     [ 2drop f f ]
 437     if ; inline
 438
 439 : (find-index) ( seq quot quot' -- i elt )
 440     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 441
 442 : (find-index-from) ( n seq quot quot' -- i elt )
 443     [ 2dup bounds-check? ] 2dip
 444     [ (find-index) ] 2curry
 445     [ 2drop f f ]
 446     if ; inline
 447
 448 : (accumulate) ( seq identity quot -- identity seq quot )
 449     swapd [ curry keep ] curry ; inline
 450
 451 : (accumulate*) ( seq identity quot -- identity seq quot )
 452     swapd [ dup ] compose ; inline
 453
 454 PRIVATE>
 455
 456 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 457     setup-each each-integer ; inline
 458
 459 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 460     -rot setup-each (each-integer) ; inline
 461
 462 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 463     swapd each ; inline
 464
 465 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 466     [ over ] dip [ [ collect ] keep ] new-like ; inline
 467
 468 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 469     [ setup-each ] dip map-integers ; inline
 470
 471 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 472     over map-as ; inline
 473
 474 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 475     [ [ drop ] prepose ] dip map-integers ; inline
 476
 477 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 478     { } replicate-as ; inline
 479
 480 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 481     over [ map-into ] keep ; inline
 482
 483 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 484     [ (accumulate) ] dip map-as ; inline
 485
 486 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 487     pick accumulate-as ; inline
 488
 489 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 490     (accumulate) map! ; inline
 491
 492 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 493     [ (accumulate*) ] dip map-as nip ; inline
 494
 495 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 496     pick accumulate*-as ; inline
 497
 498 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 499     (accumulate*) map! nip ; inline
 500
 501 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 502     (2each) each-integer ; inline
 503
 504 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 505     [ (2each) ] dip -rot (each-integer) ; inline
 506
 507 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 508     [ -rot ] dip 2each ; inline
 509
 510 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 511     [ (2each) ] dip map-integers ; inline
 512
 513 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 514     pick 2map-as ; inline
 515
 516 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 517     (2each) all-integers? ; inline
 518
 519 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 520     (3each) each-integer ; inline
 521
 522 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 523     [ (3each) ] dip map-integers ; inline
 524
 525 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 526     [ pick ] dip swap 3map-as ; inline
 527
 528 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 529     [ (find-integer) ] (find-from) ; inline
 530
 531 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 532     [ find-integer ] (find) ; inline
 533
 534 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 535     [ nip find-last-integer ] (find-from) ; inline
 536
 537 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 538     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 539
 540 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 541     [ (find-integer) ] (find-index-from) ; inline
 542
 543 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 544     [ find-integer ] (find-index) ; inline
 545
 546 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 547     setup-each all-integers? ; inline
 548
 549 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 550     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 551
 552 <PRIVATE
 553
 554 : (selector-as) ( quot length exemplar -- selector accum )
 555     new-resizable [ [ push-if ] 2curry ] keep ; inline
 556
 557 PRIVATE>
 558
 559 : selector-as ( quot exemplar -- selector accum )
 560     [ length ] keep (selector-as) ; inline
 561
 562 : selector ( quot -- selector accum )
 563     V{ } selector-as ; inline
 564
 565 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 566     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 567
 568 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 569     over filter-as ; inline
 570
 571 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 572     [ [ not ] compose ] [ filter-as ] bi* ; inline
 573
 574 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 575     over reject-as ; inline
 576
 577 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 578     [ keep swap ] 2dip ? push ; inline
 579
 580 : 2selector ( quot -- selector accum1 accum2 )
 581     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 582
 583 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 584     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 585
 586 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 587     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 588
 589 : collector-as ( quot exemplar -- quot' vec )
 590     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 591
 592 : collector-for ( seq quot -- seq quot' vec )
 593     V{ } collector-for-as ; inline
 594
 595 : collector ( quot -- quot' vec )
 596     V{ } collector-as ; inline
 597
 598 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 599     dup [ collector-as [ while ] dip ] curry dip like ; inline
 600
 601 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 602     { } produce-as ; inline
 603
 604 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 605     [ dup ] swap [ keep ] curry produce nip ; inline
 606
 607 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 608     (each-index) each-integer ; inline
 609
 610 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 611     [ dup length iota ] 2dip 2map-as ; inline
 612
 613 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 614     { } map-index-as ; inline
 615
 616 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 617     pick empty? [ 3drop ] [
 618         [ [ drop first-unsafe ] dip call ]
 619         [ [ bi* ] 2curry 1 each-from ]
 620         3bi
 621     ] if ; inline
 622
 623 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 624     swapd each-index ; inline
 625
 626 : index ( obj seq -- n )
 627     [ = ] with find drop ;
 628
 629 : index-from ( obj i seq -- n )
 630     rot [ = ] curry find-from drop ;
 631
 632 : last-index ( obj seq -- n )
 633     [ = ] with find-last drop ;
 634
 635 : last-index-from ( obj i seq -- n )
 636     rot [ = ] curry find-last-from drop ;
 637
 638 <PRIVATE
 639
 640 : (indices) ( elt i obj accum -- )
 641     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 642
 643 PRIVATE>
 644
 645 : indices ( obj seq -- indices )
 646     swap V{ } clone
 647     [ [ (indices) ] 2curry each-index ] keep ;
 648
 649 <PRIVATE
 650
 651 : nths-unsafe ( indices seq -- seq' )
 652     [ [ nth-unsafe ] curry ] keep map-as ;
 653
 654 PRIVATE>
 655
 656 : nths ( indices seq -- seq' )
 657     [ [ nth ] curry ] keep map-as ;
 658
 659 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 660     find drop >boolean ; inline
 661
 662 : member? ( elt seq -- ? )
 663     [ = ] with any? ;
 664
 665 : member-eq? ( elt seq -- ? )
 666     [ eq? ] with any? ;
 667
 668 : remove ( elt seq -- newseq )
 669     [ = ] with reject ;
 670
 671 : remove-eq ( elt seq -- newseq )
 672     [ eq? ] with reject ;
 673
 674 : sift ( seq -- newseq )
 675     [ ] filter ;
 676
 677 : harvest ( seq -- newseq )
 678     [ empty? ] reject ;
 679
 680 <PRIVATE
 681
 682 : mismatch-unsafe ( n seq1 seq2 -- i )
 683     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 684
 685 PRIVATE>
 686
 687 : mismatch ( seq1 seq2 -- i )
 688     [ min-length ] 2keep mismatch-unsafe ; inline
 689
 690 M: sequence <=>
 691     [ mismatch ] 2keep pick
 692     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 693
 694 : sequence= ( seq1 seq2 -- ? )
 695     2dup [ length ] bi@ dupd =
 696     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 697
 698 ERROR: assert-sequence got expected ;
 699
 700 : assert-sequence= ( a b -- )
 701     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 702
 703 <PRIVATE
 704
 705 : sequence-hashcode-step ( oldhash newpart -- newhash )
 706     integer>fixnum swap [
 707         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 708         fixnum+fast fixnum+fast
 709     ] keep fixnum-bitxor ; inline
 710
 711 PRIVATE>
 712
 713 : sequence-hashcode ( n seq -- x )
 714     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 715
 716 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 717
 718 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 719
 720 : move ( to from seq -- )
 721     2over =
 722     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 723
 724 <PRIVATE
 725
 726 : move-unsafe ( to from seq -- )
 727     2over =
 728     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 729
 730 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 731     2dup length < [
 732         [ move-unsafe ] 3keep
 733         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 734         [ 1 + ] dip
 735         (filter!)
 736     ] [ nip set-length drop ] if ; inline recursive
 737
 738 PRIVATE>
 739
 740 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 741     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 742
 743 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 744     [ not ] compose filter! ; inline
 745
 746 : remove! ( elt seq -- seq )
 747     [ = ] with reject! ;
 748
 749 : remove-eq! ( elt seq -- seq )
 750     [ eq? ] with reject! ;
 751
 752 : prefix ( seq elt -- newseq )
 753     over [ over length 1 + ] dip [
 754         (1sequence) [ 1 swap copy-unsafe ] keep
 755     ] new-like ;
 756
 757 : suffix ( seq elt -- newseq )
 758     over [ over length 1 + ] dip [
 759         [ [ over length ] dip set-nth-unsafe ] keep
 760         [ 0 swap copy-unsafe ] keep
 761     ] new-like ;
 762
 763 : suffix! ( seq elt -- seq ) over push ; inline
 764
 765 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 766
 767 : last ( seq -- elt )
 768     [ length 1 - ] keep
 769     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 770
 771 <PRIVATE
 772
 773 : last-unsafe ( seq -- elt )
 774     [ length 1 - ] [ nth-unsafe ] bi ; inline
 775
 776 PRIVATE>
 777
 778 : set-last ( elt seq -- )
 779     [ length 1 - ] keep
 780     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 781
 782 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 783
 784 <PRIVATE
 785
 786 : move-backward ( shift from to seq -- )
 787     2over = [
 788         4drop
 789     ] [
 790         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 791         move-backward
 792     ] if ;
 793
 794 : move-forward ( shift from to seq -- )
 795     2over = [
 796         4drop
 797     ] [
 798         [ [ pick [ dup dup ] dip + swap ] dip move-unsafe 1 - ] keep
 799         move-forward
 800     ] if ;
 801
 802 : (open-slice) ( shift from to seq ? -- )
 803     [
 804         [ [ 1 - ] bi@ ] dip move-forward
 805     ] [
 806         [ over - ] 2dip move-backward
 807     ] if ;
 808
 809 : open-slice ( shift from seq -- )
 810     pick 0 = [
 811         3drop
 812     ] [
 813         pick over length + over
 814         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 815         set-length
 816     ] if ;
 817
 818 PRIVATE>
 819
 820 : delete-slice ( from to seq -- )
 821     check-slice [ over [ - ] dip ] dip open-slice ;
 822
 823 : remove-nth! ( n seq -- seq )
 824     [ [ dup 1 + ] dip delete-slice ] keep ;
 825
 826 : snip ( from to seq -- head tail )
 827     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 828
 829 : snip-slice ( from to seq -- head tail )
 830     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 831
 832 : replace-slice ( new from to seq -- seq' )
 833     snip-slice surround ;
 834
 835 : remove-nth ( n seq -- seq' )
 836     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 837
 838 : pop ( seq -- elt )
 839     [ length 1 - ] keep over 0 >=
 840     [ [ nth-unsafe ] [ shorten ] 2bi ]
 841     [ bounds-error ] if ;
 842
 843 : exchange ( m n seq -- )
 844     [ nip bounds-check 2drop ]
 845     [ bounds-check 3drop ]
 846     [ exchange-unsafe ]
 847     3tri ;
 848
 849 : midpoint@ ( seq -- n ) length 2/ ; inline
 850
 851 : reverse! ( seq -- seq )
 852     [
 853         [ midpoint@ ] [ length ] [ ] tri
 854         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 855         each-integer
 856     ] keep ;
 857
 858 : reverse ( seq -- newseq )
 859      [
 860         dup [ length ] keep new-sequence
 861         [ 0 swap copy-unsafe ] keep reverse!
 862     ] keep like ;
 863
 864 GENERIC: sum-lengths ( seq -- n )
 865
 866 M: object sum-lengths
 867     0 [ length + ] reduce ;
 868
 869 M: repetition sum-lengths
 870     [ length>> ] [ elt>> length ] bi * ;
 871
 872 : concat-as ( seq exemplar -- newseq )
 873     [
 874         [ dup sum-lengths ] dip new-resizable
 875         [ [ push-all ] curry each ] keep
 876     ] keep like ; inline
 877
 878 : concat ( seq -- newseq )
 879     [ { } ] [ dup first concat-as ] if-empty ;
 880
 881 <PRIVATE
 882
 883 : joined-length ( seq glue -- n )
 884     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 885
 886 PRIVATE>
 887
 888 : join-as ( seq glue exemplar -- newseq )
 889     over empty? [ nip concat-as ] [
 890         [
 891             2dup joined-length over new-resizable [
 892                 [ [ push-all ] 2curry ]
 893                 [ nip [ push-all ] curry ] 2bi
 894                 interleave
 895             ] keep
 896         ] dip like
 897     ] if ;
 898
 899 : join ( seq glue -- newseq )
 900     dup join-as ; inline
 901
 902 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 903     [
 904         [ over length [-] dup 0 = [ drop ] ] dip
 905         [ <repetition> ] curry
 906     ] dip compose if ; inline
 907
 908 : pad-head ( seq n elt -- padded )
 909     [ swap dup append-as ] padding ;
 910
 911 : pad-tail ( seq n elt -- padded )
 912     [ append ] padding ;
 913
 914 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 915 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 916 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 917 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 918
 919 : head? ( seq begin -- ? )
 920     2dup shorter? [
 921         2drop f
 922     ] [
 923         [ length [ head-slice ] keep swap ] keep
 924         mismatch-unsafe not
 925     ] if ;
 926
 927 : tail? ( seq end -- ? )
 928     2dup shorter? [
 929         2drop f
 930     ] [
 931         [ length [ tail-slice* ] keep swap ] keep
 932         mismatch-unsafe not
 933     ] if ;
 934
 935 : cut-slice ( seq n -- before-slice after-slice )
 936     [ head-slice ] [ tail-slice ] 2bi ; inline
 937
 938 : insert-nth ( elt n seq -- seq' )
 939     swap cut-slice [ swap suffix ] dip append ;
 940
 941 : halves ( seq -- first-slice second-slice )
 942     dup midpoint@ cut-slice ; inline
 943
 944 <PRIVATE
 945
 946 : nth2-unsafe ( n seq -- a b )
 947     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 948
 949 : nth3-unsafe ( n seq -- a b c )
 950     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 951
 952 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 953     ! We can't use case here since combinators depends on
 954     ! sequences
 955     dup 4 < [
 956         integer>fixnum {
 957             [ 2drop nip ]
 958             [ 2nip swap nth-unsafe ]
 959             [ -rot [ drop swap nth2-unsafe ] dip call ]
 960             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 961         } dispatch
 962     ] [
 963         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 964         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 965         pick [ 3bi ] dip call
 966     ] if ; inline recursive
 967
 968 PRIVATE>
 969
 970 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 971     pick length 0 max 0 swap (binary-reduce) ; inline
 972
 973 : cut ( seq n -- before after )
 974     [ head ] [ tail ] 2bi ;
 975
 976 : cut* ( seq n -- before after )
 977     [ head* ] [ tail* ] 2bi ;
 978
 979 <PRIVATE
 980
 981 : (start) ( subseq seq n length -- subseq seq ? )
 982     [
 983         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 984     ] all-integers? nip ; inline
 985
 986 PRIVATE>
 987
 988 : start* ( subseq seq n -- i )
 989     pick length [ pick length swap - 1 + ] keep
 990     [ (start) ] curry (find-integer) 2nip ;
 991
 992 : start ( subseq seq -- i ) 0 start* ; inline
 993
 994 : subseq? ( subseq seq -- ? ) start >boolean ;
 995
 996 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 997     2dup mismatch [ 2dup min-length ] unless*
 998     [ tail-slice ] curry bi@ ;
 999
1000 : unclip ( seq -- rest first )
1001     [ rest ] [ first-unsafe ] bi ;
1002
1003 : unclip-last ( seq -- butlast last )
1004     [ but-last ] [ last-unsafe ] bi ;
1005
1006 : unclip-slice ( seq -- rest-slice first )
1007     [ rest-slice ] [ first-unsafe ] bi ; inline
1008
1009 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
1010     [ [ dup first ] dip [ call ] keep ] dip compose
1011     swapd 1 each-from ; inline
1012
1013 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
1014     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
1015     [ -rot ] dip 1 2each-from ; inline
1016
1017 <PRIVATE
1018
1019 : (map-find) ( seq quot find-quot -- result elt )
1020     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
1021     [ [ drop f ] unless ] dip ; inline
1022
1023 PRIVATE>
1024
1025 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1026     [ find ] (map-find) ; inline
1027
1028 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1029     [ find-last ] (map-find) ; inline
1030
1031 : unclip-last-slice ( seq -- butlast-slice last )
1032     [ but-last-slice ] [ last-unsafe ] bi ; inline
1033
1034 <PRIVATE
1035
1036 : (trim-head) ( seq quot -- seq n )
1037     over [ [ not ] compose find drop ] dip swap
1038     [ dup length ] unless* ; inline
1039
1040 : (trim-tail) ( seq quot -- seq n )
1041     over [ [ not ] compose find-last drop ?1+ ] dip
1042     swap ; inline
1043
1044 PRIVATE>
1045
1046 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1047     (trim-head) tail-slice ; inline
1048
1049 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1050     (trim-head) tail ; inline
1051
1052 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1053     (trim-tail) head-slice ; inline
1054
1055 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1056     (trim-tail) head ; inline
1057
1058 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1059     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1060
1061 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1062     [ trim-slice ] [ drop ] 2bi like ; inline
1063
1064 GENERIC: sum ( seq -- n )
1065 M: object sum 0 [ + ] binary-reduce ; inline
1066 M: iota-tuple sum length dup 1 - * 2/ ; inline
1067 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1068
1069 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1070
1071 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1072
1073 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1074
1075 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1076     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1077
1078 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1079     [ 1 0 ? ] compose map-sum ; inline
1080
1081 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1082     [ with each ] 2curry each ; inline
1083
1084 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1085     [ with map ] 2curry map ; inline
1086
1087 : cartesian-product ( seq1 seq2 -- newseq )
1088     [ { } 2sequence ] cartesian-map ;
1089
1090 <PRIVATE
1091
1092 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1093     [
1094         [ keep swap ] curry [ [ first ] dip call ] 2keep
1095         [ curry 2dip pick over ] curry
1096     ] [
1097         [ [ 2drop ] [ [ 2drop ] 2dip ] if ] compose
1098     ] bi* compose 1 each-from drop ; inline
1099
1100 PRIVATE>
1101
1102 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1103     [ after? ] select-by ; inline
1104
1105 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1106     [ before? ] select-by ; inline
1107
1108 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1109
1110 : longest ( seqs -- elt ) [ length ] supremum-by ;
1111
1112 ! We hand-optimize flip to such a degree because type hints
1113 ! cannot express that an array is an array of arrays yet, and
1114 ! this word happens to be performance-critical since the compiler
1115 ! itself uses it. Optimizing it like this reduced compile time.
1116 <PRIVATE
1117
1118 : generic-flip ( matrix -- newmatrix )
1119     [
1120         [ first-unsafe length 1 ] keep
1121         [ length min ] setup-each (each-integer) iota
1122     ] keep
1123     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1124
1125 USE: arrays
1126
1127 : array-length ( array -- len )
1128     { array } declare length>> ; inline
1129
1130 : array-flip ( matrix -- newmatrix )
1131     { array } declare
1132     [
1133         [ first-unsafe array-length 1 ] keep
1134         [ array-length min ] setup-each (each-integer) iota
1135     ] keep
1136     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1137
1138 PRIVATE>
1139
1140 : flip ( matrix -- newmatrix )
1141     dup empty? [
1142         dup array? [
1143             dup [ array? ] all?
1144             [ array-flip ] [ generic-flip ] if
1145         ] [ generic-flip ] if
1146     ] unless ;