core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC# bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check? ( n seq -- ? )
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota-tuple { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : iota ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota-tuple boa ; inline
 112
 113 M: iota-tuple length n>> ; inline
 114 M: iota-tuple nth-unsafe drop ; inline
 115
 116 INSTANCE: iota-tuple immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217 { from read-only }
 218 { to read-only }
 219 { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq reason ;
 225
 226 : check-slice-error ( from to seq ? string -- from to seq )
 227     [ slice-error ] curry when ; inline
 228
 229 : check-slice ( from to seq -- from to seq )
 230     3dup
 231     [ 2drop 0 < "start < 0" check-slice-error ]
 232     [ [ drop ] 2dip length > "end > sequence" check-slice-error ]
 233     [ drop > "start > end" check-slice-error ]
 234     3tri ; inline
 235
 236 <PRIVATE
 237
 238 : <slice-unsafe> ( from to seq -- slice )
 239     dup slice? [ collapse-slice ] when slice boa ; inline
 240
 241 PRIVATE>
 242
 243 : <slice> ( from to seq -- slice )
 244     check-slice <slice-unsafe> ; inline
 245
 246 M: slice virtual-exemplar seq>> ; inline
 247
 248 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 249
 250 M: slice length [ to>> ] [ from>> ] bi - ; inline
 251
 252 : short ( seq n -- seq n' ) over length min ; inline
 253
 254 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 255
 256 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 257
 258 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 259
 260 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 261
 262 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 263
 264 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 265
 266 INSTANCE: slice virtual-sequence
 267
 268 ! One element repeated many times
 269 TUPLE: repetition { len read-only } { elt read-only } ;
 270
 271 : <repetition> ( len elt -- repetition )
 272     over 0 < [ non-negative-integer-expected ] when
 273     repetition boa ; inline
 274
 275 M: repetition length len>> ; inline
 276 M: repetition nth-unsafe nip elt>> ; inline
 277
 278 INSTANCE: repetition immutable-sequence
 279
 280 <PRIVATE
 281
 282 ERROR: integer-length-expected obj ;
 283
 284 : check-length ( n -- n )
 285     dup integer? [ integer-length-expected ] unless ; inline
 286
 287 TUPLE: copy-state
 288     { src-i read-only }
 289     { src read-only }
 290     { dst-i read-only }
 291     { dst read-only } ;
 292
 293 C: <copy> copy-state
 294
 295 : ((copy)) ( n copy -- )
 296     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 297     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 298
 299 : (copy) ( n copy -- dst )
 300     over 0 <= [ nip dst>> ] [
 301         [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi
 302     ] if ; inline recursive
 303
 304 : subseq>copy ( from to seq -- n copy )
 305     [ over - check-length swap ] dip
 306     3dup nip new-sequence 0 swap <copy> ; inline
 307
 308 : bounds-check-head ( n seq -- n seq )
 309     over 0 < [ bounds-error ] when ; inline
 310
 311 : check-copy ( src n dst -- src n dst )
 312     3dup bounds-check-head
 313     [ swap length + ] dip lengthen ; inline
 314
 315 : copy-unsafe ( src i dst -- )
 316     #! The check-length call forces partial dispatch
 317     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 318
 319 PRIVATE>
 320
 321 : subseq ( from to seq -- subseq )
 322     [ check-slice subseq>copy (copy) ] keep like ;
 323
 324 : head ( seq n -- headseq ) (head) subseq ;
 325
 326 : tail ( seq n -- tailseq ) (tail) subseq ;
 327
 328 : rest ( seq -- tailseq ) 1 tail ;
 329
 330 : head* ( seq n -- headseq ) from-end head ;
 331
 332 : tail* ( seq n -- tailseq ) from-end tail ;
 333
 334 : but-last ( seq -- headseq ) 1 head* ;
 335
 336 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 337
 338 M: sequence clone-like
 339     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 340
 341 M: immutable-sequence clone-like like ; inline
 342
 343 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 344
 345 <PRIVATE
 346
 347 : (append) ( seq1 seq2 accum -- accum )
 348     [ [ over length ] dip copy-unsafe ]
 349     [ 0 swap copy-unsafe ]
 350     [ ] tri ; inline
 351
 352 PRIVATE>
 353
 354 : append-as ( seq1 seq2 exemplar -- newseq )
 355     [ 2dup [ length ] bi@ + ] dip
 356     [ (append) ] new-like ; inline
 357
 358 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 359     [ 3dup [ length ] tri@ + + ] dip [
 360         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 361         [ (append) ] bi
 362     ] new-like ; inline
 363
 364 : append ( seq1 seq2 -- newseq ) over append-as ;
 365
 366 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 367
 368 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 369
 370 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 371
 372 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 373
 374 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 375
 376 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 377     [ [ nth ] dip call ] 3keep drop set-nth-unsafe ; inline
 378
 379 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 380
 381 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 382
 383 <PRIVATE
 384
 385 : ((each)) ( seq -- n quot )
 386     [ length ] keep [ nth-unsafe ] curry ; inline
 387
 388 : (each) ( seq quot -- n quot' )
 389     [ ((each)) ] dip compose ; inline
 390
 391 : (each-index) ( seq quot -- n quot' )
 392     [ ((each)) [ keep ] curry ] dip compose ; inline
 393
 394 : (collect) ( quot into -- quot' )
 395     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 396
 397 : collect ( n quot into -- )
 398     (collect) each-integer ; inline
 399
 400 : map-into ( seq quot into -- )
 401     [ (each) ] dip collect ; inline
 402
 403 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 404     [ nth-unsafe ] bi-curry@ bi ; inline
 405
 406 : ((2each)) ( seq1 seq2 -- n quot )
 407     [ min-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 408
 409 : (2each) ( seq1 seq2 quot -- n quot' )
 410     [ ((2each)) ] dip compose ; inline
 411
 412 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 413     [ nth-unsafe ] tri-curry@ tri ; inline
 414
 415 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 416     [
 417         [ [ length ] tri@ min min ]
 418         [ [ 3nth-unsafe ] 3curry ] 3bi
 419     ] dip compose ; inline
 420
 421 : finish-find ( i seq -- i elt )
 422     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 423
 424 : (find) ( seq quot quot' -- i elt )
 425     pick [ [ (each) ] dip call ] dip finish-find ; inline
 426
 427 : (find-from) ( n seq quot quot' -- i elt )
 428     [ 2dup bounds-check? ] 2dip
 429     [ (find) ] 2curry
 430     [ 2drop f f ]
 431     if ; inline
 432
 433 : (find-index) ( seq quot quot' -- i elt )
 434     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 435
 436 : (find-index-from) ( n seq quot quot' -- i elt )
 437     [ 2dup bounds-check? ] 2dip
 438     [ (find-index) ] 2curry
 439     [ 2drop f f ]
 440     if ; inline
 441
 442 : (accumulate) ( seq identity quot -- identity seq quot )
 443     swapd [ curry keep ] curry ; inline
 444
 445 PRIVATE>
 446
 447 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 448     (each) each-integer ; inline
 449
 450 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 451     swapd each ; inline
 452
 453 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 454     [ over ] dip [ [ collect ] keep ] new-like ; inline
 455
 456 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 457     [ (each) ] dip map-integers ; inline
 458
 459 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 460     over map-as ; inline
 461
 462 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 463     [ [ drop ] prepose ] dip map-integers ; inline
 464
 465 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 466     { } replicate-as ; inline
 467
 468 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 469     over [ map-into ] keep ; inline
 470
 471 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 472     [ (accumulate) ] dip map-as ; inline
 473
 474 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 475     pick accumulate-as ; inline
 476
 477 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 478     (accumulate) map! ; inline
 479
 480 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 481     (2each) each-integer ; inline
 482
 483 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 484     [ -rot ] dip 2each ; inline
 485
 486 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 487     [ (2each) ] dip map-integers ; inline
 488
 489 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 490     pick 2map-as ; inline
 491
 492 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 493     (2each) all-integers? ; inline
 494
 495 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 496     (3each) each-integer ; inline
 497
 498 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 499     [ (3each) ] dip map-integers ; inline
 500
 501 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 502     [ pick ] dip swap 3map-as ; inline
 503
 504 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 505     [ (find-integer) ] (find-from) ; inline
 506
 507 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 508     [ find-integer ] (find) ; inline
 509
 510 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 511     [ nip find-last-integer ] (find-from) ; inline
 512
 513 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 514     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 515
 516 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 517     [ (find-integer) ] (find-index-from) ; inline
 518
 519 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 520     [ find-integer ] (find-index) ; inline
 521
 522 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 523     (each) all-integers? ; inline
 524
 525 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 526     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 527
 528 <PRIVATE
 529
 530 : (selector-for) ( quot length exemplar -- selector accum )
 531     new-resizable [ [ push-if ] 2curry ] keep ; inline
 532
 533 PRIVATE>
 534
 535 : selector-for ( quot exemplar -- selector accum )
 536     [ length ] keep (selector-for) ; inline
 537
 538 : selector ( quot -- selector accum )
 539     V{ } selector-for ; inline
 540
 541 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 542     pick length over [ (selector-for) [ each ] dip ] 2curry dip like ; inline
 543
 544 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 545     over filter-as ; inline
 546
 547 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 548     [ keep swap ] 2dip ? push ; inline
 549
 550 : 2selector ( quot -- selector accum1 accum2 )
 551     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 552
 553 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 554     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 555
 556 : collector-for ( quot exemplar -- quot' vec )
 557     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 558
 559 : collector ( quot -- quot' vec )
 560     V{ } collector-for ; inline
 561
 562 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 563     dup [ collector-for [ while ] dip ] curry dip like ; inline
 564
 565 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 566     { } produce-as ; inline
 567
 568 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 569     [ dup ] swap [ keep ] curry produce nip ; inline
 570
 571 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 572     (each-index) each-integer ; inline
 573
 574 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 575     pick empty? [ 3drop ] [
 576         [ [ drop first-unsafe ] dip call ]
 577         [ [ bi* ] 2curry [ 1 ] 2dip (each) (each-integer) ]
 578         3bi
 579     ] if ; inline
 580
 581 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 582     swapd each-index ; inline
 583
 584 : index ( obj seq -- n )
 585     [ = ] with find drop ;
 586
 587 : index-from ( obj i seq -- n )
 588     rot [ = ] curry find-from drop ;
 589
 590 : last-index ( obj seq -- n )
 591     [ = ] with find-last drop ;
 592
 593 : last-index-from ( obj i seq -- n )
 594     rot [ = ] curry find-last-from drop ;
 595
 596 <PRIVATE
 597
 598 : (indices) ( elt i obj accum -- )
 599     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 600
 601 PRIVATE>
 602
 603 : indices ( obj seq -- indices )
 604     swap V{ } clone
 605     [ [ (indices) ] 2curry each-index ] keep ;
 606
 607 <PRIVATE
 608
 609 : nths-unsafe ( indices seq -- seq' )
 610     [ [ nth-unsafe ] curry ] keep map-as ;
 611
 612 PRIVATE>
 613
 614 : nths ( indices seq -- seq' )
 615     [ [ nth ] curry ] keep map-as ;
 616
 617 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 618     find drop >boolean ; inline
 619
 620 : member? ( elt seq -- ? )
 621     [ = ] with any? ;
 622
 623 : member-eq? ( elt seq -- ? )
 624     [ eq? ] with any? ;
 625
 626 : remove ( elt seq -- newseq )
 627     [ = not ] with filter ;
 628
 629 : remove-eq ( elt seq -- newseq )
 630     [ eq? not ] with filter ;
 631
 632 : sift ( seq -- newseq )
 633     [ ] filter ;
 634
 635 : harvest ( seq -- newseq )
 636     [ empty? not ] filter ;
 637
 638 <PRIVATE
 639
 640 : mismatch-unsafe ( n seq1 seq2 -- i )
 641     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 642
 643 PRIVATE>
 644
 645 : mismatch ( seq1 seq2 -- i )
 646     [ min-length ] 2keep mismatch-unsafe ; inline
 647
 648 M: sequence <=>
 649     [ mismatch ] 2keep pick
 650     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 651
 652 : sequence= ( seq1 seq2 -- ? )
 653     2dup [ length ] bi@ dupd =
 654     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 655
 656 ERROR: assert-sequence got expected ;
 657
 658 : assert-sequence= ( a b -- )
 659     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 660
 661 <PRIVATE
 662
 663 : sequence-hashcode-step ( oldhash newpart -- newhash )
 664     integer>fixnum swap [
 665         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 666         fixnum+fast fixnum+fast
 667     ] keep fixnum-bitxor ; inline
 668
 669 PRIVATE>
 670
 671 : sequence-hashcode ( n seq -- x )
 672     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 673
 674 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 675
 676 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 677
 678 : move ( to from seq -- )
 679     2over =
 680     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 681
 682 <PRIVATE
 683
 684 : move-unsafe ( to from seq -- )
 685     2over =
 686     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 687
 688 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 689     2dup length < [
 690         [ move-unsafe ] 3keep
 691         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 692         [ 1 + ] dip
 693         (filter!)
 694     ] [ nip set-length drop ] if ; inline recursive
 695
 696 PRIVATE>
 697
 698 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 699     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 700
 701 : remove! ( elt seq -- seq )
 702     [ = not ] with filter! ;
 703
 704 : remove-eq! ( elt seq -- seq )
 705     [ eq? not ] with filter! ;
 706
 707 : prefix ( seq elt -- newseq )
 708     over [ over length 1 + ] dip [
 709         (1sequence) [ 1 swap copy-unsafe ] keep
 710     ] new-like ;
 711
 712 : suffix ( seq elt -- newseq )
 713     over [ over length 1 + ] dip [
 714         [ [ over length ] dip set-nth-unsafe ] keep
 715         [ 0 swap copy-unsafe ] keep
 716     ] new-like ;
 717
 718 : suffix! ( seq elt -- seq ) over push ; inline
 719
 720 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 721
 722 : last ( seq -- elt )
 723     [ length 1 - ] keep
 724     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 725
 726 <PRIVATE
 727
 728 : last-unsafe ( seq -- elt )
 729     [ length 1 - ] [ nth-unsafe ] bi ; inline
 730
 731 PRIVATE>
 732
 733 : set-last ( elt seq -- )
 734     [ length 1 - ] keep
 735     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 736
 737 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 738
 739 <PRIVATE
 740
 741 : move-backward ( shift from to seq -- )
 742     2over = [
 743         4drop
 744     ] [
 745         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 746         move-backward
 747     ] if ;
 748
 749 : move-forward ( shift from to seq -- )
 750     2over = [
 751         4drop
 752     ] [
 753         [ [ pick [ dup dup ] dip + swap ] dip move-unsafe 1 - ] keep
 754         move-forward
 755     ] if ;
 756
 757 : (open-slice) ( shift from to seq ? -- )
 758     [
 759         [ [ 1 - ] bi@ ] dip move-forward
 760     ] [
 761         [ over - ] 2dip move-backward
 762     ] if ;
 763
 764 : open-slice ( shift from seq -- )
 765     pick 0 = [
 766         3drop
 767     ] [
 768         pick over length + over
 769         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 770         set-length
 771     ] if ;
 772
 773 PRIVATE>
 774
 775 : delete-slice ( from to seq -- )
 776     check-slice [ over [ - ] dip ] dip open-slice ;
 777
 778 : remove-nth! ( n seq -- seq )
 779     [ [ dup 1 + ] dip delete-slice ] keep ;
 780
 781 : snip ( from to seq -- head tail )
 782     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 783
 784 : snip-slice ( from to seq -- head tail )
 785     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 786
 787 : replace-slice ( new from to seq -- seq' )
 788     snip-slice surround ;
 789
 790 : remove-nth ( n seq -- seq' )
 791     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 792
 793 : pop ( seq -- elt )
 794     [ length 1 - ] keep over 0 >=
 795     [ [ nth-unsafe ] [ shorten ] 2bi ]
 796     [ bounds-error ] if ;
 797
 798 : exchange ( m n seq -- )
 799     [ nip bounds-check 2drop ]
 800     [ bounds-check 3drop ]
 801     [ exchange-unsafe ]
 802     3tri ;
 803
 804 : midpoint@ ( seq -- n ) length 2/ ; inline
 805
 806 : reverse! ( seq -- seq )
 807     [
 808         [ midpoint@ ] [ length ] [ ] tri
 809         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 810         each-integer
 811     ] keep ;
 812
 813 : reverse ( seq -- newseq )
 814      [
 815         dup [ length ] keep new-sequence
 816         [ 0 swap copy-unsafe ] keep reverse!
 817     ] keep like ;
 818
 819 GENERIC: sum-lengths ( seq -- n )
 820
 821 M: object sum-lengths
 822     0 [ length + ] reduce ;
 823
 824 M: repetition sum-lengths
 825     [ len>> ] [ elt>> length ] bi * ;
 826
 827 : concat-as ( seq exemplar -- newseq )
 828     swap [ { } ] [
 829         [ sum-lengths over new-resizable ] keep
 830         [ append! ] each
 831     ] if-empty swap like ;
 832
 833 : concat ( seq -- newseq )
 834     [ { } ] [ dup first concat-as ] if-empty ;
 835
 836 <PRIVATE
 837
 838 : joined-length ( seq glue -- n )
 839     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 840
 841 PRIVATE>
 842
 843 : join-as ( seq glue exemplar -- newseq )
 844     over empty? [ nip concat-as ] [
 845         [
 846             2dup joined-length over new-resizable [
 847                 [ [ push-all ] 2curry ]
 848                 [ nip [ push-all ] curry ] 2bi
 849                 interleave
 850             ] keep
 851         ] dip like
 852     ] if ;
 853
 854 : join ( seq glue -- newseq )
 855     dup join-as ; inline
 856
 857 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 858     [
 859         [ over length [-] dup 0 = [ drop ] ] dip
 860         [ <repetition> ] curry
 861     ] dip compose if ; inline
 862
 863 : pad-head ( seq n elt -- padded )
 864     [ swap dup append-as ] padding ;
 865
 866 : pad-tail ( seq n elt -- padded )
 867     [ append ] padding ;
 868
 869 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 870 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 871 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 872 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 873
 874 : head? ( seq begin -- ? )
 875     2dup shorter? [
 876         2drop f
 877     ] [
 878         [ length [ head-slice ] keep swap ] keep
 879         mismatch-unsafe not
 880     ] if ;
 881
 882 : tail? ( seq end -- ? )
 883     2dup shorter? [
 884         2drop f
 885     ] [
 886         [ length [ tail-slice* ] keep swap ] keep
 887         mismatch-unsafe not
 888     ] if ;
 889
 890 : cut-slice ( seq n -- before-slice after-slice )
 891     [ head-slice ] [ tail-slice ] 2bi ; inline
 892
 893 : insert-nth ( elt n seq -- seq' )
 894     swap cut-slice [ swap suffix ] dip append ;
 895
 896 : halves ( seq -- first-slice second-slice )
 897     dup midpoint@ cut-slice ; inline
 898
 899 <PRIVATE
 900
 901 : nth2-unsafe ( n seq -- a b )
 902     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 903
 904 : nth3-unsafe ( n seq -- a b c )
 905     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 906
 907 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 908     #! We can't use case here since combinators depends on
 909     #! sequences
 910     dup 4 < [
 911         integer>fixnum {
 912             [ 2drop nip ]
 913             [ 2nip swap nth-unsafe ]
 914             [ -rot [ drop swap nth2-unsafe ] dip call ]
 915             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 916         } dispatch
 917     ] [
 918         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 919         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 920         pick [ 3bi ] dip call
 921     ] if ; inline recursive
 922
 923 PRIVATE>
 924
 925 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 926     pick length 0 max 0 swap (binary-reduce) ; inline
 927
 928 : cut ( seq n -- before after )
 929     [ head ] [ tail ] 2bi ;
 930
 931 : cut* ( seq n -- before after )
 932     [ head* ] [ tail* ] 2bi ;
 933
 934 <PRIVATE
 935
 936 : (start) ( subseq seq n length -- subseq seq ? )
 937     [
 938         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 939     ] all-integers? nip ; inline
 940
 941 PRIVATE>
 942
 943 : start* ( subseq seq n -- i )
 944     pick length [ pick length swap - 1 + ] keep
 945     [ (start) ] curry (find-integer) 2nip ;
 946
 947 : start ( subseq seq -- i ) 0 start* ; inline
 948
 949 : subseq? ( subseq seq -- ? ) start >boolean ;
 950
 951 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 952     2dup mismatch [ 2dup min-length ] unless*
 953     [ tail-slice ] curry bi@ ;
 954
 955 : unclip ( seq -- rest first )
 956     [ rest ] [ first-unsafe ] bi ;
 957
 958 : unclip-last ( seq -- butlast last )
 959     [ but-last ] [ last-unsafe ] bi ;
 960
 961 : unclip-slice ( seq -- rest-slice first )
 962     [ rest-slice ] [ first-unsafe ] bi ; inline
 963
 964 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 965     [ [ dup first ] dip [ call ] keep ] dip compose
 966     swapd [ 1 ] 2dip (each) (each-integer) ; inline
 967
 968 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 969     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 970     [ -rot ] dip [ 1 ] 3dip (2each) (each-integer) ; inline
 971
 972 <PRIVATE
 973
 974 : (map-find) ( seq quot find-quot -- result elt )
 975     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 976     [ [ drop f ] unless ] dip ; inline
 977
 978 PRIVATE>
 979
 980 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 981     [ find ] (map-find) ; inline
 982
 983 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 984     [ find-last ] (map-find) ; inline
 985
 986 : unclip-last-slice ( seq -- butlast-slice last )
 987     [ but-last-slice ] [ last-unsafe ] bi ; inline
 988
 989 <PRIVATE
 990
 991 : (trim-head) ( seq quot -- seq n )
 992     over [ [ not ] compose find drop ] dip swap
 993     [ dup length ] unless* ; inline
 994
 995 : (trim-tail) ( seq quot -- seq n )
 996     over [ [ not ] compose find-last drop ?1+ ] dip
 997     swap ; inline
 998
 999 PRIVATE>
1000
1001 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1002     (trim-head) tail-slice ; inline
1003
1004 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1005     (trim-head) tail ; inline
1006
1007 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1008     (trim-tail) head-slice ; inline
1009
1010 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1011     (trim-tail) head ; inline
1012
1013 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1014     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1015
1016 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1017     [ trim-slice ] [ drop ] 2bi like ; inline
1018
1019 GENERIC: sum ( seq -- n )
1020 M: object sum 0 [ + ] binary-reduce ; inline
1021 M: iota-tuple sum length dup 1 - * 2/ ; inline
1022 M: repetition sum [ elt>> ] [ len>> ] bi * ; inline
1023
1024 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1025
1026 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
1027
1028 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
1029
1030 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1031     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1032
1033 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1034     [ 1 0 ? ] compose map-sum ; inline
1035
1036 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1037     [ with each ] 2curry each ; inline
1038
1039 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1040     [ with map ] 2curry map ; inline
1041
1042 : cartesian-product ( seq1 seq2 -- newseq )
1043     [ { } 2sequence ] cartesian-map ;
1044
1045 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
1046     -rot (each) (each-integer) ; inline
1047
1048 <PRIVATE
1049
1050 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1051     [
1052         [ keep swap ] curry [ [ first ] dip call ] 2keep
1053         [ curry 2dip pick over ] curry
1054     ] [
1055         [ [ 2drop ] [ [ 2drop ] 2dip ] if ] compose
1056     ] bi* compose 1 each-from drop ; inline
1057
1058 PRIVATE>
1059
1060 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1061     [ after? ] select-by ; inline
1062
1063 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1064     [ before? ] select-by ; inline
1065
1066 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1067
1068 : longest ( seqs -- elt ) [ length ] supremum-by ;
1069
1070 ! We hand-optimize flip to such a degree because type hints
1071 ! cannot express that an array is an array of arrays yet, and
1072 ! this word happens to be performance-critical since the compiler
1073 ! itself uses it. Optimizing it like this reduced compile time.
1074 <PRIVATE
1075
1076 : generic-flip ( matrix -- newmatrix )
1077     [
1078         [ first-unsafe length 1 ] keep
1079         [ length min ] (each) (each-integer) iota
1080     ] keep
1081     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1082
1083 USE: arrays
1084
1085 : array-length ( array -- len )
1086     { array } declare length>> ; inline
1087
1088 : array-flip ( matrix -- newmatrix )
1089     { array } declare
1090     [
1091         [ first-unsafe array-length 1 ] keep
1092         [ array-length min ] (each) (each-integer) iota
1093     ] keep
1094     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1095
1096 PRIVATE>
1097
1098 : flip ( matrix -- newmatrix )
1099     dup empty? [
1100         dup array? [
1101             dup [ array? ] all?
1102             [ array-flip ] [ generic-flip ] if
1103         ] [ generic-flip ] if
1104     ] unless ;