core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (1sequence) ( obj seq -- seq )
 139     [ 0 swap set-nth-unsafe ] keep ; inline
 140
 141 : (2sequence) ( obj1 obj2 seq -- seq )
 142     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 146
 147 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 148     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 149
 150 PRIVATE>
 151
 152 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 153
 154 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 155
 156 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : >slice< ( slice -- from to seq )
 222     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 223
 224 : collapse-slice ( m n slice -- m' n' seq )
 225     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 226
 227 ERROR: slice-error from to seq ;
 228
 229 : check-slice ( from to seq -- from to seq )
 230     pick 0 < [ slice-error ] when
 231     2dup length > [ slice-error ] when
 232     2over > [ slice-error ] when ; inline
 233
 234 <PRIVATE
 235
 236 : <slice-unsafe> ( from to seq -- slice )
 237     dup slice? [ collapse-slice ] when slice boa ; inline
 238
 239 PRIVATE>
 240
 241 : <slice> ( from to seq -- slice )
 242     check-slice <slice-unsafe> ; inline
 243
 244 M: slice virtual-exemplar seq>> ; inline
 245
 246 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 247
 248 M: slice length [ to>> ] [ from>> ] bi - ; inline
 249
 250 : index-or-length ( seq n -- seq n' ) over length min ; inline
 251
 252 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 253
 254 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 255
 256 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 257
 258 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 259
 260 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 261
 262 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 263
 264 INSTANCE: slice virtual-sequence
 265
 266 ! One element repeated many times
 267 TUPLE: repetition
 268     { length integer read-only }
 269     { elt read-only } ;
 270
 271 : <repetition> ( len elt -- repetition )
 272     over 0 < [ non-negative-integer-expected ] when
 273     repetition boa ; inline
 274
 275 M: repetition length length>> ; inline
 276 M: repetition nth-unsafe nip elt>> ; inline
 277
 278 INSTANCE: repetition immutable-sequence
 279
 280 <PRIVATE
 281
 282 ERROR: integer-length-expected obj ;
 283
 284 ! The check-length call forces partial dispatch
 285 : check-length ( n -- n )
 286     dup integer? [ integer-length-expected ] unless ; inline
 287
 288 : >sequence< ( seq -- i n seq )
 289     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 290
 291 : length-sequence ( seq -- n seq )
 292     [ length check-length ] [ ] bi ; inline
 293
 294 : >underlying< ( slice/seq -- i n slice/seq )
 295     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 296
 297 TUPLE: copier
 298     { src-i integer read-only }
 299     { src read-only }
 300     { dst-i integer read-only }
 301     { dst read-only } ;
 302
 303 C: <copier> copier
 304
 305 : copy-nth-unsafe ( n copy -- )
 306     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 307     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 308
 309 : (copy) ( n copy -- dst )
 310     over 0 <= [ nip dst>> ] [
 311         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 312     ] if ; inline recursive
 313
 314 : subseq>copy ( from to seq -- n copy )
 315     [ over - check-length swap ] dip
 316     3dup nip new-sequence 0 swap <copier> ; inline
 317
 318 : bounds-check-head ( n seq -- n seq )
 319     over 0 < [ bounds-error ] when ; inline
 320
 321 : check-copy ( src n dst -- src n dst )
 322     3dup bounds-check-head
 323     [ swap length + ] dip lengthen ; inline
 324
 325 : copy-unsafe ( src i dst -- )
 326     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 327
 328 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 329     [ subseq>copy (copy) ] dip like ; inline
 330
 331 : subseq-unsafe ( from to seq -- subseq )
 332     dup subseq-unsafe-as ; inline
 333
 334 PRIVATE>
 335
 336 : subseq-as ( from to seq exemplar -- subseq )
 337     [ check-slice ] dip subseq-unsafe-as ;
 338
 339 : subseq ( from to seq -- subseq )
 340     dup subseq-as ;
 341
 342 : head ( seq n -- headseq ) head-to-index subseq ;
 343
 344 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 345
 346 : rest ( seq -- tailseq ) 1 tail ;
 347
 348 : head* ( seq n -- headseq ) from-tail head ;
 349
 350 : tail* ( seq n -- tailseq ) from-tail tail ;
 351
 352 : but-last ( seq -- headseq ) 1 head* ;
 353
 354 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 355
 356 M: sequence clone-like
 357     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 358
 359 M: immutable-sequence clone-like like ; inline
 360
 361 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 362
 363 <PRIVATE
 364
 365 : (append) ( seq1 seq2 accum -- accum )
 366     [ [ over length ] dip copy-unsafe ]
 367     [ 0 swap copy-unsafe ]
 368     [ ] tri ; inline
 369
 370 PRIVATE>
 371
 372 : append-as ( seq1 seq2 exemplar -- newseq )
 373     [ 2dup [ length ] bi@ + ] dip
 374     [ (append) ] new-like ; inline
 375
 376 : append ( seq1 seq2 -- newseq ) over append-as ;
 377
 378 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 379
 380 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 381
 382 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 383     [ 3dup [ length ] tri@ + + ] dip [
 384         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 385         [ (append) ] bi
 386     ] new-like ; inline
 387
 388 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 389
 390 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 391     [ swap ] 2dip 3append-as ; inline
 392
 393 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 394
 395 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 396
 397 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 398
 399 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 400
 401 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 402
 403 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 404     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 405
 406 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 407
 408 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 409
 410 <PRIVATE
 411
 412 : sequence-operator ( seq quot -- i n quot' )
 413     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 414
 415 : length-iterator ( seq -- n quot' )
 416     length-sequence [ nth-unsafe ] curry ; inline
 417
 418 : length-operator ( seq quot -- n quot' )
 419     [ length-iterator ] dip compose ; inline
 420
 421 : length-operator-last ( seq quot -- n quot' )
 422     length-operator [ 1 - ] dip ; inline
 423
 424 : sequence-operator-from ( seq quot i -- i n quot' )
 425     -rot length-operator ; inline
 426
 427 : sequence-operator-last-from ( seq quot i -- n quot' )
 428     -rot length-operator-last nip ; inline
 429
 430 : collect ( n quot into -- )
 431     [ [ keep ] dip set-nth-unsafe ] 2curry each-integer ; inline
 432
 433 : sequence-index-operator ( seq quot -- n quot' )
 434     [ length-iterator [ keep ] curry ] dip compose ; inline
 435
 436 : map-into ( seq quot into -- )
 437     [ length-operator ] dip collect ; inline
 438
 439 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 440     [ nth-unsafe ] bi-curry@ bi ; inline
 441
 442 : setup-2each ( seq1 seq2 -- n quot )
 443     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 444
 445 : (2each) ( seq1 seq2 quot -- n quot' )
 446     [ setup-2each ] dip compose ; inline
 447
 448 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 449     [ nth-unsafe ] tri-curry@ tri ; inline
 450
 451 : setup-3each ( seq1 seq2 seq3 -- n quot )
 452     [ [ length ] tri@ min min check-length ]
 453     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 454
 455 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 456     [ setup-3each ] dip compose ; inline
 457
 458 : element/index ( i/f seq -- elt/f i/f )
 459     '[ [ _ nth ] [ f ] if* ] keep ;
 460
 461 : index/element ( i/f seq -- i/f elt/f )
 462     dupd '[ _ nth ] [ f ] if* ;
 463
 464 : (accumulate) ( seq identity quot -- identity seq quot' )
 465     swapd [ keepd ] curry ; inline
 466
 467 : (accumulate*) ( seq identity quot -- identity seq quot' )
 468     swapd [ dup ] compose ; inline
 469
 470 PRIVATE>
 471
 472 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 473     sequence-operator each-integer-from ; inline
 474
 475 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 476     sequence-operator-from each-integer-from ; inline
 477
 478 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 479     swapd each ; inline
 480
 481 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 482     overd [ [ collect ] keep ] new-like ; inline
 483
 484 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 485     { } map-integers-as ; inline
 486
 487 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 488     [ length-operator ] dip map-integers-as ; inline
 489
 490 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 491     over map-as ; inline
 492
 493 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 494     [ [ drop ] prepose ] dip map-integers-as ; inline
 495
 496 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 497     { } replicate-as ; inline
 498
 499 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 500     over [ map-into ] keep ; inline
 501
 502 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 503     [ (accumulate) ] dip map-as ; inline
 504
 505 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 506     pick accumulate-as ; inline
 507
 508 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 509     (accumulate) map! ; inline
 510
 511 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 512     [ (accumulate*) ] dip map-as nip ; inline
 513
 514 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 515     pick accumulate*-as ; inline
 516
 517 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 518     (accumulate*) map! nip ; inline
 519
 520 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 521     (2each) each-integer ; inline
 522
 523 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 524     [ (2each) ] dip -rot each-integer-from ; inline
 525
 526 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 527     -rotd 2each ; inline
 528
 529 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 530     [ (2each) ] dip map-integers-as ; inline
 531
 532 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 533     pick 2map-as ; inline
 534
 535 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 536     (2each) all-integers? ; inline
 537
 538 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 539     negate 2all? not ; inline
 540
 541 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 542     (3each) each-integer ; inline
 543
 544 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 545     [ (3each) ] dip map-integers-as ; inline
 546
 547 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 548     pickd swap 3map-as ; inline
 549
 550 : bounds-check-find ( n seq quot -- elt i )
 551     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 552
 553 <PRIVATE
 554
 555 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 556     [ rot sequence-operator-from find-integer-from ] keepd
 557     index/element ; inline
 558
 559 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 560     [ rot sequence-operator-last-from find-last-integer ] keepd
 561     index/element ; inline
 562
 563 PRIVATE>
 564
 565 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 566     '[ _ find-from-unsafe ] bounds-check-find ; inline
 567
 568 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 569     [ 0 ] 2dip find-from-unsafe ; inline
 570
 571 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 572     '[ _ find-last-from-unsafe ] bounds-check-find ; inline
 573
 574 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 575     [ [ length 1 - ] keep ] dip find-last-from ; inline
 576
 577 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 578     '[
 579         _ [ sequence-index-operator find-integer-from ] keepd
 580         index/element
 581     ] bounds-check-find ; inline
 582
 583 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 584     [ 0 ] 2dip find-index-from ; inline
 585
 586 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 587     sequence-operator all-integers-from? ; inline
 588
 589 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 590     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 591
 592 <PRIVATE
 593
 594 : (selector-as) ( quot length exemplar -- selector accum )
 595     new-resizable [ [ push-if ] 2curry ] keep ; inline
 596
 597 PRIVATE>
 598
 599 : selector-as ( quot exemplar -- selector accum )
 600     [ length ] keep (selector-as) ; inline
 601
 602 : selector ( quot -- selector accum )
 603     V{ } selector-as ; inline
 604
 605 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 606     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 607
 608 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 609     over filter-as ; inline
 610
 611 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 612     [ negate ] [ filter-as ] bi* ; inline
 613
 614 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 615     over reject-as ; inline
 616
 617 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 618     [ keep swap ] 2dip ? push ; inline
 619
 620 : 2selector ( quot -- selector accum1 accum2 )
 621     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 622
 623 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 624     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 625
 626 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 627     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 628
 629 : collector-as ( quot exemplar -- quot' vec )
 630     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 631
 632 : collector-for ( seq quot -- seq quot' vec )
 633     V{ } collector-for-as ; inline
 634
 635 : collector ( quot -- quot' vec )
 636     V{ } collector-as ; inline
 637
 638 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 639     dup [ collector-as [ while ] dip ] curry dip like ; inline
 640
 641 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 642     { } produce-as ; inline
 643
 644 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 645     [ dup ] swap [ keep ] curry produce nip ; inline
 646
 647 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 648     sequence-index-operator each-integer ; inline
 649
 650 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 651     [ dup length <iota> ] 2dip 2map-as ; inline
 652
 653 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 654     over map-index-as ; inline
 655
 656 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 657     pick empty? [ 3drop ] [
 658         [ [ drop first-unsafe ] dip call ]
 659         [ [ bi* ] 2curry 1 each-from ]
 660         3bi
 661     ] if ; inline
 662
 663 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 664     swapd each-index ; inline
 665
 666 : index ( obj seq -- n )
 667     [ = ] with find drop ;
 668
 669 : index-from ( obj i seq -- n )
 670     rot [ = ] curry find-from drop ;
 671
 672 : last-index ( obj seq -- n )
 673     [ = ] with find-last drop ;
 674
 675 : last-index-from ( obj i seq -- n )
 676     rot [ = ] curry find-last-from drop ;
 677
 678 : indices ( obj seq -- indices )
 679     swap [ = ] curry [ swap ] prepose V{ } clone [
 680         [ push ] curry [ [ drop ] if ] curry compose each-index
 681     ] keep ;
 682
 683 <PRIVATE
 684
 685 : nths-unsafe ( indices seq -- seq' )
 686     [ [ nth-unsafe ] curry ] keep map-as ;
 687
 688 PRIVATE>
 689
 690 : nths ( indices seq -- seq' )
 691     [ [ nth ] curry ] keep map-as ;
 692
 693 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 694     find drop >boolean ; inline
 695
 696 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 697     any? not ; inline
 698
 699 : member? ( elt seq -- ? )
 700     [ = ] with any? ;
 701
 702 : member-of? ( seq elt -- ? )
 703     [ = ] curry any? ;
 704
 705 : member-eq? ( elt seq -- ? )
 706     [ eq? ] with any? ;
 707
 708 : member-eq-of? ( seq elt -- ? )
 709     [ eq? ] curry any? ;
 710
 711 : remove ( elt seq -- newseq )
 712     [ = ] with reject ;
 713
 714 : remove-of ( seq elt -- newseq )
 715     [ = ] curry reject ;
 716
 717 : remove-eq ( elt seq -- newseq )
 718     [ eq? ] with reject ;
 719
 720 : remove-eq-of ( seq elt -- newseq )
 721     [ eq? ] curry reject ;
 722
 723 : sift ( seq -- newseq )
 724     [ ] filter ;
 725
 726 : harvest ( seq -- newseq )
 727     [ empty? ] reject ;
 728
 729 <PRIVATE
 730
 731 : mismatch-unsafe ( n seq1 seq2 -- i )
 732     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 733
 734 PRIVATE>
 735
 736 : mismatch ( seq1 seq2 -- i )
 737     [ min-length ] 2keep mismatch-unsafe ;
 738
 739 M: sequence <=>
 740     [ mismatch ] 2keep pick
 741     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 742
 743 : sequence= ( seq1 seq2 -- ? )
 744     2dup [ length ] bi@ dupd =
 745     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 746
 747 ERROR: assert-sequence got expected ;
 748
 749 : assert-sequence= ( a b -- )
 750     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 751
 752 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 753
 754 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 755
 756 <PRIVATE
 757
 758 : sequence-hashcode-step ( oldhash newpart -- newhash )
 759     integer>fixnum swap [
 760         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 761         fixnum+fast fixnum+fast
 762     ] keep fixnum-bitxor ; inline
 763
 764 PRIVATE>
 765
 766 : sequence-hashcode ( n seq -- x )
 767     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 768
 769 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 770
 771 M: iota hashcode*
 772     over 0 <= [ 2drop 0 ] [
 773         nip length 0 swap [ sequence-hashcode-step ] each-integer
 774     ] if ;
 775
 776 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 777
 778 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 779
 780 : move ( to from seq -- )
 781     2over =
 782     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 783
 784 <PRIVATE
 785
 786 : move-unsafe* ( to from seq -- from-nth )
 787     2over =
 788     [ nth-unsafe nip ]
 789     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 790
 791 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 792     2over length < [
 793         [ [ move-unsafe* ] dip call ] 4keep
 794         [ swap [ 1 + ] when ] 3dip
 795         [ 1 + ] 2dip filter-from!
 796     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 797
 798 : move-unsafe ( to from seq -- )
 799     2over =
 800     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 801
 802 PRIVATE>
 803
 804 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 805     [ 0 0 ] 2dip filter-from! ; inline
 806
 807 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 808     negate filter! ; inline
 809
 810 : remove! ( elt seq -- seq )
 811     [ = ] with reject! ;
 812
 813 : remove-eq! ( elt seq -- seq )
 814     [ eq? ] with reject! ;
 815
 816 : prefix ( seq elt -- newseq )
 817     over [ over length 1 + ] dip [
 818         (1sequence) [ 1 swap copy-unsafe ] keep
 819     ] new-like ;
 820
 821 : suffix ( seq elt -- newseq )
 822     over [ over length 1 + ] dip [
 823         [ [ over length ] dip set-nth-unsafe ] keep
 824         [ 0 swap copy-unsafe ] keep
 825     ] new-like ;
 826
 827 : suffix! ( seq elt -- seq ) over push ; inline
 828
 829 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 830
 831 : last ( seq -- elt )
 832     [ length 1 - ] keep
 833     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 834
 835 <PRIVATE
 836
 837 : last-unsafe ( seq -- elt )
 838     [ length 1 - ] [ nth-unsafe ] bi ; inline
 839
 840 PRIVATE>
 841
 842 : set-last ( elt seq -- )
 843     [ length 1 - ] keep
 844     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 845
 846 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 847
 848 <PRIVATE
 849
 850 : move-backward ( shift from to seq -- )
 851     2over = [
 852         4drop
 853     ] [
 854         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 855         move-backward
 856     ] if ;
 857
 858 : move-forward ( shift from to seq -- )
 859     2over = [
 860         4drop
 861     ] [
 862         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 863         move-forward
 864     ] if ;
 865
 866 : (open-slice) ( shift from to seq ? -- )
 867     [
 868         [ [ 1 - ] bi@ ] dip move-forward
 869     ] [
 870         [ over - ] 2dip move-backward
 871     ] if ;
 872
 873 : open-slice ( shift from seq -- )
 874     pick 0 = [
 875         3drop
 876     ] [
 877         [ ] [ nip length + ] [ 2nip ] 3tri
 878         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 879         set-length
 880     ] if ;
 881
 882 PRIVATE>
 883
 884 : delete-slice ( from to seq -- )
 885     check-slice [ over [ - ] dip ] dip open-slice ;
 886
 887 : remove-nth! ( n seq -- seq )
 888     [ [ dup 1 + ] dip delete-slice ] keep ;
 889
 890 : snip ( from to seq -- head tail )
 891     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 892
 893 : snip-slice ( from to seq -- head tail )
 894     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 895
 896 : replace-slice ( new from to seq -- seq' )
 897     snip-slice surround ;
 898
 899 : remove-nth ( n seq -- seq' )
 900     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 901
 902 : pop ( seq -- elt )
 903     [ length 1 - ] keep over 0 >=
 904     [ [ nth-unsafe ] [ shorten ] 2bi ]
 905     [ bounds-error ] if ;
 906
 907 : exchange ( m n seq -- )
 908     [ nip bounds-check 2drop ]
 909     [ bounds-check 3drop ]
 910     [ exchange-unsafe ]
 911     3tri ;
 912
 913 : midpoint@ ( seq -- n ) length 2/ ; inline
 914
 915 : reverse! ( seq -- seq )
 916     [
 917         [ midpoint@ ] [ length ] [ ] tri
 918         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 919         each-integer
 920     ] keep ;
 921
 922 : reverse ( seq -- newseq )
 923      [
 924         dup [ length ] keep new-sequence
 925         [ 0 swap copy-unsafe ] keep reverse!
 926     ] keep like ;
 927
 928 GENERIC: sum-lengths ( seq -- n )
 929
 930 M: object sum-lengths
 931     0 [ length + ] reduce ;
 932
 933 M: repetition sum-lengths
 934     [ length>> ] [ elt>> length ] bi * ;
 935
 936 : concat-as ( seq exemplar -- newseq )
 937     [
 938         [ dup sum-lengths ] dip new-resizable
 939         [ [ push-all ] curry each ] keep
 940     ] keep like ; inline
 941
 942 : concat ( seq -- newseq )
 943     [ { } ] [ dup first concat-as ] if-empty ;
 944
 945 <PRIVATE
 946
 947 : joined-length ( seq glue -- n )
 948     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 949
 950 PRIVATE>
 951
 952 : join-as ( seq glue exemplar -- newseq )
 953     over empty? [ nip concat-as ] [
 954         [
 955             2dup joined-length over new-resizable [
 956                 [ [ push-all ] 2curry ]
 957                 [ nip [ push-all ] curry ] 2bi
 958                 interleave
 959             ] keep
 960         ] dip like
 961     ] if ;
 962
 963 : join ( seq glue -- newseq )
 964     dup join-as ; inline
 965
 966 <PRIVATE
 967
 968 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 969     [
 970         [ over length [-] dup 0 = [ drop ] ] dip
 971         [ <repetition> ] curry
 972     ] dip compose if ; inline
 973
 974 PRIVATE>
 975
 976 : pad-head ( seq n elt -- padded )
 977     [ swap dup append-as ] padding ;
 978
 979 : pad-tail ( seq n elt -- padded )
 980     [ append ] padding ;
 981
 982 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 983 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 984 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 985 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 986
 987 : head? ( seq begin -- ? )
 988     2dup shorter? [
 989         2drop f
 990     ] [
 991         [ length [ head-slice ] keep swap ] keep
 992         mismatch-unsafe not
 993     ] if ;
 994
 995 : tail? ( seq end -- ? )
 996     2dup shorter? [
 997         2drop f
 998     ] [
 999         [ length [ tail-slice* ] keep swap ] keep
1000         mismatch-unsafe not
1001     ] if ;
1002
1003 : cut-slice ( seq n -- before-slice after-slice )
1004     [ head-slice ] [ tail-slice ] 2bi ; inline
1005
1006 : cut-slice* ( seq n -- before-slice after-slice )
1007     [ head-slice* ] [ tail-slice* ] 2bi ;
1008
1009 : insert-nth ( elt n seq -- seq' )
1010     swap cut-slice [ swap suffix ] dip append ;
1011
1012 : halves ( seq -- first-slice second-slice )
1013     dup midpoint@ cut-slice ; inline
1014
1015 <PRIVATE
1016
1017 : nth2-unsafe ( n seq -- a b )
1018     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1019
1020 : nth3-unsafe ( n seq -- a b c )
1021     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1022
1023 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1024     ! We can't use case here since combinators depends on
1025     ! sequences
1026     dup 4 < [
1027         integer>fixnum {
1028             [ 2drop nip ]
1029             [ 2nip swap nth-unsafe ]
1030             [ -rot [ drop swap nth2-unsafe ] dip call ]
1031             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1032         } dispatch
1033     ] [
1034         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1035         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1036         pick [ 3bi ] dip call
1037     ] if ; inline recursive
1038
1039 PRIVATE>
1040
1041 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1042     pick dup slice? [
1043         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1044     ] [
1045         length 0 max 0 swap
1046     ] if (binary-reduce) ; inline
1047
1048 : cut ( seq n -- before after )
1049     [ head ] [ tail ] 2bi ;
1050
1051 : cut* ( seq n -- before after )
1052     [ head* ] [ tail* ] 2bi ;
1053
1054 : subseq-starts-at? ( i seq subseq -- ? )
1055     [ length swap ] keep
1056     '[
1057         [ + _ nth-unsafe ] keep _ nth-unsafe =
1058     ] with all-integers? ; inline
1059
1060 : subseq-index-from ( n seq subseq -- i/f )
1061     [ [ length ] bi@ - 1 + ] 2keep
1062     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1063
1064 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1065
1066 : subseq-index? ( seq subseq -- ? ) subseq-index >boolean ; inline
1067
1068 : subseq-start-from ( subseq seq n -- i/f )
1069     spin subseq-index-from ; inline deprecated
1070
1071 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1072
1073 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1074
1075 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1076     2dup mismatch [ 2dup min-length ] unless*
1077     [ tail-slice ] curry bi@ ;
1078
1079 : unclip ( seq -- rest first )
1080     [ rest ] [ first-unsafe ] bi ;
1081
1082 : unclip-last ( seq -- butlast last )
1083     [ but-last ] [ last-unsafe ] bi ;
1084
1085 : unclip-slice ( seq -- rest-slice first )
1086     [ rest-slice ] [ first-unsafe ] bi ; inline
1087
1088 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1089     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1090     '[ swap _ dip swap @ ] 1 each-from ; inline
1091
1092 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1093     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1094     '[ rot _ dip swap @ ] 1 2each-from ; inline
1095
1096 <PRIVATE
1097
1098 : (map-find) ( seq quot find-quot -- result elt )
1099     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1100
1101 PRIVATE>
1102
1103 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1104     [ find ] (map-find) ; inline
1105
1106 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1107     [ find-last ] (map-find) ; inline
1108
1109 : unclip-last-slice ( seq -- butlast-slice last )
1110     [ but-last-slice ] [ last-unsafe ] bi ; inline
1111
1112 <PRIVATE
1113
1114 : (trim-head) ( seq quot -- seq n )
1115     over [ negate find drop ] dip swap
1116     [ dup length ] unless* ; inline
1117
1118 : (trim-tail) ( seq quot -- seq n )
1119     over [ negate find-last drop ?1+ ] dip
1120     swap ; inline
1121
1122 PRIVATE>
1123
1124 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1125     (trim-head) tail-slice ; inline
1126
1127 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1128     (trim-head) tail ; inline
1129
1130 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1131     (trim-tail) head-slice ; inline
1132
1133 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1134     (trim-tail) head ; inline
1135
1136 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1137     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1138
1139 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1140     [ trim-slice ] [ drop ] 2bi like ; inline
1141
1142 GENERIC: sum ( seq -- n )
1143 M: object sum 0 [ + ] binary-reduce ; inline
1144 M: iota sum length dup 1 - * 2/ ; inline
1145 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1146
1147 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1148
1149 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1150
1151 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1152
1153 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1154     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1155
1156 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1157     [ 1 0 ? ] compose map-sum ; inline
1158
1159 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1160     [ with each ] 2curry each ; inline
1161
1162 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1163     [ with { } map-as ] 2curry { } map-as ; inline
1164
1165 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1166     [ 2sequence ] curry cartesian-map ; inline
1167
1168 : cartesian-product ( seq1 seq2 -- newseq )
1169     dup cartesian-product-as ; inline
1170
1171 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1172     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1173
1174 <PRIVATE
1175
1176 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1177     [
1178         [ keep swap ] curry [ [ first ] dip call ] 2keep
1179         [ curry 2dip pick over ] curry
1180     ] [
1181         [ [ 2drop ] [ 2nipd ] if ] compose
1182     ] bi* compose 1 each-from drop ; inline
1183
1184 PRIVATE>
1185
1186 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1187     [ after? ] select-by ; inline
1188
1189 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1190     [ before? ] select-by ; inline
1191
1192 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1193
1194 : longest ( seqs -- elt ) [ length ] supremum-by ;
1195
1196 ! We hand-optimize flip to such a degree because type hints
1197 ! cannot express that an array is an array of arrays yet, and
1198 ! this word happens to be performance-critical since the compiler
1199 ! itself uses it. Optimizing it like this reduced compile time.
1200 <PRIVATE
1201
1202 : generic-flip ( matrix -- newmatrix )
1203     [ [ length ] [ min ] map-reduce ] keep
1204     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1205
1206 USE: arrays
1207
1208 : array-flip ( matrix -- newmatrix )
1209     { array } declare
1210     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1211     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1212
1213 PRIVATE>
1214
1215 : flip ( matrix -- newmatrix )
1216     dup empty? [
1217         dup array? [
1218             dup [ array? ] all?
1219             [ array-flip ] [ generic-flip ] if
1220         ] [ generic-flip ] if
1221     ] unless ;