core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : >slice< ( slice -- from to seq )
 222     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 223
 224 : collapse-slice ( m n slice -- m' n' seq )
 225     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 226
 227 ERROR: slice-error from to seq ;
 228
 229 : check-slice ( from to seq -- from to seq )
 230     pick 0 < [ slice-error ] when
 231     2dup length > [ slice-error ] when
 232     2over > [ slice-error ] when ; inline
 233
 234 <PRIVATE
 235
 236 : <slice-unsafe> ( from to seq -- slice )
 237     dup slice? [ collapse-slice ] when slice boa ; inline
 238
 239 PRIVATE>
 240
 241 : <slice> ( from to seq -- slice )
 242     check-slice <slice-unsafe> ; inline
 243
 244 M: slice virtual-exemplar seq>> ; inline
 245
 246 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 247
 248 M: slice length [ to>> ] [ from>> ] bi - ; inline
 249
 250 : short ( seq n -- seq n' ) over length min ; inline
 251
 252 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 253
 254 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 255
 256 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 257
 258 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 259
 260 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 261
 262 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 263
 264 INSTANCE: slice virtual-sequence
 265
 266 ! One element repeated many times
 267 TUPLE: repetition
 268     { length integer read-only }
 269     { elt read-only } ;
 270
 271 : <repetition> ( len elt -- repetition )
 272     over 0 < [ non-negative-integer-expected ] when
 273     repetition boa ; inline
 274
 275 M: repetition length length>> ; inline
 276 M: repetition nth-unsafe nip elt>> ; inline
 277
 278 INSTANCE: repetition immutable-sequence
 279
 280 <PRIVATE
 281
 282 ERROR: integer-length-expected obj ;
 283
 284 ! The check-length call forces partial dispatch
 285 : check-length ( n -- n )
 286     dup integer? [ integer-length-expected ] unless ; inline
 287
 288 : >sequence< ( seq -- i n seq )
 289     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 290
 291 : length-sequence ( seq -- n seq )
 292     [ length check-length ] [ ] bi ; inline
 293
 294 : >underlying< ( slice/seq -- i n slice/seq )
 295     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 296
 297 TUPLE: copier
 298     { src-i integer read-only }
 299     { src read-only }
 300     { dst-i integer read-only }
 301     { dst read-only } ;
 302
 303 C: <copier> copier
 304
 305 : copy-nth-unsafe ( n copy -- )
 306     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 307     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 308
 309 : (copy) ( n copy -- dst )
 310     over 0 <= [ nip dst>> ] [
 311         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 312     ] if ; inline recursive
 313
 314 : subseq>copy ( from to seq -- n copy )
 315     [ over - check-length swap ] dip
 316     3dup nip new-sequence 0 swap <copier> ; inline
 317
 318 : bounds-check-head ( n seq -- n seq )
 319     over 0 < [ bounds-error ] when ; inline
 320
 321 : check-copy ( src n dst -- src n dst )
 322     3dup bounds-check-head
 323     [ swap length + ] dip lengthen ; inline
 324
 325 : copy-unsafe ( src i dst -- )
 326     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 327
 328 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 329     [ subseq>copy (copy) ] dip like ; inline
 330
 331 : subseq-unsafe ( from to seq -- subseq )
 332     dup subseq-unsafe-as ; inline
 333
 334 PRIVATE>
 335
 336 : subseq-as ( from to seq exemplar -- subseq )
 337     [ check-slice ] dip subseq-unsafe-as ;
 338
 339 : subseq ( from to seq -- subseq )
 340     dup subseq-as ;
 341
 342 : head ( seq n -- headseq ) (head) subseq ;
 343
 344 : tail ( seq n -- tailseq ) (tail) subseq ;
 345
 346 : rest ( seq -- tailseq ) 1 tail ;
 347
 348 : head* ( seq n -- headseq ) from-end head ;
 349
 350 : tail* ( seq n -- tailseq ) from-end tail ;
 351
 352 : but-last ( seq -- headseq ) 1 head* ;
 353
 354 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 355
 356 M: sequence clone-like
 357     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 358
 359 M: immutable-sequence clone-like like ; inline
 360
 361 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 362
 363 <PRIVATE
 364
 365 : (append) ( seq1 seq2 accum -- accum )
 366     [ [ over length ] dip copy-unsafe ]
 367     [ 0 swap copy-unsafe ]
 368     [ ] tri ; inline
 369
 370 PRIVATE>
 371
 372 : append-as ( seq1 seq2 exemplar -- newseq )
 373     [ 2dup [ length ] bi@ + ] dip
 374     [ (append) ] new-like ; inline
 375
 376 : append ( seq1 seq2 -- newseq ) over append-as ;
 377
 378 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 379
 380 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 381
 382 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 383     [ 3dup [ length ] tri@ + + ] dip [
 384         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 385         [ (append) ] bi
 386     ] new-like ; inline
 387
 388 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 389
 390 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 391     [ swap ] 2dip 3append-as ; inline
 392
 393 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 394
 395 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 396
 397 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 398
 399 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 400
 401 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 402
 403 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 404     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 405
 406 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 407
 408 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 409
 410 <PRIVATE
 411
 412 : sequence-operator ( seq quot -- i n quot' )
 413     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 414
 415 : length-iterator ( seq -- n quot' )
 416     length-sequence [ nth-unsafe ] curry ; inline
 417
 418 : length-operator ( seq quot -- n quot' )
 419     [ length-iterator ] dip compose ; inline
 420
 421 : sequence-operator-from ( seq quot i -- i n quot' )
 422     -rot length-operator ; inline
 423
 424 : collect ( n quot into -- )
 425     [ [ keep ] dip set-nth-unsafe ] 2curry each-integer ; inline
 426
 427 : sequence-index-iterator ( seq quot -- n quot' )
 428     [ length-iterator [ keep ] curry ] dip compose ; inline
 429
 430 : map-into ( seq quot into -- )
 431     [ length-operator ] dip collect ; inline
 432
 433 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 434     [ nth-unsafe ] bi-curry@ bi ; inline
 435
 436 : setup-2each ( seq1 seq2 -- n quot )
 437     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 438
 439 : (2each) ( seq1 seq2 quot -- n quot' )
 440     [ setup-2each ] dip compose ; inline
 441
 442 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 443     [ nth-unsafe ] tri-curry@ tri ; inline
 444
 445 : setup-3each ( seq1 seq2 seq3 -- n quot )
 446     [ [ length ] tri@ min min check-length ]
 447     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 448
 449 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 450     [ setup-3each ] dip compose ; inline
 451
 452 : finish-find ( i seq -- i elt )
 453     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 454
 455 : (find) ( seq quot quot' -- i elt )
 456     pick [ [ length-operator ] dip call ] dip finish-find ; inline
 457
 458 : (find-from) ( n seq quot quot' -- i elt )
 459     [ 2dup bounds-check? ] 2dip
 460     '[ _ _ (find) ] [ 2drop f f ] if ; inline
 461
 462 : (find-index) ( seq quot quot' -- i elt )
 463     pick [ [ sequence-index-iterator ] dip call ] dip finish-find ; inline
 464
 465 : (find-index-from) ( n seq quot quot' -- i elt )
 466     [ 2dup bounds-check? ] 2dip
 467     '[ _ _ (find-index) ] [ 2drop f f ] if ; inline
 468
 469 : (accumulate) ( seq identity quot -- identity seq quot )
 470     swapd [ keepd ] curry ; inline
 471
 472 : (accumulate*) ( seq identity quot -- identity seq quot )
 473     swapd [ dup ] compose ; inline
 474
 475 PRIVATE>
 476
 477 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 478     sequence-operator each-integer-from ; inline
 479
 480 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 481     sequence-operator-from each-integer-from ; inline
 482
 483 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 484     swapd each ; inline
 485
 486 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 487     overd [ [ collect ] keep ] new-like ; inline
 488
 489 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 490     [ length-operator ] dip map-integers ; inline
 491
 492 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 493     over map-as ; inline
 494
 495 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 496     [ [ drop ] prepose ] dip map-integers ; inline
 497
 498 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 499     { } replicate-as ; inline
 500
 501 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 502     over [ map-into ] keep ; inline
 503
 504 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 505     [ (accumulate) ] dip map-as ; inline
 506
 507 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 508     pick accumulate-as ; inline
 509
 510 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 511     (accumulate) map! ; inline
 512
 513 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 514     [ (accumulate*) ] dip map-as nip ; inline
 515
 516 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 517     pick accumulate*-as ; inline
 518
 519 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 520     (accumulate*) map! nip ; inline
 521
 522 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 523     (2each) each-integer ; inline
 524
 525 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 526     [ (2each) ] dip -rot each-integer-from ; inline
 527
 528 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 529     -rotd 2each ; inline
 530
 531 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 532     [ (2each) ] dip map-integers ; inline
 533
 534 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 535     pick 2map-as ; inline
 536
 537 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 538     (2each) all-integers? ; inline
 539
 540 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 541     negate 2all? not ; inline
 542
 543 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 544     (3each) each-integer ; inline
 545
 546 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 547     [ (3each) ] dip map-integers ; inline
 548
 549 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 550     pickd swap 3map-as ; inline
 551
 552 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 553     [ find-integer-from ] (find-from) ; inline
 554
 555 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 556     [ find-integer ] (find) ; inline
 557
 558 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 559     [ nip find-last-integer ] (find-from) ; inline
 560
 561 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 562     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 563
 564 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 565     [ find-integer-from ] (find-index-from) ; inline
 566
 567 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 568     [ find-integer ] (find-index) ; inline
 569
 570 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 571     sequence-operator all-integers-from? ; inline
 572
 573 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 574     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 575
 576 <PRIVATE
 577
 578 : (selector-as) ( quot length exemplar -- selector accum )
 579     new-resizable [ [ push-if ] 2curry ] keep ; inline
 580
 581 PRIVATE>
 582
 583 : selector-as ( quot exemplar -- selector accum )
 584     [ length ] keep (selector-as) ; inline
 585
 586 : selector ( quot -- selector accum )
 587     V{ } selector-as ; inline
 588
 589 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 590     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 591
 592 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 593     over filter-as ; inline
 594
 595 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 596     [ negate ] [ filter-as ] bi* ; inline
 597
 598 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 599     over reject-as ; inline
 600
 601 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 602     [ keep swap ] 2dip ? push ; inline
 603
 604 : 2selector ( quot -- selector accum1 accum2 )
 605     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 606
 607 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 608     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 609
 610 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 611     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 612
 613 : collector-as ( quot exemplar -- quot' vec )
 614     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 615
 616 : collector-for ( seq quot -- seq quot' vec )
 617     V{ } collector-for-as ; inline
 618
 619 : collector ( quot -- quot' vec )
 620     V{ } collector-as ; inline
 621
 622 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 623     dup [ collector-as [ while ] dip ] curry dip like ; inline
 624
 625 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 626     { } produce-as ; inline
 627
 628 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 629     [ dup ] swap [ keep ] curry produce nip ; inline
 630
 631 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 632     sequence-index-iterator each-integer ; inline
 633
 634 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 635     [ dup length <iota> ] 2dip 2map-as ; inline
 636
 637 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 638     over map-index-as ; inline
 639
 640 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 641     pick empty? [ 3drop ] [
 642         [ [ drop first-unsafe ] dip call ]
 643         [ [ bi* ] 2curry 1 each-from ]
 644         3bi
 645     ] if ; inline
 646
 647 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 648     swapd each-index ; inline
 649
 650 : index ( obj seq -- n )
 651     [ = ] with find drop ;
 652
 653 : index-from ( obj i seq -- n )
 654     rot [ = ] curry find-from drop ;
 655
 656 : last-index ( obj seq -- n )
 657     [ = ] with find-last drop ;
 658
 659 : last-index-from ( obj i seq -- n )
 660     rot [ = ] curry find-last-from drop ;
 661
 662 : indices ( obj seq -- indices )
 663     swap [ = ] curry [ swap ] prepose V{ } clone [
 664         [ push ] curry [ [ drop ] if ] curry compose each-index
 665     ] keep ;
 666
 667 <PRIVATE
 668
 669 : nths-unsafe ( indices seq -- seq' )
 670     [ [ nth-unsafe ] curry ] keep map-as ;
 671
 672 PRIVATE>
 673
 674 : nths ( indices seq -- seq' )
 675     [ [ nth ] curry ] keep map-as ;
 676
 677 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 678     find drop >boolean ; inline
 679
 680 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 681     any? not ; inline
 682
 683 : member? ( elt seq -- ? )
 684     [ = ] with any? ;
 685
 686 : member-of? ( seq elt -- ? )
 687     [ = ] curry any? ;
 688
 689 : member-eq? ( elt seq -- ? )
 690     [ eq? ] with any? ;
 691
 692 : member-eq-of? ( seq elt -- ? )
 693     [ eq? ] curry any? ;
 694
 695 : remove ( elt seq -- newseq )
 696     [ = ] with reject ;
 697
 698 : remove-of ( seq elt -- newseq )
 699     [ = ] curry reject ;
 700
 701 : remove-eq ( elt seq -- newseq )
 702     [ eq? ] with reject ;
 703
 704 : remove-eq-of ( seq elt -- newseq )
 705     [ eq? ] curry reject ;
 706
 707 : sift ( seq -- newseq )
 708     [ ] filter ;
 709
 710 : harvest ( seq -- newseq )
 711     [ empty? ] reject ;
 712
 713 <PRIVATE
 714
 715 : mismatch-unsafe ( n seq1 seq2 -- i )
 716     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 717
 718 PRIVATE>
 719
 720 : mismatch ( seq1 seq2 -- i )
 721     [ min-length ] 2keep mismatch-unsafe ;
 722
 723 M: sequence <=>
 724     [ mismatch ] 2keep pick
 725     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 726
 727 : sequence= ( seq1 seq2 -- ? )
 728     2dup [ length ] bi@ dupd =
 729     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 730
 731 ERROR: assert-sequence got expected ;
 732
 733 : assert-sequence= ( a b -- )
 734     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 735
 736 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 737
 738 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 739
 740 <PRIVATE
 741
 742 : sequence-hashcode-step ( oldhash newpart -- newhash )
 743     integer>fixnum swap [
 744         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 745         fixnum+fast fixnum+fast
 746     ] keep fixnum-bitxor ; inline
 747
 748 PRIVATE>
 749
 750 : sequence-hashcode ( n seq -- x )
 751     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 752
 753 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 754
 755 M: iota hashcode*
 756     over 0 <= [ 2drop 0 ] [
 757         nip length 0 swap [ sequence-hashcode-step ] each-integer
 758     ] if ;
 759
 760 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 761
 762 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 763
 764 : move ( to from seq -- )
 765     2over =
 766     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 767
 768 <PRIVATE
 769
 770 : move-unsafe ( to from seq -- )
 771     2over =
 772     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 773
 774 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 775     2dup length < [
 776         [ move-unsafe ] 3keep
 777         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 778         [ 1 + ] dip
 779         (filter!)
 780     ] [ nip set-length drop ] if ; inline recursive
 781
 782 PRIVATE>
 783
 784 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 785     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 786
 787 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 788     negate filter! ; inline
 789
 790 : remove! ( elt seq -- seq )
 791     [ = ] with reject! ;
 792
 793 : remove-eq! ( elt seq -- seq )
 794     [ eq? ] with reject! ;
 795
 796 : prefix ( seq elt -- newseq )
 797     over [ over length 1 + ] dip [
 798         (1sequence) [ 1 swap copy-unsafe ] keep
 799     ] new-like ;
 800
 801 : suffix ( seq elt -- newseq )
 802     over [ over length 1 + ] dip [
 803         [ [ over length ] dip set-nth-unsafe ] keep
 804         [ 0 swap copy-unsafe ] keep
 805     ] new-like ;
 806
 807 : suffix! ( seq elt -- seq ) over push ; inline
 808
 809 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 810
 811 : last ( seq -- elt )
 812     [ length 1 - ] keep
 813     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 814
 815 <PRIVATE
 816
 817 : last-unsafe ( seq -- elt )
 818     [ length 1 - ] [ nth-unsafe ] bi ; inline
 819
 820 PRIVATE>
 821
 822 : set-last ( elt seq -- )
 823     [ length 1 - ] keep
 824     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 825
 826 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 827
 828 <PRIVATE
 829
 830 : move-backward ( shift from to seq -- )
 831     2over = [
 832         4drop
 833     ] [
 834         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 835         move-backward
 836     ] if ;
 837
 838 : move-forward ( shift from to seq -- )
 839     2over = [
 840         4drop
 841     ] [
 842         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 843         move-forward
 844     ] if ;
 845
 846 : (open-slice) ( shift from to seq ? -- )
 847     [
 848         [ [ 1 - ] bi@ ] dip move-forward
 849     ] [
 850         [ over - ] 2dip move-backward
 851     ] if ;
 852
 853 : open-slice ( shift from seq -- )
 854     pick 0 = [
 855         3drop
 856     ] [
 857         [ ] [ nip length + ] [ 2nip ] 3tri
 858         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 859         set-length
 860     ] if ;
 861
 862 PRIVATE>
 863
 864 : delete-slice ( from to seq -- )
 865     check-slice [ over [ - ] dip ] dip open-slice ;
 866
 867 : remove-nth! ( n seq -- seq )
 868     [ [ dup 1 + ] dip delete-slice ] keep ;
 869
 870 : snip ( from to seq -- head tail )
 871     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 872
 873 : snip-slice ( from to seq -- head tail )
 874     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 875
 876 : replace-slice ( new from to seq -- seq' )
 877     snip-slice surround ;
 878
 879 : remove-nth ( n seq -- seq' )
 880     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 881
 882 : pop ( seq -- elt )
 883     [ length 1 - ] keep over 0 >=
 884     [ [ nth-unsafe ] [ shorten ] 2bi ]
 885     [ bounds-error ] if ;
 886
 887 : exchange ( m n seq -- )
 888     [ nip bounds-check 2drop ]
 889     [ bounds-check 3drop ]
 890     [ exchange-unsafe ]
 891     3tri ;
 892
 893 : midpoint@ ( seq -- n ) length 2/ ; inline
 894
 895 : reverse! ( seq -- seq )
 896     [
 897         [ midpoint@ ] [ length ] [ ] tri
 898         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 899         each-integer
 900     ] keep ;
 901
 902 : reverse ( seq -- newseq )
 903      [
 904         dup [ length ] keep new-sequence
 905         [ 0 swap copy-unsafe ] keep reverse!
 906     ] keep like ;
 907
 908 GENERIC: sum-lengths ( seq -- n )
 909
 910 M: object sum-lengths
 911     0 [ length + ] reduce ;
 912
 913 M: repetition sum-lengths
 914     [ length>> ] [ elt>> length ] bi * ;
 915
 916 : concat-as ( seq exemplar -- newseq )
 917     [
 918         [ dup sum-lengths ] dip new-resizable
 919         [ [ push-all ] curry each ] keep
 920     ] keep like ; inline
 921
 922 : concat ( seq -- newseq )
 923     [ { } ] [ dup first concat-as ] if-empty ;
 924
 925 <PRIVATE
 926
 927 : joined-length ( seq glue -- n )
 928     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 929
 930 PRIVATE>
 931
 932 : join-as ( seq glue exemplar -- newseq )
 933     over empty? [ nip concat-as ] [
 934         [
 935             2dup joined-length over new-resizable [
 936                 [ [ push-all ] 2curry ]
 937                 [ nip [ push-all ] curry ] 2bi
 938                 interleave
 939             ] keep
 940         ] dip like
 941     ] if ;
 942
 943 : join ( seq glue -- newseq )
 944     dup join-as ; inline
 945
 946 <PRIVATE
 947
 948 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 949     [
 950         [ over length [-] dup 0 = [ drop ] ] dip
 951         [ <repetition> ] curry
 952     ] dip compose if ; inline
 953
 954 PRIVATE>
 955
 956 : pad-head ( seq n elt -- padded )
 957     [ swap dup append-as ] padding ;
 958
 959 : pad-tail ( seq n elt -- padded )
 960     [ append ] padding ;
 961
 962 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 963 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 964 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 965 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 966
 967 : head? ( seq begin -- ? )
 968     2dup shorter? [
 969         2drop f
 970     ] [
 971         [ length [ head-slice ] keep swap ] keep
 972         mismatch-unsafe not
 973     ] if ;
 974
 975 : tail? ( seq end -- ? )
 976     2dup shorter? [
 977         2drop f
 978     ] [
 979         [ length [ tail-slice* ] keep swap ] keep
 980         mismatch-unsafe not
 981     ] if ;
 982
 983 : cut-slice ( seq n -- before-slice after-slice )
 984     [ head-slice ] [ tail-slice ] 2bi ; inline
 985
 986 : cut-slice* ( seq n -- before-slice after-slice )
 987     [ head-slice* ] [ tail-slice* ] 2bi ;
 988
 989 : insert-nth ( elt n seq -- seq' )
 990     swap cut-slice [ swap suffix ] dip append ;
 991
 992 : halves ( seq -- first-slice second-slice )
 993     dup midpoint@ cut-slice ; inline
 994
 995 <PRIVATE
 996
 997 : nth2-unsafe ( n seq -- a b )
 998     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 999
1000 : nth3-unsafe ( n seq -- a b c )
1001     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1002
1003 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1004     ! We can't use case here since combinators depends on
1005     ! sequences
1006     dup 4 < [
1007         integer>fixnum {
1008             [ 2drop nip ]
1009             [ 2nip swap nth-unsafe ]
1010             [ -rot [ drop swap nth2-unsafe ] dip call ]
1011             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1012         } dispatch
1013     ] [
1014         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1015         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1016         pick [ 3bi ] dip call
1017     ] if ; inline recursive
1018
1019 PRIVATE>
1020
1021 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1022     pick dup slice? [
1023         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1024     ] [
1025         length 0 max 0 swap
1026     ] if (binary-reduce) ; inline
1027
1028 : cut ( seq n -- before after )
1029     [ head ] [ tail ] 2bi ;
1030
1031 : cut* ( seq n -- before after )
1032     [ head* ] [ tail* ] 2bi ;
1033
1034 : subseq-starts-at? ( i seq subseq -- ? )
1035     [ length swap ] keep
1036     '[
1037         [ + _ nth-unsafe ] keep _ nth-unsafe =
1038     ] with all-integers? ; inline
1039
1040 : find-subseq-from ( n seq subseq -- i/f )
1041     [ [ length ] bi@ - 1 + ] 2keep
1042     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1043
1044 : subseq-start-from ( subseq seq n -- i/f ) spin find-subseq-from ; inline
1045
1046 : find-subseq ( seq subseq -- i/f ) [ 0 ] 2dip find-subseq-from ; inline
1047
1048 : find-subseq? ( seq subseq -- ? ) find-subseq >boolean ; inline
1049
1050 : subseq-start ( subseq seq -- i/f ) swap find-subseq ; inline
1051
1052 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline
1053
1054 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1055     2dup mismatch [ 2dup min-length ] unless*
1056     [ tail-slice ] curry bi@ ;
1057
1058 : unclip ( seq -- rest first )
1059     [ rest ] [ first-unsafe ] bi ;
1060
1061 : unclip-last ( seq -- butlast last )
1062     [ but-last ] [ last-unsafe ] bi ;
1063
1064 : unclip-slice ( seq -- rest-slice first )
1065     [ rest-slice ] [ first-unsafe ] bi ; inline
1066
1067 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1068     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1069     '[ swap _ dip swap @ ] 1 each-from ; inline
1070
1071 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1072     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1073     '[ rot _ dip swap @ ] 1 2each-from ; inline
1074
1075 <PRIVATE
1076
1077 : (map-find) ( seq quot find-quot -- result elt )
1078     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1079
1080 PRIVATE>
1081
1082 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1083     [ find ] (map-find) ; inline
1084
1085 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1086     [ find-last ] (map-find) ; inline
1087
1088 : unclip-last-slice ( seq -- butlast-slice last )
1089     [ but-last-slice ] [ last-unsafe ] bi ; inline
1090
1091 <PRIVATE
1092
1093 : (trim-head) ( seq quot -- seq n )
1094     over [ negate find drop ] dip swap
1095     [ dup length ] unless* ; inline
1096
1097 : (trim-tail) ( seq quot -- seq n )
1098     over [ negate find-last drop ?1+ ] dip
1099     swap ; inline
1100
1101 PRIVATE>
1102
1103 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1104     (trim-head) tail-slice ; inline
1105
1106 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1107     (trim-head) tail ; inline
1108
1109 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1110     (trim-tail) head-slice ; inline
1111
1112 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1113     (trim-tail) head ; inline
1114
1115 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1116     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1117
1118 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1119     [ trim-slice ] [ drop ] 2bi like ; inline
1120
1121 GENERIC: sum ( seq -- n )
1122 M: object sum 0 [ + ] binary-reduce ; inline
1123 M: iota sum length dup 1 - * 2/ ; inline
1124 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1125
1126 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1127
1128 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1129
1130 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1131
1132 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1133     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1134
1135 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1136     [ 1 0 ? ] compose map-sum ; inline
1137
1138 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1139     [ with each ] 2curry each ; inline
1140
1141 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1142     [ with { } map-as ] 2curry { } map-as ; inline
1143
1144 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1145     [ 2sequence ] curry cartesian-map ; inline
1146
1147 : cartesian-product ( seq1 seq2 -- newseq )
1148     dup cartesian-product-as ; inline
1149
1150 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1151     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1152
1153 <PRIVATE
1154
1155 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1156     [
1157         [ keep swap ] curry [ [ first ] dip call ] 2keep
1158         [ curry 2dip pick over ] curry
1159     ] [
1160         [ [ 2drop ] [ 2nipd ] if ] compose
1161     ] bi* compose 1 each-from drop ; inline
1162
1163 PRIVATE>
1164
1165 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1166     [ after? ] select-by ; inline
1167
1168 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1169     [ before? ] select-by ; inline
1170
1171 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1172
1173 : longest ( seqs -- elt ) [ length ] supremum-by ;
1174
1175 ! We hand-optimize flip to such a degree because type hints
1176 ! cannot express that an array is an array of arrays yet, and
1177 ! this word happens to be performance-critical since the compiler
1178 ! itself uses it. Optimizing it like this reduced compile time.
1179 <PRIVATE
1180
1181 : generic-flip ( matrix -- newmatrix )
1182     [ [ length ] [ min ] map-reduce ] keep
1183     '[ _ [ nth-unsafe ] with { } map-as ] { } map-integers ; inline
1184
1185 USE: arrays
1186
1187 : array-flip ( matrix -- newmatrix )
1188     { array } declare
1189     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1190     '[ _ [ { array } declare array-nth ] with { } map-as ] { } map-integers ;
1191
1192 PRIVATE>
1193
1194 : flip ( matrix -- newmatrix )
1195     dup empty? [
1196         dup array? [
1197             dup [ array? ] all?
1198             [ array-flip ] [ generic-flip ] if
1199         ] [ generic-flip ] if
1200     ] unless ;