core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition
 265     { length integer read-only }
 266     { elt read-only } ;
 267
 268 : <repetition> ( len elt -- repetition )
 269     over 0 < [ non-negative-integer-expected ] when
 270     repetition boa ; inline
 271
 272 M: repetition length length>> ; inline
 273 M: repetition nth-unsafe nip elt>> ; inline
 274
 275 INSTANCE: repetition immutable-sequence
 276
 277 <PRIVATE
 278
 279 ERROR: integer-length-expected obj ;
 280
 281 ! The check-length call forces partial dispatch
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i integer read-only }
 287     { src read-only }
 288     { dst-i integer read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : copy-nth-unsafe ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 315
 316 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 317     [ subseq>copy (copy) ] dip like ; inline
 318
 319 : subseq-unsafe ( from to seq -- subseq )
 320     dup subseq-unsafe-as ; inline
 321
 322 PRIVATE>
 323
 324 : subseq-as ( from to seq exemplar -- subseq )
 325     [ check-slice ] dip subseq-unsafe-as ;
 326
 327 : subseq ( from to seq -- subseq )
 328     dup subseq-as ;
 329
 330 : head ( seq n -- headseq ) (head) subseq ;
 331
 332 : tail ( seq n -- tailseq ) (tail) subseq ;
 333
 334 : rest ( seq -- tailseq ) 1 tail ;
 335
 336 : head* ( seq n -- headseq ) from-end head ;
 337
 338 : tail* ( seq n -- tailseq ) from-end tail ;
 339
 340 : but-last ( seq -- headseq ) 1 head* ;
 341
 342 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 343
 344 M: sequence clone-like
 345     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 346
 347 M: immutable-sequence clone-like like ; inline
 348
 349 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 350
 351 <PRIVATE
 352
 353 : (append) ( seq1 seq2 accum -- accum )
 354     [ [ over length ] dip copy-unsafe ]
 355     [ 0 swap copy-unsafe ]
 356     [ ] tri ; inline
 357
 358 PRIVATE>
 359
 360 : append-as ( seq1 seq2 exemplar -- newseq )
 361     [ 2dup [ length ] bi@ + ] dip
 362     [ (append) ] new-like ; inline
 363
 364 : append ( seq1 seq2 -- newseq ) over append-as ;
 365
 366 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 367
 368 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 369
 370 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 371     [ 3dup [ length ] tri@ + + ] dip [
 372         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 373         [ (append) ] bi
 374     ] new-like ; inline
 375
 376 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 377
 378 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 379     [ swap ] 2dip 3append-as ; inline
 380
 381 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 382
 383 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 384
 385 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 386
 387 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 388
 389 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 390
 391 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 392     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 393
 394 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 395
 396 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 397
 398 <PRIVATE
 399
 400 : setup-each ( seq -- i n quot )
 401     dup slice? [
 402         [ from>> ] [ to>> ] [ seq>> ] tri
 403     ] [
 404         [ length check-length 0 swap ] keep
 405     ] if [ nth-unsafe ] curry ; inline
 406
 407 : (each) ( seq quot -- i n quot' )
 408     [ setup-each ] dip compose ; inline
 409
 410 : (each-from) ( seq quot i -- i n quot' )
 411     [ (each) ] dip [ + ] curry 2dip ; inline
 412
 413 : (collect) ( quot into -- quot' )
 414     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 415
 416 : collect ( n quot into -- )
 417     (collect) each-integer ; inline
 418
 419 : setup-1each ( seq -- n quot )
 420     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 421
 422 : (1each) ( seq quot -- n quot' )
 423     [ setup-1each ] dip compose ; inline
 424
 425 : (each-index) ( seq quot -- n quot' )
 426     [ setup-1each [ keep ] curry ] dip compose ; inline
 427
 428 : map-into ( seq quot into -- )
 429     [ (1each) ] dip collect ; inline
 430
 431 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 432     [ nth-unsafe ] bi-curry@ bi ; inline
 433
 434 : setup-2each ( seq1 seq2 -- n quot )
 435     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 436
 437 : (2each) ( seq1 seq2 quot -- n quot' )
 438     [ setup-2each ] dip compose ; inline
 439
 440 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 441     [ nth-unsafe ] tri-curry@ tri ; inline
 442
 443 : setup-3each ( seq1 seq2 seq3 -- n quot )
 444     [ [ length ] tri@ min min check-length ]
 445     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 446
 447 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 448     [ setup-3each ] dip compose ; inline
 449
 450 : finish-find ( i seq -- i elt )
 451     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 452
 453 : (find) ( seq quot quot' -- i elt )
 454     pick [ [ (1each) ] dip call ] dip finish-find ; inline
 455
 456 : (find-from) ( n seq quot quot' -- i elt )
 457     [ 2dup bounds-check? ] 2dip
 458     '[ _ _ (find) ] [ 2drop f f ] if ; inline
 459
 460 : (find-index) ( seq quot quot' -- i elt )
 461     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 462
 463 : (find-index-from) ( n seq quot quot' -- i elt )
 464     [ 2dup bounds-check? ] 2dip
 465     '[ _ _ (find-index) ] [ 2drop f f ] if ; inline
 466
 467 : (accumulate) ( seq identity quot -- identity seq quot )
 468     swapd [ keepd ] curry ; inline
 469
 470 : (accumulate*) ( seq identity quot -- identity seq quot )
 471     swapd [ dup ] compose ; inline
 472
 473 PRIVATE>
 474
 475 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 476     (each) (each-integer) ; inline
 477
 478 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 479     (each-from) (each-integer) ; inline
 480
 481 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 482     swapd each ; inline
 483
 484 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 485     overd [ [ collect ] keep ] new-like ; inline
 486
 487 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 488     [ (1each) ] dip map-integers ; inline
 489
 490 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 491     over map-as ; inline
 492
 493 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 494     [ [ drop ] prepose ] dip map-integers ; inline
 495
 496 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 497     { } replicate-as ; inline
 498
 499 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 500     over [ map-into ] keep ; inline
 501
 502 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 503     [ (accumulate) ] dip map-as ; inline
 504
 505 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 506     pick accumulate-as ; inline
 507
 508 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 509     (accumulate) map! ; inline
 510
 511 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 512     [ (accumulate*) ] dip map-as nip ; inline
 513
 514 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 515     pick accumulate*-as ; inline
 516
 517 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 518     (accumulate*) map! nip ; inline
 519
 520 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 521     (2each) each-integer ; inline
 522
 523 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 524     [ (2each) ] dip -rot (each-integer) ; inline
 525
 526 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 527     -rotd 2each ; inline
 528
 529 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 530     [ (2each) ] dip map-integers ; inline
 531
 532 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 533     pick 2map-as ; inline
 534
 535 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 536     (2each) all-integers? ; inline
 537
 538 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 539     [ not ] compose 2all? not ; inline
 540
 541 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 542     (3each) each-integer ; inline
 543
 544 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 545     [ (3each) ] dip map-integers ; inline
 546
 547 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 548     pickd swap 3map-as ; inline
 549
 550 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 551     [ (find-integer) ] (find-from) ; inline
 552
 553 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 554     [ find-integer ] (find) ; inline
 555
 556 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 557     [ nip find-last-integer ] (find-from) ; inline
 558
 559 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 560     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 561
 562 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 563     [ (find-integer) ] (find-index-from) ; inline
 564
 565 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 566     [ find-integer ] (find-index) ; inline
 567
 568 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 569     (each) (all-integers?) ; inline
 570
 571 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 572     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 573
 574 <PRIVATE
 575
 576 : (selector-as) ( quot length exemplar -- selector accum )
 577     new-resizable [ [ push-if ] 2curry ] keep ; inline
 578
 579 PRIVATE>
 580
 581 : selector-as ( quot exemplar -- selector accum )
 582     [ length ] keep (selector-as) ; inline
 583
 584 : selector ( quot -- selector accum )
 585     V{ } selector-as ; inline
 586
 587 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 588     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 589
 590 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 591     over filter-as ; inline
 592
 593 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 594     [ [ not ] compose ] [ filter-as ] bi* ; inline
 595
 596 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 597     over reject-as ; inline
 598
 599 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 600     [ keep swap ] 2dip ? push ; inline
 601
 602 : 2selector ( quot -- selector accum1 accum2 )
 603     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 604
 605 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 606     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 607
 608 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 609     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 610
 611 : collector-as ( quot exemplar -- quot' vec )
 612     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 613
 614 : collector-for ( seq quot -- seq quot' vec )
 615     V{ } collector-for-as ; inline
 616
 617 : collector ( quot -- quot' vec )
 618     V{ } collector-as ; inline
 619
 620 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 621     dup [ collector-as [ while ] dip ] curry dip like ; inline
 622
 623 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 624     { } produce-as ; inline
 625
 626 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 627     [ dup ] swap [ keep ] curry produce nip ; inline
 628
 629 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 630     (each-index) each-integer ; inline
 631
 632 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 633     [ dup length <iota> ] 2dip 2map-as ; inline
 634
 635 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 636     over map-index-as ; inline
 637
 638 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 639     pick empty? [ 3drop ] [
 640         [ [ drop first-unsafe ] dip call ]
 641         [ [ bi* ] 2curry 1 each-from ]
 642         3bi
 643     ] if ; inline
 644
 645 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 646     swapd each-index ; inline
 647
 648 : index ( obj seq -- n )
 649     [ = ] with find drop ;
 650
 651 : index-from ( obj i seq -- n )
 652     rot [ = ] curry find-from drop ;
 653
 654 : last-index ( obj seq -- n )
 655     [ = ] with find-last drop ;
 656
 657 : last-index-from ( obj i seq -- n )
 658     rot [ = ] curry find-last-from drop ;
 659
 660 : indices ( obj seq -- indices )
 661     swap [ = ] curry [ swap ] prepose V{ } clone [
 662         [ push ] curry [ [ drop ] if ] curry compose each-index
 663     ] keep ;
 664
 665 <PRIVATE
 666
 667 : nths-unsafe ( indices seq -- seq' )
 668     [ [ nth-unsafe ] curry ] keep map-as ;
 669
 670 PRIVATE>
 671
 672 : nths ( indices seq -- seq' )
 673     [ [ nth ] curry ] keep map-as ;
 674
 675 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 676     find drop >boolean ; inline
 677
 678 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 679     any? not ; inline
 680
 681 : member? ( elt seq -- ? )
 682     [ = ] with any? ;
 683
 684 : member-eq? ( elt seq -- ? )
 685     [ eq? ] with any? ;
 686
 687 : remove ( elt seq -- newseq )
 688     [ = ] with reject ;
 689
 690 : remove-eq ( elt seq -- newseq )
 691     [ eq? ] with reject ;
 692
 693 : sift ( seq -- newseq )
 694     [ ] filter ;
 695
 696 : harvest ( seq -- newseq )
 697     [ empty? ] reject ;
 698
 699 <PRIVATE
 700
 701 : mismatch-unsafe ( n seq1 seq2 -- i )
 702     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 703
 704 PRIVATE>
 705
 706 : mismatch ( seq1 seq2 -- i )
 707     [ min-length ] 2keep mismatch-unsafe ;
 708
 709 M: sequence <=>
 710     [ mismatch ] 2keep pick
 711     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 712
 713 : sequence= ( seq1 seq2 -- ? )
 714     2dup [ length ] bi@ dupd =
 715     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 716
 717 ERROR: assert-sequence got expected ;
 718
 719 : assert-sequence= ( a b -- )
 720     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 721
 722 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 723
 724 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 725
 726 <PRIVATE
 727
 728 : sequence-hashcode-step ( oldhash newpart -- newhash )
 729     integer>fixnum swap [
 730         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 731         fixnum+fast fixnum+fast
 732     ] keep fixnum-bitxor ; inline
 733
 734 PRIVATE>
 735
 736 : sequence-hashcode ( n seq -- x )
 737     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 738
 739 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 740
 741 M: iota hashcode*
 742     over 0 <= [ 2drop 0 ] [
 743         nip length 0 swap [ sequence-hashcode-step ] each-integer
 744     ] if ;
 745
 746 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 747
 748 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 749
 750 : move ( to from seq -- )
 751     2over =
 752     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 753
 754 <PRIVATE
 755
 756 : move-unsafe ( to from seq -- )
 757     2over =
 758     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 759
 760 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 761     2dup length < [
 762         [ move-unsafe ] 3keep
 763         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 764         [ 1 + ] dip
 765         (filter!)
 766     ] [ nip set-length drop ] if ; inline recursive
 767
 768 PRIVATE>
 769
 770 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 771     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 772
 773 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 774     [ not ] compose filter! ; inline
 775
 776 : remove! ( elt seq -- seq )
 777     [ = ] with reject! ;
 778
 779 : remove-eq! ( elt seq -- seq )
 780     [ eq? ] with reject! ;
 781
 782 : prefix ( seq elt -- newseq )
 783     over [ over length 1 + ] dip [
 784         (1sequence) [ 1 swap copy-unsafe ] keep
 785     ] new-like ;
 786
 787 : suffix ( seq elt -- newseq )
 788     over [ over length 1 + ] dip [
 789         [ [ over length ] dip set-nth-unsafe ] keep
 790         [ 0 swap copy-unsafe ] keep
 791     ] new-like ;
 792
 793 : suffix! ( seq elt -- seq ) over push ; inline
 794
 795 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 796
 797 : last ( seq -- elt )
 798     [ length 1 - ] keep
 799     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 800
 801 <PRIVATE
 802
 803 : last-unsafe ( seq -- elt )
 804     [ length 1 - ] [ nth-unsafe ] bi ; inline
 805
 806 PRIVATE>
 807
 808 : set-last ( elt seq -- )
 809     [ length 1 - ] keep
 810     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 811
 812 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 813
 814 <PRIVATE
 815
 816 : move-backward ( shift from to seq -- )
 817     2over = [
 818         4drop
 819     ] [
 820         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 821         move-backward
 822     ] if ;
 823
 824 : move-forward ( shift from to seq -- )
 825     2over = [
 826         4drop
 827     ] [
 828         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 829         move-forward
 830     ] if ;
 831
 832 : (open-slice) ( shift from to seq ? -- )
 833     [
 834         [ [ 1 - ] bi@ ] dip move-forward
 835     ] [
 836         [ over - ] 2dip move-backward
 837     ] if ;
 838
 839 : open-slice ( shift from seq -- )
 840     pick 0 = [
 841         3drop
 842     ] [
 843         [ ] [ nip length + ] [ 2nip ] 3tri
 844         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 845         set-length
 846     ] if ;
 847
 848 PRIVATE>
 849
 850 : delete-slice ( from to seq -- )
 851     check-slice [ over [ - ] dip ] dip open-slice ;
 852
 853 : remove-nth! ( n seq -- seq )
 854     [ [ dup 1 + ] dip delete-slice ] keep ;
 855
 856 : snip ( from to seq -- head tail )
 857     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 858
 859 : snip-slice ( from to seq -- head tail )
 860     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 861
 862 : replace-slice ( new from to seq -- seq' )
 863     snip-slice surround ;
 864
 865 : remove-nth ( n seq -- seq' )
 866     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 867
 868 : pop ( seq -- elt )
 869     [ length 1 - ] keep over 0 >=
 870     [ [ nth-unsafe ] [ shorten ] 2bi ]
 871     [ bounds-error ] if ;
 872
 873 : exchange ( m n seq -- )
 874     [ nip bounds-check 2drop ]
 875     [ bounds-check 3drop ]
 876     [ exchange-unsafe ]
 877     3tri ;
 878
 879 : midpoint@ ( seq -- n ) length 2/ ; inline
 880
 881 : reverse! ( seq -- seq )
 882     [
 883         [ midpoint@ ] [ length ] [ ] tri
 884         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 885         each-integer
 886     ] keep ;
 887
 888 : reverse ( seq -- newseq )
 889      [
 890         dup [ length ] keep new-sequence
 891         [ 0 swap copy-unsafe ] keep reverse!
 892     ] keep like ;
 893
 894 GENERIC: sum-lengths ( seq -- n )
 895
 896 M: object sum-lengths
 897     0 [ length + ] reduce ;
 898
 899 M: repetition sum-lengths
 900     [ length>> ] [ elt>> length ] bi * ;
 901
 902 : concat-as ( seq exemplar -- newseq )
 903     [
 904         [ dup sum-lengths ] dip new-resizable
 905         [ [ push-all ] curry each ] keep
 906     ] keep like ; inline
 907
 908 : concat ( seq -- newseq )
 909     [ { } ] [ dup first concat-as ] if-empty ;
 910
 911 <PRIVATE
 912
 913 : joined-length ( seq glue -- n )
 914     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 915
 916 PRIVATE>
 917
 918 : join-as ( seq glue exemplar -- newseq )
 919     over empty? [ nip concat-as ] [
 920         [
 921             2dup joined-length over new-resizable [
 922                 [ [ push-all ] 2curry ]
 923                 [ nip [ push-all ] curry ] 2bi
 924                 interleave
 925             ] keep
 926         ] dip like
 927     ] if ;
 928
 929 : join ( seq glue -- newseq )
 930     dup join-as ; inline
 931
 932 <PRIVATE
 933
 934 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 935     [
 936         [ over length [-] dup 0 = [ drop ] ] dip
 937         [ <repetition> ] curry
 938     ] dip compose if ; inline
 939
 940 PRIVATE>
 941
 942 : pad-head ( seq n elt -- padded )
 943     [ swap dup append-as ] padding ;
 944
 945 : pad-tail ( seq n elt -- padded )
 946     [ append ] padding ;
 947
 948 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 949 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 950 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 951 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 952
 953 : head? ( seq begin -- ? )
 954     2dup shorter? [
 955         2drop f
 956     ] [
 957         [ length [ head-slice ] keep swap ] keep
 958         mismatch-unsafe not
 959     ] if ;
 960
 961 : tail? ( seq end -- ? )
 962     2dup shorter? [
 963         2drop f
 964     ] [
 965         [ length [ tail-slice* ] keep swap ] keep
 966         mismatch-unsafe not
 967     ] if ;
 968
 969 : cut-slice ( seq n -- before-slice after-slice )
 970     [ head-slice ] [ tail-slice ] 2bi ; inline
 971
 972 : cut-slice* ( seq n -- before-slice after-slice )
 973     [ head-slice* ] [ tail-slice* ] 2bi ;
 974
 975 : insert-nth ( elt n seq -- seq' )
 976     swap cut-slice [ swap suffix ] dip append ;
 977
 978 : halves ( seq -- first-slice second-slice )
 979     dup midpoint@ cut-slice ; inline
 980
 981 <PRIVATE
 982
 983 : nth2-unsafe ( n seq -- a b )
 984     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 985
 986 : nth3-unsafe ( n seq -- a b c )
 987     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 988
 989 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 990     ! We can't use case here since combinators depends on
 991     ! sequences
 992     dup 4 < [
 993         integer>fixnum {
 994             [ 2drop nip ]
 995             [ 2nip swap nth-unsafe ]
 996             [ -rot [ drop swap nth2-unsafe ] dip call ]
 997             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 998         } dispatch
 999     ] [
1000         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1001         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1002         pick [ 3bi ] dip call
1003     ] if ; inline recursive
1004
1005 PRIVATE>
1006
1007 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1008     pick dup slice? [
1009         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1010     ] [
1011         length 0 max 0 swap
1012     ] if (binary-reduce) ; inline
1013
1014 : cut ( seq n -- before after )
1015     [ head ] [ tail ] 2bi ;
1016
1017 : cut* ( seq n -- before after )
1018     [ head* ] [ tail* ] 2bi ;
1019
1020 <PRIVATE
1021
1022 : (subseq-start-from) ( subseq seq n length -- subseq seq ? )
1023     [
1024         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
1025     ] all-integers? nip ; inline
1026
1027 PRIVATE>
1028
1029 : subseq-start-from ( subseq seq n -- i )
1030     pick length [ pick length swap - 1 + ] keep
1031     [ (subseq-start-from) ] curry (find-integer) 2nip ;
1032
1033 : subseq-start ( subseq seq -- i ) 0 subseq-start-from ; inline
1034
1035 : subseq? ( subseq seq -- ? ) subseq-start >boolean ;
1036
1037 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1038     2dup mismatch [ 2dup min-length ] unless*
1039     [ tail-slice ] curry bi@ ;
1040
1041 : unclip ( seq -- rest first )
1042     [ rest ] [ first-unsafe ] bi ;
1043
1044 : unclip-last ( seq -- butlast last )
1045     [ but-last ] [ last-unsafe ] bi ;
1046
1047 : unclip-slice ( seq -- rest-slice first )
1048     [ rest-slice ] [ first-unsafe ] bi ; inline
1049
1050 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1051     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1052     '[ swap _ dip swap @ ] 1 each-from ; inline
1053
1054 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1055     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1056     '[ rot _ dip swap @ ] 1 2each-from ; inline
1057
1058 <PRIVATE
1059
1060 : (map-find) ( seq quot find-quot -- result elt )
1061     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1062
1063 PRIVATE>
1064
1065 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1066     [ find ] (map-find) ; inline
1067
1068 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1069     [ find-last ] (map-find) ; inline
1070
1071 : unclip-last-slice ( seq -- butlast-slice last )
1072     [ but-last-slice ] [ last-unsafe ] bi ; inline
1073
1074 <PRIVATE
1075
1076 : (trim-head) ( seq quot -- seq n )
1077     over [ [ not ] compose find drop ] dip swap
1078     [ dup length ] unless* ; inline
1079
1080 : (trim-tail) ( seq quot -- seq n )
1081     over [ [ not ] compose find-last drop ?1+ ] dip
1082     swap ; inline
1083
1084 PRIVATE>
1085
1086 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1087     (trim-head) tail-slice ; inline
1088
1089 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1090     (trim-head) tail ; inline
1091
1092 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1093     (trim-tail) head-slice ; inline
1094
1095 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1096     (trim-tail) head ; inline
1097
1098 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1099     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1100
1101 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1102     [ trim-slice ] [ drop ] 2bi like ; inline
1103
1104 GENERIC: sum ( seq -- n )
1105 M: object sum 0 [ + ] binary-reduce ; inline
1106 M: iota sum length dup 1 - * 2/ ; inline
1107 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1108
1109 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1110
1111 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1112
1113 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1114
1115 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1116     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1117
1118 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1119     [ 1 0 ? ] compose map-sum ; inline
1120
1121 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1122     [ with each ] 2curry each ; inline
1123
1124 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1125     [ with { } map-as ] 2curry { } map-as ; inline
1126
1127 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1128     [ 2sequence ] curry cartesian-map ; inline
1129
1130 : cartesian-product ( seq1 seq2 -- newseq )
1131     dup cartesian-product-as ; inline
1132
1133 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1134     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1135
1136 <PRIVATE
1137
1138 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1139     [
1140         [ keep swap ] curry [ [ first ] dip call ] 2keep
1141         [ curry 2dip pick over ] curry
1142     ] [
1143         [ [ 2drop ] [ 2nipd ] if ] compose
1144     ] bi* compose 1 each-from drop ; inline
1145
1146 PRIVATE>
1147
1148 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1149     [ after? ] select-by ; inline
1150
1151 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1152     [ before? ] select-by ; inline
1153
1154 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1155
1156 : longest ( seqs -- elt ) [ length ] supremum-by ;
1157
1158 ! We hand-optimize flip to such a degree because type hints
1159 ! cannot express that an array is an array of arrays yet, and
1160 ! this word happens to be performance-critical since the compiler
1161 ! itself uses it. Optimizing it like this reduced compile time.
1162 <PRIVATE
1163
1164 : generic-flip ( matrix -- newmatrix )
1165     [ [ length ] [ min ] map-reduce ] keep
1166     '[ _ [ nth-unsafe ] with { } map-as ] { } map-integers ; inline
1167
1168 USE: arrays
1169
1170 : array-flip ( matrix -- newmatrix )
1171     { array } declare
1172     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1173     '[ _ [ { array } declare array-nth ] with { } map-as ] { } map-integers ;
1174
1175 PRIVATE>
1176
1177 : flip ( matrix -- newmatrix )
1178     dup empty? [
1179         dup array? [
1180             dup [ array? ] all?
1181             [ array-flip ] [ generic-flip ] if
1182         ] [ generic-flip ] if
1183     ] unless ;