core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition
 265     { length integer read-only }
 266     { elt read-only } ;
 267
 268 : <repetition> ( len elt -- repetition )
 269     over 0 < [ non-negative-integer-expected ] when
 270     repetition boa ; inline
 271
 272 M: repetition length length>> ; inline
 273 M: repetition nth-unsafe nip elt>> ; inline
 274
 275 INSTANCE: repetition immutable-sequence
 276
 277 <PRIVATE
 278
 279 ERROR: integer-length-expected obj ;
 280
 281 ! The check-length call forces partial dispatch
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i integer read-only }
 287     { src read-only }
 288     { dst-i integer read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : copy-nth-unsafe ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 315
 316 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 317     [ subseq>copy (copy) ] dip like ; inline
 318
 319 : subseq-unsafe ( from to seq -- subseq )
 320     dup subseq-unsafe-as ; inline
 321
 322 PRIVATE>
 323
 324 : subseq-as ( from to seq exemplar -- subseq )
 325     [ check-slice ] dip subseq-unsafe-as ;
 326
 327 : subseq ( from to seq -- subseq )
 328     dup subseq-as ;
 329
 330 : head ( seq n -- headseq ) (head) subseq ;
 331
 332 : tail ( seq n -- tailseq ) (tail) subseq ;
 333
 334 : rest ( seq -- tailseq ) 1 tail ;
 335
 336 : head* ( seq n -- headseq ) from-end head ;
 337
 338 : tail* ( seq n -- tailseq ) from-end tail ;
 339
 340 : but-last ( seq -- headseq ) 1 head* ;
 341
 342 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 343
 344 M: sequence clone-like
 345     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 346
 347 M: immutable-sequence clone-like like ; inline
 348
 349 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 350
 351 <PRIVATE
 352
 353 : (append) ( seq1 seq2 accum -- accum )
 354     [ [ over length ] dip copy-unsafe ]
 355     [ 0 swap copy-unsafe ]
 356     [ ] tri ; inline
 357
 358 PRIVATE>
 359
 360 : append-as ( seq1 seq2 exemplar -- newseq )
 361     [ 2dup [ length ] bi@ + ] dip
 362     [ (append) ] new-like ; inline
 363
 364 : append ( seq1 seq2 -- newseq ) over append-as ;
 365
 366 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 367
 368 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 369
 370 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 371     [ 3dup [ length ] tri@ + + ] dip [
 372         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 373         [ (append) ] bi
 374     ] new-like ; inline
 375
 376 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 377
 378 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 379     [ swap ] 2dip 3append-as ; inline
 380
 381 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 382
 383 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 384
 385 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 386
 387 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 388
 389 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 390
 391 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 392     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 393
 394 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 395
 396 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 397
 398 <PRIVATE
 399
 400 : setup-each ( seq -- i n quot )
 401     dup slice? [
 402         [ from>> ] [ to>> ] [ seq>> ] tri
 403     ] [
 404         [ length check-length 0 swap ] keep
 405     ] if [ nth-unsafe ] curry ; inline
 406
 407 : (each) ( seq quot -- i n quot' )
 408     [ setup-each ] dip compose ; inline
 409
 410 : (each-from) ( seq quot i -- i n quot' )
 411     [ (each) ] dip [ + ] curry 2dip ; inline
 412
 413 : (collect) ( quot into -- quot' )
 414     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 415
 416 : collect ( n quot into -- )
 417     (collect) each-integer ; inline
 418
 419 : setup-1each ( seq -- n quot )
 420     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 421
 422 : (1each) ( seq quot -- n quot' )
 423     [ setup-1each ] dip compose ; inline
 424
 425 : (each-index) ( seq quot -- n quot' )
 426     [ setup-1each [ keep ] curry ] dip compose ; inline
 427
 428 : map-into ( seq quot into -- )
 429     [ (1each) ] dip collect ; inline
 430
 431 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 432     [ nth-unsafe ] bi-curry@ bi ; inline
 433
 434 : setup-2each ( seq1 seq2 -- n quot )
 435     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 436
 437 : (2each) ( seq1 seq2 quot -- n quot' )
 438     [ setup-2each ] dip compose ; inline
 439
 440 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 441     [ nth-unsafe ] tri-curry@ tri ; inline
 442
 443 : setup-3each ( seq1 seq2 seq3 -- n quot )
 444     [ [ length ] tri@ min min check-length ]
 445     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 446
 447 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 448     [ setup-3each ] dip compose ; inline
 449
 450 : finish-find ( i seq -- i elt )
 451     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 452
 453 : (find) ( seq quot quot' -- i elt )
 454     pick [ [ (1each) ] dip call ] dip finish-find ; inline
 455
 456 : (find-from) ( n seq quot quot' -- i elt )
 457     [ 2dup bounds-check? ] 2dip
 458     '[ _ _ (find) ] [ 2drop f f ] if ; inline
 459
 460 : (find-index) ( seq quot quot' -- i elt )
 461     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 462
 463 : (find-index-from) ( n seq quot quot' -- i elt )
 464     [ 2dup bounds-check? ] 2dip
 465     '[ _ _ (find-index) ] [ 2drop f f ] if ; inline
 466
 467 : (accumulate) ( seq identity quot -- identity seq quot )
 468     swapd [ keepd ] curry ; inline
 469
 470 : (accumulate*) ( seq identity quot -- identity seq quot )
 471     swapd [ dup ] compose ; inline
 472
 473 PRIVATE>
 474
 475 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 476     (each) each-integer-from ; inline
 477
 478 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 479     (each-from) each-integer-from ; inline
 480
 481 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 482     swapd each ; inline
 483
 484 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 485     overd [ [ collect ] keep ] new-like ; inline
 486
 487 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 488     [ (1each) ] dip map-integers ; inline
 489
 490 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 491     over map-as ; inline
 492
 493 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 494     [ [ drop ] prepose ] dip map-integers ; inline
 495
 496 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 497     { } replicate-as ; inline
 498
 499 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 500     over [ map-into ] keep ; inline
 501
 502 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 503     [ (accumulate) ] dip map-as ; inline
 504
 505 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 506     pick accumulate-as ; inline
 507
 508 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 509     (accumulate) map! ; inline
 510
 511 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 512     [ (accumulate*) ] dip map-as nip ; inline
 513
 514 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 515     pick accumulate*-as ; inline
 516
 517 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 518     (accumulate*) map! nip ; inline
 519
 520 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 521     (2each) each-integer ; inline
 522
 523 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 524     [ (2each) ] dip -rot each-integer-from ; inline
 525
 526 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 527     -rotd 2each ; inline
 528
 529 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 530     [ (2each) ] dip map-integers ; inline
 531
 532 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 533     pick 2map-as ; inline
 534
 535 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 536     (2each) all-integers? ; inline
 537
 538 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 539     [ not ] compose 2all? not ; inline
 540
 541 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 542     (3each) each-integer ; inline
 543
 544 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 545     [ (3each) ] dip map-integers ; inline
 546
 547 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 548     pickd swap 3map-as ; inline
 549
 550 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 551     [ find-integer-from ] (find-from) ; inline
 552
 553 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 554     [ find-integer ] (find) ; inline
 555
 556 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 557     [ nip find-last-integer ] (find-from) ; inline
 558
 559 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 560     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 561
 562 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 563     [ find-integer-from ] (find-index-from) ; inline
 564
 565 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 566     [ find-integer ] (find-index) ; inline
 567
 568 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 569     (each) all-integers-from? ; inline
 570
 571 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 572     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 573
 574 <PRIVATE
 575
 576 : (selector-as) ( quot length exemplar -- selector accum )
 577     new-resizable [ [ push-if ] 2curry ] keep ; inline
 578
 579 PRIVATE>
 580
 581 : selector-as ( quot exemplar -- selector accum )
 582     [ length ] keep (selector-as) ; inline
 583
 584 : selector ( quot -- selector accum )
 585     V{ } selector-as ; inline
 586
 587 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 588     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 589
 590 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 591     over filter-as ; inline
 592
 593 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 594     [ [ not ] compose ] [ filter-as ] bi* ; inline
 595
 596 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 597     over reject-as ; inline
 598
 599 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 600     [ keep swap ] 2dip ? push ; inline
 601
 602 : 2selector ( quot -- selector accum1 accum2 )
 603     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 604
 605 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 606     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 607
 608 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 609     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 610
 611 : collector-as ( quot exemplar -- quot' vec )
 612     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 613
 614 : collector-for ( seq quot -- seq quot' vec )
 615     V{ } collector-for-as ; inline
 616
 617 : collector ( quot -- quot' vec )
 618     V{ } collector-as ; inline
 619
 620 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 621     dup [ collector-as [ while ] dip ] curry dip like ; inline
 622
 623 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 624     { } produce-as ; inline
 625
 626 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 627     [ dup ] swap [ keep ] curry produce nip ; inline
 628
 629 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 630     (each-index) each-integer ; inline
 631
 632 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 633     [ dup length <iota> ] 2dip 2map-as ; inline
 634
 635 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 636     over map-index-as ; inline
 637
 638 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 639     pick empty? [ 3drop ] [
 640         [ [ drop first-unsafe ] dip call ]
 641         [ [ bi* ] 2curry 1 each-from ]
 642         3bi
 643     ] if ; inline
 644
 645 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 646     swapd each-index ; inline
 647
 648 : index ( obj seq -- n )
 649     [ = ] with find drop ;
 650
 651 : index-from ( obj i seq -- n )
 652     rot [ = ] curry find-from drop ;
 653
 654 : last-index ( obj seq -- n )
 655     [ = ] with find-last drop ;
 656
 657 : last-index-from ( obj i seq -- n )
 658     rot [ = ] curry find-last-from drop ;
 659
 660 : indices ( obj seq -- indices )
 661     swap [ = ] curry [ swap ] prepose V{ } clone [
 662         [ push ] curry [ [ drop ] if ] curry compose each-index
 663     ] keep ;
 664
 665 <PRIVATE
 666
 667 : nths-unsafe ( indices seq -- seq' )
 668     [ [ nth-unsafe ] curry ] keep map-as ;
 669
 670 PRIVATE>
 671
 672 : nths ( indices seq -- seq' )
 673     [ [ nth ] curry ] keep map-as ;
 674
 675 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 676     find drop >boolean ; inline
 677
 678 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 679     any? not ; inline
 680
 681 : member? ( elt seq -- ? )
 682     [ = ] with any? ;
 683
 684 : member-of? ( seq elt -- ? )
 685     [ = ] curry any? ;
 686
 687 : member-eq? ( elt seq -- ? )
 688     [ eq? ] with any? ;
 689
 690 : member-eq-of? ( seq elt -- ? )
 691     [ eq? ] curry any? ;
 692
 693 : remove ( elt seq -- newseq )
 694     [ = ] with reject ;
 695
 696 : remove-of ( seq elt -- newseq )
 697     [ = ] curry reject ;
 698
 699 : remove-eq ( elt seq -- newseq )
 700     [ eq? ] with reject ;
 701
 702 : remove-eq-of ( seq elt -- newseq )
 703     [ eq? ] curry reject ;
 704
 705 : sift ( seq -- newseq )
 706     [ ] filter ;
 707
 708 : harvest ( seq -- newseq )
 709     [ empty? ] reject ;
 710
 711 <PRIVATE
 712
 713 : mismatch-unsafe ( n seq1 seq2 -- i )
 714     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 715
 716 PRIVATE>
 717
 718 : mismatch ( seq1 seq2 -- i )
 719     [ min-length ] 2keep mismatch-unsafe ;
 720
 721 M: sequence <=>
 722     [ mismatch ] 2keep pick
 723     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 724
 725 : sequence= ( seq1 seq2 -- ? )
 726     2dup [ length ] bi@ dupd =
 727     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 728
 729 ERROR: assert-sequence got expected ;
 730
 731 : assert-sequence= ( a b -- )
 732     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 733
 734 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 735
 736 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 737
 738 <PRIVATE
 739
 740 : sequence-hashcode-step ( oldhash newpart -- newhash )
 741     integer>fixnum swap [
 742         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 743         fixnum+fast fixnum+fast
 744     ] keep fixnum-bitxor ; inline
 745
 746 PRIVATE>
 747
 748 : sequence-hashcode ( n seq -- x )
 749     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 750
 751 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 752
 753 M: iota hashcode*
 754     over 0 <= [ 2drop 0 ] [
 755         nip length 0 swap [ sequence-hashcode-step ] each-integer
 756     ] if ;
 757
 758 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 759
 760 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 761
 762 : move ( to from seq -- )
 763     2over =
 764     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 765
 766 <PRIVATE
 767
 768 : move-unsafe ( to from seq -- )
 769     2over =
 770     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 771
 772 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 773     2dup length < [
 774         [ move-unsafe ] 3keep
 775         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 776         [ 1 + ] dip
 777         (filter!)
 778     ] [ nip set-length drop ] if ; inline recursive
 779
 780 PRIVATE>
 781
 782 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 783     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 784
 785 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 786     [ not ] compose filter! ; inline
 787
 788 : remove! ( elt seq -- seq )
 789     [ = ] with reject! ;
 790
 791 : remove-eq! ( elt seq -- seq )
 792     [ eq? ] with reject! ;
 793
 794 : prefix ( seq elt -- newseq )
 795     over [ over length 1 + ] dip [
 796         (1sequence) [ 1 swap copy-unsafe ] keep
 797     ] new-like ;
 798
 799 : suffix ( seq elt -- newseq )
 800     over [ over length 1 + ] dip [
 801         [ [ over length ] dip set-nth-unsafe ] keep
 802         [ 0 swap copy-unsafe ] keep
 803     ] new-like ;
 804
 805 : suffix! ( seq elt -- seq ) over push ; inline
 806
 807 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 808
 809 : last ( seq -- elt )
 810     [ length 1 - ] keep
 811     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 812
 813 <PRIVATE
 814
 815 : last-unsafe ( seq -- elt )
 816     [ length 1 - ] [ nth-unsafe ] bi ; inline
 817
 818 PRIVATE>
 819
 820 : set-last ( elt seq -- )
 821     [ length 1 - ] keep
 822     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 823
 824 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 825
 826 <PRIVATE
 827
 828 : move-backward ( shift from to seq -- )
 829     2over = [
 830         4drop
 831     ] [
 832         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 833         move-backward
 834     ] if ;
 835
 836 : move-forward ( shift from to seq -- )
 837     2over = [
 838         4drop
 839     ] [
 840         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 841         move-forward
 842     ] if ;
 843
 844 : (open-slice) ( shift from to seq ? -- )
 845     [
 846         [ [ 1 - ] bi@ ] dip move-forward
 847     ] [
 848         [ over - ] 2dip move-backward
 849     ] if ;
 850
 851 : open-slice ( shift from seq -- )
 852     pick 0 = [
 853         3drop
 854     ] [
 855         [ ] [ nip length + ] [ 2nip ] 3tri
 856         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 857         set-length
 858     ] if ;
 859
 860 PRIVATE>
 861
 862 : delete-slice ( from to seq -- )
 863     check-slice [ over [ - ] dip ] dip open-slice ;
 864
 865 : remove-nth! ( n seq -- seq )
 866     [ [ dup 1 + ] dip delete-slice ] keep ;
 867
 868 : snip ( from to seq -- head tail )
 869     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 870
 871 : snip-slice ( from to seq -- head tail )
 872     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 873
 874 : replace-slice ( new from to seq -- seq' )
 875     snip-slice surround ;
 876
 877 : remove-nth ( n seq -- seq' )
 878     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 879
 880 : pop ( seq -- elt )
 881     [ length 1 - ] keep over 0 >=
 882     [ [ nth-unsafe ] [ shorten ] 2bi ]
 883     [ bounds-error ] if ;
 884
 885 : exchange ( m n seq -- )
 886     [ nip bounds-check 2drop ]
 887     [ bounds-check 3drop ]
 888     [ exchange-unsafe ]
 889     3tri ;
 890
 891 : midpoint@ ( seq -- n ) length 2/ ; inline
 892
 893 : reverse! ( seq -- seq )
 894     [
 895         [ midpoint@ ] [ length ] [ ] tri
 896         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 897         each-integer
 898     ] keep ;
 899
 900 : reverse ( seq -- newseq )
 901      [
 902         dup [ length ] keep new-sequence
 903         [ 0 swap copy-unsafe ] keep reverse!
 904     ] keep like ;
 905
 906 GENERIC: sum-lengths ( seq -- n )
 907
 908 M: object sum-lengths
 909     0 [ length + ] reduce ;
 910
 911 M: repetition sum-lengths
 912     [ length>> ] [ elt>> length ] bi * ;
 913
 914 : concat-as ( seq exemplar -- newseq )
 915     [
 916         [ dup sum-lengths ] dip new-resizable
 917         [ [ push-all ] curry each ] keep
 918     ] keep like ; inline
 919
 920 : concat ( seq -- newseq )
 921     [ { } ] [ dup first concat-as ] if-empty ;
 922
 923 <PRIVATE
 924
 925 : joined-length ( seq glue -- n )
 926     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 927
 928 PRIVATE>
 929
 930 : join-as ( seq glue exemplar -- newseq )
 931     over empty? [ nip concat-as ] [
 932         [
 933             2dup joined-length over new-resizable [
 934                 [ [ push-all ] 2curry ]
 935                 [ nip [ push-all ] curry ] 2bi
 936                 interleave
 937             ] keep
 938         ] dip like
 939     ] if ;
 940
 941 : join ( seq glue -- newseq )
 942     dup join-as ; inline
 943
 944 <PRIVATE
 945
 946 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 947     [
 948         [ over length [-] dup 0 = [ drop ] ] dip
 949         [ <repetition> ] curry
 950     ] dip compose if ; inline
 951
 952 PRIVATE>
 953
 954 : pad-head ( seq n elt -- padded )
 955     [ swap dup append-as ] padding ;
 956
 957 : pad-tail ( seq n elt -- padded )
 958     [ append ] padding ;
 959
 960 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 961 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 962 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 963 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 964
 965 : head? ( seq begin -- ? )
 966     2dup shorter? [
 967         2drop f
 968     ] [
 969         [ length [ head-slice ] keep swap ] keep
 970         mismatch-unsafe not
 971     ] if ;
 972
 973 : tail? ( seq end -- ? )
 974     2dup shorter? [
 975         2drop f
 976     ] [
 977         [ length [ tail-slice* ] keep swap ] keep
 978         mismatch-unsafe not
 979     ] if ;
 980
 981 : cut-slice ( seq n -- before-slice after-slice )
 982     [ head-slice ] [ tail-slice ] 2bi ; inline
 983
 984 : cut-slice* ( seq n -- before-slice after-slice )
 985     [ head-slice* ] [ tail-slice* ] 2bi ;
 986
 987 : insert-nth ( elt n seq -- seq' )
 988     swap cut-slice [ swap suffix ] dip append ;
 989
 990 : halves ( seq -- first-slice second-slice )
 991     dup midpoint@ cut-slice ; inline
 992
 993 <PRIVATE
 994
 995 : nth2-unsafe ( n seq -- a b )
 996     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 997
 998 : nth3-unsafe ( n seq -- a b c )
 999     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1000
1001 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1002     ! We can't use case here since combinators depends on
1003     ! sequences
1004     dup 4 < [
1005         integer>fixnum {
1006             [ 2drop nip ]
1007             [ 2nip swap nth-unsafe ]
1008             [ -rot [ drop swap nth2-unsafe ] dip call ]
1009             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1010         } dispatch
1011     ] [
1012         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1013         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1014         pick [ 3bi ] dip call
1015     ] if ; inline recursive
1016
1017 PRIVATE>
1018
1019 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1020     pick dup slice? [
1021         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1022     ] [
1023         length 0 max 0 swap
1024     ] if (binary-reduce) ; inline
1025
1026 : cut ( seq n -- before after )
1027     [ head ] [ tail ] 2bi ;
1028
1029 : cut* ( seq n -- before after )
1030     [ head* ] [ tail* ] 2bi ;
1031
1032 : subseq-starts-at? ( i seq subseq -- ? )
1033     [ length swap ] keep
1034     '[
1035         [ + _ nth-unsafe ] keep _ nth-unsafe =
1036     ] with all-integers? ; inline
1037
1038 : find-subseq-from ( n seq subseq -- i/f )
1039     [ [ length ] bi@ - 1 + ] 2keep
1040     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1041
1042 : subseq-start-from ( subseq seq n -- i/f ) spin find-subseq-from ; inline
1043
1044 : find-subseq ( seq subseq -- i/f ) [ 0 ] 2dip find-subseq-from ; inline
1045
1046 : find-subseq? ( seq subseq -- ? ) find-subseq >boolean ; inline
1047
1048 : subseq-start ( subseq seq -- i/f ) swap find-subseq ; inline
1049
1050 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline
1051
1052 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1053     2dup mismatch [ 2dup min-length ] unless*
1054     [ tail-slice ] curry bi@ ;
1055
1056 : unclip ( seq -- rest first )
1057     [ rest ] [ first-unsafe ] bi ;
1058
1059 : unclip-last ( seq -- butlast last )
1060     [ but-last ] [ last-unsafe ] bi ;
1061
1062 : unclip-slice ( seq -- rest-slice first )
1063     [ rest-slice ] [ first-unsafe ] bi ; inline
1064
1065 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1066     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1067     '[ swap _ dip swap @ ] 1 each-from ; inline
1068
1069 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1070     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1071     '[ rot _ dip swap @ ] 1 2each-from ; inline
1072
1073 <PRIVATE
1074
1075 : (map-find) ( seq quot find-quot -- result elt )
1076     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1077
1078 PRIVATE>
1079
1080 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1081     [ find ] (map-find) ; inline
1082
1083 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1084     [ find-last ] (map-find) ; inline
1085
1086 : unclip-last-slice ( seq -- butlast-slice last )
1087     [ but-last-slice ] [ last-unsafe ] bi ; inline
1088
1089 <PRIVATE
1090
1091 : (trim-head) ( seq quot -- seq n )
1092     over [ [ not ] compose find drop ] dip swap
1093     [ dup length ] unless* ; inline
1094
1095 : (trim-tail) ( seq quot -- seq n )
1096     over [ [ not ] compose find-last drop ?1+ ] dip
1097     swap ; inline
1098
1099 PRIVATE>
1100
1101 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1102     (trim-head) tail-slice ; inline
1103
1104 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1105     (trim-head) tail ; inline
1106
1107 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1108     (trim-tail) head-slice ; inline
1109
1110 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1111     (trim-tail) head ; inline
1112
1113 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1114     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1115
1116 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1117     [ trim-slice ] [ drop ] 2bi like ; inline
1118
1119 GENERIC: sum ( seq -- n )
1120 M: object sum 0 [ + ] binary-reduce ; inline
1121 M: iota sum length dup 1 - * 2/ ; inline
1122 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1123
1124 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1125
1126 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1127
1128 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1129
1130 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1131     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1132
1133 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1134     [ 1 0 ? ] compose map-sum ; inline
1135
1136 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1137     [ with each ] 2curry each ; inline
1138
1139 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1140     [ with { } map-as ] 2curry { } map-as ; inline
1141
1142 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1143     [ 2sequence ] curry cartesian-map ; inline
1144
1145 : cartesian-product ( seq1 seq2 -- newseq )
1146     dup cartesian-product-as ; inline
1147
1148 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1149     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1150
1151 <PRIVATE
1152
1153 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1154     [
1155         [ keep swap ] curry [ [ first ] dip call ] 2keep
1156         [ curry 2dip pick over ] curry
1157     ] [
1158         [ [ 2drop ] [ 2nipd ] if ] compose
1159     ] bi* compose 1 each-from drop ; inline
1160
1161 PRIVATE>
1162
1163 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1164     [ after? ] select-by ; inline
1165
1166 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1167     [ before? ] select-by ; inline
1168
1169 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1170
1171 : longest ( seqs -- elt ) [ length ] supremum-by ;
1172
1173 ! We hand-optimize flip to such a degree because type hints
1174 ! cannot express that an array is an array of arrays yet, and
1175 ! this word happens to be performance-critical since the compiler
1176 ! itself uses it. Optimizing it like this reduced compile time.
1177 <PRIVATE
1178
1179 : generic-flip ( matrix -- newmatrix )
1180     [ [ length ] [ min ] map-reduce ] keep
1181     '[ _ [ nth-unsafe ] with { } map-as ] { } map-integers ; inline
1182
1183 USE: arrays
1184
1185 : array-flip ( matrix -- newmatrix )
1186     { array } declare
1187     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1188     '[ _ [ { array } declare array-nth ] with { } map-as ] { } map-integers ;
1189
1190 PRIVATE>
1191
1192 : flip ( matrix -- newmatrix )
1193     dup empty? [
1194         dup array? [
1195             dup [ array? ] all?
1196             [ array-flip ] [ generic-flip ] if
1197         ] [ generic-flip ] if
1198     ] unless ;