core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 139
 140 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 141
 142 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 143
 144 : (1sequence) ( obj seq -- seq )
 145     [ 0 swap set-nth-unsafe ] keep ; inline
 146
 147 : (2sequence) ( obj1 obj2 seq -- seq )
 148     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 149
 150 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 151     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 152
 153 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 154     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 155
 156 PRIVATE>
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 186 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 187 : ?last ( seq -- elt/f )
 188     [ length 1 - ] keep over 0 <
 189     [ 2drop f ] [ nth-unsafe ] if ; inline
 190
 191 MIXIN: virtual-sequence
 192 GENERIC: virtual-exemplar ( seq -- seq' )
 193 GENERIC: virtual@ ( n seq -- n' seq' )
 194
 195 M: virtual-sequence nth virtual@ nth ; inline
 196 M: virtual-sequence set-nth virtual@ set-nth ; inline
 197 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 198 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 199 M: virtual-sequence like virtual-exemplar like ; inline
 200 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 201
 202 INSTANCE: virtual-sequence sequence
 203
 204 ! A reversal of an underlying sequence.
 205 TUPLE: reversed { seq read-only } ;
 206
 207 C: <reversed> reversed
 208
 209 M: reversed virtual-exemplar seq>> ; inline
 210 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 211 M: reversed length seq>> length ; inline
 212
 213 INSTANCE: reversed virtual-sequence
 214
 215 ! A slice of another sequence.
 216 TUPLE: slice
 217     { from integer read-only }
 218     { to integer read-only }
 219     { seq read-only } ;
 220
 221 : collapse-slice ( m n slice -- m' n' seq )
 222     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 223
 224 ERROR: slice-error from to seq ;
 225
 226 : check-slice ( from to seq -- from to seq )
 227     pick 0 < [ slice-error ] when
 228     2dup length > [ slice-error ] when
 229     2over > [ slice-error ] when ; inline
 230
 231 <PRIVATE
 232
 233 : <slice-unsafe> ( from to seq -- slice )
 234     dup slice? [ collapse-slice ] when slice boa ; inline
 235
 236 PRIVATE>
 237
 238 : <slice> ( from to seq -- slice )
 239     check-slice <slice-unsafe> ; inline
 240
 241 M: slice virtual-exemplar seq>> ; inline
 242
 243 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 244
 245 M: slice length [ to>> ] [ from>> ] bi - ; inline
 246
 247 : short ( seq n -- seq n' ) over length min ; inline
 248
 249 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 250
 251 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 252
 253 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 254
 255 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 256
 257 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 258
 259 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 260
 261 INSTANCE: slice virtual-sequence
 262
 263 ! One element repeated many times
 264 TUPLE: repetition
 265     { length integer read-only }
 266     { elt read-only } ;
 267
 268 : <repetition> ( len elt -- repetition )
 269     over 0 < [ non-negative-integer-expected ] when
 270     repetition boa ; inline
 271
 272 M: repetition length length>> ; inline
 273 M: repetition nth-unsafe nip elt>> ; inline
 274
 275 INSTANCE: repetition immutable-sequence
 276
 277 <PRIVATE
 278
 279 ERROR: integer-length-expected obj ;
 280
 281 ! The check-length call forces partial dispatch
 282 : check-length ( n -- n )
 283     dup integer? [ integer-length-expected ] unless ; inline
 284
 285 TUPLE: copy-state
 286     { src-i integer read-only }
 287     { src read-only }
 288     { dst-i integer read-only }
 289     { dst read-only } ;
 290
 291 C: <copy> copy-state
 292
 293 : copy-nth-unsafe ( n copy -- )
 294     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 295     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 296
 297 : (copy) ( n copy -- dst )
 298     over 0 <= [ nip dst>> ] [
 299         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 300     ] if ; inline recursive
 301
 302 : subseq>copy ( from to seq -- n copy )
 303     [ over - check-length swap ] dip
 304     3dup nip new-sequence 0 swap <copy> ; inline
 305
 306 : bounds-check-head ( n seq -- n seq )
 307     over 0 < [ bounds-error ] when ; inline
 308
 309 : check-copy ( src n dst -- src n dst )
 310     3dup bounds-check-head
 311     [ swap length + ] dip lengthen ; inline
 312
 313 : copy-unsafe ( src i dst -- )
 314     [ [ length check-length 0 ] keep ] 2dip <copy> (copy) drop ; inline
 315
 316 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 317     [ subseq>copy (copy) ] dip like ; inline
 318
 319 : subseq-unsafe ( from to seq -- subseq )
 320     dup subseq-unsafe-as ; inline
 321
 322 PRIVATE>
 323
 324 : subseq-as ( from to seq exemplar -- subseq )
 325     [ check-slice ] dip subseq-unsafe-as ;
 326
 327 : subseq ( from to seq -- subseq )
 328     dup subseq-as ;
 329
 330 : head ( seq n -- headseq ) (head) subseq ;
 331
 332 : tail ( seq n -- tailseq ) (tail) subseq ;
 333
 334 : rest ( seq -- tailseq ) 1 tail ;
 335
 336 : head* ( seq n -- headseq ) from-end head ;
 337
 338 : tail* ( seq n -- tailseq ) from-end tail ;
 339
 340 : but-last ( seq -- headseq ) 1 head* ;
 341
 342 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 343
 344 M: sequence clone-like
 345     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 346
 347 M: immutable-sequence clone-like like ; inline
 348
 349 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 350
 351 <PRIVATE
 352
 353 : (append) ( seq1 seq2 accum -- accum )
 354     [ [ over length ] dip copy-unsafe ]
 355     [ 0 swap copy-unsafe ]
 356     [ ] tri ; inline
 357
 358 PRIVATE>
 359
 360 : append-as ( seq1 seq2 exemplar -- newseq )
 361     [ 2dup [ length ] bi@ + ] dip
 362     [ (append) ] new-like ; inline
 363
 364 : append ( seq1 seq2 -- newseq ) over append-as ;
 365
 366 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 367
 368 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 369
 370 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 371     [ 3dup [ length ] tri@ + + ] dip [
 372         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 373         [ (append) ] bi
 374     ] new-like ; inline
 375
 376 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 377
 378 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 379     [ swap ] 2dip 3append-as ; inline
 380
 381 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 382
 383 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 384
 385 : 1surround ( seq1 seq2 -- newseq ) over 1surround-as ; inline
 386
 387 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 388
 389 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 390
 391 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 392     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 393
 394 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 395
 396 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 397
 398 <PRIVATE
 399
 400 : setup-each ( seq -- n quot )
 401     [ length check-length ] keep [ nth-unsafe ] curry ; inline
 402
 403 : (each) ( seq quot -- n quot' )
 404     [ setup-each ] dip compose ; inline
 405
 406 : (each-index) ( seq quot -- n quot' )
 407     [ setup-each [ keep ] curry ] dip compose ; inline
 408
 409 : (collect) ( quot into -- quot' )
 410     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 411
 412 : collect ( n quot into -- )
 413     (collect) each-integer ; inline
 414
 415 : map-into ( seq quot into -- )
 416     [ (each) ] dip collect ; inline
 417
 418 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 419     [ nth-unsafe ] bi-curry@ bi ; inline
 420
 421 : setup-2each ( seq1 seq2 -- n quot )
 422     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 423
 424 : (2each) ( seq1 seq2 quot -- n quot' )
 425     [ setup-2each ] dip compose ; inline
 426
 427 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 428     [ nth-unsafe ] tri-curry@ tri ; inline
 429
 430 : setup-3each ( seq1 seq2 seq3 -- n quot )
 431     [ [ length ] tri@ min min check-length ]
 432     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 433
 434 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 435     [ setup-3each ] dip compose ; inline
 436
 437 : finish-find ( i seq -- i elt )
 438     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 439
 440 : (find) ( seq quot quot' -- i elt )
 441     pick [ [ (each) ] dip call ] dip finish-find ; inline
 442
 443 : (find-from) ( n seq quot quot' -- i elt )
 444     [ 2dup bounds-check? ] 2dip
 445     [ (find) ] 2curry
 446     [ 2drop f f ]
 447     if ; inline
 448
 449 : (find-index) ( seq quot quot' -- i elt )
 450     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 451
 452 : (find-index-from) ( n seq quot quot' -- i elt )
 453     [ 2dup bounds-check? ] 2dip
 454     [ (find-index) ] 2curry
 455     [ 2drop f f ]
 456     if ; inline
 457
 458 : (accumulate) ( seq identity quot -- identity seq quot )
 459     swapd [ keepd ] curry ; inline
 460
 461 : (accumulate*) ( seq identity quot -- identity seq quot )
 462     swapd [ dup ] compose ; inline
 463
 464 PRIVATE>
 465
 466 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 467     (each) each-integer ; inline
 468
 469 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 470     -rot (each) (each-integer) ; inline
 471
 472 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 473     swapd each ; inline
 474
 475 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 476     overd [ [ collect ] keep ] new-like ; inline
 477
 478 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 479     [ (each) ] dip map-integers ; inline
 480
 481 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 482     over map-as ; inline
 483
 484 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 485     [ [ drop ] prepose ] dip map-integers ; inline
 486
 487 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 488     { } replicate-as ; inline
 489
 490 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 491     over [ map-into ] keep ; inline
 492
 493 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 494     [ (accumulate) ] dip map-as ; inline
 495
 496 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 497     pick accumulate-as ; inline
 498
 499 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 500     (accumulate) map! ; inline
 501
 502 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 503     [ (accumulate*) ] dip map-as nip ; inline
 504
 505 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 506     pick accumulate*-as ; inline
 507
 508 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 509     (accumulate*) map! nip ; inline
 510
 511 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 512     (2each) each-integer ; inline
 513
 514 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 515     [ (2each) ] dip -rot (each-integer) ; inline
 516
 517 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 518     -rotd 2each ; inline
 519
 520 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 521     [ (2each) ] dip map-integers ; inline
 522
 523 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 524     pick 2map-as ; inline
 525
 526 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 527     (2each) all-integers? ; inline
 528
 529 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 530     [ not ] compose 2all? not ; inline
 531
 532 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 533     (3each) each-integer ; inline
 534
 535 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 536     [ (3each) ] dip map-integers ; inline
 537
 538 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 539     pickd swap 3map-as ; inline
 540
 541 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 542     [ (find-integer) ] (find-from) ; inline
 543
 544 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 545     [ find-integer ] (find) ; inline
 546
 547 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 548     [ nip find-last-integer ] (find-from) ; inline
 549
 550 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 551     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 552
 553 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 554     [ (find-integer) ] (find-index-from) ; inline
 555
 556 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 557     [ find-integer ] (find-index) ; inline
 558
 559 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 560     (each) all-integers? ; inline
 561
 562 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 563     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 564
 565 <PRIVATE
 566
 567 : (selector-as) ( quot length exemplar -- selector accum )
 568     new-resizable [ [ push-if ] 2curry ] keep ; inline
 569
 570 PRIVATE>
 571
 572 : selector-as ( quot exemplar -- selector accum )
 573     [ length ] keep (selector-as) ; inline
 574
 575 : selector ( quot -- selector accum )
 576     V{ } selector-as ; inline
 577
 578 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 579     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 580
 581 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 582     over filter-as ; inline
 583
 584 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 585     [ [ not ] compose ] [ filter-as ] bi* ; inline
 586
 587 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 588     over reject-as ; inline
 589
 590 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 591     [ keep swap ] 2dip ? push ; inline
 592
 593 : 2selector ( quot -- selector accum1 accum2 )
 594     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 595
 596 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 597     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 598
 599 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 600     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 601
 602 : collector-as ( quot exemplar -- quot' vec )
 603     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 604
 605 : collector-for ( seq quot -- seq quot' vec )
 606     V{ } collector-for-as ; inline
 607
 608 : collector ( quot -- quot' vec )
 609     V{ } collector-as ; inline
 610
 611 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 612     dup [ collector-as [ while ] dip ] curry dip like ; inline
 613
 614 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 615     { } produce-as ; inline
 616
 617 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 618     [ dup ] swap [ keep ] curry produce nip ; inline
 619
 620 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 621     (each-index) each-integer ; inline
 622
 623 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 624     [ dup length <iota> ] 2dip 2map-as ; inline
 625
 626 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 627     { } map-index-as ; inline
 628
 629 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 630     pick empty? [ 3drop ] [
 631         [ [ drop first-unsafe ] dip call ]
 632         [ [ bi* ] 2curry 1 each-from ]
 633         3bi
 634     ] if ; inline
 635
 636 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 637     swapd each-index ; inline
 638
 639 : index ( obj seq -- n )
 640     [ = ] with find drop ;
 641
 642 : index-from ( obj i seq -- n )
 643     rot [ = ] curry find-from drop ;
 644
 645 : last-index ( obj seq -- n )
 646     [ = ] with find-last drop ;
 647
 648 : last-index-from ( obj i seq -- n )
 649     rot [ = ] curry find-last-from drop ;
 650
 651 : indices ( obj seq -- indices )
 652     swap [ = ] curry [ swap ] prepose V{ } clone [
 653         [ push ] curry [ [ drop ] if ] curry compose each-index
 654     ] keep ;
 655
 656 <PRIVATE
 657
 658 : nths-unsafe ( indices seq -- seq' )
 659     [ [ nth-unsafe ] curry ] keep map-as ;
 660
 661 PRIVATE>
 662
 663 : nths ( indices seq -- seq' )
 664     [ [ nth ] curry ] keep map-as ;
 665
 666 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 667     find drop >boolean ; inline
 668
 669 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 670     any? not ; inline
 671
 672 : member? ( elt seq -- ? )
 673     [ = ] with any? ;
 674
 675 : member-eq? ( elt seq -- ? )
 676     [ eq? ] with any? ;
 677
 678 : remove ( elt seq -- newseq )
 679     [ = ] with reject ;
 680
 681 : remove-eq ( elt seq -- newseq )
 682     [ eq? ] with reject ;
 683
 684 : sift ( seq -- newseq )
 685     [ ] filter ;
 686
 687 : harvest ( seq -- newseq )
 688     [ empty? ] reject ;
 689
 690 <PRIVATE
 691
 692 : mismatch-unsafe ( n seq1 seq2 -- i )
 693     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 694
 695 PRIVATE>
 696
 697 : mismatch ( seq1 seq2 -- i )
 698     [ min-length ] 2keep mismatch-unsafe ;
 699
 700 M: sequence <=>
 701     [ mismatch ] 2keep pick
 702     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 703
 704 : sequence= ( seq1 seq2 -- ? )
 705     2dup [ length ] bi@ dupd =
 706     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 707
 708 ERROR: assert-sequence got expected ;
 709
 710 : assert-sequence= ( a b -- )
 711     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 712
 713 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 714
 715 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 716
 717 <PRIVATE
 718
 719 : sequence-hashcode-step ( oldhash newpart -- newhash )
 720     integer>fixnum swap [
 721         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 722         fixnum+fast fixnum+fast
 723     ] keep fixnum-bitxor ; inline
 724
 725 PRIVATE>
 726
 727 : sequence-hashcode ( n seq -- x )
 728     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 729
 730 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 731
 732 M: iota hashcode*
 733     over 0 <= [ 2drop 0 ] [
 734         nip length 0 swap [ sequence-hashcode-step ] each-integer
 735     ] if ;
 736
 737 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 738
 739 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 740
 741 : move ( to from seq -- )
 742     2over =
 743     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 744
 745 <PRIVATE
 746
 747 : move-unsafe ( to from seq -- )
 748     2over =
 749     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 750
 751 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 752     2dup length < [
 753         [ move-unsafe ] 3keep
 754         [ nth-unsafe -rot [ [ call ] keep ] dip rot [ 1 + ] when ] 2keep
 755         [ 1 + ] dip
 756         (filter!)
 757     ] [ nip set-length drop ] if ; inline recursive
 758
 759 PRIVATE>
 760
 761 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 762     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 763
 764 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 765     [ not ] compose filter! ; inline
 766
 767 : remove! ( elt seq -- seq )
 768     [ = ] with reject! ;
 769
 770 : remove-eq! ( elt seq -- seq )
 771     [ eq? ] with reject! ;
 772
 773 : prefix ( seq elt -- newseq )
 774     over [ over length 1 + ] dip [
 775         (1sequence) [ 1 swap copy-unsafe ] keep
 776     ] new-like ;
 777
 778 : suffix ( seq elt -- newseq )
 779     over [ over length 1 + ] dip [
 780         [ [ over length ] dip set-nth-unsafe ] keep
 781         [ 0 swap copy-unsafe ] keep
 782     ] new-like ;
 783
 784 : suffix! ( seq elt -- seq ) over push ; inline
 785
 786 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 787
 788 : last ( seq -- elt )
 789     [ length 1 - ] keep
 790     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 791
 792 <PRIVATE
 793
 794 : last-unsafe ( seq -- elt )
 795     [ length 1 - ] [ nth-unsafe ] bi ; inline
 796
 797 PRIVATE>
 798
 799 : set-last ( elt seq -- )
 800     [ length 1 - ] keep
 801     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 802
 803 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 804
 805 <PRIVATE
 806
 807 : move-backward ( shift from to seq -- )
 808     2over = [
 809         4drop
 810     ] [
 811         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 812         move-backward
 813     ] if ;
 814
 815 : move-forward ( shift from to seq -- )
 816     2over = [
 817         4drop
 818     ] [
 819         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 820         move-forward
 821     ] if ;
 822
 823 : (open-slice) ( shift from to seq ? -- )
 824     [
 825         [ [ 1 - ] bi@ ] dip move-forward
 826     ] [
 827         [ over - ] 2dip move-backward
 828     ] if ;
 829
 830 : open-slice ( shift from seq -- )
 831     pick 0 = [
 832         3drop
 833     ] [
 834         [ ] [ nip length + ] [ 2nip ] 3tri
 835         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 836         set-length
 837     ] if ;
 838
 839 PRIVATE>
 840
 841 : delete-slice ( from to seq -- )
 842     check-slice [ over [ - ] dip ] dip open-slice ;
 843
 844 : remove-nth! ( n seq -- seq )
 845     [ [ dup 1 + ] dip delete-slice ] keep ;
 846
 847 : snip ( from to seq -- head tail )
 848     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 849
 850 : snip-slice ( from to seq -- head tail )
 851     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 852
 853 : replace-slice ( new from to seq -- seq' )
 854     snip-slice surround ;
 855
 856 : remove-nth ( n seq -- seq' )
 857     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 858
 859 : pop ( seq -- elt )
 860     [ length 1 - ] keep over 0 >=
 861     [ [ nth-unsafe ] [ shorten ] 2bi ]
 862     [ bounds-error ] if ;
 863
 864 : exchange ( m n seq -- )
 865     [ nip bounds-check 2drop ]
 866     [ bounds-check 3drop ]
 867     [ exchange-unsafe ]
 868     3tri ;
 869
 870 : midpoint@ ( seq -- n ) length 2/ ; inline
 871
 872 : reverse! ( seq -- seq )
 873     [
 874         [ midpoint@ ] [ length ] [ ] tri
 875         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 876         each-integer
 877     ] keep ;
 878
 879 : reverse ( seq -- newseq )
 880      [
 881         dup [ length ] keep new-sequence
 882         [ 0 swap copy-unsafe ] keep reverse!
 883     ] keep like ;
 884
 885 GENERIC: sum-lengths ( seq -- n )
 886
 887 M: object sum-lengths
 888     0 [ length + ] reduce ;
 889
 890 M: repetition sum-lengths
 891     [ length>> ] [ elt>> length ] bi * ;
 892
 893 : concat-as ( seq exemplar -- newseq )
 894     [
 895         [ dup sum-lengths ] dip new-resizable
 896         [ [ push-all ] curry each ] keep
 897     ] keep like ; inline
 898
 899 : concat ( seq -- newseq )
 900     [ { } ] [ dup first concat-as ] if-empty ;
 901
 902 <PRIVATE
 903
 904 : joined-length ( seq glue -- n )
 905     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 906
 907 PRIVATE>
 908
 909 : join-as ( seq glue exemplar -- newseq )
 910     over empty? [ nip concat-as ] [
 911         [
 912             2dup joined-length over new-resizable [
 913                 [ [ push-all ] 2curry ]
 914                 [ nip [ push-all ] curry ] 2bi
 915                 interleave
 916             ] keep
 917         ] dip like
 918     ] if ;
 919
 920 : join ( seq glue -- newseq )
 921     dup join-as ; inline
 922
 923 <PRIVATE
 924
 925 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 926     [
 927         [ over length [-] dup 0 = [ drop ] ] dip
 928         [ <repetition> ] curry
 929     ] dip compose if ; inline
 930
 931 PRIVATE>
 932
 933 : pad-head ( seq n elt -- padded )
 934     [ swap dup append-as ] padding ;
 935
 936 : pad-tail ( seq n elt -- padded )
 937     [ append ] padding ;
 938
 939 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 940 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 941 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 942 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 943
 944 : head? ( seq begin -- ? )
 945     2dup shorter? [
 946         2drop f
 947     ] [
 948         [ length [ head-slice ] keep swap ] keep
 949         mismatch-unsafe not
 950     ] if ;
 951
 952 : tail? ( seq end -- ? )
 953     2dup shorter? [
 954         2drop f
 955     ] [
 956         [ length [ tail-slice* ] keep swap ] keep
 957         mismatch-unsafe not
 958     ] if ;
 959
 960 : cut-slice ( seq n -- before-slice after-slice )
 961     [ head-slice ] [ tail-slice ] 2bi ; inline
 962
 963 : cut-slice* ( seq n -- before-slice after-slice )
 964     [ head-slice* ] [ tail-slice* ] 2bi ;
 965
 966 : insert-nth ( elt n seq -- seq' )
 967     swap cut-slice [ swap suffix ] dip append ;
 968
 969 : halves ( seq -- first-slice second-slice )
 970     dup midpoint@ cut-slice ; inline
 971
 972 <PRIVATE
 973
 974 : nth2-unsafe ( n seq -- a b )
 975     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
 976
 977 : nth3-unsafe ( n seq -- a b c )
 978     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
 979
 980 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
 981     ! We can't use case here since combinators depends on
 982     ! sequences
 983     dup 4 < [
 984         integer>fixnum {
 985             [ 2drop nip ]
 986             [ 2nip swap nth-unsafe ]
 987             [ -rot [ drop swap nth2-unsafe ] dip call ]
 988             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
 989         } dispatch
 990     ] [
 991         [ 2/ ] [ over - ] bi [ 2dup + ] dip
 992         [ (binary-reduce) ] [ 2curry ] curry 2bi@
 993         pick [ 3bi ] dip call
 994     ] if ; inline recursive
 995
 996 PRIVATE>
 997
 998 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 999     pick length 0 max 0 swap (binary-reduce) ; inline
1000
1001 : cut ( seq n -- before after )
1002     [ head ] [ tail ] 2bi ;
1003
1004 : cut* ( seq n -- before after )
1005     [ head* ] [ tail* ] 2bi ;
1006
1007 <PRIVATE
1008
1009 : (subseq-start-from) ( subseq seq n length -- subseq seq ? )
1010     [
1011         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
1012     ] all-integers? nip ; inline
1013
1014 PRIVATE>
1015
1016 : subseq-start-from ( subseq seq n -- i )
1017     pick length [ pick length swap - 1 + ] keep
1018     [ (subseq-start-from) ] curry (find-integer) 2nip ;
1019
1020 : subseq-start ( subseq seq -- i ) 0 subseq-start-from ; inline
1021
1022 : subseq? ( subseq seq -- ? ) subseq-start >boolean ;
1023
1024 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1025     2dup mismatch [ 2dup min-length ] unless*
1026     [ tail-slice ] curry bi@ ;
1027
1028 : unclip ( seq -- rest first )
1029     [ rest ] [ first-unsafe ] bi ;
1030
1031 : unclip-last ( seq -- butlast last )
1032     [ but-last ] [ last-unsafe ] bi ;
1033
1034 : unclip-slice ( seq -- rest-slice first )
1035     [ rest-slice ] [ first-unsafe ] bi ; inline
1036
1037 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1038     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1039     '[ swap _ dip swap @ ] 1 each-from ; inline
1040
1041 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1042     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1043     '[ rot _ dip swap @ ] 1 2each-from ; inline
1044
1045 <PRIVATE
1046
1047 : (map-find) ( seq quot find-quot -- result elt )
1048     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1049
1050 PRIVATE>
1051
1052 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1053     [ find ] (map-find) ; inline
1054
1055 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1056     [ find-last ] (map-find) ; inline
1057
1058 : unclip-last-slice ( seq -- butlast-slice last )
1059     [ but-last-slice ] [ last-unsafe ] bi ; inline
1060
1061 <PRIVATE
1062
1063 : (trim-head) ( seq quot -- seq n )
1064     over [ [ not ] compose find drop ] dip swap
1065     [ dup length ] unless* ; inline
1066
1067 : (trim-tail) ( seq quot -- seq n )
1068     over [ [ not ] compose find-last drop ?1+ ] dip
1069     swap ; inline
1070
1071 PRIVATE>
1072
1073 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1074     (trim-head) tail-slice ; inline
1075
1076 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1077     (trim-head) tail ; inline
1078
1079 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1080     (trim-tail) head-slice ; inline
1081
1082 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1083     (trim-tail) head ; inline
1084
1085 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1086     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1087
1088 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1089     [ trim-slice ] [ drop ] 2bi like ; inline
1090
1091 GENERIC: sum ( seq -- n )
1092 M: object sum 0 [ + ] binary-reduce ; inline
1093 M: iota sum length dup 1 - * 2/ ; inline
1094 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1095
1096 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1097
1098 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1099
1100 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1101
1102 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1103     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1104
1105 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1106     [ 1 0 ? ] compose map-sum ; inline
1107
1108 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1109     [ with each ] 2curry each ; inline
1110
1111 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1112     [ with { } map-as ] 2curry { } map-as ; inline
1113
1114 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1115     [ 2sequence ] curry cartesian-map ; inline
1116
1117 : cartesian-product ( seq1 seq2 -- newseq )
1118     dup cartesian-product-as ; inline
1119
1120 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1121     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1122
1123 <PRIVATE
1124
1125 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1126     [
1127         [ keep swap ] curry [ [ first ] dip call ] 2keep
1128         [ curry 2dip pick over ] curry
1129     ] [
1130         [ [ 2drop ] [ 2nipd ] if ] compose
1131     ] bi* compose 1 each-from drop ; inline
1132
1133 PRIVATE>
1134
1135 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1136     [ after? ] select-by ; inline
1137
1138 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1139     [ before? ] select-by ; inline
1140
1141 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1142
1143 : longest ( seqs -- elt ) [ length ] supremum-by ;
1144
1145 ! We hand-optimize flip to such a degree because type hints
1146 ! cannot express that an array is an array of arrays yet, and
1147 ! this word happens to be performance-critical since the compiler
1148 ! itself uses it. Optimizing it like this reduced compile time.
1149 <PRIVATE
1150
1151 : generic-flip ( matrix -- newmatrix )
1152     [ [ length ] [ min ] map-reduce ] keep
1153     '[ _ [ nth-unsafe ] with { } map-as ] { } map-integers ; inline
1154
1155 USE: arrays
1156
1157 : array-flip ( matrix -- newmatrix )
1158     { array } declare
1159     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1160     '[ _ [ { array } declare array-nth ] with { } map-as ] { } map-integers ;
1161
1162 PRIVATE>
1163
1164 : flip ( matrix -- newmatrix )
1165     dup empty? [
1166         dup array? [
1167             dup [ array? ] all?
1168             [ array-flip ] [ generic-flip ] if
1169         ] [ generic-flip ] if
1170     ] unless ;