core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition
 265     { length integer read-only }
 266     { elt read-only } ;
 267
 268 : <repetition> ( len elt -- repetition )
 269     over 0 < [ non-negative-integer-expected ] when
 270     repetition boa ; inline
 271
 272 M: repetition length length>> ; inline
 273 M: repetition nth-unsafe nip elt>> ; inline
 274
 275 INSTANCE: repetition immutable-sequence
 276
 277 <PRIVATE
 278
 279 ERROR: integer-length-expected obj ;
 280
 281 ! The check-length call forces partial dispatch
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i integer read-only }
 287     { src read-only }
 288     { dst-i integer read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : copy-nth-unsafe ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 315
 316 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 317     [ subseq>copy (copy) ] dip like ;
 318
 319 : subseq-unsafe ( from to seq -- subseq )
 320     dup subseq-unsafe-as ; inline
 321
 322 PRIVATE>
 323
 324 : subseq-as ( from to seq exemplar -- subseq )
 325     [ check-slice ] dip subseq-unsafe-as ;
 326
 327 : subseq ( from to seq -- subseq )
 328     dup subseq-as ; inline
 329
 330 : head ( seq n -- headseq ) (head) subseq ;
 331
 332 : tail ( seq n -- tailseq ) (tail) subseq ;
 333
 334 : rest ( seq -- tailseq ) 1 tail ;
 335
 336 : head* ( seq n -- headseq ) from-end head ;
 337
 338 : tail* ( seq n -- tailseq ) from-end tail ;
 339
 340 : but-last ( seq -- headseq ) 1 head* ;
 341
 342 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 343
 344 M: sequence clone-like
 345     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 346
 347 M: immutable-sequence clone-like like ; inline
 348
 349 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 350
 351 <PRIVATE
 352
 353 : (append) ( seq1 seq2 accum -- accum )
 354     [ [ over length ] dip copy-unsafe ]
 355     [ 0 swap copy-unsafe ]
 356     [ ] tri ; inline
 357
 358 PRIVATE>
 359
 360 : append-as ( seq1 seq2 exemplar -- newseq )
 361     [ 2dup [ length ] bi@ + ] dip
 362     [ (append) ] new-like ; inline
 363
 364 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 365     [ 3dup [ length ] tri@ + + ] dip [
 366         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 367         [ (append) ] bi
 368     ] new-like ; inline
 369
 370 : append ( seq1 seq2 -- newseq ) over append-as ;
 371
 372 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 373
 374 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 375
 376 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 377
 378 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 379
 380 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 381
 382 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 383     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 384
 385 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 386
 387 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 388
 389 <PRIVATE
 390
 391 : setup-each ( seq -- n quot )
 392     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 393
 394 : (each) ( seq quot -- n quot' )
 395     [ setup-each ] dip compose ; inline
 396
 397 : (each-index) ( seq quot -- n quot' )
 398     [ setup-each [ keep ] curry ] dip compose ; inline
 399
 400 : (collect) ( quot into -- quot' )
 401     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 402
 403 : collect ( n quot into -- )
 404     (collect) each-integer ; inline
 405
 406 : map-into ( seq quot into -- )
 407     [ (each) ] dip collect ; inline
 408
 409 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 410     [ nth-unsafe ] bi-curry@ bi ; inline
 411
 412 : setup-2each ( seq1 seq2 -- n quot )
 413     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 414
 415 : (2each) ( seq1 seq2 quot -- n quot' )
 416     [ setup-2each ] dip compose ; inline
 417
 418 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 419     [ nth-unsafe ] tri-curry@ tri ; inline
 420
 421 : setup-3each ( seq1 seq2 seq3 -- n quot )
 422     [ [ length ] tri@ min min check-length ]
 423     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 424
 425 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 426     [ setup-3each ] dip compose ; inline
 427
 428 : finish-find ( i seq -- i elt )
 429     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 430
 431 : (find) ( seq quot quot' -- i elt )
 432     pick [ [ (each) ] dip call ] dip finish-find ; inline
 433
 434 : (find-from) ( n seq quot quot' -- i elt )
 435     [ 2dup bounds-check? ] 2dip
 436     [ (find) ] 2curry
 437     [ 2drop f f ]
 438     if ; inline
 439
 440 : (find-index) ( seq quot quot' -- i elt )
 441     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 442
 443 : (find-index-from) ( n seq quot quot' -- i elt )
 444     [ 2dup bounds-check? ] 2dip
 445     [ (find-index) ] 2curry
 446     [ 2drop f f ]
 447     if ; inline
 448
 449 : (accumulate) ( seq identity quot -- identity seq quot )
 450     swapd [ keepd ] curry ; inline
 451
 452 : (accumulate*) ( seq identity quot -- identity seq quot )
 453     swapd [ dup ] compose ; inline
 454
 455 PRIVATE>
 456
 457 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 458     (each) each-integer ; inline
 459
 460 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 461     -rot (each) (each-integer) ; inline
 462
 463 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 464     swapd each ; inline
 465
 466 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 467     overd [ [ collect ] keep ] new-like ; inline
 468
 469 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 470     [ (each) ] dip map-integers ; inline
 471
 472 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 473     over map-as ; inline
 474
 475 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 476     [ [ drop ] prepose ] dip map-integers ; inline
 477
 478 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 479     { } replicate-as ; inline
 480
 481 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 482     over [ map-into ] keep ; inline
 483
 484 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 485     [ (accumulate) ] dip map-as ; inline
 486
 487 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 488     pick accumulate-as ; inline
 489
 490 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 491     (accumulate) map! ; inline
 492
 493 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 494     [ (accumulate*) ] dip map-as nip ; inline
 495
 496 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 497     pick accumulate*-as ; inline
 498
 499 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 500     (accumulate*) map! nip ; inline
 501
 502 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 503     (2each) each-integer ; inline
 504
 505 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 506     [ (2each) ] dip -rot (each-integer) ; inline
 507
 508 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 509     -rotd 2each ; inline
 510
 511 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 512     [ (2each) ] dip map-integers ; inline
 513
 514 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 515     pick 2map-as ; inline
 516
 517 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 518     (2each) all-integers? ; inline
 519
 520 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 521     (3each) each-integer ; inline
 522
 523 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 524     [ (3each) ] dip map-integers ; inline
 525
 526 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 527     pickd swap 3map-as ; inline
 528
 529 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 530     [ (find-integer) ] (find-from) ; inline
 531
 532 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 533     [ find-integer ] (find) ; inline
 534
 535 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 536     [ nip find-last-integer ] (find-from) ; inline
 537
 538 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 539     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 540
 541 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 542     [ (find-integer) ] (find-index-from) ; inline
 543
 544 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 545     [ find-integer ] (find-index) ; inline
 546
 547 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 548     (each) all-integers? ; inline
 549
 550 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 551     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 552
 553 <PRIVATE
 554
 555 : (selector-as) ( quot length exemplar -- selector accum )
 556     new-resizable [ [ push-if ] 2curry ] keep ; inline
 557
 558 PRIVATE>
 559
 560 : selector-as ( quot exemplar -- selector accum )
 561     [ length ] keep (selector-as) ; inline
 562
 563 : selector ( quot -- selector accum )
 564     V{ } selector-as ; inline
 565
 566 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 567     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 568
 569 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 570     over filter-as ; inline
 571
 572 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 573     [ [ not ] compose ] [ filter-as ] bi* ; inline
 574
 575 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 576     over reject-as ; inline
 577
 578 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 579     [ keep swap ] 2dip ? push ; inline
 580
 581 : 2selector ( quot -- selector accum1 accum2 )
 582     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 583
 584 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 585     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 586
 587 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 588     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 589
 590 : collector-as ( quot exemplar -- quot' vec )
 591     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 592
 593 : collector-for ( seq quot -- seq quot' vec )
 594     V{ } collector-for-as ; inline
 595
 596 : collector ( quot -- quot' vec )
 597     V{ } collector-as ; inline
 598
 599 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 600     dup [ collector-as [ while ] dip ] curry dip like ; inline
 601
 602 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 603     { } produce-as ; inline
 604
 605 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 606     [ dup ] swap [ keep ] curry produce nip ; inline
 607
 608 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 609     (each-index) each-integer ; inline
 610
 611 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 612     [ dup length <iota> ] 2dip 2map-as ; inline
 613
 614 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 615     { } map-index-as ; inline
 616
 617 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 618     pick empty? [ 3drop ] [
 619         [ [ drop first-unsafe ] dip call ]
 620         [ [ bi* ] 2curry 1 each-from ]
 621         3bi
 622     ] if ; inline
 623
 624 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 625     swapd each-index ; inline
 626
 627 : index ( obj seq -- n )
 628     [ = ] with find drop ;
 629
 630 : index-from ( obj i seq -- n )
 631     rot [ = ] curry find-from drop ;
 632
 633 : last-index ( obj seq -- n )
 634     [ = ] with find-last drop ;
 635
 636 : last-index-from ( obj i seq -- n )
 637     rot [ = ] curry find-last-from drop ;
 638
 639 : indices ( obj seq -- indices )
 640     swap [ = ] curry [ swap ] prepose V{ } clone [
 641         [ push ] curry [ [ drop ] if ] curry compose each-index
 642     ] keep ;
 643
 644 <PRIVATE
 645
 646 : nths-unsafe ( indices seq -- seq' )
 647     [ [ nth-unsafe ] curry ] keep map-as ;
 648
 649 PRIVATE>
 650
 651 : nths ( indices seq -- seq' )
 652     [ [ nth ] curry ] keep map-as ;
 653
 654 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 655     find drop >boolean ; inline
 656
 657 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 658     any? not ; inline
 659
 660 : member? ( elt seq -- ? )
 661     [ = ] with any? ;
 662
 663 : member-eq? ( elt seq -- ? )
 664     [ eq? ] with any? ;
 665
 666 : remove ( elt seq -- newseq )
 667     [ = ] with reject ;
 668
 669 : remove-eq ( elt seq -- newseq )
 670     [ eq? ] with reject ;
 671
 672 : sift ( seq -- newseq )
 673     [ ] filter ;
 674
 675 : harvest ( seq -- newseq )
 676     [ empty? ] reject ;
 677
 678 <PRIVATE
 679
 680 : mismatch-unsafe ( n seq1 seq2 -- i )
 681     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 682
 683 PRIVATE>
 684
 685 : mismatch ( seq1 seq2 -- i )
 686     [ min-length ] 2keep mismatch-unsafe ; inline
 687
 688 M: sequence <=>
 689     [ mismatch ] 2keep pick
 690     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 691
 692 : sequence= ( seq1 seq2 -- ? )
 693     2dup [ length ] bi@ dupd =
 694     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 695
 696 ERROR: assert-sequence got expected ;
 697
 698 : assert-sequence= ( a b -- )
 699     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 700
 701 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 702
 703 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 704
 705 <PRIVATE
 706
 707 : sequence-hashcode-step ( oldhash newpart -- newhash )
 708     integer>fixnum swap [
 709         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 710         fixnum+fast fixnum+fast
 711     ] keep fixnum-bitxor ; inline
 712
 713 PRIVATE>
 714
 715 : sequence-hashcode ( n seq -- x )
 716     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 717
 718 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 719
 720 M: iota hashcode*
 721     over 0 <= [ 2drop 0 ] [
 722         nip length 0 swap [ sequence-hashcode-step ] each-integer
 723     ] if ;
 724
 725 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 726
 727 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 728
 729 : move ( to from seq -- )
 730     2over =
 731     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 732
 733 <PRIVATE
 734
 735 : move-unsafe ( to from seq -- )
 736     2over =
 737     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 738
 739 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 740     2dup length < [
 741         [ move-unsafe ] 3keep
 742         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 743         [ 1 + ] dip
 744         (filter!)
 745     ] [ nip set-length drop ] if ; inline recursive
 746
 747 PRIVATE>
 748
 749 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 750     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 751
 752 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 753     [ not ] compose filter! ; inline
 754
 755 : remove! ( elt seq -- seq )
 756     [ = ] with reject! ;
 757
 758 : remove-eq! ( elt seq -- seq )
 759     [ eq? ] with reject! ;
 760
 761 : prefix ( seq elt -- newseq )
 762     over [ over length 1 + ] dip [
 763         (1sequence) [ 1 swap copy-unsafe ] keep
 764     ] new-like ;
 765
 766 : suffix ( seq elt -- newseq )
 767     over [ over length 1 + ] dip [
 768         [ [ over length ] dip set-nth-unsafe ] keep
 769         [ 0 swap copy-unsafe ] keep
 770     ] new-like ;
 771
 772 : suffix! ( seq elt -- seq ) over push ; inline
 773
 774 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 775
 776 : last ( seq -- elt )
 777     [ length 1 - ] keep
 778     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 779
 780 <PRIVATE
 781
 782 : last-unsafe ( seq -- elt )
 783     [ length 1 - ] [ nth-unsafe ] bi ; inline
 784
 785 PRIVATE>
 786
 787 : set-last ( elt seq -- )
 788     [ length 1 - ] keep
 789     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 790
 791 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 792
 793 <PRIVATE
 794
 795 : move-backward ( shift from to seq -- )
 796     2over = [
 797         4drop
 798     ] [
 799         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 800         move-backward
 801     ] if ;
 802
 803 : move-forward ( shift from to seq -- )
 804     2over = [
 805         4drop
 806     ] [
 807         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 808         move-forward
 809     ] if ;
 810
 811 : (open-slice) ( shift from to seq ? -- )
 812     [
 813         [ [ 1 - ] bi@ ] dip move-forward
 814     ] [
 815         [ over - ] 2dip move-backward
 816     ] if ;
 817
 818 : open-slice ( shift from seq -- )
 819     pick 0 = [
 820         3drop
 821     ] [
 822         [ ] [ nip length + ] [ 2nip ] 3tri
 823         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 824         set-length
 825     ] if ;
 826
 827 PRIVATE>
 828
 829 : delete-slice ( from to seq -- )
 830     check-slice [ over [ - ] dip ] dip open-slice ;
 831
 832 : remove-nth! ( n seq -- seq )
 833     [ [ dup 1 + ] dip delete-slice ] keep ;
 834
 835 : snip ( from to seq -- head tail )
 836     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 837
 838 : snip-slice ( from to seq -- head tail )
 839     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 840
 841 : replace-slice ( new from to seq -- seq' )
 842     snip-slice surround ;
 843
 844 : remove-nth ( n seq -- seq' )
 845     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 846
 847 : pop ( seq -- elt )
 848     [ length 1 - ] keep over 0 >=
 849     [ [ nth-unsafe ] [ shorten ] 2bi ]
 850     [ bounds-error ] if ;
 851
 852 : exchange ( m n seq -- )
 853     [ nip bounds-check 2drop ]
 854     [ bounds-check 3drop ]
 855     [ exchange-unsafe ]
 856     3tri ;
 857
 858 : midpoint@ ( seq -- n ) length 2/ ; inline
 859
 860 : reverse! ( seq -- seq )
 861     [
 862         [ midpoint@ ] [ length ] [ ] tri
 863         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 864         each-integer
 865     ] keep ;
 866
 867 : reverse ( seq -- newseq )
 868      [
 869         dup [ length ] keep new-sequence
 870         [ 0 swap copy-unsafe ] keep reverse!
 871     ] keep like ;
 872
 873 GENERIC: sum-lengths ( seq -- n )
 874
 875 M: object sum-lengths
 876     0 [ length + ] reduce ;
 877
 878 M: repetition sum-lengths
 879     [ length>> ] [ elt>> length ] bi * ;
 880
 881 : concat-as ( seq exemplar -- newseq )
 882     [
 883         [ dup sum-lengths ] dip new-resizable
 884         [ [ push-all ] curry each ] keep
 885     ] keep like ; inline
 886
 887 : concat ( seq -- newseq )
 888     [ { } ] [ dup first concat-as ] if-empty ;
 889
 890 <PRIVATE
 891
 892 : joined-length ( seq glue -- n )
 893     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 894
 895 PRIVATE>
 896
 897 : join-as ( seq glue exemplar -- newseq )
 898     over empty? [ nip concat-as ] [
 899         [
 900             2dup joined-length over new-resizable [
 901                 [ [ push-all ] 2curry ]
 902                 [ nip [ push-all ] curry ] 2bi
 903                 interleave
 904             ] keep
 905         ] dip like
 906     ] if ;
 907
 908 : join ( seq glue -- newseq )
 909     dup join-as ; inline
 910
 911 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 912     [
 913         [ over length [-] dup 0 = [ drop ] ] dip
 914         [ <repetition> ] curry
 915     ] dip compose if ; inline
 916
 917 : pad-head ( seq n elt -- padded )
 918     [ swap dup append-as ] padding ;
 919
 920 : pad-tail ( seq n elt -- padded )
 921     [ append ] padding ;
 922
 923 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 924 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 925 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 926 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 927
 928 : head? ( seq begin -- ? )
 929     2dup shorter? [
 930         2drop f
 931     ] [
 932         [ length [ head-slice ] keep swap ] keep
 933         mismatch-unsafe not
 934     ] if ;
 935
 936 : tail? ( seq end -- ? )
 937     2dup shorter? [
 938         2drop f
 939     ] [
 940         [ length [ tail-slice* ] keep swap ] keep
 941         mismatch-unsafe not
 942     ] if ;
 943
 944 : cut-slice ( seq n -- before-slice after-slice )
 945     [ head-slice ] [ tail-slice ] 2bi ; inline
 946
 947 : insert-nth ( elt n seq -- seq' )
 948     swap cut-slice [ swap suffix ] dip append ;
 949
 950 : halves ( seq -- first-slice second-slice )
 951     dup midpoint@ cut-slice ; inline
 952
 953 <PRIVATE
 954
 955 : nth2-unsafe ( n seq -- a b )
 956     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 957
 958 : nth3-unsafe ( n seq -- a b c )
 959     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 960
 961 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 962     ! We can't use case here since combinators depends on
 963     ! sequences
 964     dup 4 < [
 965         integer>fixnum {
 966             [ 2drop nip ]
 967             [ 2nip swap nth-unsafe ]
 968             [ -rot [ drop swap nth2-unsafe ] dip call ]
 969             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 970         } dispatch
 971     ] [
 972         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 973         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 974         pick [ 3bi ] dip call
 975     ] if ; inline recursive
 976
 977 PRIVATE>
 978
 979 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 980     pick length 0 max 0 swap (binary-reduce) ; inline
 981
 982 : cut ( seq n -- before after )
 983     [ head ] [ tail ] 2bi ;
 984
 985 : cut* ( seq n -- before after )
 986     [ head* ] [ tail* ] 2bi ;
 987
 988 <PRIVATE
 989
 990 : (subseq-start-from) ( subseq seq n length -- subseq seq ? )
 991     [
 992         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 993     ] all-integers? nip ; inline
 994
 995 PRIVATE>
 996
 997 : subseq-start-from ( subseq seq n -- i )
 998     pick length [ pick length swap - 1 + ] keep
 999     [ (subseq-start-from) ] curry (find-integer) 2nip ;
1000
1001 : subseq-start ( subseq seq -- i ) 0 subseq-start-from ; inline
1002
1003 : subseq? ( subseq seq -- ? ) subseq-start >boolean ;
1004
1005 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1006     2dup mismatch [ 2dup min-length ] unless*
1007     [ tail-slice ] curry bi@ ;
1008
1009 : unclip ( seq -- rest first )
1010     [ rest ] [ first-unsafe ] bi ;
1011
1012 : unclip-last ( seq -- butlast last )
1013     [ but-last ] [ last-unsafe ] bi ;
1014
1015 : unclip-slice ( seq -- rest-slice first )
1016     [ rest-slice ] [ first-unsafe ] bi ; inline
1017
1018 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
1019     [ [ [ first ] keep ] dip [ dip ] keep ] dip compose 1 each-from ; inline
1020
1021 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
1022     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip compose 1 2each-from ; inline
1023
1024 <PRIVATE
1025
1026 : (map-find) ( seq quot find-quot -- result elt )
1027     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1028
1029 PRIVATE>
1030
1031 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1032     [ find ] (map-find) ; inline
1033
1034 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1035     [ find-last ] (map-find) ; inline
1036
1037 : unclip-last-slice ( seq -- butlast-slice last )
1038     [ but-last-slice ] [ last-unsafe ] bi ; inline
1039
1040 <PRIVATE
1041
1042 : (trim-head) ( seq quot -- seq n )
1043     over [ [ not ] compose find drop ] dip swap
1044     [ dup length ] unless* ; inline
1045
1046 : (trim-tail) ( seq quot -- seq n )
1047     over [ [ not ] compose find-last drop ?1+ ] dip
1048     swap ; inline
1049
1050 PRIVATE>
1051
1052 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1053     (trim-head) tail-slice ; inline
1054
1055 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1056     (trim-head) tail ; inline
1057
1058 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1059     (trim-tail) head-slice ; inline
1060
1061 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1062     (trim-tail) head ; inline
1063
1064 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1065     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1066
1067 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1068     [ trim-slice ] [ drop ] 2bi like ; inline
1069
1070 GENERIC: sum ( seq -- n )
1071 M: object sum 0 [ + ] binary-reduce ; inline
1072 M: iota sum length dup 1 - * 2/ ; inline
1073 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1074
1075 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1076
1077 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1078
1079 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1080
1081 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1082     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1083
1084 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1085     [ 1 0 ? ] compose map-sum ; inline
1086
1087 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1088     [ with each ] 2curry each ; inline
1089
1090 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1091     [ with map ] 2curry map ; inline
1092
1093 : cartesian-product ( seq1 seq2 -- newseq )
1094     [ { } 2sequence ] cartesian-map ;
1095
1096 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1097     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1098
1099 <PRIVATE
1100
1101 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1102     [
1103         [ keep swap ] curry [ [ first ] dip call ] 2keep
1104         [ curry 2dip pick over ] curry
1105     ] [
1106         [ [ 2drop ] [ 2nipd ] if ] compose
1107     ] bi* compose 1 each-from drop ; inline
1108
1109 PRIVATE>
1110
1111 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1112     [ after? ] select-by ; inline
1113
1114 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1115     [ before? ] select-by ; inline
1116
1117 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1118
1119 : longest ( seqs -- elt ) [ length ] supremum-by ;
1120
1121 ! We hand-optimize flip to such a degree because type hints
1122 ! cannot express that an array is an array of arrays yet, and
1123 ! this word happens to be performance-critical since the compiler
1124 ! itself uses it. Optimizing it like this reduced compile time.
1125 <PRIVATE
1126
1127 : generic-flip ( matrix -- newmatrix )
1128     [
1129         [ first-unsafe length 1 ] keep
1130         [ length min ] (each) (each-integer) <iota>
1131     ] keep
1132     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1133
1134 USE: arrays
1135
1136 : array-length ( array -- len )
1137     { array } declare length>> ; inline
1138
1139 : array-flip ( matrix -- newmatrix )
1140     { array } declare
1141     [
1142         [ first-unsafe array-length 1 ] keep
1143         [ array-length min ] (each) (each-integer) <iota>
1144     ] keep
1145     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1146
1147 PRIVATE>
1148
1149 : flip ( matrix -- newmatrix )
1150     dup empty? [
1151         dup array? [
1152             dup [ array? ] all?
1153             [ array-flip ] [ generic-flip ] if
1154         ] [ generic-flip ] if
1155     ] unless ;