core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC# bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check? ( n seq -- ? )
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota-tuple { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : iota ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     \ iota-tuple boa ; inline
 112
 113 M: iota-tuple length n>> ; inline
 114 M: iota-tuple nth-unsafe drop ; inline
 115
 116 INSTANCE: iota-tuple immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217 { from read-only }
 218 { to read-only }
 219 { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq reason ;
 225
 226 : check-slice-error ( from to seq ? string -- from to seq )
 227     [ slice-error ] curry when ; inline
 228
 229 : check-slice ( from to seq -- from to seq )
 230     3dup
 231     [ 2drop 0 < "start < 0" check-slice-error ]
 232     [ [ drop ] 2dip length > "end > sequence" check-slice-error ]
 233     [ drop > "start > end" check-slice-error ]
 234     3tri ; inline
 235
 236 <PRIVATE
 237
 238 : <slice-unsafe> ( from to seq -- slice )
 239     dup slice? [ collapse-slice ] when slice boa ; inline
 240
 241 PRIVATE>
 242
 243 : <slice> ( from to seq -- slice )
 244     check-slice <slice-unsafe> ; inline
 245
 246 M: slice virtual-exemplar seq>> ; inline
 247
 248 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 249
 250 M: slice length [ to>> ] [ from>> ] bi - ; inline
 251
 252 : short ( seq n -- seq n' ) over length min ; inline
 253
 254 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 255
 256 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 257
 258 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 259
 260 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 261
 262 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 263
 264 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 265
 266 INSTANCE: slice virtual-sequence
 267
 268 ! One element repeated many times
 269 TUPLE: repetition { len read-only } { elt read-only } ;
 270
 271 C: <repetition> repetition
 272
 273 M: repetition length len>> ; inline
 274 M: repetition nth-unsafe nip elt>> ; inline
 275
 276 INSTANCE: repetition immutable-sequence
 277
 278 <PRIVATE
 279
 280 ERROR: integer-length-expected obj ;
 281
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i read-only }
 287     { src read-only }
 288     { dst-i read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : ((copy)) ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     #! The check-length call forces partial dispatch
 315     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 316
 317 PRIVATE>
 318
 319 : subseq ( from to seq -- subseq )
 320     [ check-slice subseq>copy (copy) ] keep like ;
 321
 322 : head ( seq n -- headseq ) (head) subseq ;
 323
 324 : tail ( seq n -- tailseq ) (tail) subseq ;
 325
 326 : rest ( seq -- tailseq ) 1 tail ;
 327
 328 : head* ( seq n -- headseq ) from-end head ;
 329
 330 : tail* ( seq n -- tailseq ) from-end tail ;
 331
 332 : but-last ( seq -- headseq ) 1 head* ;
 333
 334 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 335
 336 M: sequence clone-like
 337     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 338
 339 M: immutable-sequence clone-like like ; inline
 340
 341 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 342
 343 <PRIVATE
 344
 345 : (append) ( seq1 seq2 accum -- accum )
 346     [ [ over length ] dip copy-unsafe ]
 347     [ 0 swap copy-unsafe ]
 348     [ ] tri ; inline
 349
 350 PRIVATE>
 351
 352 : append-as ( seq1 seq2 exemplar -- newseq )
 353     [ 2dup [ length ] bi@ + ] dip
 354     [ (append) ] new-like ; inline
 355
 356 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 357     [ 3dup [ length ] tri@ + + ] dip [
 358         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 359         [ (append) ] bi
 360     ] new-like ; inline
 361
 362 : append ( seq1 seq2 -- newseq ) over append-as ;
 363
 364 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 365
 366 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 367
 368 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 369
 370 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 371
 372 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 373
 374 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 375     [ [ nth ] dip call ] 3keep drop set-nth-unsafe ; inline
 376
 377 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 378
 379 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 380
 381 <PRIVATE
 382
 383 : ((each)) ( seq -- n quot )
 384     [ length ] keep [ nth-unsafe ] curry ; inline
 385
 386 : (each) ( seq quot -- n quot' )
 387     [ ((each)) ] dip compose ; inline
 388
 389 : (each-index) ( seq quot -- n quot' )
 390     [ ((each)) [ keep ] curry ] dip compose ; inline
 391
 392 : (collect) ( quot into -- quot' )
 393     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 394
 395 : collect ( n quot into -- )
 396     (collect) each-integer ; inline
 397
 398 : map-into ( seq quot into -- )
 399     [ (each) ] dip collect ; inline
 400
 401 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 402     [ nth-unsafe ] bi-curry@ bi ; inline
 403
 404 : ((2each)) ( seq1 seq2 -- n quot )
 405     [ min-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 406
 407 : (2each) ( seq1 seq2 quot -- n quot' )
 408     [ ((2each)) ] dip compose ; inline
 409
 410 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 411     [ nth-unsafe ] tri-curry@ tri ; inline
 412
 413 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 414     [
 415         [ [ length ] tri@ min min ]
 416         [ [ 3nth-unsafe ] 3curry ] 3bi
 417     ] dip compose ; inline
 418
 419 : finish-find ( i seq -- i elt )
 420     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 421
 422 : (find) ( seq quot quot' -- i elt )
 423     pick [ [ (each) ] dip call ] dip finish-find ; inline
 424
 425 : (find-from) ( n seq quot quot' -- i elt )
 426     [ 2dup bounds-check? ] 2dip
 427     [ (find) ] 2curry
 428     [ 2drop f f ]
 429     if ; inline
 430
 431 : (find-index) ( seq quot quot' -- i elt )
 432     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 433
 434 : (find-index-from) ( n seq quot quot' -- i elt )
 435     [ 2dup bounds-check? ] 2dip
 436     [ (find-index) ] 2curry
 437     [ 2drop f f ]
 438     if ; inline
 439
 440 : (accumulate) ( seq identity quot -- identity seq quot )
 441     swapd [ curry keep ] curry ; inline
 442
 443 PRIVATE>
 444
 445 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 446     (each) each-integer ; inline
 447
 448 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 449     swapd each ; inline
 450
 451 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 452     [ over ] dip [ [ collect ] keep ] new-like ; inline
 453
 454 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 455     [ (each) ] dip map-integers ; inline
 456
 457 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 458     over map-as ; inline
 459
 460 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 461     [ [ drop ] prepose ] dip map-integers ; inline
 462
 463 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 464     { } replicate-as ; inline
 465
 466 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 467     over [ map-into ] keep ; inline
 468
 469 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 470     [ (accumulate) ] dip map-as ; inline
 471
 472 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 473     pick accumulate-as ; inline
 474
 475 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 476     (accumulate) map! ; inline
 477
 478 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 479     (2each) each-integer ; inline
 480
 481 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 482     [ -rot ] dip 2each ; inline
 483
 484 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 485     [ (2each) ] dip map-integers ; inline
 486
 487 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 488     pick 2map-as ; inline
 489
 490 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 491     (2each) all-integers? ; inline
 492
 493 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 494     (3each) each-integer ; inline
 495
 496 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 497     [ (3each) ] dip map-integers ; inline
 498
 499 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 500     [ pick ] dip swap 3map-as ; inline
 501
 502 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 503     [ (find-integer) ] (find-from) ; inline
 504
 505 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 506     [ find-integer ] (find) ; inline
 507
 508 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 509     [ nip find-last-integer ] (find-from) ; inline
 510
 511 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 512     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 513
 514 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 515     [ (find-integer) ] (find-index-from) ; inline
 516
 517 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 518     [ find-integer ] (find-index) ; inline
 519
 520 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 521     (each) all-integers? ; inline
 522
 523 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 524     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 525
 526 <PRIVATE
 527
 528 : (selector-for) ( quot length exemplar -- selector accum )
 529     new-resizable [ [ push-if ] 2curry ] keep ; inline
 530
 531 PRIVATE>
 532
 533 : selector-for ( quot exemplar -- selector accum )
 534     [ length ] keep (selector-for) ; inline
 535
 536 : selector ( quot -- selector accum )
 537     V{ } selector-for ; inline
 538
 539 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 540     pick length over [ (selector-for) [ each ] dip ] 2curry dip like ; inline
 541
 542 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 543     over filter-as ; inline
 544
 545 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 546     [ keep swap ] 2dip ? push ; inline
 547
 548 : 2selector ( quot -- selector accum1 accum2 )
 549     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 550
 551 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 552     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 553
 554 : collector-for ( quot exemplar -- quot' vec )
 555     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 556
 557 : collector ( quot -- quot' vec )
 558     V{ } collector-for ; inline
 559
 560 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 561     dup [ collector-for [ while ] dip ] curry dip like ; inline
 562
 563 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 564     { } produce-as ; inline
 565
 566 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 567     [ dup ] swap [ keep ] curry produce nip ; inline
 568
 569 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 570     (each-index) each-integer ; inline
 571
 572 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 573     pick empty? [ 3drop ] [
 574         [ [ drop first-unsafe ] dip call ]
 575         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 576         3bi
 577     ] if ; inline
 578
 579 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 580     [ dup length iota ] dip 2map ; inline
 581
 582 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 583     swapd each-index ; inline
 584
 585 : index ( obj seq -- n )
 586     [ = ] with find drop ;
 587
 588 : index-from ( obj i seq -- n )
 589     rot [ = ] curry find-from drop ;
 590
 591 : last-index ( obj seq -- n )
 592     [ = ] with find-last drop ;
 593
 594 : last-index-from ( obj i seq -- n )
 595     rot [ = ] curry find-last-from drop ;
 596
 597 <PRIVATE
 598
 599 : (indices) ( elt i obj accum -- )
 600     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 601
 602 PRIVATE>
 603
 604 : indices ( obj seq -- indices )
 605     swap V{ } clone
 606     [ [ (indices) ] 2curry each-index ] keep ;
 607
 608 <PRIVATE
 609
 610 : nths-unsafe ( indices seq -- seq' )
 611     [ [ nth-unsafe ] curry ] keep map-as ;
 612
 613 PRIVATE>
 614
 615 : nths ( indices seq -- seq' )
 616     [ [ nth ] curry ] keep map-as ;
 617
 618 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 619     find drop >boolean ; inline
 620
 621 : member? ( elt seq -- ? )
 622     [ = ] with any? ;
 623
 624 : member-eq? ( elt seq -- ? )
 625     [ eq? ] with any? ;
 626
 627 : remove ( elt seq -- newseq )
 628     [ = not ] with filter ;
 629
 630 : remove-eq ( elt seq -- newseq )
 631     [ eq? not ] with filter ;
 632
 633 : sift ( seq -- newseq )
 634     [ ] filter ;
 635
 636 : harvest ( seq -- newseq )
 637     [ empty? not ] filter ;
 638
 639 <PRIVATE
 640
 641 : mismatch-unsafe ( n seq1 seq2 -- i )
 642     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 643
 644 PRIVATE>
 645
 646 : mismatch ( seq1 seq2 -- i )
 647     [ min-length ] 2keep mismatch-unsafe ; inline
 648
 649 M: sequence <=>
 650     [ mismatch ] 2keep pick
 651     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 652
 653 : sequence= ( seq1 seq2 -- ? )
 654     2dup [ length ] bi@ dupd =
 655     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 656
 657 ERROR: assert-sequence got expected ;
 658
 659 : assert-sequence= ( a b -- )
 660     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 661
 662 <PRIVATE
 663
 664 : sequence-hashcode-step ( oldhash newpart -- newhash )
 665     integer>fixnum swap [
 666         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 667         fixnum+fast fixnum+fast
 668     ] keep fixnum-bitxor ; inline
 669
 670 PRIVATE>
 671
 672 : sequence-hashcode ( n seq -- x )
 673     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 674
 675 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 676
 677 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 678
 679 : move ( to from seq -- )
 680     2over =
 681     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 682
 683 <PRIVATE
 684
 685 : move-unsafe ( to from seq -- )
 686     2over =
 687     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 688
 689 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 690     2dup length < [
 691         [ move-unsafe ] 3keep
 692         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 693         [ 1 + ] dip
 694         (filter!)
 695     ] [ nip set-length drop ] if ; inline recursive
 696
 697 PRIVATE>
 698
 699 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 700     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 701
 702 : remove! ( elt seq -- seq )
 703     [ = not ] with filter! ;
 704
 705 : remove-eq! ( elt seq -- seq )
 706     [ eq? not ] with filter! ;
 707
 708 : prefix ( seq elt -- newseq )
 709     over [ over length 1 + ] dip [
 710         (1sequence) [ 1 swap copy-unsafe ] keep
 711     ] new-like ;
 712
 713 : suffix ( seq elt -- newseq )
 714     over [ over length 1 + ] dip [
 715         [ [ over length ] dip set-nth-unsafe ] keep
 716         [ 0 swap copy-unsafe ] keep
 717     ] new-like ;
 718
 719 : suffix! ( seq elt -- seq ) over push ; inline
 720
 721 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 722
 723 : last ( seq -- elt )
 724     [ length 1 - ] keep
 725     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 726
 727 <PRIVATE
 728
 729 : last-unsafe ( seq -- elt )
 730     [ length 1 - ] [ nth-unsafe ] bi ; inline
 731
 732 PRIVATE>
 733
 734 : set-last ( elt seq -- )
 735     [ length 1 - ] keep
 736     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 737
 738 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 739
 740 <PRIVATE
 741
 742 : move-backward ( shift from to seq -- )
 743     2over = [
 744         4drop
 745     ] [
 746         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 747         move-backward
 748     ] if ;
 749
 750 : move-forward ( shift from to seq -- )
 751     2over = [
 752         4drop
 753     ] [
 754         [ [ pick [ dup dup ] dip + swap ] dip move-unsafe 1 - ] keep
 755         move-forward
 756     ] if ;
 757
 758 : (open-slice) ( shift from to seq ? -- )
 759     [
 760         [ [ 1 - ] bi@ ] dip move-forward
 761     ] [
 762         [ over - ] 2dip move-backward
 763     ] if ;
 764
 765 : open-slice ( shift from seq -- )
 766     pick 0 = [
 767         3drop
 768     ] [
 769         pick over length + over
 770         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 771         set-length
 772     ] if ;
 773
 774 PRIVATE>
 775
 776 : delete-slice ( from to seq -- )
 777     check-slice [ over [ - ] dip ] dip open-slice ;
 778
 779 : remove-nth! ( n seq -- seq )
 780     [ [ dup 1 + ] dip delete-slice ] keep ;
 781
 782 : snip ( from to seq -- head tail )
 783     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 784
 785 : snip-slice ( from to seq -- head tail )
 786     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 787
 788 : replace-slice ( new from to seq -- seq' )
 789     snip-slice surround ;
 790
 791 : remove-nth ( n seq -- seq' )
 792     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 793
 794 : pop ( seq -- elt )
 795     [ length 1 - ] keep over 0 >=
 796     [ [ nth-unsafe ] [ shorten ] 2bi ]
 797     [ bounds-error ] if ;
 798
 799 : exchange ( m n seq -- )
 800     [ nip bounds-check 2drop ]
 801     [ bounds-check 3drop ]
 802     [ exchange-unsafe ]
 803     3tri ;
 804
 805 : midpoint@ ( seq -- n ) length 2/ ; inline
 806
 807 : reverse! ( seq -- seq )
 808     [
 809         [ midpoint@ ] [ length ] [ ] tri
 810         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 811         each-integer
 812     ] keep ;
 813
 814 : reverse ( seq -- newseq )
 815      [
 816         dup [ length ] keep new-sequence
 817         [ 0 swap copy-unsafe ] keep reverse!
 818     ] keep like ;
 819
 820 : sum-lengths ( seq -- n )
 821     0 [ length + ] reduce ;
 822
 823 : concat-as ( seq exemplar -- newseq )
 824     swap [ { } ] [
 825         [ sum-lengths over new-resizable ] keep
 826         [ append! ] each
 827     ] if-empty swap like ;
 828
 829 : concat ( seq -- newseq )
 830     [ { } ] [ dup first concat-as ] if-empty ;
 831
 832 <PRIVATE
 833
 834 : joined-length ( seq glue -- n )
 835     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 836
 837 PRIVATE>
 838
 839 : join-as ( seq glue exemplar -- newseq )
 840     over empty? [ nip concat-as ] [
 841         [
 842             2dup joined-length over new-resizable [
 843                 [ [ push-all ] 2curry ]
 844                 [ nip [ push-all ] curry ] 2bi
 845                 interleave
 846             ] keep
 847         ] dip like
 848     ] if ;
 849
 850 : join ( seq glue -- newseq )
 851     dup join-as ; inline
 852
 853 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 854     [
 855         [ over length [-] dup 0 = [ drop ] ] dip
 856         [ <repetition> ] curry
 857     ] dip compose if ; inline
 858
 859 : pad-head ( seq n elt -- padded )
 860     [ swap dup append-as ] padding ;
 861
 862 : pad-tail ( seq n elt -- padded )
 863     [ append ] padding ;
 864
 865 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 866 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ;
 867 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 868 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 869
 870 : head? ( seq begin -- ? )
 871     2dup shorter? [
 872         2drop f
 873     ] [
 874         [ nip ] [ length head-slice ] 2bi sequence=
 875     ] if ;
 876
 877 : tail? ( seq end -- ? )
 878     2dup shorter? [
 879         2drop f
 880     ] [
 881         [ nip ] [ length tail-slice* ] 2bi sequence=
 882     ] if ;
 883
 884 : cut-slice ( seq n -- before-slice after-slice )
 885     [ head-slice ] [ tail-slice ] 2bi ; inline
 886
 887 : insert-nth ( elt n seq -- seq' )
 888     swap cut-slice [ swap suffix ] dip append ;
 889
 890 : halves ( seq -- first-slice second-slice )
 891     dup midpoint@ cut-slice ; inline
 892
 893 <PRIVATE
 894
 895 : nth2-unsafe ( n seq -- a b )
 896     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 897
 898 : nth3-unsafe ( n seq -- a b c )
 899     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 900
 901 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 902     #! We can't use case here since combinators depends on
 903     #! sequences
 904     dup 4 < [
 905         integer>fixnum {
 906             [ 2drop nip ]
 907             [ 2nip swap nth-unsafe ]
 908             [ -rot [ drop swap nth2-unsafe ] dip call ]
 909             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 910         } dispatch
 911     ] [
 912         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 913         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 914         pick [ 3bi ] dip call
 915     ] if ; inline recursive
 916
 917 PRIVATE>
 918
 919 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 920     pick length 0 max 0 swap (binary-reduce) ; inline
 921
 922 : cut ( seq n -- before after )
 923     [ head ] [ tail ] 2bi ;
 924
 925 : cut* ( seq n -- before after )
 926     [ head* ] [ tail* ] 2bi ;
 927
 928 <PRIVATE
 929
 930 : (start) ( subseq seq n length -- subseq seq ? )
 931     [
 932         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 933     ] all-integers? nip ; inline
 934
 935 PRIVATE>
 936
 937 : start* ( subseq seq n -- i )
 938     pick length [ pick length swap - 1 + ] keep
 939     [ (start) ] curry (find-integer) 2nip ;
 940
 941 : start ( subseq seq -- i ) 0 start* ; inline
 942
 943 : subseq? ( subseq seq -- ? ) start >boolean ;
 944
 945 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 946     2dup mismatch [ 2dup min-length ] unless*
 947     [ tail-slice ] curry bi@ ;
 948
 949 : unclip ( seq -- rest first )
 950     [ rest ] [ first-unsafe ] bi ;
 951
 952 : unclip-last ( seq -- butlast last )
 953     [ but-last ] [ last-unsafe ] bi ;
 954
 955 : unclip-slice ( seq -- rest-slice first )
 956     [ rest-slice ] [ first-unsafe ] bi ; inline
 957
 958 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 959     [ [ dup first ] dip [ call ] keep ] dip compose
 960     swapd [ 1 ] 2dip (each) (each-integer) ; inline
 961
 962 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 963     [ [ 2dup [ first ] bi@ ] dip [ call ] keep ] dip compose
 964     [ -rot ] dip [ 1 ] 3dip (2each) (each-integer) ; inline
 965
 966 <PRIVATE
 967
 968 : (map-find) ( seq quot find-quot -- result elt )
 969     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 970     [ [ drop f ] unless ] dip ; inline
 971
 972 PRIVATE>
 973
 974 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 975     [ find ] (map-find) ; inline
 976
 977 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 978     [ find-last ] (map-find) ; inline
 979
 980 : unclip-last-slice ( seq -- butlast-slice last )
 981     [ but-last-slice ] [ last-unsafe ] bi ; inline
 982
 983 <PRIVATE
 984
 985 : (trim-head) ( seq quot -- seq n )
 986     over [ [ not ] compose find drop ] dip
 987     [ length or ] keep swap ; inline
 988
 989 : (trim-tail) ( seq quot -- seq n )
 990     over [ [ not ] compose find-last drop ?1+ ] dip
 991     swap ; inline
 992
 993 PRIVATE>
 994
 995 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 996     (trim-head) tail-slice ; inline
 997
 998 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 999     (trim-head) tail ; inline
1000
1001 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1002     (trim-tail) head-slice ; inline
1003
1004 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1005     (trim-tail) head ; inline
1006
1007 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1008     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1009
1010 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1011     [ trim-slice ] [ drop ] 2bi like ; inline
1012
1013 GENERIC: sum ( seq -- n )
1014 M: object sum 0 [ + ] binary-reduce ; inline
1015 M: iota-tuple sum length dup 1 - * 2/ ; inline
1016
1017 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1018
1019 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
1020
1021 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
1022
1023 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1024     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1025
1026 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1027     [ 1 0 ? ] compose map-sum ; inline
1028
1029 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1030     [ with each ] 2curry each ; inline
1031
1032 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1033     [ with map ] 2curry map ; inline
1034
1035 : cartesian-product ( seq1 seq2 -- newseq )
1036     [ { } 2sequence ] cartesian-map ;
1037
1038 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
1039     -rot (each) (each-integer) ; inline
1040
1041 <PRIVATE
1042
1043 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1044     [
1045         [ keep swap ] curry [ [ first ] dip call ] 2keep
1046         [ curry 2dip pick over ] curry
1047     ] [
1048         [ [ 2drop ] [ [ 2drop ] 2dip ] if ] compose
1049     ] bi* compose 1 each-from drop ; inline
1050
1051 PRIVATE>
1052
1053 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1054     [ after? ] select-by ; inline
1055
1056 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1057     [ before? ] select-by ; inline
1058
1059 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1060
1061 : longest ( seqs -- elt ) [ length ] supremum-by ;
1062
1063 ! We hand-optimize flip to such a degree because type hints
1064 ! cannot express that an array is an array of arrays yet, and
1065 ! this word happens to be performance-critical since the compiler
1066 ! itself uses it. Optimizing it like this reduced compile time.
1067 <PRIVATE
1068
1069 : generic-flip ( matrix -- newmatrix )
1070     [
1071         [ first-unsafe length 1 ] keep
1072         [ length min ] (each) (each-integer) iota
1073     ] keep
1074     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
1075
1076 USE: arrays
1077
1078 : array-length ( array -- len )
1079     { array } declare length>> ; inline
1080
1081 : array-flip ( matrix -- newmatrix )
1082     { array } declare
1083     [
1084         [ first-unsafe array-length 1 ] keep
1085         [ array-length min ] (each) (each-integer) iota
1086     ] keep
1087     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
1088
1089 PRIVATE>
1090
1091 : flip ( matrix -- newmatrix )
1092     dup empty? [
1093         dup array? [
1094             dup [ array? ] all?
1095             [ array-flip ] [ generic-flip ] if
1096         ] [ generic-flip ] if
1097     ] unless ;