core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC# bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check? ( n seq -- ? )
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota-tuple { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : iota ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota-tuple boa ; inline
 112
 113 M: iota-tuple length n>> ; inline
 114 M: iota-tuple nth-unsafe drop ; inline
 115
 116 INSTANCE: iota-tuple immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition { len read-only } { elt read-only } ;
 265
 266 : <repetition> ( len elt -- repetition )
 267     over 0 < [ non-negative-integer-expected ] when
 268     repetition boa ; inline
 269
 270 M: repetition length len>> ; inline
 271 M: repetition nth-unsafe nip elt>> ; inline
 272
 273 INSTANCE: repetition immutable-sequence
 274
 275 <PRIVATE
 276
 277 ERROR: integer-length-expected obj ;
 278
 279 #! The check-length call forces partial dispatch
 280 : check-length ( n -- n )
 281     dup integer? [ integer-length-expected ] unless ; inline
 282
 283 TUPLE: copy-state
 284     { src-i read-only }
 285     { src read-only }
 286     { dst-i read-only }
 287     { dst read-only } ;
 288
 289 C: <copy> copy-state
 290
 291 : ((copy)) ( n copy -- )
 292     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 293     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 294
 295 : (copy) ( n copy -- dst )
 296     over 0 <= [ nip dst>> ] [
 297         [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi
 298     ] if ; inline recursive
 299
 300 : subseq>copy ( from to seq -- n copy )
 301     [ over - check-length swap ] dip
 302     3dup nip new-sequence 0 swap <copy> ; inline
 303
 304 : bounds-check-head ( n seq -- n seq )
 305     over 0 < [ bounds-error ] when ; inline
 306
 307 : check-copy ( src n dst -- src n dst )
 308     3dup bounds-check-head
 309     [ swap length + ] dip lengthen ; inline
 310
 311 : copy-unsafe ( src i dst -- )
 312     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 313
 314 : subseq-unsafe ( from to seq -- subseq )
 315     [ subseq>copy (copy) ] keep like ;
 316
 317 PRIVATE>
 318
 319 : subseq ( from to seq -- subseq )
 320     [ check-slice subseq>copy (copy) ] keep like ;
 321
 322 : head ( seq n -- headseq ) (head) subseq ;
 323
 324 : tail ( seq n -- tailseq ) (tail) subseq ;
 325
 326 : rest ( seq -- tailseq ) 1 tail ;
 327
 328 : head* ( seq n -- headseq ) from-end head ;
 329
 330 : tail* ( seq n -- tailseq ) from-end tail ;
 331
 332 : but-last ( seq -- headseq ) 1 head* ;
 333
 334 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 335
 336 M: sequence clone-like
 337     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 338
 339 M: immutable-sequence clone-like like ; inline
 340
 341 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 342
 343 <PRIVATE
 344
 345 : (append) ( seq1 seq2 accum -- accum )
 346     [ [ over length ] dip copy-unsafe ]
 347     [ 0 swap copy-unsafe ]
 348     [ ] tri ; inline
 349
 350 PRIVATE>
 351
 352 : append-as ( seq1 seq2 exemplar -- newseq )
 353     [ 2dup [ length ] bi@ + ] dip
 354     [ (append) ] new-like ; inline
 355
 356 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 357     [ 3dup [ length ] tri@ + + ] dip [
 358         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 359         [ (append) ] bi
 360     ] new-like ; inline
 361
 362 : append ( seq1 seq2 -- newseq ) over append-as ;
 363
 364 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 365
 366 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 367
 368 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 369
 370 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 371
 372 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 373
 374 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 375     [ [ nth ] dip call ] 3keep drop set-nth-unsafe ; inline
 376
 377 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 378
 379 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 380
 381 <PRIVATE
 382
 383 : ((each)) ( seq -- n quot )
 384     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 385
 386 : (each) ( seq quot -- n quot' )
 387     [ ((each)) ] dip compose ; inline
 388
 389 : (each-index) ( seq quot -- n quot' )
 390     [ ((each)) [ keep ] curry ] dip compose ; inline
 391
 392 : (collect) ( quot into -- quot' )
 393     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 394
 395 : collect ( n quot into -- )
 396     (collect) each-integer ; inline
 397
 398 : map-into ( seq quot into -- )
 399     [ (each) ] dip collect ; inline
 400
 401 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 402     [ nth-unsafe ] bi-curry@ bi ; inline
 403
 404 : ((2each)) ( seq1 seq2 -- n quot )
 405     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 406
 407 : (2each) ( seq1 seq2 quot -- n quot' )
 408     [ ((2each)) ] dip compose ; inline
 409
 410 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 411     [ nth-unsafe ] tri-curry@ tri ; inline
 412
 413 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 414     [
 415         [ [ length ] tri@ min min check-length ]
 416         [ [ 3nth-unsafe ] 3curry ] 3bi
 417     ] dip compose ; inline
 418
 419 : finish-find ( i seq -- i elt )
 420     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 421
 422 : (find) ( seq quot quot' -- i elt )
 423     pick [ [ (each) ] dip call ] dip finish-find ; inline
 424
 425 : (find-index) ( seq quot quot' -- i elt )
 426     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 427
 428 : (accumulate) ( seq identity quot -- identity seq quot )
 429     swapd [ curry keep ] curry ; inline
 430
 431 PRIVATE>
 432
 433 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 434     (each) each-integer ; inline
 435
 436 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 437     -rot (each) (each-integer) ; inline
 438
 439 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 440     swapd each ; inline
 441
 442 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 443     [ over ] dip [ [ collect ] keep ] new-like ; inline
 444
 445 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 446     [ (each) ] dip map-integers ; inline
 447
 448 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 449     over map-as ; inline
 450
 451 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 452     [ [ drop ] prepose ] dip map-integers ; inline
 453
 454 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 455     { } replicate-as ; inline
 456
 457 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 458     over [ map-into ] keep ; inline
 459
 460 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 461     [ (accumulate) ] dip map-as ; inline
 462
 463 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 464     pick accumulate-as ; inline
 465
 466 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 467     (accumulate) map! ; inline
 468
 469 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 470     (2each) each-integer ; inline
 471
 472 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 473     [ (2each) ] dip -rot (each-integer) ; inline
 474
 475 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 476     [ -rot ] dip 2each ; inline
 477
 478 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 479     [ (2each) ] dip map-integers ; inline
 480
 481 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 482     pick 2map-as ; inline
 483
 484 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 485     (2each) all-integers? ; inline
 486
 487 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 488     (3each) each-integer ; inline
 489
 490 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 491     [ (3each) ] dip map-integers ; inline
 492
 493 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 494     [ pick ] dip swap 3map-as ; inline
 495
 496 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 497     [ (find-integer) ] (find) ; inline
 498
 499 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 500     [ find-integer ] (find) ; inline
 501
 502 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 503     [ nip find-last-integer ] (find) ; inline
 504
 505 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 506     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 507
 508 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 509     [ (find-integer) ] (find-index) ; inline
 510
 511 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 512     [ find-integer ] (find-index) ; inline
 513
 514 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 515     (each) all-integers? ; inline
 516
 517 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 518     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 519
 520 <PRIVATE
 521
 522 : (selector-for) ( quot length exemplar -- selector accum )
 523     new-resizable [ [ push-if ] 2curry ] keep ; inline
 524
 525 PRIVATE>
 526
 527 : selector-for ( quot exemplar -- selector accum )
 528     [ length ] keep (selector-for) ; inline
 529
 530 : selector ( quot -- selector accum )
 531     V{ } selector-for ; inline
 532
 533 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 534     pick length over [ (selector-for) [ each ] dip ] 2curry dip like ; inline
 535
 536 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 537     over filter-as ; inline
 538
 539 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 540     [ [ not ] compose ] [ filter-as ] bi* ; inline
 541
 542 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 543     over reject-as ; inline
 544
 545 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 546     [ keep swap ] 2dip ? push ; inline
 547
 548 : 2selector ( quot -- selector accum1 accum2 )
 549     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 550
 551 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 552     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 553
 554 : collector-for ( quot exemplar -- quot' vec )
 555     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 556
 557 : collector ( quot -- quot' vec )
 558     V{ } collector-for ; inline
 559
 560 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 561     dup [ collector-for [ while ] dip ] curry dip like ; inline
 562
 563 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 564     { } produce-as ; inline
 565
 566 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 567     [ dup ] swap [ keep ] curry produce nip ; inline
 568
 569 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 570     (each-index) each-integer ; inline
 571
 572 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 573     [ dup length iota ] 2dip 2map-as ; inline
 574
 575 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 576     { } map-index-as ; inline
 577
 578 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 579     pick empty? [ 3drop ] [
 580         [ [ drop first-unsafe ] dip call ]
 581         [ [ bi* ] 2curry 1 each-from ]
 582         3bi
 583     ] if ; inline
 584
 585 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 586     swapd each-index ; inline
 587
 588 : index ( obj seq -- n )
 589     [ = ] with find drop ;
 590
 591 : index-from ( obj i seq -- n )
 592     rot [ = ] curry find-from drop ;
 593
 594 : last-index ( obj seq -- n )
 595     [ = ] with find-last drop ;
 596
 597 : last-index-from ( obj i seq -- n )
 598     rot [ = ] curry find-last-from drop ;
 599
 600 <PRIVATE
 601
 602 : (indices) ( elt i obj accum -- )
 603     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 604
 605 PRIVATE>
 606
 607 : indices ( obj seq -- indices )
 608     swap V{ } clone
 609     [ [ (indices) ] 2curry each-index ] keep ;
 610
 611 <PRIVATE
 612
 613 : nths-unsafe ( indices seq -- seq' )
 614     [ [ nth-unsafe ] curry ] keep map-as ;
 615
 616 PRIVATE>
 617
 618 : nths ( indices seq -- seq' )
 619     [ [ nth ] curry ] keep map-as ;
 620
 621 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 622     find drop >boolean ; inline
 623
 624 : member? ( elt seq -- ? )
 625     [ = ] with any? ;
 626
 627 : member-eq? ( elt seq -- ? )
 628     [ eq? ] with any? ;
 629
 630 : remove ( elt seq -- newseq )
 631     [ = ] with reject ;
 632
 633 : remove-eq ( elt seq -- newseq )
 634     [ eq? ] with reject ;
 635
 636 : sift ( seq -- newseq )
 637     [ ] filter ;
 638
 639 : harvest ( seq -- newseq )
 640     [ empty? ] reject ;
 641
 642 <PRIVATE
 643
 644 : mismatch-unsafe ( n seq1 seq2 -- i )
 645     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 646
 647 PRIVATE>
 648
 649 : mismatch ( seq1 seq2 -- i )
 650     [ min-length ] 2keep mismatch-unsafe ; inline
 651
 652 M: sequence <=>
 653     [ mismatch ] 2keep pick
 654     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 655
 656 : sequence= ( seq1 seq2 -- ? )
 657     2dup [ length ] bi@ dupd =
 658     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 659
 660 ERROR: assert-sequence got expected ;
 661
 662 : assert-sequence= ( a b -- )
 663     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 664
 665 <PRIVATE
 666
 667 : sequence-hashcode-step ( oldhash newpart -- newhash )
 668     integer>fixnum swap [
 669         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 670         fixnum+fast fixnum+fast
 671     ] keep fixnum-bitxor ; inline
 672
 673 PRIVATE>
 674
 675 : sequence-hashcode ( n seq -- x )
 676     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 677
 678 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 679
 680 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 681
 682 : move ( to from seq -- )
 683     2over =
 684     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 685
 686 <PRIVATE
 687
 688 : move-unsafe ( to from seq -- )
 689     2over =
 690     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 691
 692 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 693     2dup length < [
 694         [ move-unsafe ] 3keep
 695         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 696         [ 1 + ] dip
 697         (filter!)
 698     ] [ nip set-length drop ] if ; inline recursive
 699
 700 PRIVATE>
 701
 702 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 703     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 704
 705 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 706     [ not ] compose filter! ; inline
 707
 708 : remove! ( elt seq -- seq )
 709     [ = ] with reject! ;
 710
 711 : remove-eq! ( elt seq -- seq )
 712     [ eq? ] with reject! ;
 713
 714 : prefix ( seq elt -- newseq )
 715     over [ over length 1 + ] dip [
 716         (1sequence) [ 1 swap copy-unsafe ] keep
 717     ] new-like ;
 718
 719 : suffix ( seq elt -- newseq )
 720     over [ over length 1 + ] dip [
 721         [ [ over length ] dip set-nth-unsafe ] keep
 722         [ 0 swap copy-unsafe ] keep
 723     ] new-like ;
 724
 725 : suffix! ( seq elt -- seq ) over push ; inline
 726
 727 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 728
 729 : last ( seq -- elt )
 730     [ length 1 - ] keep
 731     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 732
 733 <PRIVATE
 734
 735 : last-unsafe ( seq -- elt )
 736     [ length 1 - ] [ nth-unsafe ] bi ; inline
 737
 738 PRIVATE>
 739
 740 : set-last ( elt seq -- )
 741     [ length 1 - ] keep
 742     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 743
 744 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 745
 746 <PRIVATE
 747
 748 : move-backward ( shift from to seq -- )
 749     2over = [
 750         4drop
 751     ] [
 752         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 753         move-backward
 754     ] if ;
 755
 756 : move-forward ( shift from to seq -- )
 757     2over = [
 758         4drop
 759     ] [
 760         [ [ pick [ dup dup ] dip + swap ] dip move-unsafe 1 - ] keep
 761         move-forward
 762     ] if ;
 763
 764 : (open-slice) ( shift from to seq ? -- )
 765     [
 766         [ [ 1 - ] bi@ ] dip move-forward
 767     ] [
 768         [ over - ] 2dip move-backward
 769     ] if ;
 770
 771 : open-slice ( shift from seq -- )
 772     pick 0 = [
 773         3drop
 774     ] [
 775         pick over length + over
 776         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 777         set-length
 778     ] if ;
 779
 780 PRIVATE>
 781
 782 : delete-slice ( from to seq -- )
 783     check-slice [ over [ - ] dip ] dip open-slice ;
 784
 785 : remove-nth! ( n seq -- seq )
 786     [ [ dup 1 + ] dip delete-slice ] keep ;
 787
 788 : snip ( from to seq -- head tail )
 789     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 790
 791 : snip-slice ( from to seq -- head tail )
 792     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 793
 794 : replace-slice ( new from to seq -- seq' )
 795     snip-slice surround ;
 796
 797 : remove-nth ( n seq -- seq' )
 798     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 799
 800 : pop ( seq -- elt )
 801     [ length 1 - ] keep over 0 >=
 802     [ [ nth-unsafe ] [ shorten ] 2bi ]
 803     [ bounds-error ] if ;
 804
 805 : exchange ( m n seq -- )
 806     [ nip bounds-check 2drop ]
 807     [ bounds-check 3drop ]
 808     [ exchange-unsafe ]
 809     3tri ;
 810
 811 : midpoint@ ( seq -- n ) length 2/ ; inline
 812
 813 : reverse! ( seq -- seq )
 814     [
 815         [ midpoint@ ] [ length ] [ ] tri
 816         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 817         each-integer
 818     ] keep ;
 819
 820 : reverse ( seq -- newseq )
 821      [
 822         dup [ length ] keep new-sequence
 823         [ 0 swap copy-unsafe ] keep reverse!
 824     ] keep like ;
 825
 826 GENERIC: sum-lengths ( seq -- n )
 827
 828 M: object sum-lengths
 829     0 [ length + ] reduce ;
 830
 831 M: repetition sum-lengths
 832     [ len>> ] [ elt>> length ] bi * ;
 833
 834 : concat-as ( seq exemplar -- newseq )
 835     [
 836         [ dup sum-lengths ] dip new-resizable
 837         [ [ push-all ] curry each ] keep
 838     ] keep like ; inline
 839
 840 : concat ( seq -- newseq )
 841     [ { } ] [ dup first concat-as ] if-empty ;
 842
 843 <PRIVATE
 844
 845 : joined-length ( seq glue -- n )
 846     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 847
 848 PRIVATE>
 849
 850 : join-as ( seq glue exemplar -- newseq )
 851     over empty? [ nip concat-as ] [
 852         [
 853             2dup joined-length over new-resizable [
 854                 [ [ push-all ] 2curry ]
 855                 [ nip [ push-all ] curry ] 2bi
 856                 interleave
 857             ] keep
 858         ] dip like
 859     ] if ;
 860
 861 : join ( seq glue -- newseq )
 862     dup join-as ; inline
 863
 864 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 865     [
 866         [ over length [-] dup 0 = [ drop ] ] dip
 867         [ <repetition> ] curry
 868     ] dip compose if ; inline
 869
 870 : pad-head ( seq n elt -- padded )
 871     [ swap dup append-as ] padding ;
 872
 873 : pad-tail ( seq n elt -- padded )
 874     [ append ] padding ;
 875
 876 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 877 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 878 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 879 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 880
 881 : head? ( seq begin -- ? )
 882     2dup shorter? [
 883         2drop f
 884     ] [
 885         [ length [ head-slice ] keep swap ] keep
 886         mismatch-unsafe not
 887     ] if ;
 888
 889 : tail? ( seq end -- ? )
 890     2dup shorter? [
 891         2drop f
 892     ] [
 893         [ length [ tail-slice* ] keep swap ] keep
 894         mismatch-unsafe not
 895     ] if ;
 896
 897 : cut-slice ( seq n -- before-slice after-slice )
 898     [ head-slice ] [ tail-slice ] 2bi ; inline
 899
 900 : insert-nth ( elt n seq -- seq' )
 901     swap cut-slice [ swap suffix ] dip append ;
 902
 903 : halves ( seq -- first-slice second-slice )
 904     dup midpoint@ cut-slice ; inline
 905
 906 <PRIVATE
 907
 908 : nth2-unsafe ( n seq -- a b )
 909     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 910
 911 : nth3-unsafe ( n seq -- a b c )
 912     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 913
 914 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 915     #! We can't use case here since combinators depends on
 916     #! sequences
 917     dup 4 < [
 918         integer>fixnum {
 919             [ 2drop nip ]
 920             [ 2nip swap nth-unsafe ]
 921             [ -rot [ drop swap nth2-unsafe ] dip call ]
 922             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 923         } dispatch
 924     ] [
 925         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 926         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 927         pick [ 3bi ] dip call
 928     ] if ; inline recursive
 929
 930 PRIVATE>
 931
 932 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 933     pick length 0 max 0 swap (binary-reduce) ; inline
 934
 935 : cut ( seq n -- before after )
 936     [ head ] [ tail ] 2bi ;
 937
 938 : cut* ( seq n -- before after )
 939     [ head* ] [ tail* ] 2bi ;
 940
 941 <PRIVATE
 942
 943 : (start) ( subseq seq n length -- subseq seq ? )
 944     [
 945         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 946     ] all-integers? nip ; inline
 947
 948 PRIVATE>
 949
 950 : start* ( subseq seq n -- i )
 951     pick length [ pick length swap - 1 + ] keep
 952     [ (start) ] curry (find-integer) 2nip ;
 953
 954 : start ( subseq seq -- i ) 0 start* ; inline
 955
 956 : subseq? ( subseq seq -- ? ) start >boolean ;
 957
 958 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 959     2dup mismatch [ 2dup min-length ] unless*
 960     [ tail-slice ] curry bi@ ;
 961
 962 : unclip ( seq -- rest first )
 963     [ rest ] [ first-unsafe ] bi ;
 964
 965 : unclip-last ( seq -- butlast last )
 966     [ but-last ] [ last-unsafe ] bi ;
 967
 968 : unclip-slice ( seq -- rest-slice first )
 969     [ rest-slice ] [ first-unsafe ] bi ; inline
 970
 971 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 972     [ [ dup first ] dip [ call ] keep ] dip compose
 973     swapd 1 each-from ; inline
 974
 975 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 976     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 977     [ -rot ] dip 1 2each-from ; inline
 978
 979 <PRIVATE
 980
 981 : (map-find) ( seq quot find-quot -- result elt )
 982     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 983     [ [ drop f ] unless ] dip ; inline
 984
 985 PRIVATE>
 986
 987 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 988     [ find ] (map-find) ; inline
 989
 990 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 991     [ find-last ] (map-find) ; inline
 992
 993 : unclip-last-slice ( seq -- butlast-slice last )
 994     [ but-last-slice ] [ last-unsafe ] bi ; inline
 995
 996 <PRIVATE
 997
 998 : (trim-head) ( seq quot -- seq n )
 999     over [ [ not ] compose find drop ] dip swap
1000     [ dup length ] unless* ; inline
1001
1002 : (trim-tail) ( seq quot -- seq n )
1003     over [ [ not ] compose find-last drop ?1+ ] dip
1004     swap ; inline
1005
1006 PRIVATE>
1007
1008 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1009     (trim-head) tail-slice ; inline
1010
1011 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1012     (trim-head) tail ; inline
1013
1014 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1015     (trim-tail) head-slice ; inline
1016
1017 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1018     (trim-tail) head ; inline
1019
1020 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1021     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1022
1023 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1024     [ trim-slice ] [ drop ] 2bi like ; inline
1025
1026 GENERIC: sum ( seq -- n )
1027 M: object sum 0 [ + ] binary-reduce ; inline
1028 M: iota-tuple sum length dup 1 - * 2/ ; inline
1029 M: repetition sum [ elt>> ] [ len>> ] bi * ; inline
1030
1031 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1032
1033 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1034
1035 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1036
1037 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1038     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1039
1040 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1041     [ 1 0 ? ] compose map-sum ; inline
1042
1043 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1044     [ with each ] 2curry each ; inline
1045
1046 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1047     [ with map ] 2curry map ; inline
1048
1049 : cartesian-product ( seq1 seq2 -- newseq )
1050     [ { } 2sequence ] cartesian-map ;
1051
1052 <PRIVATE
1053
1054 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1055     [
1056         [ keep swap ] curry [ [ first ] dip call ] 2keep
1057         [ curry 2dip pick over ] curry
1058     ] [
1059         [ [ 2drop ] [ [ 2drop ] 2dip ] if ] compose
1060     ] bi* compose 1 each-from drop ; inline
1061
1062 PRIVATE>
1063
1064 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1065     [ after? ] select-by ; inline
1066
1067 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1068     [ before? ] select-by ; inline
1069
1070 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1071
1072 : longest ( seqs -- elt ) [ length ] supremum-by ;
1073
1074 ! We hand-optimize flip to such a degree because type hints
1075 ! cannot express that an array is an array of arrays yet, and
1076 ! this word happens to be performance-critical since the compiler
1077 ! itself uses it. Optimizing it like this reduced compile time.
1078 <PRIVATE
1079
1080 : generic-flip ( matrix -- newmatrix )
1081     [
1082         [ first-unsafe length 1 ] keep
1083         [ length min ] (each) (each-integer) iota
1084     ] keep
1085     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1086
1087 USE: arrays
1088
1089 : array-length ( array -- len )
1090     { array } declare length>> ; inline
1091
1092 : array-flip ( matrix -- newmatrix )
1093     { array } declare
1094     [
1095         [ first-unsafe array-length 1 ] keep
1096         [ array-length min ] (each) (each-integer) iota
1097     ] keep
1098     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1099
1100 PRIVATE>
1101
1102 : flip ( matrix -- newmatrix )
1103     dup empty? [
1104         dup array? [
1105             dup [ array? ] all?
1106             [ array-flip ] [ generic-flip ] if
1107         ] [ generic-flip ] if
1108     ] unless ;