core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC# bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check? ( n seq -- ? )
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota-tuple { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : iota ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota-tuple boa ; inline
 112
 113 M: iota-tuple length n>> ; inline
 114 M: iota-tuple nth-unsafe drop ; inline
 115
 116 INSTANCE: iota-tuple immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition { len read-only } { elt read-only } ;
 265
 266 : <repetition> ( len elt -- repetition )
 267     over 0 < [ non-negative-integer-expected ] when
 268     repetition boa ; inline
 269
 270 M: repetition length len>> ; inline
 271 M: repetition nth-unsafe nip elt>> ; inline
 272
 273 INSTANCE: repetition immutable-sequence
 274
 275 <PRIVATE
 276
 277 ERROR: integer-length-expected obj ;
 278
 279 : check-length ( n -- n )
 280     dup integer? [ integer-length-expected ] unless ; inline
 281
 282 TUPLE: copy-state
 283     { src-i read-only }
 284     { src read-only }
 285     { dst-i read-only }
 286     { dst read-only } ;
 287
 288 C: <copy> copy-state
 289
 290 : ((copy)) ( n copy -- )
 291     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 292     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 293
 294 : (copy) ( n copy -- dst )
 295     over 0 <= [ nip dst>> ] [
 296         [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi
 297     ] if ; inline recursive
 298
 299 : subseq>copy ( from to seq -- n copy )
 300     [ over - check-length swap ] dip
 301     3dup nip new-sequence 0 swap <copy> ; inline
 302
 303 : bounds-check-head ( n seq -- n seq )
 304     over 0 < [ bounds-error ] when ; inline
 305
 306 : check-copy ( src n dst -- src n dst )
 307     3dup bounds-check-head
 308     [ swap length + ] dip lengthen ; inline
 309
 310 : copy-unsafe ( src i dst -- )
 311     #! The check-length call forces partial dispatch
 312     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 313
 314 : subseq-unsafe ( from to seq -- subseq )
 315     [ subseq>copy (copy) ] keep like ;
 316
 317 PRIVATE>
 318
 319 : subseq ( from to seq -- subseq )
 320     [ check-slice subseq>copy (copy) ] keep like ;
 321
 322 : head ( seq n -- headseq ) (head) subseq ;
 323
 324 : tail ( seq n -- tailseq ) (tail) subseq ;
 325
 326 : rest ( seq -- tailseq ) 1 tail ;
 327
 328 : head* ( seq n -- headseq ) from-end head ;
 329
 330 : tail* ( seq n -- tailseq ) from-end tail ;
 331
 332 : but-last ( seq -- headseq ) 1 head* ;
 333
 334 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 335
 336 M: sequence clone-like
 337     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 338
 339 M: immutable-sequence clone-like like ; inline
 340
 341 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 342
 343 <PRIVATE
 344
 345 : (append) ( seq1 seq2 accum -- accum )
 346     [ [ over length ] dip copy-unsafe ]
 347     [ 0 swap copy-unsafe ]
 348     [ ] tri ; inline
 349
 350 PRIVATE>
 351
 352 : append-as ( seq1 seq2 exemplar -- newseq )
 353     [ 2dup [ length ] bi@ + ] dip
 354     [ (append) ] new-like ; inline
 355
 356 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 357     [ 3dup [ length ] tri@ + + ] dip [
 358         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 359         [ (append) ] bi
 360     ] new-like ; inline
 361
 362 : append ( seq1 seq2 -- newseq ) over append-as ;
 363
 364 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 365
 366 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 367
 368 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 369
 370 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 371
 372 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 373
 374 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 375     [ [ nth ] dip call ] 3keep drop set-nth-unsafe ; inline
 376
 377 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 378
 379 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 380
 381 <PRIVATE
 382
 383 : ((each)) ( seq -- n quot )
 384     [ length ] keep [ nth-unsafe ] curry ; inline
 385
 386 : (each) ( seq quot -- n quot' )
 387     [ ((each)) ] dip compose ; inline
 388
 389 : (each-index) ( seq quot -- n quot' )
 390     [ ((each)) [ keep ] curry ] dip compose ; inline
 391
 392 : (collect) ( quot into -- quot' )
 393     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 394
 395 : collect ( n quot into -- )
 396     (collect) each-integer ; inline
 397
 398 : map-into ( seq quot into -- )
 399     [ (each) ] dip collect ; inline
 400
 401 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 402     [ nth-unsafe ] bi-curry@ bi ; inline
 403
 404 : ((2each)) ( seq1 seq2 -- n quot )
 405     [ min-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 406
 407 : (2each) ( seq1 seq2 quot -- n quot' )
 408     [ ((2each)) ] dip compose ; inline
 409
 410 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 411     [ nth-unsafe ] tri-curry@ tri ; inline
 412
 413 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 414     [
 415         [ [ length ] tri@ min min ]
 416         [ [ 3nth-unsafe ] 3curry ] 3bi
 417     ] dip compose ; inline
 418
 419 : finish-find ( i seq -- i elt )
 420     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 421
 422 : (find) ( seq quot quot' -- i elt )
 423     pick [ [ (each) ] dip call ] dip finish-find ; inline
 424
 425 : (find-from) ( n seq quot quot' -- i elt )
 426     [ 2dup bounds-check? ] 2dip
 427     [ (find) ] 2curry
 428     [ 2drop f f ]
 429     if ; inline
 430
 431 : (find-index) ( seq quot quot' -- i elt )
 432     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 433
 434 : (find-index-from) ( n seq quot quot' -- i elt )
 435     [ 2dup bounds-check? ] 2dip
 436     [ (find-index) ] 2curry
 437     [ 2drop f f ]
 438     if ; inline
 439
 440 : (accumulate) ( seq identity quot -- identity seq quot )
 441     swapd [ curry keep ] curry ; inline
 442
 443 PRIVATE>
 444
 445 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 446     (each) each-integer ; inline
 447
 448 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 449     swapd each ; inline
 450
 451 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 452     [ over ] dip [ [ collect ] keep ] new-like ; inline
 453
 454 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 455     [ (each) ] dip map-integers ; inline
 456
 457 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 458     over map-as ; inline
 459
 460 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 461     [ [ drop ] prepose ] dip map-integers ; inline
 462
 463 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 464     { } replicate-as ; inline
 465
 466 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 467     over [ map-into ] keep ; inline
 468
 469 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 470     [ (accumulate) ] dip map-as ; inline
 471
 472 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 473     pick accumulate-as ; inline
 474
 475 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 476     (accumulate) map! ; inline
 477
 478 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 479     (2each) each-integer ; inline
 480
 481 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 482     [ -rot ] dip 2each ; inline
 483
 484 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 485     [ (2each) ] dip map-integers ; inline
 486
 487 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 488     pick 2map-as ; inline
 489
 490 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 491     (2each) all-integers? ; inline
 492
 493 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 494     (3each) each-integer ; inline
 495
 496 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 497     [ (3each) ] dip map-integers ; inline
 498
 499 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 500     [ pick ] dip swap 3map-as ; inline
 501
 502 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 503     [ (find-integer) ] (find-from) ; inline
 504
 505 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 506     [ find-integer ] (find) ; inline
 507
 508 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 509     [ nip find-last-integer ] (find-from) ; inline
 510
 511 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 512     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 513
 514 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 515     [ (find-integer) ] (find-index-from) ; inline
 516
 517 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 518     [ find-integer ] (find-index) ; inline
 519
 520 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 521     (each) all-integers? ; inline
 522
 523 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 524     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 525
 526 <PRIVATE
 527
 528 : (selector-for) ( quot length exemplar -- selector accum )
 529     new-resizable [ [ push-if ] 2curry ] keep ; inline
 530
 531 PRIVATE>
 532
 533 : selector-for ( quot exemplar -- selector accum )
 534     [ length ] keep (selector-for) ; inline
 535
 536 : selector ( quot -- selector accum )
 537     V{ } selector-for ; inline
 538
 539 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 540     pick length over [ (selector-for) [ each ] dip ] 2curry dip like ; inline
 541
 542 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 543     over filter-as ; inline
 544
 545 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 546     [ [ not ] compose ] [ filter-as ] bi* ; inline
 547
 548 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 549     over reject-as ; inline
 550
 551 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 552     [ keep swap ] 2dip ? push ; inline
 553
 554 : 2selector ( quot -- selector accum1 accum2 )
 555     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 556
 557 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 558     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 559
 560 : collector-for ( quot exemplar -- quot' vec )
 561     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 562
 563 : collector ( quot -- quot' vec )
 564     V{ } collector-for ; inline
 565
 566 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 567     dup [ collector-for [ while ] dip ] curry dip like ; inline
 568
 569 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 570     { } produce-as ; inline
 571
 572 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 573     [ dup ] swap [ keep ] curry produce nip ; inline
 574
 575 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 576     (each-index) each-integer ; inline
 577
 578 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 579     [ dup length iota ] 2dip 2map-as ; inline
 580
 581 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 582     { } map-index-as ; inline
 583
 584 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 585     pick empty? [ 3drop ] [
 586         [ [ drop first-unsafe ] dip call ]
 587         [ [ bi* ] 2curry [ 1 ] 2dip (each) (each-integer) ]
 588         3bi
 589     ] if ; inline
 590
 591 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 592     swapd each-index ; inline
 593
 594 : index ( obj seq -- n )
 595     [ = ] with find drop ;
 596
 597 : index-from ( obj i seq -- n )
 598     rot [ = ] curry find-from drop ;
 599
 600 : last-index ( obj seq -- n )
 601     [ = ] with find-last drop ;
 602
 603 : last-index-from ( obj i seq -- n )
 604     rot [ = ] curry find-last-from drop ;
 605
 606 <PRIVATE
 607
 608 : (indices) ( elt i obj accum -- )
 609     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 610
 611 PRIVATE>
 612
 613 : indices ( obj seq -- indices )
 614     swap V{ } clone
 615     [ [ (indices) ] 2curry each-index ] keep ;
 616
 617 <PRIVATE
 618
 619 : nths-unsafe ( indices seq -- seq' )
 620     [ [ nth-unsafe ] curry ] keep map-as ;
 621
 622 PRIVATE>
 623
 624 : nths ( indices seq -- seq' )
 625     [ [ nth ] curry ] keep map-as ;
 626
 627 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 628     find drop >boolean ; inline
 629
 630 : member? ( elt seq -- ? )
 631     [ = ] with any? ;
 632
 633 : member-eq? ( elt seq -- ? )
 634     [ eq? ] with any? ;
 635
 636 : remove ( elt seq -- newseq )
 637     [ = ] with reject ;
 638
 639 : remove-eq ( elt seq -- newseq )
 640     [ eq? ] with reject ;
 641
 642 : sift ( seq -- newseq )
 643     [ ] filter ;
 644
 645 : harvest ( seq -- newseq )
 646     [ empty? ] reject ;
 647
 648 <PRIVATE
 649
 650 : mismatch-unsafe ( n seq1 seq2 -- i )
 651     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 652
 653 PRIVATE>
 654
 655 : mismatch ( seq1 seq2 -- i )
 656     [ min-length ] 2keep mismatch-unsafe ; inline
 657
 658 M: sequence <=>
 659     [ mismatch ] 2keep pick
 660     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 661
 662 : sequence= ( seq1 seq2 -- ? )
 663     2dup [ length ] bi@ dupd =
 664     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 665
 666 ERROR: assert-sequence got expected ;
 667
 668 : assert-sequence= ( a b -- )
 669     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 670
 671 <PRIVATE
 672
 673 : sequence-hashcode-step ( oldhash newpart -- newhash )
 674     integer>fixnum swap [
 675         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 676         fixnum+fast fixnum+fast
 677     ] keep fixnum-bitxor ; inline
 678
 679 PRIVATE>
 680
 681 : sequence-hashcode ( n seq -- x )
 682     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 683
 684 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 685
 686 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 687
 688 : move ( to from seq -- )
 689     2over =
 690     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 691
 692 <PRIVATE
 693
 694 : move-unsafe ( to from seq -- )
 695     2over =
 696     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 697
 698 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 699     2dup length < [
 700         [ move-unsafe ] 3keep
 701         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 702         [ 1 + ] dip
 703         (filter!)
 704     ] [ nip set-length drop ] if ; inline recursive
 705
 706 PRIVATE>
 707
 708 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 709     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 710
 711 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 712     [ not ] compose filter! ; inline
 713
 714 : remove! ( elt seq -- seq )
 715     [ = ] with reject! ;
 716
 717 : remove-eq! ( elt seq -- seq )
 718     [ eq? ] with reject! ;
 719
 720 : prefix ( seq elt -- newseq )
 721     over [ over length 1 + ] dip [
 722         (1sequence) [ 1 swap copy-unsafe ] keep
 723     ] new-like ;
 724
 725 : suffix ( seq elt -- newseq )
 726     over [ over length 1 + ] dip [
 727         [ [ over length ] dip set-nth-unsafe ] keep
 728         [ 0 swap copy-unsafe ] keep
 729     ] new-like ;
 730
 731 : suffix! ( seq elt -- seq ) over push ; inline
 732
 733 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 734
 735 : last ( seq -- elt )
 736     [ length 1 - ] keep
 737     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 738
 739 <PRIVATE
 740
 741 : last-unsafe ( seq -- elt )
 742     [ length 1 - ] [ nth-unsafe ] bi ; inline
 743
 744 PRIVATE>
 745
 746 : set-last ( elt seq -- )
 747     [ length 1 - ] keep
 748     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 749
 750 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 751
 752 <PRIVATE
 753
 754 : move-backward ( shift from to seq -- )
 755     2over = [
 756         4drop
 757     ] [
 758         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 759         move-backward
 760     ] if ;
 761
 762 : move-forward ( shift from to seq -- )
 763     2over = [
 764         4drop
 765     ] [
 766         [ [ pick [ dup dup ] dip + swap ] dip move-unsafe 1 - ] keep
 767         move-forward
 768     ] if ;
 769
 770 : (open-slice) ( shift from to seq ? -- )
 771     [
 772         [ [ 1 - ] bi@ ] dip move-forward
 773     ] [
 774         [ over - ] 2dip move-backward
 775     ] if ;
 776
 777 : open-slice ( shift from seq -- )
 778     pick 0 = [
 779         3drop
 780     ] [
 781         pick over length + over
 782         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 783         set-length
 784     ] if ;
 785
 786 PRIVATE>
 787
 788 : delete-slice ( from to seq -- )
 789     check-slice [ over [ - ] dip ] dip open-slice ;
 790
 791 : remove-nth! ( n seq -- seq )
 792     [ [ dup 1 + ] dip delete-slice ] keep ;
 793
 794 : snip ( from to seq -- head tail )
 795     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 796
 797 : snip-slice ( from to seq -- head tail )
 798     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 799
 800 : replace-slice ( new from to seq -- seq' )
 801     snip-slice surround ;
 802
 803 : remove-nth ( n seq -- seq' )
 804     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 805
 806 : pop ( seq -- elt )
 807     [ length 1 - ] keep over 0 >=
 808     [ [ nth-unsafe ] [ shorten ] 2bi ]
 809     [ bounds-error ] if ;
 810
 811 : exchange ( m n seq -- )
 812     [ nip bounds-check 2drop ]
 813     [ bounds-check 3drop ]
 814     [ exchange-unsafe ]
 815     3tri ;
 816
 817 : midpoint@ ( seq -- n ) length 2/ ; inline
 818
 819 : reverse! ( seq -- seq )
 820     [
 821         [ midpoint@ ] [ length ] [ ] tri
 822         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 823         each-integer
 824     ] keep ;
 825
 826 : reverse ( seq -- newseq )
 827      [
 828         dup [ length ] keep new-sequence
 829         [ 0 swap copy-unsafe ] keep reverse!
 830     ] keep like ;
 831
 832 GENERIC: sum-lengths ( seq -- n )
 833
 834 M: object sum-lengths
 835     0 [ length + ] reduce ;
 836
 837 M: repetition sum-lengths
 838     [ len>> ] [ elt>> length ] bi * ;
 839
 840 : concat-as ( seq exemplar -- newseq )
 841     [
 842         [ dup sum-lengths ] dip new-resizable
 843         [ [ push-all ] curry each ] keep
 844     ] keep like ; inline
 845
 846 : concat ( seq -- newseq )
 847     [ { } ] [ dup first concat-as ] if-empty ;
 848
 849 <PRIVATE
 850
 851 : joined-length ( seq glue -- n )
 852     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 853
 854 PRIVATE>
 855
 856 : join-as ( seq glue exemplar -- newseq )
 857     over empty? [ nip concat-as ] [
 858         [
 859             2dup joined-length over new-resizable [
 860                 [ [ push-all ] 2curry ]
 861                 [ nip [ push-all ] curry ] 2bi
 862                 interleave
 863             ] keep
 864         ] dip like
 865     ] if ;
 866
 867 : join ( seq glue -- newseq )
 868     dup join-as ; inline
 869
 870 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 871     [
 872         [ over length [-] dup 0 = [ drop ] ] dip
 873         [ <repetition> ] curry
 874     ] dip compose if ; inline
 875
 876 : pad-head ( seq n elt -- padded )
 877     [ swap dup append-as ] padding ;
 878
 879 : pad-tail ( seq n elt -- padded )
 880     [ append ] padding ;
 881
 882 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 883 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 884 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 885 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 886
 887 : head? ( seq begin -- ? )
 888     2dup shorter? [
 889         2drop f
 890     ] [
 891         [ length [ head-slice ] keep swap ] keep
 892         mismatch-unsafe not
 893     ] if ;
 894
 895 : tail? ( seq end -- ? )
 896     2dup shorter? [
 897         2drop f
 898     ] [
 899         [ length [ tail-slice* ] keep swap ] keep
 900         mismatch-unsafe not
 901     ] if ;
 902
 903 : cut-slice ( seq n -- before-slice after-slice )
 904     [ head-slice ] [ tail-slice ] 2bi ; inline
 905
 906 : insert-nth ( elt n seq -- seq' )
 907     swap cut-slice [ swap suffix ] dip append ;
 908
 909 : halves ( seq -- first-slice second-slice )
 910     dup midpoint@ cut-slice ; inline
 911
 912 <PRIVATE
 913
 914 : nth2-unsafe ( n seq -- a b )
 915     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 916
 917 : nth3-unsafe ( n seq -- a b c )
 918     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 919
 920 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 921     #! We can't use case here since combinators depends on
 922     #! sequences
 923     dup 4 < [
 924         integer>fixnum {
 925             [ 2drop nip ]
 926             [ 2nip swap nth-unsafe ]
 927             [ -rot [ drop swap nth2-unsafe ] dip call ]
 928             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 929         } dispatch
 930     ] [
 931         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 932         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 933         pick [ 3bi ] dip call
 934     ] if ; inline recursive
 935
 936 PRIVATE>
 937
 938 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 939     pick length 0 max 0 swap (binary-reduce) ; inline
 940
 941 : cut ( seq n -- before after )
 942     [ head ] [ tail ] 2bi ;
 943
 944 : cut* ( seq n -- before after )
 945     [ head* ] [ tail* ] 2bi ;
 946
 947 <PRIVATE
 948
 949 : (start) ( subseq seq n length -- subseq seq ? )
 950     [
 951         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 952     ] all-integers? nip ; inline
 953
 954 PRIVATE>
 955
 956 : start* ( subseq seq n -- i )
 957     pick length [ pick length swap - 1 + ] keep
 958     [ (start) ] curry (find-integer) 2nip ;
 959
 960 : start ( subseq seq -- i ) 0 start* ; inline
 961
 962 : subseq? ( subseq seq -- ? ) start >boolean ;
 963
 964 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 965     2dup mismatch [ 2dup min-length ] unless*
 966     [ tail-slice ] curry bi@ ;
 967
 968 : unclip ( seq -- rest first )
 969     [ rest ] [ first-unsafe ] bi ;
 970
 971 : unclip-last ( seq -- butlast last )
 972     [ but-last ] [ last-unsafe ] bi ;
 973
 974 : unclip-slice ( seq -- rest-slice first )
 975     [ rest-slice ] [ first-unsafe ] bi ; inline
 976
 977 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 978     [ [ dup first ] dip [ call ] keep ] dip compose
 979     swapd [ 1 ] 2dip (each) (each-integer) ; inline
 980
 981 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 982     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 983     [ -rot ] dip [ 1 ] 3dip (2each) (each-integer) ; inline
 984
 985 <PRIVATE
 986
 987 : (map-find) ( seq quot find-quot -- result elt )
 988     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 989     [ [ drop f ] unless ] dip ; inline
 990
 991 PRIVATE>
 992
 993 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 994     [ find ] (map-find) ; inline
 995
 996 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 997     [ find-last ] (map-find) ; inline
 998
 999 : unclip-last-slice ( seq -- butlast-slice last )
1000     [ but-last-slice ] [ last-unsafe ] bi ; inline
1001
1002 <PRIVATE
1003
1004 : (trim-head) ( seq quot -- seq n )
1005     over [ [ not ] compose find drop ] dip swap
1006     [ dup length ] unless* ; inline
1007
1008 : (trim-tail) ( seq quot -- seq n )
1009     over [ [ not ] compose find-last drop ?1+ ] dip
1010     swap ; inline
1011
1012 PRIVATE>
1013
1014 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1015     (trim-head) tail-slice ; inline
1016
1017 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1018     (trim-head) tail ; inline
1019
1020 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1021     (trim-tail) head-slice ; inline
1022
1023 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1024     (trim-tail) head ; inline
1025
1026 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1027     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1028
1029 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1030     [ trim-slice ] [ drop ] 2bi like ; inline
1031
1032 GENERIC: sum ( seq -- n )
1033 M: object sum 0 [ + ] binary-reduce ; inline
1034 M: iota-tuple sum length dup 1 - * 2/ ; inline
1035 M: repetition sum [ elt>> ] [ len>> ] bi * ; inline
1036
1037 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1038
1039 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1040
1041 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1042
1043 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1044     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1045
1046 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1047     [ 1 0 ? ] compose map-sum ; inline
1048
1049 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1050     [ with each ] 2curry each ; inline
1051
1052 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1053     [ with map ] 2curry map ; inline
1054
1055 : cartesian-product ( seq1 seq2 -- newseq )
1056     [ { } 2sequence ] cartesian-map ;
1057
1058 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
1059     -rot (each) (each-integer) ; inline
1060
1061 <PRIVATE
1062
1063 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1064     [
1065         [ keep swap ] curry [ [ first ] dip call ] 2keep
1066         [ curry 2dip pick over ] curry
1067     ] [
1068         [ [ 2drop ] [ [ 2drop ] 2dip ] if ] compose
1069     ] bi* compose 1 each-from drop ; inline
1070
1071 PRIVATE>
1072
1073 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1074     [ after? ] select-by ; inline
1075
1076 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1077     [ before? ] select-by ; inline
1078
1079 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1080
1081 : longest ( seqs -- elt ) [ length ] supremum-by ;
1082
1083 ! We hand-optimize flip to such a degree because type hints
1084 ! cannot express that an array is an array of arrays yet, and
1085 ! this word happens to be performance-critical since the compiler
1086 ! itself uses it. Optimizing it like this reduced compile time.
1087 <PRIVATE
1088
1089 : generic-flip ( matrix -- newmatrix )
1090     [
1091         [ first-unsafe length 1 ] keep
1092         [ length min ] (each) (each-integer) iota
1093     ] keep
1094     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1095
1096 USE: arrays
1097
1098 : array-length ( array -- len )
1099     { array } declare length>> ; inline
1100
1101 : array-flip ( matrix -- newmatrix )
1102     { array } declare
1103     [
1104         [ first-unsafe array-length 1 ] keep
1105         [ array-length min ] (each) (each-integer) iota
1106     ] keep
1107     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1108
1109 PRIVATE>
1110
1111 : flip ( matrix -- newmatrix )
1112     dup empty? [
1113         dup array? [
1114             dup [ array? ] all?
1115             [ array-flip ] [ generic-flip ] if
1116         ] [ generic-flip ] if
1117     ] unless ;