core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC# bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check? ( n seq -- ? )
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota-tuple { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : iota ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota-tuple boa ; inline
 112
 113 M: iota-tuple length n>> ; inline
 114 M: iota-tuple nth-unsafe drop ; inline
 115
 116 INSTANCE: iota-tuple immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition { len read-only } { elt read-only } ;
 265
 266 : <repetition> ( len elt -- repetition )
 267     over 0 < [ non-negative-integer-expected ] when
 268     repetition boa ; inline
 269
 270 M: repetition length len>> ; inline
 271 M: repetition nth-unsafe nip elt>> ; inline
 272
 273 INSTANCE: repetition immutable-sequence
 274
 275 <PRIVATE
 276
 277 ERROR: integer-length-expected obj ;
 278
 279 : check-length ( n -- n )
 280     dup integer? [ integer-length-expected ] unless ; inline
 281
 282 TUPLE: copy-state
 283     { src-i read-only }
 284     { src read-only }
 285     { dst-i read-only }
 286     { dst read-only } ;
 287
 288 C: <copy> copy-state
 289
 290 : ((copy)) ( n copy -- )
 291     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 292     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 293
 294 : (copy) ( n copy -- dst )
 295     over 0 <= [ nip dst>> ] [
 296         [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi
 297     ] if ; inline recursive
 298
 299 : subseq>copy ( from to seq -- n copy )
 300     [ over - check-length swap ] dip
 301     3dup nip new-sequence 0 swap <copy> ; inline
 302
 303 : bounds-check-head ( n seq -- n seq )
 304     over 0 < [ bounds-error ] when ; inline
 305
 306 : check-copy ( src n dst -- src n dst )
 307     3dup bounds-check-head
 308     [ swap length + ] dip lengthen ; inline
 309
 310 : copy-unsafe ( src i dst -- )
 311     #! The check-length call forces partial dispatch
 312     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 313
 314 : subseq-unsafe ( from to seq -- subseq )
 315     [ subseq>copy (copy) ] keep like ;
 316
 317 PRIVATE>
 318
 319 : subseq ( from to seq -- subseq )
 320     [ check-slice subseq>copy (copy) ] keep like ;
 321
 322 : head ( seq n -- headseq ) (head) subseq ;
 323
 324 : tail ( seq n -- tailseq ) (tail) subseq ;
 325
 326 : rest ( seq -- tailseq ) 1 tail ;
 327
 328 : head* ( seq n -- headseq ) from-end head ;
 329
 330 : tail* ( seq n -- tailseq ) from-end tail ;
 331
 332 : but-last ( seq -- headseq ) 1 head* ;
 333
 334 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 335
 336 M: sequence clone-like
 337     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 338
 339 M: immutable-sequence clone-like like ; inline
 340
 341 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 342
 343 <PRIVATE
 344
 345 : (append) ( seq1 seq2 accum -- accum )
 346     [ [ over length ] dip copy-unsafe ]
 347     [ 0 swap copy-unsafe ]
 348     [ ] tri ; inline
 349
 350 PRIVATE>
 351
 352 : append-as ( seq1 seq2 exemplar -- newseq )
 353     [ 2dup [ length ] bi@ + ] dip
 354     [ (append) ] new-like ; inline
 355
 356 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 357     [ 3dup [ length ] tri@ + + ] dip [
 358         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 359         [ (append) ] bi
 360     ] new-like ; inline
 361
 362 : append ( seq1 seq2 -- newseq ) over append-as ;
 363
 364 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 365
 366 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 367
 368 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 369
 370 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 371
 372 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 373
 374 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 375     [ [ nth ] dip call ] 3keep drop set-nth-unsafe ; inline
 376
 377 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 378
 379 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 380
 381 <PRIVATE
 382
 383 : ((each)) ( seq -- n quot )
 384     [ length ] keep [ nth-unsafe ] curry ; inline
 385
 386 : (each) ( seq quot -- n quot' )
 387     [ ((each)) ] dip compose ; inline
 388
 389 : (each-index) ( seq quot -- n quot' )
 390     [ ((each)) [ keep ] curry ] dip compose ; inline
 391
 392 : (collect) ( quot into -- quot' )
 393     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 394
 395 : collect ( n quot into -- )
 396     (collect) each-integer ; inline
 397
 398 : map-into ( seq quot into -- )
 399     [ (each) ] dip collect ; inline
 400
 401 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 402     [ nth-unsafe ] bi-curry@ bi ; inline
 403
 404 : ((2each)) ( seq1 seq2 -- n quot )
 405     [ min-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 406
 407 : (2each) ( seq1 seq2 quot -- n quot' )
 408     [ ((2each)) ] dip compose ; inline
 409
 410 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 411     [ nth-unsafe ] tri-curry@ tri ; inline
 412
 413 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 414     [
 415         [ [ length ] tri@ min min ]
 416         [ [ 3nth-unsafe ] 3curry ] 3bi
 417     ] dip compose ; inline
 418
 419 : finish-find ( i seq -- i elt )
 420     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 421
 422 : (find) ( seq quot quot' -- i elt )
 423     pick [ [ (each) ] dip call ] dip finish-find ; inline
 424
 425 : (find-index) ( seq quot quot' -- i elt )
 426     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 427
 428 : (accumulate) ( seq identity quot -- identity seq quot )
 429     swapd [ curry keep ] curry ; inline
 430
 431 PRIVATE>
 432
 433 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 434     (each) each-integer ; inline
 435
 436 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 437     swapd each ; inline
 438
 439 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 440     [ over ] dip [ [ collect ] keep ] new-like ; inline
 441
 442 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 443     [ (each) ] dip map-integers ; inline
 444
 445 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 446     over map-as ; inline
 447
 448 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 449     [ [ drop ] prepose ] dip map-integers ; inline
 450
 451 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 452     { } replicate-as ; inline
 453
 454 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 455     over [ map-into ] keep ; inline
 456
 457 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 458     [ (accumulate) ] dip map-as ; inline
 459
 460 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 461     pick accumulate-as ; inline
 462
 463 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 464     (accumulate) map! ; inline
 465
 466 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 467     (2each) each-integer ; inline
 468
 469 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 470     [ -rot ] dip 2each ; inline
 471
 472 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 473     [ (2each) ] dip map-integers ; inline
 474
 475 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 476     pick 2map-as ; inline
 477
 478 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 479     (2each) all-integers? ; inline
 480
 481 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 482     (3each) each-integer ; inline
 483
 484 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 485     [ (3each) ] dip map-integers ; inline
 486
 487 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 488     [ pick ] dip swap 3map-as ; inline
 489
 490 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 491     [ (find-integer) ] (find) ; inline
 492
 493 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 494     [ find-integer ] (find) ; inline
 495
 496 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 497     [ nip find-last-integer ] (find) ; inline
 498
 499 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 500     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 501
 502 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 503     [ (find-integer) ] (find-index) ; inline
 504
 505 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 506     [ find-integer ] (find-index) ; inline
 507
 508 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 509     (each) all-integers? ; inline
 510
 511 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 512     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 513
 514 <PRIVATE
 515
 516 : (selector-for) ( quot length exemplar -- selector accum )
 517     new-resizable [ [ push-if ] 2curry ] keep ; inline
 518
 519 PRIVATE>
 520
 521 : selector-for ( quot exemplar -- selector accum )
 522     [ length ] keep (selector-for) ; inline
 523
 524 : selector ( quot -- selector accum )
 525     V{ } selector-for ; inline
 526
 527 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 528     pick length over [ (selector-for) [ each ] dip ] 2curry dip like ; inline
 529
 530 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 531     over filter-as ; inline
 532
 533 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 534     [ [ not ] compose ] [ filter-as ] bi* ; inline
 535
 536 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 537     over reject-as ; inline
 538
 539 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 540     [ keep swap ] 2dip ? push ; inline
 541
 542 : 2selector ( quot -- selector accum1 accum2 )
 543     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 544
 545 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 546     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 547
 548 : collector-for ( quot exemplar -- quot' vec )
 549     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 550
 551 : collector ( quot -- quot' vec )
 552     V{ } collector-for ; inline
 553
 554 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 555     dup [ collector-for [ while ] dip ] curry dip like ; inline
 556
 557 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 558     { } produce-as ; inline
 559
 560 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 561     [ dup ] swap [ keep ] curry produce nip ; inline
 562
 563 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 564     (each-index) each-integer ; inline
 565
 566 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 567     [ dup length iota ] 2dip 2map-as ; inline
 568
 569 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 570     { } map-index-as ; inline
 571
 572 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 573     pick empty? [ 3drop ] [
 574         [ [ drop first-unsafe ] dip call ]
 575         [ [ bi* ] 2curry [ 1 ] 2dip (each) (each-integer) ]
 576         3bi
 577     ] if ; inline
 578
 579 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 580     swapd each-index ; inline
 581
 582 : index ( obj seq -- n )
 583     [ = ] with find drop ;
 584
 585 : index-from ( obj i seq -- n )
 586     rot [ = ] curry find-from drop ;
 587
 588 : last-index ( obj seq -- n )
 589     [ = ] with find-last drop ;
 590
 591 : last-index-from ( obj i seq -- n )
 592     rot [ = ] curry find-last-from drop ;
 593
 594 <PRIVATE
 595
 596 : (indices) ( elt i obj accum -- )
 597     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 598
 599 PRIVATE>
 600
 601 : indices ( obj seq -- indices )
 602     swap V{ } clone
 603     [ [ (indices) ] 2curry each-index ] keep ;
 604
 605 <PRIVATE
 606
 607 : nths-unsafe ( indices seq -- seq' )
 608     [ [ nth-unsafe ] curry ] keep map-as ;
 609
 610 PRIVATE>
 611
 612 : nths ( indices seq -- seq' )
 613     [ [ nth ] curry ] keep map-as ;
 614
 615 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 616     find drop >boolean ; inline
 617
 618 : member? ( elt seq -- ? )
 619     [ = ] with any? ;
 620
 621 : member-eq? ( elt seq -- ? )
 622     [ eq? ] with any? ;
 623
 624 : remove ( elt seq -- newseq )
 625     [ = ] with reject ;
 626
 627 : remove-eq ( elt seq -- newseq )
 628     [ eq? ] with reject ;
 629
 630 : sift ( seq -- newseq )
 631     [ ] filter ;
 632
 633 : harvest ( seq -- newseq )
 634     [ empty? ] reject ;
 635
 636 <PRIVATE
 637
 638 : mismatch-unsafe ( n seq1 seq2 -- i )
 639     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 640
 641 PRIVATE>
 642
 643 : mismatch ( seq1 seq2 -- i )
 644     [ min-length ] 2keep mismatch-unsafe ; inline
 645
 646 M: sequence <=>
 647     [ mismatch ] 2keep pick
 648     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 649
 650 : sequence= ( seq1 seq2 -- ? )
 651     2dup [ length ] bi@ dupd =
 652     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 653
 654 ERROR: assert-sequence got expected ;
 655
 656 : assert-sequence= ( a b -- )
 657     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 658
 659 <PRIVATE
 660
 661 : sequence-hashcode-step ( oldhash newpart -- newhash )
 662     integer>fixnum swap [
 663         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 664         fixnum+fast fixnum+fast
 665     ] keep fixnum-bitxor ; inline
 666
 667 PRIVATE>
 668
 669 : sequence-hashcode ( n seq -- x )
 670     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 671
 672 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 673
 674 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 675
 676 : move ( to from seq -- )
 677     2over =
 678     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 679
 680 <PRIVATE
 681
 682 : move-unsafe ( to from seq -- )
 683     2over =
 684     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 685
 686 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 687     2dup length < [
 688         [ move-unsafe ] 3keep
 689         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 690         [ 1 + ] dip
 691         (filter!)
 692     ] [ nip set-length drop ] if ; inline recursive
 693
 694 PRIVATE>
 695
 696 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 697     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 698
 699 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 700     [ not ] compose filter! ; inline
 701
 702 : remove! ( elt seq -- seq )
 703     [ = ] with reject! ;
 704
 705 : remove-eq! ( elt seq -- seq )
 706     [ eq? ] with reject! ;
 707
 708 : prefix ( seq elt -- newseq )
 709     over [ over length 1 + ] dip [
 710         (1sequence) [ 1 swap copy-unsafe ] keep
 711     ] new-like ;
 712
 713 : suffix ( seq elt -- newseq )
 714     over [ over length 1 + ] dip [
 715         [ [ over length ] dip set-nth-unsafe ] keep
 716         [ 0 swap copy-unsafe ] keep
 717     ] new-like ;
 718
 719 : suffix! ( seq elt -- seq ) over push ; inline
 720
 721 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 722
 723 : last ( seq -- elt )
 724     [ length 1 - ] keep
 725     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 726
 727 <PRIVATE
 728
 729 : last-unsafe ( seq -- elt )
 730     [ length 1 - ] [ nth-unsafe ] bi ; inline
 731
 732 PRIVATE>
 733
 734 : set-last ( elt seq -- )
 735     [ length 1 - ] keep
 736     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 737
 738 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 739
 740 <PRIVATE
 741
 742 : move-backward ( shift from to seq -- )
 743     2over = [
 744         4drop
 745     ] [
 746         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 747         move-backward
 748     ] if ;
 749
 750 : move-forward ( shift from to seq -- )
 751     2over = [
 752         4drop
 753     ] [
 754         [ [ pick [ dup dup ] dip + swap ] dip move-unsafe 1 - ] keep
 755         move-forward
 756     ] if ;
 757
 758 : (open-slice) ( shift from to seq ? -- )
 759     [
 760         [ [ 1 - ] bi@ ] dip move-forward
 761     ] [
 762         [ over - ] 2dip move-backward
 763     ] if ;
 764
 765 : open-slice ( shift from seq -- )
 766     pick 0 = [
 767         3drop
 768     ] [
 769         pick over length + over
 770         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 771         set-length
 772     ] if ;
 773
 774 PRIVATE>
 775
 776 : delete-slice ( from to seq -- )
 777     check-slice [ over [ - ] dip ] dip open-slice ;
 778
 779 : remove-nth! ( n seq -- seq )
 780     [ [ dup 1 + ] dip delete-slice ] keep ;
 781
 782 : snip ( from to seq -- head tail )
 783     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 784
 785 : snip-slice ( from to seq -- head tail )
 786     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 787
 788 : replace-slice ( new from to seq -- seq' )
 789     snip-slice surround ;
 790
 791 : remove-nth ( n seq -- seq' )
 792     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 793
 794 : pop ( seq -- elt )
 795     [ length 1 - ] keep over 0 >=
 796     [ [ nth-unsafe ] [ shorten ] 2bi ]
 797     [ bounds-error ] if ;
 798
 799 : exchange ( m n seq -- )
 800     [ nip bounds-check 2drop ]
 801     [ bounds-check 3drop ]
 802     [ exchange-unsafe ]
 803     3tri ;
 804
 805 : midpoint@ ( seq -- n ) length 2/ ; inline
 806
 807 : reverse! ( seq -- seq )
 808     [
 809         [ midpoint@ ] [ length ] [ ] tri
 810         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 811         each-integer
 812     ] keep ;
 813
 814 : reverse ( seq -- newseq )
 815      [
 816         dup [ length ] keep new-sequence
 817         [ 0 swap copy-unsafe ] keep reverse!
 818     ] keep like ;
 819
 820 GENERIC: sum-lengths ( seq -- n )
 821
 822 M: object sum-lengths
 823     0 [ length + ] reduce ;
 824
 825 M: repetition sum-lengths
 826     [ len>> ] [ elt>> length ] bi * ;
 827
 828 : concat-as ( seq exemplar -- newseq )
 829     [
 830         [ dup sum-lengths ] dip new-resizable
 831         [ [ push-all ] curry each ] keep
 832     ] keep like ; inline
 833
 834 : concat ( seq -- newseq )
 835     [ { } ] [ dup first concat-as ] if-empty ;
 836
 837 <PRIVATE
 838
 839 : joined-length ( seq glue -- n )
 840     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 841
 842 PRIVATE>
 843
 844 : join-as ( seq glue exemplar -- newseq )
 845     over empty? [ nip concat-as ] [
 846         [
 847             2dup joined-length over new-resizable [
 848                 [ [ push-all ] 2curry ]
 849                 [ nip [ push-all ] curry ] 2bi
 850                 interleave
 851             ] keep
 852         ] dip like
 853     ] if ;
 854
 855 : join ( seq glue -- newseq )
 856     dup join-as ; inline
 857
 858 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 859     [
 860         [ over length [-] dup 0 = [ drop ] ] dip
 861         [ <repetition> ] curry
 862     ] dip compose if ; inline
 863
 864 : pad-head ( seq n elt -- padded )
 865     [ swap dup append-as ] padding ;
 866
 867 : pad-tail ( seq n elt -- padded )
 868     [ append ] padding ;
 869
 870 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 871 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 872 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 873 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 874
 875 : head? ( seq begin -- ? )
 876     2dup shorter? [
 877         2drop f
 878     ] [
 879         [ length [ head-slice ] keep swap ] keep
 880         mismatch-unsafe not
 881     ] if ;
 882
 883 : tail? ( seq end -- ? )
 884     2dup shorter? [
 885         2drop f
 886     ] [
 887         [ length [ tail-slice* ] keep swap ] keep
 888         mismatch-unsafe not
 889     ] if ;
 890
 891 : cut-slice ( seq n -- before-slice after-slice )
 892     [ head-slice ] [ tail-slice ] 2bi ; inline
 893
 894 : insert-nth ( elt n seq -- seq' )
 895     swap cut-slice [ swap suffix ] dip append ;
 896
 897 : halves ( seq -- first-slice second-slice )
 898     dup midpoint@ cut-slice ; inline
 899
 900 <PRIVATE
 901
 902 : nth2-unsafe ( n seq -- a b )
 903     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 904
 905 : nth3-unsafe ( n seq -- a b c )
 906     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 907
 908 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 909     #! We can't use case here since combinators depends on
 910     #! sequences
 911     dup 4 < [
 912         integer>fixnum {
 913             [ 2drop nip ]
 914             [ 2nip swap nth-unsafe ]
 915             [ -rot [ drop swap nth2-unsafe ] dip call ]
 916             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 917         } dispatch
 918     ] [
 919         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 920         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 921         pick [ 3bi ] dip call
 922     ] if ; inline recursive
 923
 924 PRIVATE>
 925
 926 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 927     pick length 0 max 0 swap (binary-reduce) ; inline
 928
 929 : cut ( seq n -- before after )
 930     [ head ] [ tail ] 2bi ;
 931
 932 : cut* ( seq n -- before after )
 933     [ head* ] [ tail* ] 2bi ;
 934
 935 <PRIVATE
 936
 937 : (start) ( subseq seq n length -- subseq seq ? )
 938     [
 939         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 940     ] all-integers? nip ; inline
 941
 942 PRIVATE>
 943
 944 : start* ( subseq seq n -- i )
 945     pick length [ pick length swap - 1 + ] keep
 946     [ (start) ] curry (find-integer) 2nip ;
 947
 948 : start ( subseq seq -- i ) 0 start* ; inline
 949
 950 : subseq? ( subseq seq -- ? ) start >boolean ;
 951
 952 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 953     2dup mismatch [ 2dup min-length ] unless*
 954     [ tail-slice ] curry bi@ ;
 955
 956 : unclip ( seq -- rest first )
 957     [ rest ] [ first-unsafe ] bi ;
 958
 959 : unclip-last ( seq -- butlast last )
 960     [ but-last ] [ last-unsafe ] bi ;
 961
 962 : unclip-slice ( seq -- rest-slice first )
 963     [ rest-slice ] [ first-unsafe ] bi ; inline
 964
 965 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 966     [ [ dup first ] dip [ call ] keep ] dip compose
 967     swapd [ 1 ] 2dip (each) (each-integer) ; inline
 968
 969 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 970     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 971     [ -rot ] dip [ 1 ] 3dip (2each) (each-integer) ; inline
 972
 973 <PRIVATE
 974
 975 : (map-find) ( seq quot find-quot -- result elt )
 976     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 977     [ [ drop f ] unless ] dip ; inline
 978
 979 PRIVATE>
 980
 981 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 982     [ find ] (map-find) ; inline
 983
 984 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 985     [ find-last ] (map-find) ; inline
 986
 987 : unclip-last-slice ( seq -- butlast-slice last )
 988     [ but-last-slice ] [ last-unsafe ] bi ; inline
 989
 990 <PRIVATE
 991
 992 : (trim-head) ( seq quot -- seq n )
 993     over [ [ not ] compose find drop ] dip swap
 994     [ dup length ] unless* ; inline
 995
 996 : (trim-tail) ( seq quot -- seq n )
 997     over [ [ not ] compose find-last drop ?1+ ] dip
 998     swap ; inline
 999
1000 PRIVATE>
1001
1002 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1003     (trim-head) tail-slice ; inline
1004
1005 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1006     (trim-head) tail ; inline
1007
1008 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1009     (trim-tail) head-slice ; inline
1010
1011 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1012     (trim-tail) head ; inline
1013
1014 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1015     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1016
1017 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1018     [ trim-slice ] [ drop ] 2bi like ; inline
1019
1020 GENERIC: sum ( seq -- n )
1021 M: object sum 0 [ + ] binary-reduce ; inline
1022 M: iota-tuple sum length dup 1 - * 2/ ; inline
1023 M: repetition sum [ elt>> ] [ len>> ] bi * ; inline
1024
1025 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1026
1027 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1028
1029 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1030
1031 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1032     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1033
1034 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1035     [ 1 0 ? ] compose map-sum ; inline
1036
1037 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1038     [ with each ] 2curry each ; inline
1039
1040 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1041     [ with map ] 2curry map ; inline
1042
1043 : cartesian-product ( seq1 seq2 -- newseq )
1044     [ { } 2sequence ] cartesian-map ;
1045
1046 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
1047     -rot (each) (each-integer) ; inline
1048
1049 <PRIVATE
1050
1051 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1052     [
1053         [ keep swap ] curry [ [ first ] dip call ] 2keep
1054         [ curry 2dip pick over ] curry
1055     ] [
1056         [ [ 2drop ] [ [ 2drop ] 2dip ] if ] compose
1057     ] bi* compose 1 each-from drop ; inline
1058
1059 PRIVATE>
1060
1061 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1062     [ after? ] select-by ; inline
1063
1064 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1065     [ before? ] select-by ; inline
1066
1067 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1068
1069 : longest ( seqs -- elt ) [ length ] supremum-by ;
1070
1071 ! We hand-optimize flip to such a degree because type hints
1072 ! cannot express that an array is an array of arrays yet, and
1073 ! this word happens to be performance-critical since the compiler
1074 ! itself uses it. Optimizing it like this reduced compile time.
1075 <PRIVATE
1076
1077 : generic-flip ( matrix -- newmatrix )
1078     [
1079         [ first-unsafe length 1 ] keep
1080         [ length min ] (each) (each-integer) iota
1081     ] keep
1082     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1083
1084 USE: arrays
1085
1086 : array-length ( array -- len )
1087     { array } declare length>> ; inline
1088
1089 : array-flip ( matrix -- newmatrix )
1090     { array } declare
1091     [
1092         [ first-unsafe array-length 1 ] keep
1093         [ array-length min ] (each) (each-integer) iota
1094     ] keep
1095     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1096
1097 PRIVATE>
1098
1099 : flip ( matrix -- newmatrix )
1100     dup empty? [
1101         dup array? [
1102             dup [ array? ] all?
1103             [ array-flip ] [ generic-flip ] if
1104         ] [ generic-flip ] if
1105     ] unless ;