core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : >slice< ( slice -- from to seq )
 222     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 223
 224 : collapse-slice ( m n slice -- m' n' seq )
 225     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 226
 227 ERROR: slice-error from to seq ;
 228
 229 : check-slice ( from to seq -- from to seq )
 230     pick 0 < [ slice-error ] when
 231     2dup length > [ slice-error ] when
 232     2over > [ slice-error ] when ; inline
 233
 234 <PRIVATE
 235
 236 : <slice-unsafe> ( from to seq -- slice )
 237     dup slice? [ collapse-slice ] when slice boa ; inline
 238
 239 PRIVATE>
 240
 241 : <slice> ( from to seq -- slice )
 242     check-slice <slice-unsafe> ; inline
 243
 244 M: slice virtual-exemplar seq>> ; inline
 245
 246 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 247
 248 M: slice length [ to>> ] [ from>> ] bi - ; inline
 249
 250 : short ( seq n -- seq n' ) over length min ; inline
 251
 252 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 253
 254 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 255
 256 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 257
 258 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 259
 260 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 261
 262 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 263
 264 INSTANCE: slice virtual-sequence
 265
 266 ! One element repeated many times
 267 TUPLE: repetition
 268     { length integer read-only }
 269     { elt read-only } ;
 270
 271 : <repetition> ( len elt -- repetition )
 272     over 0 < [ non-negative-integer-expected ] when
 273     repetition boa ; inline
 274
 275 M: repetition length length>> ; inline
 276 M: repetition nth-unsafe nip elt>> ; inline
 277
 278 INSTANCE: repetition immutable-sequence
 279
 280 <PRIVATE
 281
 282 ERROR: integer-length-expected obj ;
 283
 284 ! The check-length call forces partial dispatch
 285 : check-length ( n -- n )
 286     dup integer? [ integer-length-expected ] unless ; inline
 287
 288 : >sequence< ( seq -- i n seq )
 289     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 290
 291 : length-sequence ( seq -- n seq )
 292     [ length check-length ] [ ] bi ; inline
 293
 294 : >range-iterator< ( slice/seq -- i n slice/seq )
 295     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 296
 297 TUPLE: copier
 298     { src-i integer read-only }
 299     { src read-only }
 300     { dst-i integer read-only }
 301     { dst read-only } ;
 302
 303 C: <copier> copier
 304
 305 : copy-nth-unsafe ( n copy -- )
 306     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 307     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 308
 309 : (copy) ( n copy -- dst )
 310     over 0 <= [ nip dst>> ] [
 311         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 312     ] if ; inline recursive
 313
 314 : subseq>copy ( from to seq -- n copy )
 315     [ over - check-length swap ] dip
 316     3dup nip new-sequence 0 swap <copier> ; inline
 317
 318 : bounds-check-head ( n seq -- n seq )
 319     over 0 < [ bounds-error ] when ; inline
 320
 321 : check-copy ( src n dst -- src n dst )
 322     3dup bounds-check-head
 323     [ swap length + ] dip lengthen ; inline
 324
 325 : copy-unsafe ( src i dst -- )
 326     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 327
 328 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 329     [ subseq>copy (copy) ] dip like ; inline
 330
 331 : subseq-unsafe ( from to seq -- subseq )
 332     dup subseq-unsafe-as ; inline
 333
 334 PRIVATE>
 335
 336 : subseq-as ( from to seq exemplar -- subseq )
 337     [ check-slice ] dip subseq-unsafe-as ;
 338
 339 : subseq ( from to seq -- subseq )
 340     dup subseq-as ;
 341
 342 : head ( seq n -- headseq ) (head) subseq ;
 343
 344 : tail ( seq n -- tailseq ) (tail) subseq ;
 345
 346 : rest ( seq -- tailseq ) 1 tail ;
 347
 348 : head* ( seq n -- headseq ) from-end head ;
 349
 350 : tail* ( seq n -- tailseq ) from-end tail ;
 351
 352 : but-last ( seq -- headseq ) 1 head* ;
 353
 354 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 355
 356 M: sequence clone-like
 357     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 358
 359 M: immutable-sequence clone-like like ; inline
 360
 361 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 362
 363 <PRIVATE
 364
 365 : (append) ( seq1 seq2 accum -- accum )
 366     [ [ over length ] dip copy-unsafe ]
 367     [ 0 swap copy-unsafe ]
 368     [ ] tri ; inline
 369
 370 PRIVATE>
 371
 372 : append-as ( seq1 seq2 exemplar -- newseq )
 373     [ 2dup [ length ] bi@ + ] dip
 374     [ (append) ] new-like ; inline
 375
 376 : append ( seq1 seq2 -- newseq ) over append-as ;
 377
 378 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 379
 380 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 381
 382 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 383     [ 3dup [ length ] tri@ + + ] dip [
 384         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 385         [ (append) ] bi
 386     ] new-like ; inline
 387
 388 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 389
 390 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 391     [ swap ] 2dip 3append-as ; inline
 392
 393 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 394
 395 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 396
 397 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 398
 399 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 400
 401 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 402
 403 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 404     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 405
 406 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 407
 408 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 409
 410 <PRIVATE
 411
 412 : sequence-iterator ( seq quot -- i n quot' )
 413     [ >range-iterator< [ nth-unsafe ] curry ] dip compose ; inline
 414
 415 ! setup-1each
 416 : length-iterator ( seq quot -- n quot' )
 417     length-sequence [ nth-unsafe ] curry ; inline
 418
 419 ! (1each)
 420 : length-operator ( seq quot -- n quot' )
 421     [ length-iterator ] dip compose ; inline
 422
 423 : sequence-iterator-from ( seq quot i -- i n quot' )
 424     -rot length-operator ; inline
 425
 426 : collect ( n quot into -- )
 427     [ [ keep ] dip set-nth-unsafe ] 2curry each-integer ; inline
 428
 429 : sequence-index-iterator ( seq quot -- n quot' )
 430     [ length-iterator [ keep ] curry ] dip compose ; inline
 431
 432 : map-into ( seq quot into -- )
 433     [ length-operator ] dip collect ; inline
 434
 435 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 436     [ nth-unsafe ] bi-curry@ bi ; inline
 437
 438 : setup-2each ( seq1 seq2 -- n quot )
 439     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 440
 441 : (2each) ( seq1 seq2 quot -- n quot' )
 442     [ setup-2each ] dip compose ; inline
 443
 444 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 445     [ nth-unsafe ] tri-curry@ tri ; inline
 446
 447 : setup-3each ( seq1 seq2 seq3 -- n quot )
 448     [ [ length ] tri@ min min check-length ]
 449     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 450
 451 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 452     [ setup-3each ] dip compose ; inline
 453
 454 : finish-find ( i seq -- i elt )
 455     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 456
 457 : (find) ( seq quot quot' -- i elt )
 458     pick [ [ length-operator ] dip call ] dip finish-find ; inline
 459
 460 : (find-from) ( n seq quot quot' -- i elt )
 461     [ 2dup bounds-check? ] 2dip
 462     '[ _ _ (find) ] [ 2drop f f ] if ; inline
 463
 464 : (find-index) ( seq quot quot' -- i elt )
 465     pick [ [ sequence-index-iterator ] dip call ] dip finish-find ; inline
 466
 467 : (find-index-from) ( n seq quot quot' -- i elt )
 468     [ 2dup bounds-check? ] 2dip
 469     '[ _ _ (find-index) ] [ 2drop f f ] if ; inline
 470
 471 : (accumulate) ( seq identity quot -- identity seq quot )
 472     swapd [ keepd ] curry ; inline
 473
 474 : (accumulate*) ( seq identity quot -- identity seq quot )
 475     swapd [ dup ] compose ; inline
 476
 477 PRIVATE>
 478
 479 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 480     sequence-iterator each-integer-from ; inline
 481
 482 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 483     sequence-iterator-from each-integer-from ; inline
 484
 485 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 486     swapd each ; inline
 487
 488 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 489     overd [ [ collect ] keep ] new-like ; inline
 490
 491 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 492     [ length-operator ] dip map-integers ; inline
 493
 494 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 495     over map-as ; inline
 496
 497 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 498     [ [ drop ] prepose ] dip map-integers ; inline
 499
 500 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 501     { } replicate-as ; inline
 502
 503 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 504     over [ map-into ] keep ; inline
 505
 506 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 507     [ (accumulate) ] dip map-as ; inline
 508
 509 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 510     pick accumulate-as ; inline
 511
 512 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 513     (accumulate) map! ; inline
 514
 515 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 516     [ (accumulate*) ] dip map-as nip ; inline
 517
 518 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 519     pick accumulate*-as ; inline
 520
 521 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 522     (accumulate*) map! nip ; inline
 523
 524 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 525     (2each) each-integer ; inline
 526
 527 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 528     [ (2each) ] dip -rot each-integer-from ; inline
 529
 530 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 531     -rotd 2each ; inline
 532
 533 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 534     [ (2each) ] dip map-integers ; inline
 535
 536 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 537     pick 2map-as ; inline
 538
 539 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 540     (2each) all-integers? ; inline
 541
 542 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 543     [ not ] compose 2all? not ; inline
 544
 545 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 546     (3each) each-integer ; inline
 547
 548 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 549     [ (3each) ] dip map-integers ; inline
 550
 551 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 552     pickd swap 3map-as ; inline
 553
 554 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 555     [ find-integer-from ] (find-from) ; inline
 556
 557 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 558     [ find-integer ] (find) ; inline
 559
 560 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 561     [ nip find-last-integer ] (find-from) ; inline
 562
 563 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 564     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 565
 566 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 567     [ find-integer-from ] (find-index-from) ; inline
 568
 569 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 570     [ find-integer ] (find-index) ; inline
 571
 572 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 573     sequence-iterator all-integers-from? ; inline
 574
 575 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 576     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 577
 578 <PRIVATE
 579
 580 : (selector-as) ( quot length exemplar -- selector accum )
 581     new-resizable [ [ push-if ] 2curry ] keep ; inline
 582
 583 PRIVATE>
 584
 585 : selector-as ( quot exemplar -- selector accum )
 586     [ length ] keep (selector-as) ; inline
 587
 588 : selector ( quot -- selector accum )
 589     V{ } selector-as ; inline
 590
 591 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 592     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 593
 594 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 595     over filter-as ; inline
 596
 597 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 598     [ [ not ] compose ] [ filter-as ] bi* ; inline
 599
 600 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 601     over reject-as ; inline
 602
 603 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 604     [ keep swap ] 2dip ? push ; inline
 605
 606 : 2selector ( quot -- selector accum1 accum2 )
 607     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 608
 609 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 610     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 611
 612 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 613     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 614
 615 : collector-as ( quot exemplar -- quot' vec )
 616     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 617
 618 : collector-for ( seq quot -- seq quot' vec )
 619     V{ } collector-for-as ; inline
 620
 621 : collector ( quot -- quot' vec )
 622     V{ } collector-as ; inline
 623
 624 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 625     dup [ collector-as [ while ] dip ] curry dip like ; inline
 626
 627 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 628     { } produce-as ; inline
 629
 630 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 631     [ dup ] swap [ keep ] curry produce nip ; inline
 632
 633 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 634     sequence-index-iterator each-integer ; inline
 635
 636 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 637     [ dup length <iota> ] 2dip 2map-as ; inline
 638
 639 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 640     over map-index-as ; inline
 641
 642 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 643     pick empty? [ 3drop ] [
 644         [ [ drop first-unsafe ] dip call ]
 645         [ [ bi* ] 2curry 1 each-from ]
 646         3bi
 647     ] if ; inline
 648
 649 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 650     swapd each-index ; inline
 651
 652 : index ( obj seq -- n )
 653     [ = ] with find drop ;
 654
 655 : index-from ( obj i seq -- n )
 656     rot [ = ] curry find-from drop ;
 657
 658 : last-index ( obj seq -- n )
 659     [ = ] with find-last drop ;
 660
 661 : last-index-from ( obj i seq -- n )
 662     rot [ = ] curry find-last-from drop ;
 663
 664 : indices ( obj seq -- indices )
 665     swap [ = ] curry [ swap ] prepose V{ } clone [
 666         [ push ] curry [ [ drop ] if ] curry compose each-index
 667     ] keep ;
 668
 669 <PRIVATE
 670
 671 : nths-unsafe ( indices seq -- seq' )
 672     [ [ nth-unsafe ] curry ] keep map-as ;
 673
 674 PRIVATE>
 675
 676 : nths ( indices seq -- seq' )
 677     [ [ nth ] curry ] keep map-as ;
 678
 679 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 680     find drop >boolean ; inline
 681
 682 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 683     any? not ; inline
 684
 685 : member? ( elt seq -- ? )
 686     [ = ] with any? ;
 687
 688 : member-of? ( seq elt -- ? )
 689     [ = ] curry any? ;
 690
 691 : member-eq? ( elt seq -- ? )
 692     [ eq? ] with any? ;
 693
 694 : member-eq-of? ( seq elt -- ? )
 695     [ eq? ] curry any? ;
 696
 697 : remove ( elt seq -- newseq )
 698     [ = ] with reject ;
 699
 700 : remove-of ( seq elt -- newseq )
 701     [ = ] curry reject ;
 702
 703 : remove-eq ( elt seq -- newseq )
 704     [ eq? ] with reject ;
 705
 706 : remove-eq-of ( seq elt -- newseq )
 707     [ eq? ] curry reject ;
 708
 709 : sift ( seq -- newseq )
 710     [ ] filter ;
 711
 712 : harvest ( seq -- newseq )
 713     [ empty? ] reject ;
 714
 715 <PRIVATE
 716
 717 : mismatch-unsafe ( n seq1 seq2 -- i )
 718     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 719
 720 PRIVATE>
 721
 722 : mismatch ( seq1 seq2 -- i )
 723     [ min-length ] 2keep mismatch-unsafe ;
 724
 725 M: sequence <=>
 726     [ mismatch ] 2keep pick
 727     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 728
 729 : sequence= ( seq1 seq2 -- ? )
 730     2dup [ length ] bi@ dupd =
 731     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 732
 733 ERROR: assert-sequence got expected ;
 734
 735 : assert-sequence= ( a b -- )
 736     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 737
 738 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 739
 740 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 741
 742 <PRIVATE
 743
 744 : sequence-hashcode-step ( oldhash newpart -- newhash )
 745     integer>fixnum swap [
 746         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 747         fixnum+fast fixnum+fast
 748     ] keep fixnum-bitxor ; inline
 749
 750 PRIVATE>
 751
 752 : sequence-hashcode ( n seq -- x )
 753     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 754
 755 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 756
 757 M: iota hashcode*
 758     over 0 <= [ 2drop 0 ] [
 759         nip length 0 swap [ sequence-hashcode-step ] each-integer
 760     ] if ;
 761
 762 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 763
 764 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 765
 766 : move ( to from seq -- )
 767     2over =
 768     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 769
 770 <PRIVATE
 771
 772 : move-unsafe ( to from seq -- )
 773     2over =
 774     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 775
 776 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 777     2dup length < [
 778         [ move-unsafe ] 3keep
 779         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 780         [ 1 + ] dip
 781         (filter!)
 782     ] [ nip set-length drop ] if ; inline recursive
 783
 784 PRIVATE>
 785
 786 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 787     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 788
 789 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 790     [ not ] compose filter! ; inline
 791
 792 : remove! ( elt seq -- seq )
 793     [ = ] with reject! ;
 794
 795 : remove-eq! ( elt seq -- seq )
 796     [ eq? ] with reject! ;
 797
 798 : prefix ( seq elt -- newseq )
 799     over [ over length 1 + ] dip [
 800         (1sequence) [ 1 swap copy-unsafe ] keep
 801     ] new-like ;
 802
 803 : suffix ( seq elt -- newseq )
 804     over [ over length 1 + ] dip [
 805         [ [ over length ] dip set-nth-unsafe ] keep
 806         [ 0 swap copy-unsafe ] keep
 807     ] new-like ;
 808
 809 : suffix! ( seq elt -- seq ) over push ; inline
 810
 811 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 812
 813 : last ( seq -- elt )
 814     [ length 1 - ] keep
 815     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 816
 817 <PRIVATE
 818
 819 : last-unsafe ( seq -- elt )
 820     [ length 1 - ] [ nth-unsafe ] bi ; inline
 821
 822 PRIVATE>
 823
 824 : set-last ( elt seq -- )
 825     [ length 1 - ] keep
 826     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 827
 828 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 829
 830 <PRIVATE
 831
 832 : move-backward ( shift from to seq -- )
 833     2over = [
 834         4drop
 835     ] [
 836         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 837         move-backward
 838     ] if ;
 839
 840 : move-forward ( shift from to seq -- )
 841     2over = [
 842         4drop
 843     ] [
 844         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 845         move-forward
 846     ] if ;
 847
 848 : (open-slice) ( shift from to seq ? -- )
 849     [
 850         [ [ 1 - ] bi@ ] dip move-forward
 851     ] [
 852         [ over - ] 2dip move-backward
 853     ] if ;
 854
 855 : open-slice ( shift from seq -- )
 856     pick 0 = [
 857         3drop
 858     ] [
 859         [ ] [ nip length + ] [ 2nip ] 3tri
 860         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 861         set-length
 862     ] if ;
 863
 864 PRIVATE>
 865
 866 : delete-slice ( from to seq -- )
 867     check-slice [ over [ - ] dip ] dip open-slice ;
 868
 869 : remove-nth! ( n seq -- seq )
 870     [ [ dup 1 + ] dip delete-slice ] keep ;
 871
 872 : snip ( from to seq -- head tail )
 873     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 874
 875 : snip-slice ( from to seq -- head tail )
 876     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 877
 878 : replace-slice ( new from to seq -- seq' )
 879     snip-slice surround ;
 880
 881 : remove-nth ( n seq -- seq' )
 882     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 883
 884 : pop ( seq -- elt )
 885     [ length 1 - ] keep over 0 >=
 886     [ [ nth-unsafe ] [ shorten ] 2bi ]
 887     [ bounds-error ] if ;
 888
 889 : exchange ( m n seq -- )
 890     [ nip bounds-check 2drop ]
 891     [ bounds-check 3drop ]
 892     [ exchange-unsafe ]
 893     3tri ;
 894
 895 : midpoint@ ( seq -- n ) length 2/ ; inline
 896
 897 : reverse! ( seq -- seq )
 898     [
 899         [ midpoint@ ] [ length ] [ ] tri
 900         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 901         each-integer
 902     ] keep ;
 903
 904 : reverse ( seq -- newseq )
 905      [
 906         dup [ length ] keep new-sequence
 907         [ 0 swap copy-unsafe ] keep reverse!
 908     ] keep like ;
 909
 910 GENERIC: sum-lengths ( seq -- n )
 911
 912 M: object sum-lengths
 913     0 [ length + ] reduce ;
 914
 915 M: repetition sum-lengths
 916     [ length>> ] [ elt>> length ] bi * ;
 917
 918 : concat-as ( seq exemplar -- newseq )
 919     [
 920         [ dup sum-lengths ] dip new-resizable
 921         [ [ push-all ] curry each ] keep
 922     ] keep like ; inline
 923
 924 : concat ( seq -- newseq )
 925     [ { } ] [ dup first concat-as ] if-empty ;
 926
 927 <PRIVATE
 928
 929 : joined-length ( seq glue -- n )
 930     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 931
 932 PRIVATE>
 933
 934 : join-as ( seq glue exemplar -- newseq )
 935     over empty? [ nip concat-as ] [
 936         [
 937             2dup joined-length over new-resizable [
 938                 [ [ push-all ] 2curry ]
 939                 [ nip [ push-all ] curry ] 2bi
 940                 interleave
 941             ] keep
 942         ] dip like
 943     ] if ;
 944
 945 : join ( seq glue -- newseq )
 946     dup join-as ; inline
 947
 948 <PRIVATE
 949
 950 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 951     [
 952         [ over length [-] dup 0 = [ drop ] ] dip
 953         [ <repetition> ] curry
 954     ] dip compose if ; inline
 955
 956 PRIVATE>
 957
 958 : pad-head ( seq n elt -- padded )
 959     [ swap dup append-as ] padding ;
 960
 961 : pad-tail ( seq n elt -- padded )
 962     [ append ] padding ;
 963
 964 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 965 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 966 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 967 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 968
 969 : head? ( seq begin -- ? )
 970     2dup shorter? [
 971         2drop f
 972     ] [
 973         [ length [ head-slice ] keep swap ] keep
 974         mismatch-unsafe not
 975     ] if ;
 976
 977 : tail? ( seq end -- ? )
 978     2dup shorter? [
 979         2drop f
 980     ] [
 981         [ length [ tail-slice* ] keep swap ] keep
 982         mismatch-unsafe not
 983     ] if ;
 984
 985 : cut-slice ( seq n -- before-slice after-slice )
 986     [ head-slice ] [ tail-slice ] 2bi ; inline
 987
 988 : cut-slice* ( seq n -- before-slice after-slice )
 989     [ head-slice* ] [ tail-slice* ] 2bi ;
 990
 991 : insert-nth ( elt n seq -- seq' )
 992     swap cut-slice [ swap suffix ] dip append ;
 993
 994 : halves ( seq -- first-slice second-slice )
 995     dup midpoint@ cut-slice ; inline
 996
 997 <PRIVATE
 998
 999 : nth2-unsafe ( n seq -- a b )
1000     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1001
1002 : nth3-unsafe ( n seq -- a b c )
1003     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1004
1005 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1006     ! We can't use case here since combinators depends on
1007     ! sequences
1008     dup 4 < [
1009         integer>fixnum {
1010             [ 2drop nip ]
1011             [ 2nip swap nth-unsafe ]
1012             [ -rot [ drop swap nth2-unsafe ] dip call ]
1013             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1014         } dispatch
1015     ] [
1016         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1017         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1018         pick [ 3bi ] dip call
1019     ] if ; inline recursive
1020
1021 PRIVATE>
1022
1023 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1024     pick dup slice? [
1025         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1026     ] [
1027         length 0 max 0 swap
1028     ] if (binary-reduce) ; inline
1029
1030 : cut ( seq n -- before after )
1031     [ head ] [ tail ] 2bi ;
1032
1033 : cut* ( seq n -- before after )
1034     [ head* ] [ tail* ] 2bi ;
1035
1036 : subseq-starts-at? ( i seq subseq -- ? )
1037     [ length swap ] keep
1038     '[
1039         [ + _ nth-unsafe ] keep _ nth-unsafe =
1040     ] with all-integers? ; inline
1041
1042 : find-subseq-from ( n seq subseq -- i/f )
1043     [ [ length ] bi@ - 1 + ] 2keep
1044     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1045
1046 : subseq-start-from ( subseq seq n -- i/f ) spin find-subseq-from ; inline
1047
1048 : find-subseq ( seq subseq -- i/f ) [ 0 ] 2dip find-subseq-from ; inline
1049
1050 : find-subseq? ( seq subseq -- ? ) find-subseq >boolean ; inline
1051
1052 : subseq-start ( subseq seq -- i/f ) swap find-subseq ; inline
1053
1054 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline
1055
1056 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1057     2dup mismatch [ 2dup min-length ] unless*
1058     [ tail-slice ] curry bi@ ;
1059
1060 : unclip ( seq -- rest first )
1061     [ rest ] [ first-unsafe ] bi ;
1062
1063 : unclip-last ( seq -- butlast last )
1064     [ but-last ] [ last-unsafe ] bi ;
1065
1066 : unclip-slice ( seq -- rest-slice first )
1067     [ rest-slice ] [ first-unsafe ] bi ; inline
1068
1069 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1070     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1071     '[ swap _ dip swap @ ] 1 each-from ; inline
1072
1073 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1074     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1075     '[ rot _ dip swap @ ] 1 2each-from ; inline
1076
1077 <PRIVATE
1078
1079 : (map-find) ( seq quot find-quot -- result elt )
1080     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1081
1082 PRIVATE>
1083
1084 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1085     [ find ] (map-find) ; inline
1086
1087 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1088     [ find-last ] (map-find) ; inline
1089
1090 : unclip-last-slice ( seq -- butlast-slice last )
1091     [ but-last-slice ] [ last-unsafe ] bi ; inline
1092
1093 <PRIVATE
1094
1095 : (trim-head) ( seq quot -- seq n )
1096     over [ [ not ] compose find drop ] dip swap
1097     [ dup length ] unless* ; inline
1098
1099 : (trim-tail) ( seq quot -- seq n )
1100     over [ [ not ] compose find-last drop ?1+ ] dip
1101     swap ; inline
1102
1103 PRIVATE>
1104
1105 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1106     (trim-head) tail-slice ; inline
1107
1108 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1109     (trim-head) tail ; inline
1110
1111 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1112     (trim-tail) head-slice ; inline
1113
1114 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1115     (trim-tail) head ; inline
1116
1117 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1118     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1119
1120 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1121     [ trim-slice ] [ drop ] 2bi like ; inline
1122
1123 GENERIC: sum ( seq -- n )
1124 M: object sum 0 [ + ] binary-reduce ; inline
1125 M: iota sum length dup 1 - * 2/ ; inline
1126 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1127
1128 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1129
1130 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1131
1132 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1133
1134 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1135     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1136
1137 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1138     [ 1 0 ? ] compose map-sum ; inline
1139
1140 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1141     [ with each ] 2curry each ; inline
1142
1143 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1144     [ with { } map-as ] 2curry { } map-as ; inline
1145
1146 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1147     [ 2sequence ] curry cartesian-map ; inline
1148
1149 : cartesian-product ( seq1 seq2 -- newseq )
1150     dup cartesian-product-as ; inline
1151
1152 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1153     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1154
1155 <PRIVATE
1156
1157 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1158     [
1159         [ keep swap ] curry [ [ first ] dip call ] 2keep
1160         [ curry 2dip pick over ] curry
1161     ] [
1162         [ [ 2drop ] [ 2nipd ] if ] compose
1163     ] bi* compose 1 each-from drop ; inline
1164
1165 PRIVATE>
1166
1167 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1168     [ after? ] select-by ; inline
1169
1170 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1171     [ before? ] select-by ; inline
1172
1173 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1174
1175 : longest ( seqs -- elt ) [ length ] supremum-by ;
1176
1177 ! We hand-optimize flip to such a degree because type hints
1178 ! cannot express that an array is an array of arrays yet, and
1179 ! this word happens to be performance-critical since the compiler
1180 ! itself uses it. Optimizing it like this reduced compile time.
1181 <PRIVATE
1182
1183 : generic-flip ( matrix -- newmatrix )
1184     [ [ length ] [ min ] map-reduce ] keep
1185     '[ _ [ nth-unsafe ] with { } map-as ] { } map-integers ; inline
1186
1187 USE: arrays
1188
1189 : array-flip ( matrix -- newmatrix )
1190     { array } declare
1191     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1192     '[ _ [ { array } declare array-nth ] with { } map-as ] { } map-integers ;
1193
1194 PRIVATE>
1195
1196 : flip ( matrix -- newmatrix )
1197     dup empty? [
1198         dup array? [
1199             dup [ array? ] all?
1200             [ array-flip ] [ generic-flip ] if
1201         ] [ generic-flip ] if
1202     ] unless ;