core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop [ f ] when-empty ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 PRIVATE>
 105
 106 ! In the future, this will replace integer sequences
 107 TUPLE: iota { n integer read-only } ;
 108
 109 : iota ( n -- iota ) \ iota boa ; inline
 110
 111 <PRIVATE
 112
 113 M: iota length n>> ;
 114 M: iota nth-unsafe drop ;
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 : first-unsafe ( seq -- first )
 119     0 swap nth-unsafe ; inline
 120
 121 : first2-unsafe ( seq -- first second )
 122     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 123
 124 : first3-unsafe ( seq -- first second third )
 125     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 126
 127 : first4-unsafe ( seq -- first second third fourth )
 128     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 129
 130 : exchange-unsafe ( m n seq -- )
 131     [ tuck [ nth-unsafe ] 2bi@ ]
 132     [ tuck [ set-nth-unsafe ] 2bi@ ] 3bi ; inline
 133
 134 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 135
 136 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 137
 138 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 139
 140 : (1sequence) ( obj seq -- seq )
 141     [ 0 swap set-nth-unsafe ] keep ; inline
 142
 143 : (2sequence) ( obj1 obj2 seq -- seq )
 144     [ 1 swap set-nth-unsafe ] keep
 145     (1sequence) ; inline
 146
 147 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 148     [ 2 swap set-nth-unsafe ] keep
 149     (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep
 153     (3sequence) ; inline
 154
 155 PRIVATE>
 156
 157 : 1sequence ( obj exemplar -- seq )
 158     1 swap [ (1sequence) ] new-like ; inline
 159
 160 : 2sequence ( obj1 obj2 exemplar -- seq )
 161     2 swap [ (2sequence) ] new-like ; inline
 162
 163 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 164     3 swap [ (3sequence) ] new-like ; inline
 165
 166 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 167     4 swap [ (4sequence) ] new-like ; inline
 168
 169 : first2 ( seq -- first second )
 170     1 swap bounds-check nip first2-unsafe ; flushable
 171
 172 : first3 ( seq -- first second third )
 173     2 swap bounds-check nip first3-unsafe ; flushable
 174
 175 : first4 ( seq -- first second third fourth )
 176     3 swap bounds-check nip first4-unsafe ; flushable
 177
 178 : ?nth ( n seq -- elt/f )
 179     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 180
 181 MIXIN: virtual-sequence
 182 GENERIC: virtual-seq ( seq -- seq' )
 183 GENERIC: virtual@ ( n seq -- n' seq' )
 184
 185 M: virtual-sequence nth virtual@ nth ;
 186 M: virtual-sequence set-nth virtual@ set-nth ;
 187 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 188 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 189 M: virtual-sequence like virtual-seq like ;
 190 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 191
 192 INSTANCE: virtual-sequence sequence
 193
 194 ! A reversal of an underlying sequence.
 195 TUPLE: reversed { seq read-only } ;
 196
 197 C: <reversed> reversed
 198
 199 M: reversed virtual-seq seq>> ;
 200
 201 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 202
 203 M: reversed length seq>> length ;
 204
 205 INSTANCE: reversed virtual-sequence
 206
 207 ! A slice of another sequence.
 208 TUPLE: slice
 209 { from read-only }
 210 { to read-only }
 211 { seq read-only } ;
 212
 213 : collapse-slice ( m n slice -- m' n' seq )
 214     [ from>> ] [ seq>> ] bi [ tuck [ + ] 2bi@ ] dip ; inline
 215
 216 ERROR: slice-error from to seq reason ;
 217
 218 : check-slice ( from to seq -- from to seq )
 219     pick 0 < [ "start < 0" slice-error ] when
 220     dup length pick < [ "end > sequence" slice-error ] when
 221     2over > [ "start > end" slice-error ] when ; inline
 222
 223 : <slice> ( from to seq -- slice )
 224     dup slice? [ collapse-slice ] when
 225     check-slice
 226     slice boa ; inline
 227
 228 M: slice virtual-seq seq>> ;
 229
 230 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 231
 232 M: slice length [ to>> ] [ from>> ] bi - ;
 233
 234 : short ( seq n -- seq n' ) over length min ; inline
 235
 236 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 237
 238 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 239
 240 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 241
 242 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 243
 244 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 245
 246 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 247
 248 INSTANCE: slice virtual-sequence
 249
 250 ! One element repeated many times
 251 TUPLE: repetition { len read-only } { elt read-only } ;
 252
 253 C: <repetition> repetition
 254
 255 M: repetition length len>> ;
 256 M: repetition nth-unsafe nip elt>> ;
 257
 258 INSTANCE: repetition immutable-sequence
 259
 260 <PRIVATE
 261
 262 : check-length ( n -- n )
 263     #! Ricing.
 264     dup integer? [ "length not an integer" throw ] unless ; inline
 265
 266 : ((copy)) ( dst i src j n -- dst i src j n )
 267     dup -roll [
 268         + swap nth-unsafe -roll [
 269             + swap set-nth-unsafe
 270         ] 3keep drop
 271     ] 3keep ; inline
 272
 273 : (copy) ( dst i src j n -- dst )
 274     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 275     inline recursive
 276
 277 : prepare-subseq ( from to seq -- dst i src j n )
 278     #! The check-length call forces partial dispatch
 279     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 280     -rot drop roll length check-length ; inline
 281
 282 : check-copy ( src n dst -- )
 283     over 0 < [ bounds-error ] when
 284     [ swap length + ] dip lengthen ; inline
 285
 286 PRIVATE>
 287
 288 : subseq ( from to seq -- subseq )
 289     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 290
 291 : head ( seq n -- headseq ) (head) subseq ;
 292
 293 : tail ( seq n -- tailseq ) (tail) subseq ;
 294
 295 : rest ( seq -- tailseq ) 1 tail ;
 296
 297 : head* ( seq n -- headseq ) from-end head ;
 298
 299 : tail* ( seq n -- tailseq ) from-end tail ;
 300
 301 : but-last ( seq -- headseq ) 1 head* ;
 302
 303 : copy ( src i dst -- )
 304     #! The check-length call forces partial dispatch
 305     pick length check-length [ 3dup check-copy spin 0 ] dip
 306     (copy) drop ; inline
 307
 308 M: sequence clone-like
 309     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 310
 311 M: immutable-sequence clone-like like ;
 312
 313 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 314
 315 <PRIVATE
 316
 317 : (append) ( seq1 seq2 accum -- accum )
 318     [ [ over length ] dip copy ]
 319     [ 0 swap copy ]
 320     [ ] tri ; inline
 321
 322 PRIVATE>
 323
 324 : append-as ( seq1 seq2 exemplar -- newseq )
 325     [ over length over length + ] dip
 326     [ (append) ] new-like ; inline
 327
 328 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 329     [ pick length pick length pick length + + ] dip [
 330         [ [ pick length pick length + ] dip copy ]
 331         [ (append) ] bi
 332     ] new-like ; inline
 333
 334 : append ( seq1 seq2 -- newseq ) over append-as ;
 335
 336 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 337
 338 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 339
 340 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 341
 342 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 343
 344 : change-nth ( i seq quot -- )
 345     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 346
 347 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 348
 349 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 350
 351 <PRIVATE
 352
 353 : (each) ( seq quot -- n quot' )
 354     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 355
 356 : (collect) ( quot into -- quot' )
 357     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 358
 359 : collect ( n quot into -- )
 360     (collect) each-integer ; inline
 361
 362 : map-into ( seq quot into -- )
 363     [ (each) ] dip collect ; inline
 364
 365 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 366     [ over ] dip [ nth-unsafe ] 2bi@ ; inline
 367
 368 : (2each) ( seq1 seq2 quot -- n quot' )
 369     [
 370         [ min-length ] 2keep
 371         [ 2nth-unsafe ] 2curry
 372     ] dip compose ; inline
 373
 374 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 375     [ over ] 2dip [ over ] dip [ nth-unsafe ] 2tri@ ; inline
 376
 377 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 378     [
 379         [ [ length ] tri@ min min ] 3keep
 380         [ 3nth-unsafe ] 3curry
 381     ] dip compose ; inline
 382
 383 : finish-find ( i seq -- i elt )
 384     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 385
 386 : (find) ( seq quot quot' -- i elt )
 387     pick [ [ (each) ] dip call ] dip finish-find ; inline
 388
 389 : (find-from) ( n seq quot quot' -- i elt )
 390     [ 2dup bounds-check? ] 2dip
 391     [ (find) ] 2curry
 392     [ 2drop f f ]
 393     if ; inline
 394
 395 : (interleave) ( n elt between quot -- )
 396     roll 0 = [ nip ] [ swapd 2slip ] if call ; inline
 397
 398 PRIVATE>
 399
 400 : each ( seq quot -- )
 401     (each) each-integer ; inline
 402
 403 : reduce ( seq identity quot -- result )
 404     swapd each ; inline
 405
 406 : map-as ( seq quot exemplar -- newseq )
 407     [ over length ] dip [ [ map-into ] keep ] new-like ; inline
 408
 409 : map ( seq quot -- newseq )
 410     over map-as ; inline
 411
 412 : replicate ( seq quot -- newseq )
 413     [ drop ] prepose map ; inline
 414
 415 : replicate-as ( seq quot exemplar -- newseq )
 416     [ [ drop ] prepose ] dip map-as ; inline
 417
 418 : change-each ( seq quot -- )
 419     over map-into ; inline
 420
 421 : accumulate ( seq identity quot -- final newseq )
 422     swapd [ pick slip ] curry map ; inline
 423
 424 : 2each ( seq1 seq2 quot -- )
 425     (2each) each-integer ; inline
 426
 427 : 2reverse-each ( seq1 seq2 quot -- )
 428     [ [ <reversed> ] bi@ ] dip 2each ; inline
 429
 430 : 2reduce ( seq1 seq2 identity quot -- result )
 431     [ -rot ] dip 2each ; inline
 432
 433 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 434     [ (2each) ] dip map-as ; inline
 435
 436 : 2map ( seq1 seq2 quot -- newseq )
 437     pick 2map-as ; inline
 438
 439 : 2all? ( seq1 seq2 quot -- ? )
 440     (2each) all-integers? ; inline
 441
 442 : 3each ( seq1 seq2 seq3 quot -- )
 443     (3each) each ; inline
 444
 445 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 446     [ (3each) ] dip map-as ; inline
 447
 448 : 3map ( seq1 seq2 seq3 quot -- newseq )
 449     [ pick ] dip swap 3map-as ; inline
 450
 451 : find-from ( n seq quot -- i elt )
 452     [ (find-integer) ] (find-from) ; inline
 453
 454 : find ( seq quot -- i elt )
 455     [ find-integer ] (find) ; inline
 456
 457 : find-last-from ( n seq quot -- i elt )
 458     [ nip find-last-integer ] (find-from) ; inline
 459
 460 : find-last ( seq quot -- i elt )
 461     [ [ 1- ] dip find-last-integer ] (find) ; inline
 462
 463 : all? ( seq quot -- ? )
 464     (each) all-integers? ; inline
 465
 466 : push-if ( elt quot accum -- )
 467     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 468
 469 : pusher ( quot -- quot accum )
 470     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 471
 472 : filter ( seq quot -- subseq )
 473     over [ pusher [ each ] dip ] dip like ; inline
 474
 475 : push-either ( elt quot accum1 accum2 -- )
 476     [ keep swap ] 2dip ? push ; inline
 477
 478 : 2pusher ( quot -- quot accum1 accum2 )
 479     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 480
 481 : partition ( seq quot -- trueseq falseseq )
 482     over [ 2pusher [ each ] 2dip ] dip tuck [ like ] 2bi@ ; inline
 483
 484 : interleave ( seq between quot -- )
 485     [ (interleave) ] 2curry [ [ length ] keep ] dip 2each ; inline
 486
 487 : accumulator ( quot -- quot' vec )
 488     V{ } clone [ [ push ] curry compose ] keep ; inline
 489
 490 : produce-as ( pred quot tail exemplar -- seq )
 491     [ swap accumulator [ swap while ] dip ] dip like ; inline
 492
 493 : produce ( pred quot tail -- seq )
 494     { } produce-as ; inline
 495
 496 : follow ( obj quot -- seq )
 497     [ dup ] swap [ keep ] curry [ ] produce nip ; inline
 498
 499 : prepare-index ( seq quot -- seq n quot )
 500     [ dup length ] dip ; inline
 501
 502 : each-index ( seq quot -- )
 503     prepare-index 2each ; inline
 504
 505 : map-index ( seq quot -- )
 506     prepare-index 2map ; inline
 507
 508 : reduce-index ( seq identity quot -- )
 509     swapd each-index ; inline
 510
 511 : index ( obj seq -- n )
 512     [ = ] with find drop ;
 513
 514 : index-from ( obj i seq -- n )
 515     rot [ = ] curry find-from drop ;
 516
 517 : last-index ( obj seq -- n )
 518     [ = ] with find-last drop ;
 519
 520 : last-index-from ( obj i seq -- n )
 521     rot [ = ] curry find-last-from drop ;
 522
 523 : (indices) ( elt i obj accum -- )
 524     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 525
 526 : indices ( obj seq -- indices )
 527     swap V{ } clone
 528     [ [ (indices) ] 2curry each-index ] keep ;
 529
 530 : nths ( indices seq -- seq' )
 531     [ nth ] curry map ;
 532
 533 : any? ( seq quot -- ? )
 534     find drop >boolean ; inline
 535
 536 : member? ( elt seq -- ? )
 537     [ = ] with any? ;
 538
 539 : memq? ( elt seq -- ? )
 540     [ eq? ] with any? ;
 541
 542 : remove ( elt seq -- newseq )
 543     [ = not ] with filter ;
 544
 545 : remq ( elt seq -- newseq )
 546     [ eq? not ] with filter ;
 547
 548 : sift ( seq -- newseq )
 549     [ ] filter ;
 550
 551 : harvest ( seq -- newseq )
 552     [ empty? not ] filter ;
 553
 554 : mismatch ( seq1 seq2 -- i )
 555     [ min-length ] 2keep
 556     [ 2nth-unsafe = not ] 2curry
 557     find drop ; inline
 558
 559 M: sequence <=>
 560     2dup mismatch
 561     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 562
 563 : sequence= ( seq1 seq2 -- ? )
 564     2dup [ length ] bi@ =
 565     [ mismatch not ] [ 2drop f ] if ; inline
 566
 567 : sequence-hashcode-step ( oldhash newpart -- newhash )
 568     >fixnum swap [
 569         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 570         fixnum+fast fixnum+fast
 571     ] keep fixnum-bitxor ; inline
 572
 573 : sequence-hashcode ( n seq -- x )
 574     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 575
 576 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 577
 578 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 579
 580 : move ( to from seq -- )
 581     2over =
 582     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 583
 584 <PRIVATE
 585
 586 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 587     2dup length < [
 588         [ move ] 3keep
 589         [ nth-unsafe pick call [ 1+ ] when ] 2keep
 590         [ 1+ ] dip
 591         (filter-here)
 592     ] [ nip set-length drop ] if ; inline recursive
 593
 594 PRIVATE>
 595
 596 : filter-here ( seq quot -- )
 597     swap [ 0 0 ] dip (filter-here) ; inline
 598
 599 : delete ( elt seq -- )
 600     [ = not ] with filter-here ;
 601
 602 : delq ( elt seq -- )
 603     [ eq? not ] with filter-here ;
 604
 605 : prefix ( seq elt -- newseq )
 606     over [ over length 1+ ] dip [
 607         [ 0 swap set-nth-unsafe ] keep
 608         [ 1 swap copy ] keep
 609     ] new-like ;
 610
 611 : suffix ( seq elt -- newseq )
 612     over [ over length 1+ ] dip [
 613         [ [ over length ] dip set-nth-unsafe ] keep
 614         [ 0 swap copy ] keep
 615     ] new-like ;
 616
 617 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 618
 619 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 620
 621 <PRIVATE
 622
 623 : move-backward ( shift from to seq -- )
 624     2over = [
 625         2drop 2drop
 626     ] [
 627         [ [ 2over + pick ] dip move [ 1+ ] dip ] keep
 628         move-backward
 629     ] if ;
 630
 631 : move-forward ( shift from to seq -- )
 632     2over = [
 633         2drop 2drop
 634     ] [
 635         [ [ pick [ dup dup ] dip + swap ] dip move 1- ] keep
 636         move-forward
 637     ] if ;
 638
 639 : (open-slice) ( shift from to seq ? -- )
 640     [
 641         [ [ 1- ] bi@ ] dip move-forward
 642     ] [
 643         [ over - ] 2dip move-backward
 644     ] if ;
 645
 646 PRIVATE>
 647
 648 : open-slice ( shift from seq -- )
 649     pick 0 = [
 650         3drop
 651     ] [
 652         pick over length + over
 653         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 654         set-length
 655     ] if ;
 656
 657 : delete-slice ( from to seq -- )
 658     check-slice [ over [ - ] dip ] dip open-slice ;
 659
 660 : delete-nth ( n seq -- )
 661     [ dup 1+ ] dip delete-slice ;
 662
 663 : replace-slice ( new from to seq -- )
 664     [ [ [ dup pick length + ] dip - over ] dip open-slice ] keep
 665     copy ;
 666
 667 : remove-nth ( n seq -- seq' )
 668     [ swap head-slice ] [ swap 1+ tail-slice ] 2bi append ;
 669
 670 : pop ( seq -- elt )
 671     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 672
 673 : exchange ( m n seq -- )
 674     pick over bounds-check 2drop 2dup bounds-check 2drop
 675     exchange-unsafe ;
 676
 677 : reverse-here ( seq -- )
 678     dup length dup 2/ [
 679         [ 2dup ] dip
 680         tuck - 1- rot exchange-unsafe
 681     ] each 2drop ;
 682
 683 : reverse ( seq -- newseq )
 684     [
 685         dup [ length ] keep new-sequence
 686         [ 0 swap copy ] keep
 687         [ reverse-here ] keep
 688     ] keep like ;
 689
 690 : sum-lengths ( seq -- n )
 691     0 [ length + ] reduce ;
 692
 693 : concat ( seq -- newseq )
 694     [ { } ] [
 695         [ sum-lengths ] keep
 696         [ first new-resizable ] keep
 697         [ [ over push-all ] each ] keep
 698         first like
 699     ] if-empty ;
 700
 701 <PRIVATE
 702
 703 : joined-length ( seq glue -- n )
 704     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 705
 706 PRIVATE>
 707
 708 : join ( seq glue -- newseq )
 709     [
 710         2dup joined-length over new-resizable spin
 711         [ dup pick push-all ] [ pick push-all ] interleave drop
 712     ] keep like ;
 713
 714 : padding ( seq n elt quot -- newseq )
 715     [
 716         [ over length [-] dup 0 = [ drop ] ] dip
 717         [ <repetition> ] curry
 718     ] dip compose if ; inline
 719
 720 : pad-head ( seq n elt -- padded )
 721     [ swap dup append-as ] padding ;
 722
 723 : pad-tail ( seq n elt -- padded )
 724     [ append ] padding ;
 725
 726 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 727
 728 : head? ( seq begin -- ? )
 729     2dup shorter? [
 730         2drop f
 731     ] [
 732         [ nip ] [ length head-slice ] 2bi sequence=
 733     ] if ;
 734
 735 : tail? ( seq end -- ? )
 736     2dup shorter? [
 737         2drop f
 738     ] [
 739         [ nip ] [ length tail-slice* ] 2bi sequence=
 740     ] if ;
 741
 742 : cut-slice ( seq n -- before-slice after-slice )
 743     [ head-slice ] [ tail-slice ] 2bi ;
 744
 745 : insert-nth ( elt n seq -- seq' )
 746     swap cut-slice [ swap suffix ] dip append ;
 747
 748 : midpoint@ ( seq -- n ) length 2/ ; inline
 749
 750 : halves ( seq -- first-slice second-slice )
 751     dup midpoint@ cut-slice ;
 752
 753 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 754     #! We can't use case here since combinators depends on
 755     #! sequences
 756     pick length dup 0 3 between? [
 757         >fixnum {
 758             [ drop nip ]
 759             [ 2drop first ]
 760             [ [ drop first2 ] dip call ]
 761             [ [ drop first3 ] dip bi@ ]
 762         } dispatch
 763     ] [
 764         drop
 765         [ halves ] 2dip
 766         [ [ binary-reduce ] 2curry bi@ ] keep
 767         call
 768     ] if ; inline recursive
 769
 770 : cut ( seq n -- before after )
 771     [ head ] [ tail ] 2bi ;
 772
 773 : cut* ( seq n -- before after )
 774     [ head* ] [ tail* ] 2bi ;
 775
 776 <PRIVATE
 777
 778 : (start) ( subseq seq n -- subseq seq ? )
 779     pick length [
 780         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 781     ] all? nip ; inline
 782
 783 PRIVATE>
 784
 785 : start* ( subseq seq n -- i )
 786     pick length pick length swap - 1+
 787     [ (start) ] find-from
 788     swap [ 3drop ] dip ;
 789
 790 : start ( subseq seq -- i ) 0 start* ; inline
 791
 792 : subseq? ( subseq seq -- ? ) start >boolean ;
 793
 794 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 795     2dup mismatch [ 2dup min-length ] unless*
 796     tuck [ tail-slice ] 2bi@ ;
 797
 798 : unclip ( seq -- rest first )
 799     [ rest ] [ first-unsafe ] bi ;
 800
 801 : unclip-last ( seq -- butlast last )
 802     [ but-last ] [ peek ] bi ;
 803
 804 : unclip-slice ( seq -- rest-slice first )
 805     [ rest-slice ] [ first-unsafe ] bi ; inline
 806
 807 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 808     [ unclip-slice ] bi@ swapd ; inline
 809
 810 : map-reduce ( seq map-quot reduce-quot -- result )
 811     [ [ unclip-slice ] dip [ call ] keep ] dip
 812     compose reduce ; inline
 813
 814 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 815     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 816     compose 2reduce ; inline
 817
 818 : unclip-last-slice ( seq -- butlast-slice last )
 819     [ but-last-slice ] [ peek ] bi ; inline
 820
 821 : <flat-slice> ( seq -- slice )
 822     dup slice? [ { } like ] when 0 over length rot <slice> ;
 823     inline
 824
 825 : trim-head-slice ( seq quot -- slice )
 826     over [ [ not ] compose find drop ] dip swap
 827     [ tail-slice ] [ dup length tail-slice ] if* ; inline
 828
 829 : trim-head ( seq quot -- newseq )
 830     over [ trim-head-slice ] dip like ; inline
 831
 832 : trim-tail-slice ( seq quot -- slice )
 833     over [ [ not ] compose find-last drop ] dip swap
 834     [ 1+ head-slice ] [ 0 head-slice ] if* ; inline
 835
 836 : trim-tail ( seq quot -- newseq )
 837     over [ trim-tail-slice ] dip like ; inline
 838
 839 : trim-slice ( seq quot -- slice )
 840     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 841
 842 : trim ( seq quot -- newseq )
 843     over [ trim-slice ] dip like ; inline
 844
 845 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 846
 847 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 848
 849 : infimum ( seq -- n ) dup first [ min ] reduce ;
 850
 851 : supremum ( seq -- n ) dup first [ max ] reduce ;
 852
 853 : sigma ( seq quot -- n ) [ 0 ] 2dip [ rot slip + ] curry each ; inline
 854
 855 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 856
 857 ! We hand-optimize flip to such a degree because type hints
 858 ! cannot express that an array is an array of arrays yet, and
 859 ! this word happens to be performance-critical since the compiler
 860 ! itself uses it. Optimizing it like this reduced compile time.
 861 <PRIVATE
 862
 863 : generic-flip ( matrix -- newmatrix )
 864     [ dup first length [ length min ] reduce ] keep
 865     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 866
 867 USE: arrays
 868
 869 : array-length ( array -- len )
 870     { array } declare length>> ; inline
 871
 872 : array-flip ( matrix -- newmatrix )
 873     { array } declare
 874     [ dup first array-length [ array-length min ] reduce ] keep
 875     [ [ array-nth ] with { } map-as ] curry { } map-as ;
 876
 877 PRIVATE>
 878
 879 : flip ( matrix -- newmatrix )
 880     dup empty? [
 881         dup array? [
 882             dup [ array? ] all?
 883             [ array-flip ] [ generic-flip ] if
 884         ] [ generic-flip ] if
 885     ] unless ;