core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (1sequence) ( obj seq -- seq )
 139     [ 0 swap set-nth-unsafe ] keep ; inline
 140
 141 : (2sequence) ( obj1 obj2 seq -- seq )
 142     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 146
 147 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 148     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 149
 150 PRIVATE>
 151
 152 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 153
 154 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 155
 156 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : >slice< ( slice -- from to seq )
 222     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 223
 224 : collapse-slice ( m n slice -- m' n' seq )
 225     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 226
 227 ERROR: slice-error from to seq ;
 228
 229 : check-slice ( from to seq -- from to seq )
 230     pick 0 < [ slice-error ] when
 231     2dup length > [ slice-error ] when
 232     2over > [ slice-error ] when ; inline
 233
 234 <PRIVATE
 235
 236 : <slice-unsafe> ( from to seq -- slice )
 237     dup slice? [ collapse-slice ] when slice boa ; inline
 238
 239 PRIVATE>
 240
 241 : <slice> ( from to seq -- slice )
 242     check-slice <slice-unsafe> ; inline
 243
 244 M: slice virtual-exemplar seq>> ; inline
 245
 246 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 247
 248 M: slice length [ to>> ] [ from>> ] bi - ; inline
 249
 250 : cramp ( seq n -- seq n' ) over length min ; inline
 251
 252 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 253
 254 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 255
 256 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 257
 258 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 259
 260 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 261
 262 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 263
 264 INSTANCE: slice virtual-sequence
 265
 266 ! One element repeated many times
 267 TUPLE: repetition
 268     { length integer read-only }
 269     { elt read-only } ;
 270
 271 : <repetition> ( len elt -- repetition )
 272     over 0 < [ non-negative-integer-expected ] when
 273     repetition boa ; inline
 274
 275 M: repetition length length>> ; inline
 276 M: repetition nth-unsafe nip elt>> ; inline
 277
 278 INSTANCE: repetition immutable-sequence
 279
 280 <PRIVATE
 281
 282 ERROR: integer-length-expected obj ;
 283
 284 ! The check-length call forces partial dispatch
 285 : check-length ( n -- n )
 286     dup integer? [ integer-length-expected ] unless ; inline
 287
 288 : >sequence< ( seq -- i n seq )
 289     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 290
 291 : length-sequence ( seq -- n seq )
 292     [ length check-length ] [ ] bi ; inline
 293
 294 : >underlying< ( slice/seq -- i n slice/seq )
 295     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 296
 297 TUPLE: copier
 298     { src-i integer read-only }
 299     { src read-only }
 300     { dst-i integer read-only }
 301     { dst read-only } ;
 302
 303 C: <copier> copier
 304
 305 : copy-nth-unsafe ( n copy -- )
 306     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 307     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 308
 309 : (copy) ( n copy -- dst )
 310     over 0 <= [ nip dst>> ] [
 311         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 312     ] if ; inline recursive
 313
 314 : subseq>copy ( from to seq -- n copy )
 315     [ over - check-length swap ] dip
 316     3dup nip new-sequence 0 swap <copier> ; inline
 317
 318 : bounds-check-head ( n seq -- n seq )
 319     over 0 < [ bounds-error ] when ; inline
 320
 321 : check-copy ( src n dst -- src n dst )
 322     3dup bounds-check-head
 323     [ swap length + ] dip lengthen ; inline
 324
 325 : copy-unsafe ( src i dst -- )
 326     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 327
 328 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 329     [ subseq>copy (copy) ] dip like ; inline
 330
 331 : subseq-unsafe ( from to seq -- subseq )
 332     dup subseq-unsafe-as ; inline
 333
 334 PRIVATE>
 335
 336 : subseq-as ( from to seq exemplar -- subseq )
 337     [ check-slice ] dip subseq-unsafe-as ;
 338
 339 : subseq ( from to seq -- subseq )
 340     dup subseq-as ;
 341
 342 : head ( seq n -- headseq ) head-to-index subseq ;
 343
 344 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 345
 346 : rest ( seq -- tailseq ) 1 tail ;
 347
 348 : head* ( seq n -- headseq ) from-tail head ;
 349
 350 : tail* ( seq n -- tailseq ) from-tail tail ;
 351
 352 : but-last ( seq -- headseq ) 1 head* ;
 353
 354 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 355
 356 M: sequence clone-like
 357     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 358
 359 M: immutable-sequence clone-like like ; inline
 360
 361 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 362
 363 <PRIVATE
 364
 365 : (append) ( seq1 seq2 accum -- accum )
 366     [ [ over length ] dip copy-unsafe ]
 367     [ 0 swap copy-unsafe ]
 368     [ ] tri ; inline
 369
 370 PRIVATE>
 371
 372 : append-as ( seq1 seq2 exemplar -- newseq )
 373     [ 2dup [ length ] bi@ + ] dip
 374     [ (append) ] new-like ; inline
 375
 376 : append ( seq1 seq2 -- newseq ) over append-as ;
 377
 378 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 379
 380 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 381
 382 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 383     [ 3dup [ length ] tri@ + + ] dip [
 384         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 385         [ (append) ] bi
 386     ] new-like ; inline
 387
 388 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 389
 390 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 391     [ swap ] 2dip 3append-as ; inline
 392
 393 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 394
 395 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 396
 397 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 398
 399 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 400
 401 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 402
 403 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 404     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 405
 406 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 407
 408 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 409
 410 <PRIVATE
 411
 412 : sequence-operator ( seq quot -- i n quot' )
 413     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 414
 415 : length-iterator ( seq -- n quot' )
 416     length-sequence [ nth-unsafe ] curry ; inline
 417
 418 : length-operator ( seq quot -- n quot' )
 419     [ length-iterator ] dip compose ; inline
 420
 421 : sequence-operator-from ( seq quot i -- i n quot' )
 422     -rot length-operator ; inline
 423
 424 : collect ( n quot into -- )
 425     [ [ keep ] dip set-nth-unsafe ] 2curry each-integer ; inline
 426
 427 : sequence-index-iterator ( seq quot -- n quot' )
 428     [ length-iterator [ keep ] curry ] dip compose ; inline
 429
 430 : map-into ( seq quot into -- )
 431     [ length-operator ] dip collect ; inline
 432
 433 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 434     [ nth-unsafe ] bi-curry@ bi ; inline
 435
 436 : setup-2each ( seq1 seq2 -- n quot )
 437     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 438
 439 : (2each) ( seq1 seq2 quot -- n quot' )
 440     [ setup-2each ] dip compose ; inline
 441
 442 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 443     [ nth-unsafe ] tri-curry@ tri ; inline
 444
 445 : setup-3each ( seq1 seq2 seq3 -- n quot )
 446     [ [ length ] tri@ min min check-length ]
 447     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 448
 449 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 450     [ setup-3each ] dip compose ; inline
 451
 452 : finish-find ( i seq -- i elt )
 453     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 454
 455 : (find) ( seq quot quot' -- i elt )
 456     pick [ [ length-operator ] dip call ] dip finish-find ; inline
 457
 458 : (find-from) ( n seq quot quot' -- i elt )
 459     [ 2dup bounds-check? ] 2dip
 460     '[ _ _ (find) ] [ 2drop f f ] if ; inline
 461
 462 : (find-index) ( seq quot quot' -- i elt )
 463     pick [ [ sequence-index-iterator ] dip call ] dip finish-find ; inline
 464
 465 : (find-index-from) ( n seq quot quot' -- i elt )
 466     [ 2dup bounds-check? ] 2dip
 467     '[ _ _ (find-index) ] [ 2drop f f ] if ; inline
 468
 469 : (accumulate) ( seq identity quot -- identity seq quot' )
 470     swapd [ keepd ] curry ; inline
 471
 472 : (accumulate*) ( seq identity quot -- identity seq quot' )
 473     swapd [ dup ] compose ; inline
 474
 475 PRIVATE>
 476
 477 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 478     sequence-operator each-integer-from ; inline
 479
 480 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 481     sequence-operator-from each-integer-from ; inline
 482
 483 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 484     swapd each ; inline
 485
 486 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 487     overd [ [ collect ] keep ] new-like ; inline
 488
 489 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 490     { } map-integers-as ; inline
 491
 492 ! : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 493 !     overd [ [ collect ] keep ] new-like ; inline
 494
 495 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 496     [ length-operator ] dip map-integers-as ; inline
 497
 498 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 499     over map-as ; inline
 500
 501 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 502     [ [ drop ] prepose ] dip map-integers-as ; inline
 503
 504 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 505     { } replicate-as ; inline
 506
 507 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 508     over [ map-into ] keep ; inline
 509
 510 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 511     [ (accumulate) ] dip map-as ; inline
 512
 513 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 514     pick accumulate-as ; inline
 515
 516 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 517     (accumulate) map! ; inline
 518
 519 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 520     [ (accumulate*) ] dip map-as nip ; inline
 521
 522 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 523     pick accumulate*-as ; inline
 524
 525 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 526     (accumulate*) map! nip ; inline
 527
 528 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 529     (2each) each-integer ; inline
 530
 531 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 532     [ (2each) ] dip -rot each-integer-from ; inline
 533
 534 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 535     -rotd 2each ; inline
 536
 537 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 538     [ (2each) ] dip map-integers-as ; inline
 539
 540 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 541     pick 2map-as ; inline
 542
 543 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 544     (2each) all-integers? ; inline
 545
 546 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 547     negate 2all? not ; inline
 548
 549 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 550     (3each) each-integer ; inline
 551
 552 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 553     [ (3each) ] dip map-integers-as ; inline
 554
 555 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 556     pickd swap 3map-as ; inline
 557
 558 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 559     [ find-integer-from ] (find-from) ; inline
 560
 561 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 562     [ find-integer ] (find) ; inline
 563
 564 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 565     [ nip find-last-integer ] (find-from) ; inline
 566
 567 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 568     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 569
 570 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 571     [ find-integer-from ] (find-index-from) ; inline
 572
 573 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 574     [ find-integer ] (find-index) ; inline
 575
 576 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 577     sequence-operator all-integers-from? ; inline
 578
 579 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 580     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 581
 582 <PRIVATE
 583
 584 : (selector-as) ( quot length exemplar -- selector accum )
 585     new-resizable [ [ push-if ] 2curry ] keep ; inline
 586
 587 PRIVATE>
 588
 589 : selector-as ( quot exemplar -- selector accum )
 590     [ length ] keep (selector-as) ; inline
 591
 592 : selector ( quot -- selector accum )
 593     V{ } selector-as ; inline
 594
 595 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 596     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 597
 598 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 599     over filter-as ; inline
 600
 601 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 602     [ negate ] [ filter-as ] bi* ; inline
 603
 604 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 605     over reject-as ; inline
 606
 607 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 608     [ keep swap ] 2dip ? push ; inline
 609
 610 : 2selector ( quot -- selector accum1 accum2 )
 611     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 612
 613 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 614     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 615
 616 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 617     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 618
 619 : collector-as ( quot exemplar -- quot' vec )
 620     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 621
 622 : collector-for ( seq quot -- seq quot' vec )
 623     V{ } collector-for-as ; inline
 624
 625 : collector ( quot -- quot' vec )
 626     V{ } collector-as ; inline
 627
 628 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 629     dup [ collector-as [ while ] dip ] curry dip like ; inline
 630
 631 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 632     { } produce-as ; inline
 633
 634 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 635     [ dup ] swap [ keep ] curry produce nip ; inline
 636
 637 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 638     sequence-index-iterator each-integer ; inline
 639
 640 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 641     [ dup length <iota> ] 2dip 2map-as ; inline
 642
 643 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 644     over map-index-as ; inline
 645
 646 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 647     pick empty? [ 3drop ] [
 648         [ [ drop first-unsafe ] dip call ]
 649         [ [ bi* ] 2curry 1 each-from ]
 650         3bi
 651     ] if ; inline
 652
 653 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 654     swapd each-index ; inline
 655
 656 : index ( obj seq -- n )
 657     [ = ] with find drop ;
 658
 659 : index-from ( obj i seq -- n )
 660     rot [ = ] curry find-from drop ;
 661
 662 : last-index ( obj seq -- n )
 663     [ = ] with find-last drop ;
 664
 665 : last-index-from ( obj i seq -- n )
 666     rot [ = ] curry find-last-from drop ;
 667
 668 : indices ( obj seq -- indices )
 669     swap [ = ] curry [ swap ] prepose V{ } clone [
 670         [ push ] curry [ [ drop ] if ] curry compose each-index
 671     ] keep ;
 672
 673 <PRIVATE
 674
 675 : nths-unsafe ( indices seq -- seq' )
 676     [ [ nth-unsafe ] curry ] keep map-as ;
 677
 678 PRIVATE>
 679
 680 : nths ( indices seq -- seq' )
 681     [ [ nth ] curry ] keep map-as ;
 682
 683 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 684     find drop >boolean ; inline
 685
 686 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 687     any? not ; inline
 688
 689 : member? ( elt seq -- ? )
 690     [ = ] with any? ;
 691
 692 : member-of? ( seq elt -- ? )
 693     [ = ] curry any? ;
 694
 695 : member-eq? ( elt seq -- ? )
 696     [ eq? ] with any? ;
 697
 698 : member-eq-of? ( seq elt -- ? )
 699     [ eq? ] curry any? ;
 700
 701 : remove ( elt seq -- newseq )
 702     [ = ] with reject ;
 703
 704 : remove-of ( seq elt -- newseq )
 705     [ = ] curry reject ;
 706
 707 : remove-eq ( elt seq -- newseq )
 708     [ eq? ] with reject ;
 709
 710 : remove-eq-of ( seq elt -- newseq )
 711     [ eq? ] curry reject ;
 712
 713 : sift ( seq -- newseq )
 714     [ ] filter ;
 715
 716 : harvest ( seq -- newseq )
 717     [ empty? ] reject ;
 718
 719 <PRIVATE
 720
 721 : mismatch-unsafe ( n seq1 seq2 -- i )
 722     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 723
 724 PRIVATE>
 725
 726 : mismatch ( seq1 seq2 -- i )
 727     [ min-length ] 2keep mismatch-unsafe ;
 728
 729 M: sequence <=>
 730     [ mismatch ] 2keep pick
 731     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 732
 733 : sequence= ( seq1 seq2 -- ? )
 734     2dup [ length ] bi@ dupd =
 735     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 736
 737 ERROR: assert-sequence got expected ;
 738
 739 : assert-sequence= ( a b -- )
 740     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 741
 742 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 743
 744 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 745
 746 <PRIVATE
 747
 748 : sequence-hashcode-step ( oldhash newpart -- newhash )
 749     integer>fixnum swap [
 750         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 751         fixnum+fast fixnum+fast
 752     ] keep fixnum-bitxor ; inline
 753
 754 PRIVATE>
 755
 756 : sequence-hashcode ( n seq -- x )
 757     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 758
 759 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 760
 761 M: iota hashcode*
 762     over 0 <= [ 2drop 0 ] [
 763         nip length 0 swap [ sequence-hashcode-step ] each-integer
 764     ] if ;
 765
 766 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 767
 768 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 769
 770 : move ( to from seq -- )
 771     2over =
 772     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 773
 774 <PRIVATE
 775
 776 : move-unsafe ( to from seq -- )
 777     2over =
 778     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 779
 780 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 781     2dup length < [
 782         [ move-unsafe ] 3keep
 783         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 784         [ 1 + ] dip
 785         (filter!)
 786     ] [ nip set-length drop ] if ; inline recursive
 787
 788 PRIVATE>
 789
 790 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 791     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 792
 793 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 794     negate filter! ; inline
 795
 796 : remove! ( elt seq -- seq )
 797     [ = ] with reject! ;
 798
 799 : remove-eq! ( elt seq -- seq )
 800     [ eq? ] with reject! ;
 801
 802 : prefix ( seq elt -- newseq )
 803     over [ over length 1 + ] dip [
 804         (1sequence) [ 1 swap copy-unsafe ] keep
 805     ] new-like ;
 806
 807 : suffix ( seq elt -- newseq )
 808     over [ over length 1 + ] dip [
 809         [ [ over length ] dip set-nth-unsafe ] keep
 810         [ 0 swap copy-unsafe ] keep
 811     ] new-like ;
 812
 813 : suffix! ( seq elt -- seq ) over push ; inline
 814
 815 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 816
 817 : last ( seq -- elt )
 818     [ length 1 - ] keep
 819     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 820
 821 <PRIVATE
 822
 823 : last-unsafe ( seq -- elt )
 824     [ length 1 - ] [ nth-unsafe ] bi ; inline
 825
 826 PRIVATE>
 827
 828 : set-last ( elt seq -- )
 829     [ length 1 - ] keep
 830     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 831
 832 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 833
 834 <PRIVATE
 835
 836 : move-backward ( shift from to seq -- )
 837     2over = [
 838         4drop
 839     ] [
 840         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 841         move-backward
 842     ] if ;
 843
 844 : move-forward ( shift from to seq -- )
 845     2over = [
 846         4drop
 847     ] [
 848         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 849         move-forward
 850     ] if ;
 851
 852 : (open-slice) ( shift from to seq ? -- )
 853     [
 854         [ [ 1 - ] bi@ ] dip move-forward
 855     ] [
 856         [ over - ] 2dip move-backward
 857     ] if ;
 858
 859 : open-slice ( shift from seq -- )
 860     pick 0 = [
 861         3drop
 862     ] [
 863         [ ] [ nip length + ] [ 2nip ] 3tri
 864         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 865         set-length
 866     ] if ;
 867
 868 PRIVATE>
 869
 870 : delete-slice ( from to seq -- )
 871     check-slice [ over [ - ] dip ] dip open-slice ;
 872
 873 : remove-nth! ( n seq -- seq )
 874     [ [ dup 1 + ] dip delete-slice ] keep ;
 875
 876 : snip ( from to seq -- head tail )
 877     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 878
 879 : snip-slice ( from to seq -- head tail )
 880     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 881
 882 : replace-slice ( new from to seq -- seq' )
 883     snip-slice surround ;
 884
 885 : remove-nth ( n seq -- seq' )
 886     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 887
 888 : pop ( seq -- elt )
 889     [ length 1 - ] keep over 0 >=
 890     [ [ nth-unsafe ] [ shorten ] 2bi ]
 891     [ bounds-error ] if ;
 892
 893 : exchange ( m n seq -- )
 894     [ nip bounds-check 2drop ]
 895     [ bounds-check 3drop ]
 896     [ exchange-unsafe ]
 897     3tri ;
 898
 899 : midpoint@ ( seq -- n ) length 2/ ; inline
 900
 901 : reverse! ( seq -- seq )
 902     [
 903         [ midpoint@ ] [ length ] [ ] tri
 904         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 905         each-integer
 906     ] keep ;
 907
 908 : reverse ( seq -- newseq )
 909      [
 910         dup [ length ] keep new-sequence
 911         [ 0 swap copy-unsafe ] keep reverse!
 912     ] keep like ;
 913
 914 GENERIC: sum-lengths ( seq -- n )
 915
 916 M: object sum-lengths
 917     0 [ length + ] reduce ;
 918
 919 M: repetition sum-lengths
 920     [ length>> ] [ elt>> length ] bi * ;
 921
 922 : concat-as ( seq exemplar -- newseq )
 923     [
 924         [ dup sum-lengths ] dip new-resizable
 925         [ [ push-all ] curry each ] keep
 926     ] keep like ; inline
 927
 928 : concat ( seq -- newseq )
 929     [ { } ] [ dup first concat-as ] if-empty ;
 930
 931 <PRIVATE
 932
 933 : joined-length ( seq glue -- n )
 934     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 935
 936 PRIVATE>
 937
 938 : join-as ( seq glue exemplar -- newseq )
 939     over empty? [ nip concat-as ] [
 940         [
 941             2dup joined-length over new-resizable [
 942                 [ [ push-all ] 2curry ]
 943                 [ nip [ push-all ] curry ] 2bi
 944                 interleave
 945             ] keep
 946         ] dip like
 947     ] if ;
 948
 949 : join ( seq glue -- newseq )
 950     dup join-as ; inline
 951
 952 <PRIVATE
 953
 954 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 955     [
 956         [ over length [-] dup 0 = [ drop ] ] dip
 957         [ <repetition> ] curry
 958     ] dip compose if ; inline
 959
 960 PRIVATE>
 961
 962 : pad-head ( seq n elt -- padded )
 963     [ swap dup append-as ] padding ;
 964
 965 : pad-tail ( seq n elt -- padded )
 966     [ append ] padding ;
 967
 968 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 969 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 970 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 971 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 972
 973 : head? ( seq begin -- ? )
 974     2dup shorter? [
 975         2drop f
 976     ] [
 977         [ length [ head-slice ] keep swap ] keep
 978         mismatch-unsafe not
 979     ] if ;
 980
 981 : tail? ( seq end -- ? )
 982     2dup shorter? [
 983         2drop f
 984     ] [
 985         [ length [ tail-slice* ] keep swap ] keep
 986         mismatch-unsafe not
 987     ] if ;
 988
 989 : cut-slice ( seq n -- before-slice after-slice )
 990     [ head-slice ] [ tail-slice ] 2bi ; inline
 991
 992 : cut-slice* ( seq n -- before-slice after-slice )
 993     [ head-slice* ] [ tail-slice* ] 2bi ;
 994
 995 : insert-nth ( elt n seq -- seq' )
 996     swap cut-slice [ swap suffix ] dip append ;
 997
 998 : halves ( seq -- first-slice second-slice )
 999     dup midpoint@ cut-slice ; inline
1000
1001 <PRIVATE
1002
1003 : nth2-unsafe ( n seq -- a b )
1004     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1005
1006 : nth3-unsafe ( n seq -- a b c )
1007     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1008
1009 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1010     ! We can't use case here since combinators depends on
1011     ! sequences
1012     dup 4 < [
1013         integer>fixnum {
1014             [ 2drop nip ]
1015             [ 2nip swap nth-unsafe ]
1016             [ -rot [ drop swap nth2-unsafe ] dip call ]
1017             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1018         } dispatch
1019     ] [
1020         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1021         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1022         pick [ 3bi ] dip call
1023     ] if ; inline recursive
1024
1025 PRIVATE>
1026
1027 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1028     pick dup slice? [
1029         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1030     ] [
1031         length 0 max 0 swap
1032     ] if (binary-reduce) ; inline
1033
1034 : cut ( seq n -- before after )
1035     [ head ] [ tail ] 2bi ;
1036
1037 : cut* ( seq n -- before after )
1038     [ head* ] [ tail* ] 2bi ;
1039
1040 : subseq-starts-at? ( i seq subseq -- ? )
1041     [ length swap ] keep
1042     '[
1043         [ + _ nth-unsafe ] keep _ nth-unsafe =
1044     ] with all-integers? ; inline
1045
1046 : find-subseq-from ( n seq subseq -- i/f )
1047     [ [ length ] bi@ - 1 + ] 2keep
1048     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1049
1050 : subseq-start-from ( subseq seq n -- i/f ) spin find-subseq-from ; inline
1051
1052 : find-subseq ( seq subseq -- i/f ) [ 0 ] 2dip find-subseq-from ; inline
1053
1054 : find-subseq? ( seq subseq -- ? ) find-subseq >boolean ; inline
1055
1056 : subseq-start ( subseq seq -- i/f ) swap find-subseq ; inline
1057
1058 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline
1059
1060 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1061     2dup mismatch [ 2dup min-length ] unless*
1062     [ tail-slice ] curry bi@ ;
1063
1064 : unclip ( seq -- rest first )
1065     [ rest ] [ first-unsafe ] bi ;
1066
1067 : unclip-last ( seq -- butlast last )
1068     [ but-last ] [ last-unsafe ] bi ;
1069
1070 : unclip-slice ( seq -- rest-slice first )
1071     [ rest-slice ] [ first-unsafe ] bi ; inline
1072
1073 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1074     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1075     '[ swap _ dip swap @ ] 1 each-from ; inline
1076
1077 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1078     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1079     '[ rot _ dip swap @ ] 1 2each-from ; inline
1080
1081 <PRIVATE
1082
1083 : (map-find) ( seq quot find-quot -- result elt )
1084     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1085
1086 PRIVATE>
1087
1088 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1089     [ find ] (map-find) ; inline
1090
1091 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1092     [ find-last ] (map-find) ; inline
1093
1094 : unclip-last-slice ( seq -- butlast-slice last )
1095     [ but-last-slice ] [ last-unsafe ] bi ; inline
1096
1097 <PRIVATE
1098
1099 : (trim-head) ( seq quot -- seq n )
1100     over [ negate find drop ] dip swap
1101     [ dup length ] unless* ; inline
1102
1103 : (trim-tail) ( seq quot -- seq n )
1104     over [ negate find-last drop ?1+ ] dip
1105     swap ; inline
1106
1107 PRIVATE>
1108
1109 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1110     (trim-head) tail-slice ; inline
1111
1112 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1113     (trim-head) tail ; inline
1114
1115 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1116     (trim-tail) head-slice ; inline
1117
1118 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1119     (trim-tail) head ; inline
1120
1121 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1122     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1123
1124 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1125     [ trim-slice ] [ drop ] 2bi like ; inline
1126
1127 GENERIC: sum ( seq -- n )
1128 M: object sum 0 [ + ] binary-reduce ; inline
1129 M: iota sum length dup 1 - * 2/ ; inline
1130 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1131
1132 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1133
1134 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1135
1136 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1137
1138 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1139     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1140
1141 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1142     [ 1 0 ? ] compose map-sum ; inline
1143
1144 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1145     [ with each ] 2curry each ; inline
1146
1147 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1148     [ with { } map-as ] 2curry { } map-as ; inline
1149
1150 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1151     [ 2sequence ] curry cartesian-map ; inline
1152
1153 : cartesian-product ( seq1 seq2 -- newseq )
1154     dup cartesian-product-as ; inline
1155
1156 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1157     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1158
1159 <PRIVATE
1160
1161 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1162     [
1163         [ keep swap ] curry [ [ first ] dip call ] 2keep
1164         [ curry 2dip pick over ] curry
1165     ] [
1166         [ [ 2drop ] [ 2nipd ] if ] compose
1167     ] bi* compose 1 each-from drop ; inline
1168
1169 PRIVATE>
1170
1171 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1172     [ after? ] select-by ; inline
1173
1174 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1175     [ before? ] select-by ; inline
1176
1177 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1178
1179 : longest ( seqs -- elt ) [ length ] supremum-by ;
1180
1181 ! We hand-optimize flip to such a degree because type hints
1182 ! cannot express that an array is an array of arrays yet, and
1183 ! this word happens to be performance-critical since the compiler
1184 ! itself uses it. Optimizing it like this reduced compile time.
1185 <PRIVATE
1186
1187 : generic-flip ( matrix -- newmatrix )
1188     [ [ length ] [ min ] map-reduce ] keep
1189     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1190
1191 USE: arrays
1192
1193 : array-flip ( matrix -- newmatrix )
1194     { array } declare
1195     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1196     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1197
1198 PRIVATE>
1199
1200 : flip ( matrix -- newmatrix )
1201     dup empty? [
1202         dup array? [
1203             dup [ array? ] all?
1204             [ array-flip ] [ generic-flip ] if
1205         ] [ generic-flip ] if
1206     ] unless ;